Devel-FindRef/FindRef.pm

package Devel::FindRef;

use strict;

use XSLoader;
use Scalar::Util;

BEGIN {
   our $VERSION = '1.2';
   XSLoader::load __PACKAGE__, $VERSION;
}

=head1 NAME

Devel::FindRef - where is that reference to my scalar hiding?

=head1 SYNOPSIS

  use Devel::FindRef;

=head1 DESCRIPTION

Tracking down reference problems (e.g. you expect some object to be
destroyed, but there are still references to it that keep it alive) can be
very hard. Fortunately, perl keeps track of all its values, so tracking
references "backwards" is usually possible.

The C<track> function can help track down some of those references back to
the variables containing them.

For example, for this fragment:

   package Test;           
                         
   our $var = "hi\n";
   my $x = \$var;      
   our %hash = (ukukey => \$var);
   our $hash2 = {ukukey2 => \$var};
                           
   sub testsub {             
      my $local = $hash2;      
      print Devel::FindRef::track \$var;
   }                             
                                   
   testsub;                        

The output is as follows (or similar to this, in case I forget to update
the manpage after some changes):

   SCALAR(0x7bd2d0) is
      in the global $Test::var.
      referenced by REF(0x7bd240), which is
         in the member 'ukukey2' of HASH(0x7bd228), which is
            referenced by REF(0x81dae8), which is
               in the lexical '$local' in CODE(0x81da88), which is
                  in the global &Test::testsub.
            referenced by REF(0x81da40), which is
               in the global $Test::hash2.
      referenced by REF(0x79f3f8), which is
         in the lexical '$x' in CODE(0x79f518), which is
            the containing scope for CODE(0x81da88), which is
               in the global &Test::testsub.
      referenced by REF(0x79f2f0), which is
         not found anywhere I looked :(
      referenced by REF(0x79f140), which is
         in the member 'ukukey' of HASH(0x81d698), which is
            in the global %Test::hash.

It is a bit convoluted to read, but basically it says that the value
stored in C<$var> can be found:

=over 4

=item - in some variable C<$x> whose origin is not known (I frankly have no
idea why, hints accepted).

=item - in the hash element with key C<ukukey> in the hash stored in C<%Test::hash>.

=item - in the global variable named C<$Test::var>.

=item - in the hash element C<ukukey2>, in the hash in the my variable
C<$local> in the sub C<Test::testsub> and also in the hash referenced by
C<$Test::hash2>.

=back

=head1 EXPORTS

None.

=head1 FUNCTIONS

=over 4

=item $string = Devel::FindRef::track $ref[, $depth]

Track the perl value pointed to by C<$ref> up to a depth of C<$depth> and
return a descriptive string. C<$ref> can point at any perl value, be it
anonymous sub, hash, array, scalar etc.

This is the function you most often use.

=cut

sub find($);

sub track {
   my ($ref, $depth) = @_;
   @_ = ();

   my $buf = "";
   my %seen;

   Scalar::Util::weaken $ref;

   my $track; $track = sub {
      my ($refref, $depth, $indent) = @_;

      if ($depth) {
         my (@about) = find $$refref;
         if (@about) {
            for my $about (@about) {
               $buf .= ("   ") x $indent;
               $buf .= $about->[0];
               if (@$about > 1) {
                  if ($seen{$about->[1]+0}++) {
                     $buf .= " $about->[1], which was seen before.\n";
                  } else {
                     $buf .= " $about->[1], which is\n";
                     $track->(\$about->[1], $depth - 1, $indent + 1);
                  }
               } else {
                  $buf .= ".\n";
               }
            }
         } else {
            $buf .= ("   ") x $indent;
            $buf .= "not found anywhere I looked :(\n";
         }
      } else {
         $buf .= ("   ") x $indent;
         $buf .= "not referenced within the search depth.\n";
      }
   };

   $buf .= "$ref is\n";
   $track->(\$ref, $depth || 10, 1);
   $buf
}

=item @references = Devel::FindRef::find $ref

Return arrayrefs that contain [$message, $ref] pairs. The message
describes what kind of reference was found and the C<$ref> is the
reference itself, which can be omitted if C<find> decided to end the
search. The returned references are all weak references.

The C<track> function uses this to find references to the value you are
interested in and recurses on the returned references.

=cut

sub find($) {
   my ($about, $excl) = &find_;
   my %excl = map +($_ => undef), @$excl;
   grep !exists $excl{$_->[1] + 0}, @$about
}

=item $ref = Devel::FindRef::ptr2ref $integer

Sometimes you know (from debugging output) the address of a perl scalar
you are interested in (e.g. C<HASH(0x176ff70)>). This function can be used
to turn the address into a reference to that scalar. It is quite safe to
call on valid addresses, but extremely dangerous to call on invalid ones.

   # we know that HASH(0x176ff70) exists, so turn it into a hashref:
   my $ref_to_hash = Devel::FindRef::ptr2ref 0x176ff70;

=back

=head1 AUTHOR

Marc Lehmann <pcg@goof.com>.

=head1 BUGS

Only code values, arrays, hashes, scalars and magic are being looked at.

This is a quick hack only.

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2007 by Marc Lehmann.

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself, either Perl version 5.8.8 or,
at your option, any later version of Perl 5 you may have available.

=cut

1

Revision:	1.11
Committed:	Fri Jul 11 17:59:19 2008 UTC (15 years, 10 months ago) by root
Branch:	MAIN
Changes since 1.10:	+7 -2 lines
Log Message:	* empty log message *
#	Content
1	package Devel::FindRef;
2
3	use strict;
4
5	use XSLoader;
6	use Scalar::Util;
7
8	BEGIN {
9	our $VERSION = '1.2';
10	XSLoader::load __PACKAGE__, $VERSION;
11	}
12
13	=head1 NAME
14
15	Devel::FindRef - where is that reference to my scalar hiding?
16
17	=head1 SYNOPSIS
18
19	use Devel::FindRef;
20
21	=head1 DESCRIPTION
22
23	Tracking down reference problems (e.g. you expect some object to be
24	destroyed, but there are still references to it that keep it alive) can be
25	very hard. Fortunately, perl keeps track of all its values, so tracking
26	references "backwards" is usually possible.
27
28	The C<track> function can help track down some of those references back to
29	the variables containing them.
30
31	For example, for this fragment:
32
33	package Test;
34
35	our $var = "hi\n";
36	my $x = \$var;
37	our %hash = (ukukey => \$var);
38	our $hash2 = {ukukey2 => \$var};
39
40	sub testsub {
41	my $local = $hash2;
42	print Devel::FindRef::track \$var;
43	}
44
45	testsub;
46
47	The output is as follows (or similar to this, in case I forget to update
48	the manpage after some changes):
49
50	SCALAR(0x7bd2d0) is
51	in the global $Test::var.
52	referenced by REF(0x7bd240), which is
53	in the member 'ukukey2' of HASH(0x7bd228), which is
54	referenced by REF(0x81dae8), which is
55	in the lexical '$local' in CODE(0x81da88), which is
56	in the global &Test::testsub.
57	referenced by REF(0x81da40), which is
58	in the global $Test::hash2.
59	referenced by REF(0x79f3f8), which is
60	in the lexical '$x' in CODE(0x79f518), which is
61	the containing scope for CODE(0x81da88), which is
62	in the global &Test::testsub.
63	referenced by REF(0x79f2f0), which is
64	not found anywhere I looked :(
65	referenced by REF(0x79f140), which is
66	in the member 'ukukey' of HASH(0x81d698), which is
67	in the global %Test::hash.
68
69	It is a bit convoluted to read, but basically it says that the value
70	stored in C<$var> can be found:
71
72	=over 4
73
74	=item - in some variable C<$x> whose origin is not known (I frankly have no
75	idea why, hints accepted).
76
77	=item - in the hash element with key C<ukukey> in the hash stored in C<%Test::hash>.
78
79	=item - in the global variable named C<$Test::var>.
80
81	=item - in the hash element C<ukukey2>, in the hash in the my variable
82	C<$local> in the sub C<Test::testsub> and also in the hash referenced by
83	C<$Test::hash2>.
84
85	=back
86
87	=head1 EXPORTS
88
89	None.
90
91	=head1 FUNCTIONS
92
93	=over 4
94
95	=item $string = Devel::FindRef::track $ref[, $depth]
96
97	Track the perl value pointed to by C<$ref> up to a depth of C<$depth> and
98	return a descriptive string. C<$ref> can point at any perl value, be it
99	anonymous sub, hash, array, scalar etc.
100
101	This is the function you most often use.
102
103	=cut
104
105	sub find($);
106
107	sub track {
108	my ($ref, $depth) = @_;
109	@_ = ();
110
111	my $buf = "";
112	my %seen;
113
114	Scalar::Util::weaken $ref;
115
116	my $track; $track = sub {
117	my ($refref, $depth, $indent) = @_;
118
119	if ($depth) {
120	my (@about) = find $$refref;
121	if (@about) {
122	for my $about (@about) {
123	$buf .= (" ") x $indent;
124	$buf .= $about->[0];
125	if (@$about > 1) {
126	if ($seen{$about->[1]+0}++) {
127	$buf .= " $about->[1], which was seen before.\n";
128	} else {
129	$buf .= " $about->[1], which is\n";
130	$track->(\$about->[1], $depth - 1, $indent + 1);
131	}
132	} else {
133	$buf .= ".\n";
134	}
135	}
136	} else {
137	$buf .= (" ") x $indent;
138	$buf .= "not found anywhere I looked :(\n";
139	}
140	} else {
141	$buf .= (" ") x $indent;
142	$buf .= "not referenced within the search depth.\n";
143	}
144	};
145
146	$buf .= "$ref is\n";
147	$track->(\$ref, $depth \|\| 10, 1);
148	$buf
149	}
150
151	=item @references = Devel::FindRef::find $ref
152
153	Return arrayrefs that contain [$message, $ref] pairs. The message
154	describes what kind of reference was found and the C<$ref> is the
155	reference itself, which can be omitted if C<find> decided to end the
156	search. The returned references are all weak references.
157
158	The C<track> function uses this to find references to the value you are
159	interested in and recurses on the returned references.
160
161	=cut
162
163	sub find($) {
164	my ($about, $excl) = &find_;
165	my %excl = map +($_ => undef), @$excl;
166	grep !exists $excl{$_->[1] + 0}, @$about
167	}
168
169	=item $ref = Devel::FindRef::ptr2ref $integer
170
171	Sometimes you know (from debugging output) the address of a perl scalar
172	you are interested in (e.g. C<HASH(0x176ff70)>). This function can be used
173	to turn the address into a reference to that scalar. It is quite safe to
174	call on valid addresses, but extremely dangerous to call on invalid ones.
175
176	# we know that HASH(0x176ff70) exists, so turn it into a hashref:
177	my $ref_to_hash = Devel::FindRef::ptr2ref 0x176ff70;
178
179	=back
180
181	=head1 AUTHOR
182
183	Marc Lehmann <pcg@goof.com>.
184
185	=head1 BUGS
186
187	Only code values, arrays, hashes, scalars and magic are being looked at.
188
189	This is a quick hack only.
190
191	=head1 COPYRIGHT AND LICENSE
192
193	Copyright (C) 2007 by Marc Lehmann.
194
195	This library is free software; you can redistribute it and/or modify
196	it under the same terms as Perl itself, either Perl version 5.8.8 or,
197	at your option, any later version of Perl 5 you may have available.
198
199	=cut
200
201	1
202