| 1 |
use Coro; |
| 2 |
use Coro::Semaphore; |
| 3 |
use Coro::Event; |
| 4 |
use Coro::Socket; |
| 5 |
|
| 6 |
use HTTP::Date; |
| 7 |
|
| 8 |
no utf8; |
| 9 |
use bytes; |
| 10 |
|
| 11 |
# at least on my machine, this thingy serves files |
| 12 |
# quite a bit faster than apache, ;) |
| 13 |
# and quite a bit slower than thttpd :( |
| 14 |
|
| 15 |
$SIG{PIPE} = 'IGNORE'; |
| 16 |
|
| 17 |
our $accesslog; |
| 18 |
|
| 19 |
if ($ACCESS_LOG) { |
| 20 |
use IO::Handle; |
| 21 |
open $accesslog, ">>$ACCESS_LOG" |
| 22 |
or die "$ACCESS_LOG: $!"; |
| 23 |
$accesslog->autoflush(1); |
| 24 |
} |
| 25 |
|
| 26 |
sub slog { |
| 27 |
my $level = shift; |
| 28 |
my $format = shift; |
| 29 |
printf "---: $format\n", @_; |
| 30 |
} |
| 31 |
|
| 32 |
our $connections = new Coro::Semaphore $MAX_CONNECTS || 250; |
| 33 |
|
| 34 |
our $wait_factor = 0.95; |
| 35 |
|
| 36 |
our @transfers = ( |
| 37 |
[(new Coro::Semaphore $MAX_TRANSFERS_SMALL || 50), 1], |
| 38 |
[(new Coro::Semaphore $MAX_TRANSFERS_LARGE || 50), 1], |
| 39 |
); |
| 40 |
|
| 41 |
my @newcons; |
| 42 |
my @pool; |
| 43 |
|
| 44 |
# one "execution thread" |
| 45 |
sub handler { |
| 46 |
while () { |
| 47 |
if (@newcons) { |
| 48 |
eval { |
| 49 |
conn->new(@{pop @newcons})->handle; |
| 50 |
}; |
| 51 |
slog 1, "$@" if $@ && !ref $@; |
| 52 |
$connections->up; |
| 53 |
} else { |
| 54 |
last if @pool >= $MAX_POOL; |
| 55 |
push @pool, $Coro::current; |
| 56 |
schedule; |
| 57 |
} |
| 58 |
} |
| 59 |
} |
| 60 |
|
| 61 |
sub listen_on { |
| 62 |
my $listen = $_[0]; |
| 63 |
|
| 64 |
push @listen_sockets, $listen; |
| 65 |
|
| 66 |
# the "main thread" |
| 67 |
async { |
| 68 |
slog 1, "accepting connections"; |
| 69 |
while () { |
| 70 |
$connections->down; |
| 71 |
push @newcons, [$listen->accept]; |
| 72 |
#slog 3, "accepted @$connections ".scalar(@pool); |
| 73 |
if (@pool) { |
| 74 |
(pop @pool)->ready; |
| 75 |
} else { |
| 76 |
async \&handler; |
| 77 |
} |
| 78 |
|
| 79 |
} |
| 80 |
}; |
| 81 |
} |
| 82 |
|
| 83 |
my $http_port = new Coro::Socket |
| 84 |
LocalAddr => $SERVER_HOST, |
| 85 |
LocalPort => $SERVER_PORT, |
| 86 |
ReuseAddr => 1, |
| 87 |
Listen => 50, |
| 88 |
or die "unable to start server"; |
| 89 |
|
| 90 |
listen_on $http_port; |
| 91 |
|
| 92 |
my $http_port = new Coro::Socket |
| 93 |
LocalAddr => $SERVER_HOST, |
| 94 |
LocalPort => $SERVER_PORT2, |
| 95 |
ReuseAddr => 1, |
| 96 |
Listen => 50, |
| 97 |
or die "unable to start server"; |
| 98 |
|
| 99 |
listen_on $http_port; |
| 100 |
|
| 101 |
our $NOW; |
| 102 |
our $HTTP_NOW; |
| 103 |
|
| 104 |
Event->timer(interval => 1, hard => 1, cb => sub { |
| 105 |
$NOW = time; |
| 106 |
$HTTP_NOW = time2str $NOW; |
| 107 |
})->now; |
| 108 |
|
| 109 |
package conn; |
| 110 |
|
| 111 |
use Socket; |
| 112 |
use HTTP::Date; |
| 113 |
use Convert::Scalar 'weaken'; |
| 114 |
use Linux::AIO; |
| 115 |
|
| 116 |
Linux::AIO::min_parallel $::AIO_PARALLEL; |
| 117 |
|
| 118 |
Event->io(fd => Linux::AIO::poll_fileno, |
| 119 |
poll => 'r', async => 1, |
| 120 |
cb => \&Linux::AIO::poll_cb); |
| 121 |
|
| 122 |
our %conn; # $conn{ip}{self} => connobj |
| 123 |
our %uri; # $uri{ip}{uri}{self} |
| 124 |
our %blocked; |
| 125 |
our %mimetype; |
| 126 |
|
| 127 |
sub read_mimetypes { |
| 128 |
local *M; |
| 129 |
if (open M, "<mime_types") { |
| 130 |
while (<M>) { |
| 131 |
if (/^([^#]\S+)\t+(\S+)$/) { |
| 132 |
$mimetype{lc $1} = $2; |
| 133 |
} |
| 134 |
} |
| 135 |
} else { |
| 136 |
print "cannot open mime_types\n"; |
| 137 |
} |
| 138 |
} |
| 139 |
|
| 140 |
read_mimetypes; |
| 141 |
|
| 142 |
sub new { |
| 143 |
my $class = shift; |
| 144 |
my $peername = shift; |
| 145 |
my $fh = shift; |
| 146 |
my $self = bless { fh => $fh }, $class; |
| 147 |
my (undef, $iaddr) = unpack_sockaddr_in $peername |
| 148 |
or $self->err(500, "unable to decode peername"); |
| 149 |
|
| 150 |
$self->{remote_addr} = inet_ntoa $iaddr; |
| 151 |
$self->{time} = $::NOW; |
| 152 |
|
| 153 |
$::conns++; |
| 154 |
|
| 155 |
$self; |
| 156 |
} |
| 157 |
|
| 158 |
sub DESTROY { |
| 159 |
my $self = shift; |
| 160 |
$::conns--; |
| 161 |
$self->eoconn; |
| 162 |
} |
| 163 |
|
| 164 |
# end of connection |
| 165 |
sub eoconn { |
| 166 |
my $self = shift; |
| 167 |
|
| 168 |
# clean up hints |
| 169 |
delete $conn{$self->{remote_id}}{$self*1}; |
| 170 |
delete $uri{$self->{remote_id}}{$self->{uri}}{$self*1}; |
| 171 |
} |
| 172 |
|
| 173 |
sub slog { |
| 174 |
my $self = shift; |
| 175 |
main::slog($_[0], ($self->{remote_id} || $self->{remote_addr}) ."> $_[1]"); |
| 176 |
} |
| 177 |
|
| 178 |
sub response { |
| 179 |
my ($self, $code, $msg, $hdr, $content) = @_; |
| 180 |
my $res = "HTTP/1.1 $code $msg\015\012"; |
| 181 |
|
| 182 |
$self->{h}{connection} ||= $hdr->{Connection}; |
| 183 |
|
| 184 |
$res .= "Date: $HTTP_NOW\015\012"; |
| 185 |
|
| 186 |
while (my ($h, $v) = each %$hdr) { |
| 187 |
$res .= "$h: $v\015\012" |
| 188 |
} |
| 189 |
$res .= "\015\012"; |
| 190 |
|
| 191 |
$res .= $content if defined $content and $self->{method} ne "HEAD"; |
| 192 |
|
| 193 |
my $log = "$self->{remote_addr} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}." \"$self->{h}{referer}\"\n"; |
| 194 |
|
| 195 |
print $accesslog $log if $accesslog; |
| 196 |
print STDERR $log; |
| 197 |
|
| 198 |
$self->{written} += |
| 199 |
print {$self->{fh}} $res; |
| 200 |
} |
| 201 |
|
| 202 |
sub err { |
| 203 |
my $self = shift; |
| 204 |
my ($code, $msg, $hdr, $content) = @_; |
| 205 |
|
| 206 |
unless (defined $content) { |
| 207 |
$content = "$code $msg\n"; |
| 208 |
$hdr->{"Content-Type"} = "text/plain"; |
| 209 |
$hdr->{"Content-Length"} = length $content; |
| 210 |
} |
| 211 |
$hdr->{"Connection"} = "close"; |
| 212 |
|
| 213 |
$self->response($code, $msg, $hdr, $content); |
| 214 |
|
| 215 |
die bless {}, err::; |
| 216 |
} |
| 217 |
|
| 218 |
sub handle { |
| 219 |
my $self = shift; |
| 220 |
my $fh = $self->{fh}; |
| 221 |
|
| 222 |
my $host; |
| 223 |
|
| 224 |
$fh->timeout($::REQ_TIMEOUT); |
| 225 |
while() { |
| 226 |
$self->{reqs}++; |
| 227 |
|
| 228 |
# read request and parse first line |
| 229 |
my $req = $fh->readline("\015\012\015\012"); |
| 230 |
|
| 231 |
unless (defined $req) { |
| 232 |
if (exists $self->{version}) { |
| 233 |
last; |
| 234 |
} else { |
| 235 |
$self->err(408, "request timeout"); |
| 236 |
} |
| 237 |
} |
| 238 |
|
| 239 |
$self->{h} = {}; |
| 240 |
|
| 241 |
$fh->timeout($::RES_TIMEOUT); |
| 242 |
|
| 243 |
$req =~ /^(?:\015\012)? |
| 244 |
(GET|HEAD) \040+ |
| 245 |
([^\040]+) \040+ |
| 246 |
HTTP\/([0-9]+\.[0-9]+) |
| 247 |
\015\012/gx |
| 248 |
or $self->err(405, "method not allowed", { Allow => "GET,HEAD" }); |
| 249 |
|
| 250 |
$self->{method} = $1; |
| 251 |
$self->{uri} = $2; |
| 252 |
$self->{version} = $3; |
| 253 |
|
| 254 |
$3 =~ /^1\./ |
| 255 |
or $self->err(506, "http protocol version $3 not supported"); |
| 256 |
|
| 257 |
# parse headers |
| 258 |
{ |
| 259 |
my (%hdr, $h, $v); |
| 260 |
|
| 261 |
$hdr{lc $1} .= ",$2" |
| 262 |
while $req =~ /\G |
| 263 |
([^:\000-\040]+): |
| 264 |
[\008\040]* |
| 265 |
((?: [^\015\012]+ | \015\012[\008\040] )*) |
| 266 |
\015\012 |
| 267 |
/gxc; |
| 268 |
|
| 269 |
$req =~ /\G\015\012$/ |
| 270 |
or $self->err(400, "bad request"); |
| 271 |
|
| 272 |
$self->{h}{$h} = substr $v, 1 |
| 273 |
while ($h, $v) = each %hdr; |
| 274 |
} |
| 275 |
|
| 276 |
# remote id should be unique per user |
| 277 |
my $id = $self->{remote_addr}; |
| 278 |
|
| 279 |
if (exists $self->{h}{"client-ip"}) { |
| 280 |
$id .= "[".$self->{h}{"client-ip"}."]"; |
| 281 |
} elsif (exists $self->{h}{"x-forwarded-for"}) { |
| 282 |
$id .= "[".$self->{h}{"x-forwarded-for"}."]"; |
| 283 |
} |
| 284 |
|
| 285 |
$self->{remote_id} = $id; |
| 286 |
|
| 287 |
if ($blocked{$id}) { |
| 288 |
$self->err_blocked($blocked{$id}) |
| 289 |
if $blocked{$id} > $::NOW; |
| 290 |
|
| 291 |
delete $blocked{$id}; |
| 292 |
} |
| 293 |
|
| 294 |
if (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 295 |
my $delay = $::PER_TIMEOUT + 15; |
| 296 |
while (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 297 |
if ($delay <= 0) { |
| 298 |
$self->slog(2, "blocked ip $id"); |
| 299 |
$self->err_blocked; |
| 300 |
} else { |
| 301 |
Coro::Event::do_timer(after => 4); $delay -= 4; |
| 302 |
} |
| 303 |
} |
| 304 |
} |
| 305 |
|
| 306 |
# find out server name and port |
| 307 |
if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) { |
| 308 |
$host = $1; |
| 309 |
} else { |
| 310 |
$host = $self->{h}{host}; |
| 311 |
} |
| 312 |
|
| 313 |
if (defined $host) { |
| 314 |
$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80; |
| 315 |
} else { |
| 316 |
($self->{server_port}, $host) |
| 317 |
= unpack_sockaddr_in $self->{fh}->getsockname |
| 318 |
or $self->err(500, "unable to get socket name"); |
| 319 |
$host = inet_ntoa $host; |
| 320 |
} |
| 321 |
|
| 322 |
$self->{server_name} = $host; |
| 323 |
|
| 324 |
# enter ourselves into various lists |
| 325 |
weaken ($conn{$id}{$self*1} = $self); |
| 326 |
weaken ($uri{$id}{$self->{uri}}{$self*1} = $self); |
| 327 |
|
| 328 |
eval { |
| 329 |
$self->map_uri; |
| 330 |
$self->respond; |
| 331 |
}; |
| 332 |
|
| 333 |
$self->eoconn; |
| 334 |
|
| 335 |
die if $@ && !ref $@; |
| 336 |
|
| 337 |
last if $self->{h}{connection} =~ /close/ || $self->{version} < 1.1; |
| 338 |
|
| 339 |
$fh->timeout($::PER_TIMEOUT); |
| 340 |
} |
| 341 |
} |
| 342 |
|
| 343 |
# uri => path mapping |
| 344 |
sub map_uri { |
| 345 |
my $self = shift; |
| 346 |
my $host = $self->{server_name}; |
| 347 |
my $uri = $self->{uri}; |
| 348 |
|
| 349 |
# some massaging, also makes it more secure |
| 350 |
$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge; |
| 351 |
$uri =~ s%//+%/%g; |
| 352 |
$uri =~ s%/\.(?=/|$)%%g; |
| 353 |
1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%; |
| 354 |
|
| 355 |
$uri =~ m%^/?\.\.(?=/|$)% |
| 356 |
and $self->err(400, "bad request"); |
| 357 |
|
| 358 |
$self->{name} = $uri; |
| 359 |
|
| 360 |
# now do the path mapping |
| 361 |
$self->{path} = "$::DOCROOT/$host$uri"; |
| 362 |
|
| 363 |
$self->access_check; |
| 364 |
} |
| 365 |
|
| 366 |
sub _cgi { |
| 367 |
my $self = shift; |
| 368 |
my $path = shift; |
| 369 |
my $fh; |
| 370 |
|
| 371 |
# no two-way xxx supported |
| 372 |
if (0 == fork) { |
| 373 |
open STDOUT, ">&".fileno($self->{fh}); |
| 374 |
if (chdir $::DOCROOT) { |
| 375 |
$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike |
| 376 |
$ENV{HTTP_HOST} = $self->{server_name}; |
| 377 |
$ENV{HTTP_PORT} = $self->{server_port}; |
| 378 |
$ENV{SCRIPT_NAME} = $self->{name}; |
| 379 |
exec $path; |
| 380 |
} |
| 381 |
Coro::State::_exit(0); |
| 382 |
} else { |
| 383 |
die; |
| 384 |
} |
| 385 |
} |
| 386 |
|
| 387 |
sub server_hostport { |
| 388 |
$_[0]{server_port} == 80 |
| 389 |
? $_[0]{server_name} |
| 390 |
: "$_[0]{server_name}:$_[0]{server_port}"; |
| 391 |
} |
| 392 |
|
| 393 |
sub respond { |
| 394 |
my $self = shift; |
| 395 |
my $path = $self->{path}; |
| 396 |
|
| 397 |
stat $path |
| 398 |
or $self->err(404, "not found"); |
| 399 |
|
| 400 |
$self->{stat} = [stat _]; |
| 401 |
|
| 402 |
# idiotic netscape sends idiotic headers AGAIN |
| 403 |
my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/ |
| 404 |
? str2time $1 : 0; |
| 405 |
|
| 406 |
if (-d _ && -r _) { |
| 407 |
# directory |
| 408 |
if ($path !~ /\/$/) { |
| 409 |
# create a redirect to get the trailing "/" |
| 410 |
# we don't try to avoid the :80 |
| 411 |
$self->err(301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" }); |
| 412 |
} else { |
| 413 |
$ims < $self->{stat}[9] |
| 414 |
or $self->err(304, "not modified"); |
| 415 |
|
| 416 |
if (-r "$path/index.html") { |
| 417 |
$self->{path} .= "/index.html"; |
| 418 |
$self->handle_file; |
| 419 |
} else { |
| 420 |
$self->handle_dir; |
| 421 |
} |
| 422 |
} |
| 423 |
} elsif (-f _ && -r _) { |
| 424 |
-x _ and $self->err(403, "forbidden"); |
| 425 |
$self->handle_file; |
| 426 |
} else { |
| 427 |
$self->err(404, "not found"); |
| 428 |
} |
| 429 |
} |
| 430 |
|
| 431 |
sub handle_dir { |
| 432 |
my $self = shift; |
| 433 |
my $idx = $self->diridx; |
| 434 |
|
| 435 |
$self->response(200, "ok", |
| 436 |
{ |
| 437 |
"Content-Type" => "text/html", |
| 438 |
"Content-Length" => length $idx, |
| 439 |
}, |
| 440 |
$idx); |
| 441 |
} |
| 442 |
|
| 443 |
sub handle_file { |
| 444 |
my $self = shift; |
| 445 |
my $length = $self->{stat}[7]; |
| 446 |
my $queue = $::transfers[$length >= $::TRANSFER_SMALL]; |
| 447 |
my $hdr = { |
| 448 |
"Last-Modified" => time2str ((stat _)[9]), |
| 449 |
}; |
| 450 |
|
| 451 |
my @code = (200, "ok"); |
| 452 |
my ($l, $h); |
| 453 |
|
| 454 |
if ($self->{h}{range} =~ /^bytes=(.*)$/) { |
| 455 |
for (split /,/, $1) { |
| 456 |
if (/^-(\d+)$/) { |
| 457 |
($l, $h) = ($length - $1, $length - 1); |
| 458 |
} elsif (/^(\d+)-(\d*)$/) { |
| 459 |
($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1); |
| 460 |
} else { |
| 461 |
($l, $h) = (0, $length - 1); |
| 462 |
goto ignore; |
| 463 |
} |
| 464 |
goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l; |
| 465 |
} |
| 466 |
$hdr->{"Content-Range"} = "bytes */$length"; |
| 467 |
$hdr->{"Content-Length"} = $length; |
| 468 |
$self->err(416, "not satisfiable", $hdr, ""); |
| 469 |
|
| 470 |
satisfiable: |
| 471 |
# check for segmented downloads |
| 472 |
if ($l && $::NO_SEGMENTED) { |
| 473 |
my $delay = $::PER_TIMEOUT + 15; |
| 474 |
while (%{$uri{$self->{remote_id}}{$self->{uri}}} > 1) { |
| 475 |
if ($delay <= 0) { |
| 476 |
$self->err_segmented_download; |
| 477 |
} else { |
| 478 |
Coro::Event::do_timer(after => 4); $delay -= 4; |
| 479 |
} |
| 480 |
} |
| 481 |
} |
| 482 |
|
| 483 |
$hdr->{"Content-Range"} = "bytes $l-$h/$length"; |
| 484 |
@code = (206, "partial content"); |
| 485 |
$length = $h - $l + 1; |
| 486 |
|
| 487 |
ignore: |
| 488 |
} else { |
| 489 |
($l, $h) = (0, $length - 1); |
| 490 |
} |
| 491 |
|
| 492 |
$self->{path} =~ /\.([^.]+)$/; |
| 493 |
$hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream"; |
| 494 |
$hdr->{"Content-Length"} = $length; |
| 495 |
|
| 496 |
$self->response(@code, $hdr, ""); |
| 497 |
|
| 498 |
if ($self->{method} eq "GET") { |
| 499 |
$self->{time} = $::NOW; |
| 500 |
|
| 501 |
my $fudge = $queue->[0]->waiters; |
| 502 |
$fudge = $fudge ? ($fudge+1)/$fudge : 1; |
| 503 |
|
| 504 |
$queue->[1] *= $fudge; |
| 505 |
my $transfer = $queue->[0]->guard; |
| 506 |
|
| 507 |
if ($fudge != 1) { |
| 508 |
$queue->[1] /= $fudge; |
| 509 |
$queue->[1] = $queue->[1] * $::wait_factor |
| 510 |
+ ($::NOW - $self->{time}) * (1 - $::wait_factor); |
| 511 |
} |
| 512 |
$self->{time} = $::NOW; |
| 513 |
|
| 514 |
$self->{fh}->writable or return; |
| 515 |
|
| 516 |
my ($fh, $buf, $r); |
| 517 |
my $current = $Coro::current; |
| 518 |
open $fh, "<", $self->{path} |
| 519 |
or die "$self->{path}: late open failure ($!)"; |
| 520 |
|
| 521 |
$h -= $l - 1; |
| 522 |
|
| 523 |
if (0) { |
| 524 |
if ($l) { |
| 525 |
sysseek $fh, $l, 0; |
| 526 |
} |
| 527 |
} |
| 528 |
|
| 529 |
while ($h > 0) { |
| 530 |
if (0) { |
| 531 |
sysread $fh, $buf, $h > $::BUFSIZE ? $::BUFSIZE : $h |
| 532 |
or last; |
| 533 |
} else { |
| 534 |
aio_read($fh, $l, ($h > $::BUFSIZE ? $::BUFSIZE : $h), |
| 535 |
$buf, 0, sub { |
| 536 |
$r = $_[0]; |
| 537 |
Coro::ready($current); |
| 538 |
}); |
| 539 |
&Coro::schedule; |
| 540 |
last unless $r; |
| 541 |
} |
| 542 |
my $w = syswrite $self->{fh}, $buf |
| 543 |
or last; |
| 544 |
$::written += $w; |
| 545 |
$self->{written} += $w; |
| 546 |
$l += $r; |
| 547 |
} |
| 548 |
|
| 549 |
close $fh; |
| 550 |
} |
| 551 |
} |
| 552 |
|
| 553 |
1; |
