1 |
=head1 NAME |
2 |
|
3 |
IO::AIO - Asynchronous Input/Output |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use IO::AIO; |
8 |
|
9 |
aio_open "/etc/passwd", O_RDONLY, 0, sub { |
10 |
my ($fh) = @_; |
11 |
... |
12 |
}; |
13 |
|
14 |
aio_unlink "/tmp/file", sub { }; |
15 |
|
16 |
aio_read $fh, 30000, 1024, $buffer, 0, sub { |
17 |
$_[0] > 0 or die "read error: $!"; |
18 |
}; |
19 |
|
20 |
# version 2+ has request and group objects |
21 |
use IO::AIO 2; |
22 |
|
23 |
aioreq_pri 4; # give next request a very high priority |
24 |
my $req = aio_unlink "/tmp/file", sub { }; |
25 |
$req->cancel; # cancel request if still in queue |
26 |
|
27 |
my $grp = aio_group sub { print "all stats done\n" }; |
28 |
add $grp aio_stat "..." for ...; |
29 |
|
30 |
# AnyEvent integration |
31 |
open my $fh, "<&=" . IO::AIO::poll_fileno or die "$!"; |
32 |
my $w = AnyEvent->io (fh => $fh, poll => 'r', cb => sub { IO::AIO::poll_cb }); |
33 |
|
34 |
# Event integration |
35 |
Event->io (fd => IO::AIO::poll_fileno, |
36 |
poll => 'r', |
37 |
cb => \&IO::AIO::poll_cb); |
38 |
|
39 |
# Glib/Gtk2 integration |
40 |
add_watch Glib::IO IO::AIO::poll_fileno, |
41 |
in => sub { IO::AIO::poll_cb; 1 }; |
42 |
|
43 |
# Tk integration |
44 |
Tk::Event::IO->fileevent (IO::AIO::poll_fileno, "", |
45 |
readable => \&IO::AIO::poll_cb); |
46 |
|
47 |
# Danga::Socket integration |
48 |
Danga::Socket->AddOtherFds (IO::AIO::poll_fileno => |
49 |
\&IO::AIO::poll_cb); |
50 |
|
51 |
=head1 DESCRIPTION |
52 |
|
53 |
This module implements asynchronous I/O using whatever means your |
54 |
operating system supports. |
55 |
|
56 |
Asynchronous means that operations that can normally block your program |
57 |
(e.g. reading from disk) will be done asynchronously: the operation |
58 |
will still block, but you can do something else in the meantime. This |
59 |
is extremely useful for programs that need to stay interactive even |
60 |
when doing heavy I/O (GUI programs, high performance network servers |
61 |
etc.), but can also be used to easily do operations in parallel that are |
62 |
normally done sequentially, e.g. stat'ing many files, which is much faster |
63 |
on a RAID volume or over NFS when you do a number of stat operations |
64 |
concurrently. |
65 |
|
66 |
While this works on all types of file descriptors (for example sockets), |
67 |
using these functions on file descriptors that support nonblocking |
68 |
operation (again, sockets, pipes etc.) is very inefficient. Use an event |
69 |
loop for that (such as the L<Event|Event> module): IO::AIO will naturally |
70 |
fit into such an event loop itself. |
71 |
|
72 |
In this version, a number of threads are started that execute your |
73 |
requests and signal their completion. You don't need thread support |
74 |
in perl, and the threads created by this module will not be visible |
75 |
to perl. In the future, this module might make use of the native aio |
76 |
functions available on many operating systems. However, they are often |
77 |
not well-supported or restricted (GNU/Linux doesn't allow them on normal |
78 |
files currently, for example), and they would only support aio_read and |
79 |
aio_write, so the remaining functionality would have to be implemented |
80 |
using threads anyway. |
81 |
|
82 |
Although the module will work with in the presence of other (Perl-) |
83 |
threads, it is currently not reentrant in any way, so use appropriate |
84 |
locking yourself, always call C<poll_cb> from within the same thread, or |
85 |
never call C<poll_cb> (or other C<aio_> functions) recursively. |
86 |
|
87 |
=head2 EXAMPLE |
88 |
|
89 |
This is a simple example that uses the Event module and loads |
90 |
F</etc/passwd> asynchronously: |
91 |
|
92 |
use Fcntl; |
93 |
use Event; |
94 |
use IO::AIO; |
95 |
|
96 |
# register the IO::AIO callback with Event |
97 |
Event->io (fd => IO::AIO::poll_fileno, |
98 |
poll => 'r', |
99 |
cb => \&IO::AIO::poll_cb); |
100 |
|
101 |
# queue the request to open /etc/passwd |
102 |
aio_open "/etc/passwd", O_RDONLY, 0, sub { |
103 |
my $fh = $_[0] |
104 |
or die "error while opening: $!"; |
105 |
|
106 |
# stat'ing filehandles is generally non-blocking |
107 |
my $size = -s $fh; |
108 |
|
109 |
# queue a request to read the file |
110 |
my $contents; |
111 |
aio_read $fh, 0, $size, $contents, 0, sub { |
112 |
$_[0] == $size |
113 |
or die "short read: $!"; |
114 |
|
115 |
close $fh; |
116 |
|
117 |
# file contents now in $contents |
118 |
print $contents; |
119 |
|
120 |
# exit event loop and program |
121 |
Event::unloop; |
122 |
}; |
123 |
}; |
124 |
|
125 |
# possibly queue up other requests, or open GUI windows, |
126 |
# check for sockets etc. etc. |
127 |
|
128 |
# process events as long as there are some: |
129 |
Event::loop; |
130 |
|
131 |
=head1 REQUEST ANATOMY AND LIFETIME |
132 |
|
133 |
Every C<aio_*> function creates a request. which is a C data structure not |
134 |
directly visible to Perl. |
135 |
|
136 |
If called in non-void context, every request function returns a Perl |
137 |
object representing the request. In void context, nothing is returned, |
138 |
which saves a bit of memory. |
139 |
|
140 |
The perl object is a fairly standard ref-to-hash object. The hash contents |
141 |
are not used by IO::AIO so you are free to store anything you like in it. |
142 |
|
143 |
During their existance, aio requests travel through the following states, |
144 |
in order: |
145 |
|
146 |
=over 4 |
147 |
|
148 |
=item ready |
149 |
|
150 |
Immediately after a request is created it is put into the ready state, |
151 |
waiting for a thread to execute it. |
152 |
|
153 |
=item execute |
154 |
|
155 |
A thread has accepted the request for processing and is currently |
156 |
executing it (e.g. blocking in read). |
157 |
|
158 |
=item pending |
159 |
|
160 |
The request has been executed and is waiting for result processing. |
161 |
|
162 |
While request submission and execution is fully asynchronous, result |
163 |
processing is not and relies on the perl interpreter calling C<poll_cb> |
164 |
(or another function with the same effect). |
165 |
|
166 |
=item result |
167 |
|
168 |
The request results are processed synchronously by C<poll_cb>. |
169 |
|
170 |
The C<poll_cb> function will process all outstanding aio requests by |
171 |
calling their callbacks, freeing memory associated with them and managing |
172 |
any groups they are contained in. |
173 |
|
174 |
=item done |
175 |
|
176 |
Request has reached the end of its lifetime and holds no resources anymore |
177 |
(except possibly for the Perl object, but its connection to the actual |
178 |
aio request is severed and calling its methods will either do nothing or |
179 |
result in a runtime error). |
180 |
|
181 |
=back |
182 |
|
183 |
=cut |
184 |
|
185 |
package IO::AIO; |
186 |
|
187 |
no warnings; |
188 |
use strict 'vars'; |
189 |
|
190 |
use base 'Exporter'; |
191 |
|
192 |
BEGIN { |
193 |
our $VERSION = '2.1'; |
194 |
|
195 |
our @AIO_REQ = qw(aio_sendfile aio_read aio_write aio_open aio_close aio_stat |
196 |
aio_lstat aio_unlink aio_rmdir aio_readdir aio_scandir aio_symlink |
197 |
aio_fsync aio_fdatasync aio_readahead aio_rename aio_link aio_move |
198 |
aio_copy aio_group aio_nop aio_mknod); |
199 |
our @EXPORT = (@AIO_REQ, qw(aioreq_pri aioreq_nice)); |
200 |
our @EXPORT_OK = qw(poll_fileno poll_cb poll_wait flush |
201 |
min_parallel max_parallel max_idle |
202 |
nreqs nready npending nthreads |
203 |
max_poll_time max_poll_reqs); |
204 |
|
205 |
@IO::AIO::GRP::ISA = 'IO::AIO::REQ'; |
206 |
|
207 |
require XSLoader; |
208 |
XSLoader::load ("IO::AIO", $VERSION); |
209 |
} |
210 |
|
211 |
=head1 FUNCTIONS |
212 |
|
213 |
=head2 AIO REQUEST FUNCTIONS |
214 |
|
215 |
All the C<aio_*> calls are more or less thin wrappers around the syscall |
216 |
with the same name (sans C<aio_>). The arguments are similar or identical, |
217 |
and they all accept an additional (and optional) C<$callback> argument |
218 |
which must be a code reference. This code reference will get called with |
219 |
the syscall return code (e.g. most syscalls return C<-1> on error, unlike |
220 |
perl, which usually delivers "false") as it's sole argument when the given |
221 |
syscall has been executed asynchronously. |
222 |
|
223 |
All functions expecting a filehandle keep a copy of the filehandle |
224 |
internally until the request has finished. |
225 |
|
226 |
All functions return request objects of type L<IO::AIO::REQ> that allow |
227 |
further manipulation of those requests while they are in-flight. |
228 |
|
229 |
The pathnames you pass to these routines I<must> be absolute and |
230 |
encoded as octets. The reason for the former is that at the time the |
231 |
request is being executed, the current working directory could have |
232 |
changed. Alternatively, you can make sure that you never change the |
233 |
current working directory anywhere in the program and then use relative |
234 |
paths. |
235 |
|
236 |
To encode pathnames as octets, either make sure you either: a) always pass |
237 |
in filenames you got from outside (command line, readdir etc.) without |
238 |
tinkering, b) are ASCII or ISO 8859-1, c) use the Encode module and encode |
239 |
your pathnames to the locale (or other) encoding in effect in the user |
240 |
environment, d) use Glib::filename_from_unicode on unicode filenames or e) |
241 |
use something else to ensure your scalar has the correct contents. |
242 |
|
243 |
This works, btw. independent of the internal UTF-8 bit, which IO::AIO |
244 |
handles correctly wether it is set or not. |
245 |
|
246 |
=over 4 |
247 |
|
248 |
=item $prev_pri = aioreq_pri [$pri] |
249 |
|
250 |
Returns the priority value that would be used for the next request and, if |
251 |
C<$pri> is given, sets the priority for the next aio request. |
252 |
|
253 |
The default priority is C<0>, the minimum and maximum priorities are C<-4> |
254 |
and C<4>, respectively. Requests with higher priority will be serviced |
255 |
first. |
256 |
|
257 |
The priority will be reset to C<0> after each call to one of the C<aio_*> |
258 |
functions. |
259 |
|
260 |
Example: open a file with low priority, then read something from it with |
261 |
higher priority so the read request is serviced before other low priority |
262 |
open requests (potentially spamming the cache): |
263 |
|
264 |
aioreq_pri -3; |
265 |
aio_open ..., sub { |
266 |
return unless $_[0]; |
267 |
|
268 |
aioreq_pri -2; |
269 |
aio_read $_[0], ..., sub { |
270 |
... |
271 |
}; |
272 |
}; |
273 |
|
274 |
=item aioreq_nice $pri_adjust |
275 |
|
276 |
Similar to C<aioreq_pri>, but subtracts the given value from the current |
277 |
priority, so the effect is cumulative. |
278 |
|
279 |
=item aio_open $pathname, $flags, $mode, $callback->($fh) |
280 |
|
281 |
Asynchronously open or create a file and call the callback with a newly |
282 |
created filehandle for the file. |
283 |
|
284 |
The pathname passed to C<aio_open> must be absolute. See API NOTES, above, |
285 |
for an explanation. |
286 |
|
287 |
The C<$flags> argument is a bitmask. See the C<Fcntl> module for a |
288 |
list. They are the same as used by C<sysopen>. |
289 |
|
290 |
Likewise, C<$mode> specifies the mode of the newly created file, if it |
291 |
didn't exist and C<O_CREAT> has been given, just like perl's C<sysopen>, |
292 |
except that it is mandatory (i.e. use C<0> if you don't create new files, |
293 |
and C<0666> or C<0777> if you do). |
294 |
|
295 |
Example: |
296 |
|
297 |
aio_open "/etc/passwd", O_RDONLY, 0, sub { |
298 |
if ($_[0]) { |
299 |
print "open successful, fh is $_[0]\n"; |
300 |
... |
301 |
} else { |
302 |
die "open failed: $!\n"; |
303 |
} |
304 |
}; |
305 |
|
306 |
=item aio_close $fh, $callback->($status) |
307 |
|
308 |
Asynchronously close a file and call the callback with the result |
309 |
code. I<WARNING:> although accepted, you should not pass in a perl |
310 |
filehandle here, as perl will likely close the file descriptor another |
311 |
time when the filehandle is destroyed. Normally, you can safely call perls |
312 |
C<close> or just let filehandles go out of scope. |
313 |
|
314 |
This is supposed to be a bug in the API, so that might change. It's |
315 |
therefore best to avoid this function. |
316 |
|
317 |
=item aio_read $fh,$offset,$length, $data,$dataoffset, $callback->($retval) |
318 |
|
319 |
=item aio_write $fh,$offset,$length, $data,$dataoffset, $callback->($retval) |
320 |
|
321 |
Reads or writes C<length> bytes from the specified C<fh> and C<offset> |
322 |
into the scalar given by C<data> and offset C<dataoffset> and calls the |
323 |
callback without the actual number of bytes read (or -1 on error, just |
324 |
like the syscall). |
325 |
|
326 |
The C<$data> scalar I<MUST NOT> be modified in any way while the request |
327 |
is outstanding. Modifying it can result in segfaults or WW3 (if the |
328 |
necessary/optional hardware is installed). |
329 |
|
330 |
Example: Read 15 bytes at offset 7 into scalar C<$buffer>, starting at |
331 |
offset C<0> within the scalar: |
332 |
|
333 |
aio_read $fh, 7, 15, $buffer, 0, sub { |
334 |
$_[0] > 0 or die "read error: $!"; |
335 |
print "read $_[0] bytes: <$buffer>\n"; |
336 |
}; |
337 |
|
338 |
=item aio_sendfile $out_fh, $in_fh, $in_offset, $length, $callback->($retval) |
339 |
|
340 |
Tries to copy C<$length> bytes from C<$in_fh> to C<$out_fh>. It starts |
341 |
reading at byte offset C<$in_offset>, and starts writing at the current |
342 |
file offset of C<$out_fh>. Because of that, it is not safe to issue more |
343 |
than one C<aio_sendfile> per C<$out_fh>, as they will interfere with each |
344 |
other. |
345 |
|
346 |
This call tries to make use of a native C<sendfile> syscall to provide |
347 |
zero-copy operation. For this to work, C<$out_fh> should refer to a |
348 |
socket, and C<$in_fh> should refer to mmap'able file. |
349 |
|
350 |
If the native sendfile call fails or is not implemented, it will be |
351 |
emulated, so you can call C<aio_sendfile> on any type of filehandle |
352 |
regardless of the limitations of the operating system. |
353 |
|
354 |
Please note, however, that C<aio_sendfile> can read more bytes from |
355 |
C<$in_fh> than are written, and there is no way to find out how many |
356 |
bytes have been read from C<aio_sendfile> alone, as C<aio_sendfile> only |
357 |
provides the number of bytes written to C<$out_fh>. Only if the result |
358 |
value equals C<$length> one can assume that C<$length> bytes have been |
359 |
read. |
360 |
|
361 |
=item aio_readahead $fh,$offset,$length, $callback->($retval) |
362 |
|
363 |
C<aio_readahead> populates the page cache with data from a file so that |
364 |
subsequent reads from that file will not block on disk I/O. The C<$offset> |
365 |
argument specifies the starting point from which data is to be read and |
366 |
C<$length> specifies the number of bytes to be read. I/O is performed in |
367 |
whole pages, so that offset is effectively rounded down to a page boundary |
368 |
and bytes are read up to the next page boundary greater than or equal to |
369 |
(off-set+length). C<aio_readahead> does not read beyond the end of the |
370 |
file. The current file offset of the file is left unchanged. |
371 |
|
372 |
If that syscall doesn't exist (likely if your OS isn't Linux) it will be |
373 |
emulated by simply reading the data, which would have a similar effect. |
374 |
|
375 |
=item aio_stat $fh_or_path, $callback->($status) |
376 |
|
377 |
=item aio_lstat $fh, $callback->($status) |
378 |
|
379 |
Works like perl's C<stat> or C<lstat> in void context. The callback will |
380 |
be called after the stat and the results will be available using C<stat _> |
381 |
or C<-s _> etc... |
382 |
|
383 |
The pathname passed to C<aio_stat> must be absolute. See API NOTES, above, |
384 |
for an explanation. |
385 |
|
386 |
Currently, the stats are always 64-bit-stats, i.e. instead of returning an |
387 |
error when stat'ing a large file, the results will be silently truncated |
388 |
unless perl itself is compiled with large file support. |
389 |
|
390 |
Example: Print the length of F</etc/passwd>: |
391 |
|
392 |
aio_stat "/etc/passwd", sub { |
393 |
$_[0] and die "stat failed: $!"; |
394 |
print "size is ", -s _, "\n"; |
395 |
}; |
396 |
|
397 |
=item aio_unlink $pathname, $callback->($status) |
398 |
|
399 |
Asynchronously unlink (delete) a file and call the callback with the |
400 |
result code. |
401 |
|
402 |
=item aio_mknod $path, $mode, $dev, $callback->($status) |
403 |
|
404 |
[EXPERIMENTAL] |
405 |
|
406 |
Asynchronously create a device node (or fifo). See mknod(2). |
407 |
|
408 |
The only (POSIX-) portable way of calling this function is: |
409 |
|
410 |
aio_mknod $path, IO::AIO::S_IFIFO | $mode, 0, sub { ... |
411 |
|
412 |
=item aio_link $srcpath, $dstpath, $callback->($status) |
413 |
|
414 |
Asynchronously create a new link to the existing object at C<$srcpath> at |
415 |
the path C<$dstpath> and call the callback with the result code. |
416 |
|
417 |
=item aio_symlink $srcpath, $dstpath, $callback->($status) |
418 |
|
419 |
Asynchronously create a new symbolic link to the existing object at C<$srcpath> at |
420 |
the path C<$dstpath> and call the callback with the result code. |
421 |
|
422 |
=item aio_rename $srcpath, $dstpath, $callback->($status) |
423 |
|
424 |
Asynchronously rename the object at C<$srcpath> to C<$dstpath>, just as |
425 |
rename(2) and call the callback with the result code. |
426 |
|
427 |
=item aio_rmdir $pathname, $callback->($status) |
428 |
|
429 |
Asynchronously rmdir (delete) a directory and call the callback with the |
430 |
result code. |
431 |
|
432 |
=item aio_readdir $pathname, $callback->($entries) |
433 |
|
434 |
Unlike the POSIX call of the same name, C<aio_readdir> reads an entire |
435 |
directory (i.e. opendir + readdir + closedir). The entries will not be |
436 |
sorted, and will B<NOT> include the C<.> and C<..> entries. |
437 |
|
438 |
The callback a single argument which is either C<undef> or an array-ref |
439 |
with the filenames. |
440 |
|
441 |
=item aio_copy $srcpath, $dstpath, $callback->($status) |
442 |
|
443 |
Try to copy the I<file> (directories not supported as either source or |
444 |
destination) from C<$srcpath> to C<$dstpath> and call the callback with |
445 |
the C<0> (error) or C<-1> ok. |
446 |
|
447 |
This is a composite request that it creates the destination file with |
448 |
mode 0200 and copies the contents of the source file into it using |
449 |
C<aio_sendfile>, followed by restoring atime, mtime, access mode and |
450 |
uid/gid, in that order. |
451 |
|
452 |
If an error occurs, the partial destination file will be unlinked, if |
453 |
possible, except when setting atime, mtime, access mode and uid/gid, where |
454 |
errors are being ignored. |
455 |
|
456 |
=cut |
457 |
|
458 |
sub aio_copy($$;$) { |
459 |
my ($src, $dst, $cb) = @_; |
460 |
|
461 |
my $pri = aioreq_pri; |
462 |
my $grp = aio_group $cb; |
463 |
|
464 |
aioreq_pri $pri; |
465 |
add $grp aio_open $src, O_RDONLY, 0, sub { |
466 |
if (my $src_fh = $_[0]) { |
467 |
my @stat = stat $src_fh; |
468 |
|
469 |
aioreq_pri $pri; |
470 |
add $grp aio_open $dst, O_CREAT | O_WRONLY | O_TRUNC, 0200, sub { |
471 |
if (my $dst_fh = $_[0]) { |
472 |
aioreq_pri $pri; |
473 |
add $grp aio_sendfile $dst_fh, $src_fh, 0, $stat[7], sub { |
474 |
if ($_[0] == $stat[7]) { |
475 |
$grp->result (0); |
476 |
close $src_fh; |
477 |
|
478 |
# those should not normally block. should. should. |
479 |
utime $stat[8], $stat[9], $dst; |
480 |
chmod $stat[2] & 07777, $dst_fh; |
481 |
chown $stat[4], $stat[5], $dst_fh; |
482 |
close $dst_fh; |
483 |
} else { |
484 |
$grp->result (-1); |
485 |
close $src_fh; |
486 |
close $dst_fh; |
487 |
|
488 |
aioreq $pri; |
489 |
add $grp aio_unlink $dst; |
490 |
} |
491 |
}; |
492 |
} else { |
493 |
$grp->result (-1); |
494 |
} |
495 |
}, |
496 |
|
497 |
} else { |
498 |
$grp->result (-1); |
499 |
} |
500 |
}; |
501 |
|
502 |
$grp |
503 |
} |
504 |
|
505 |
=item aio_move $srcpath, $dstpath, $callback->($status) |
506 |
|
507 |
Try to move the I<file> (directories not supported as either source or |
508 |
destination) from C<$srcpath> to C<$dstpath> and call the callback with |
509 |
the C<0> (error) or C<-1> ok. |
510 |
|
511 |
This is a composite request that tries to rename(2) the file first. If |
512 |
rename files with C<EXDEV>, it copies the file with C<aio_copy> and, if |
513 |
that is successful, unlinking the C<$srcpath>. |
514 |
|
515 |
=cut |
516 |
|
517 |
sub aio_move($$;$) { |
518 |
my ($src, $dst, $cb) = @_; |
519 |
|
520 |
my $pri = aioreq_pri; |
521 |
my $grp = aio_group $cb; |
522 |
|
523 |
aioreq_pri $pri; |
524 |
add $grp aio_rename $src, $dst, sub { |
525 |
if ($_[0] && $! == EXDEV) { |
526 |
aioreq_pri $pri; |
527 |
add $grp aio_copy $src, $dst, sub { |
528 |
$grp->result ($_[0]); |
529 |
|
530 |
if (!$_[0]) { |
531 |
aioreq_pri $pri; |
532 |
add $grp aio_unlink $src; |
533 |
} |
534 |
}; |
535 |
} else { |
536 |
$grp->result ($_[0]); |
537 |
} |
538 |
}; |
539 |
|
540 |
$grp |
541 |
} |
542 |
|
543 |
=item aio_scandir $path, $maxreq, $callback->($dirs, $nondirs) |
544 |
|
545 |
Scans a directory (similar to C<aio_readdir>) but additionally tries to |
546 |
efficiently separate the entries of directory C<$path> into two sets of |
547 |
names, directories you can recurse into (directories), and ones you cannot |
548 |
recurse into (everything else, including symlinks to directories). |
549 |
|
550 |
C<aio_scandir> is a composite request that creates of many sub requests_ |
551 |
C<$maxreq> specifies the maximum number of outstanding aio requests that |
552 |
this function generates. If it is C<< <= 0 >>, then a suitable default |
553 |
will be chosen (currently 4). |
554 |
|
555 |
On error, the callback is called without arguments, otherwise it receives |
556 |
two array-refs with path-relative entry names. |
557 |
|
558 |
Example: |
559 |
|
560 |
aio_scandir $dir, 0, sub { |
561 |
my ($dirs, $nondirs) = @_; |
562 |
print "real directories: @$dirs\n"; |
563 |
print "everything else: @$nondirs\n"; |
564 |
}; |
565 |
|
566 |
Implementation notes. |
567 |
|
568 |
The C<aio_readdir> cannot be avoided, but C<stat()>'ing every entry can. |
569 |
|
570 |
After reading the directory, the modification time, size etc. of the |
571 |
directory before and after the readdir is checked, and if they match (and |
572 |
isn't the current time), the link count will be used to decide how many |
573 |
entries are directories (if >= 2). Otherwise, no knowledge of the number |
574 |
of subdirectories will be assumed. |
575 |
|
576 |
Then entries will be sorted into likely directories (everything without |
577 |
a non-initial dot currently) and likely non-directories (everything |
578 |
else). Then every entry plus an appended C</.> will be C<stat>'ed, |
579 |
likely directories first. If that succeeds, it assumes that the entry |
580 |
is a directory or a symlink to directory (which will be checked |
581 |
seperately). This is often faster than stat'ing the entry itself because |
582 |
filesystems might detect the type of the entry without reading the inode |
583 |
data (e.g. ext2fs filetype feature). |
584 |
|
585 |
If the known number of directories (link count - 2) has been reached, the |
586 |
rest of the entries is assumed to be non-directories. |
587 |
|
588 |
This only works with certainty on POSIX (= UNIX) filesystems, which |
589 |
fortunately are the vast majority of filesystems around. |
590 |
|
591 |
It will also likely work on non-POSIX filesystems with reduced efficiency |
592 |
as those tend to return 0 or 1 as link counts, which disables the |
593 |
directory counting heuristic. |
594 |
|
595 |
=cut |
596 |
|
597 |
sub aio_scandir($$$) { |
598 |
my ($path, $maxreq, $cb) = @_; |
599 |
|
600 |
my $pri = aioreq_pri; |
601 |
|
602 |
my $grp = aio_group $cb; |
603 |
|
604 |
$maxreq = 4 if $maxreq <= 0; |
605 |
|
606 |
# stat once |
607 |
aioreq_pri $pri; |
608 |
add $grp aio_stat $path, sub { |
609 |
return $grp->result () if $_[0]; |
610 |
my $now = time; |
611 |
my $hash1 = join ":", (stat _)[0,1,3,7,9]; |
612 |
|
613 |
# read the directory entries |
614 |
aioreq_pri $pri; |
615 |
add $grp aio_readdir $path, sub { |
616 |
my $entries = shift |
617 |
or return $grp->result (); |
618 |
|
619 |
# stat the dir another time |
620 |
aioreq_pri $pri; |
621 |
add $grp aio_stat $path, sub { |
622 |
my $hash2 = join ":", (stat _)[0,1,3,7,9]; |
623 |
|
624 |
my $ndirs; |
625 |
|
626 |
# take the slow route if anything looks fishy |
627 |
if ($hash1 ne $hash2 or (stat _)[9] == $now) { |
628 |
$ndirs = -1; |
629 |
} else { |
630 |
# if nlink == 2, we are finished |
631 |
# on non-posix-fs's, we rely on nlink < 2 |
632 |
$ndirs = (stat _)[3] - 2 |
633 |
or return $grp->result ([], $entries); |
634 |
} |
635 |
|
636 |
# sort into likely dirs and likely nondirs |
637 |
# dirs == files without ".", short entries first |
638 |
$entries = [map $_->[0], |
639 |
sort { $b->[1] cmp $a->[1] } |
640 |
map [$_, sprintf "%s%04d", (/.\./ ? "1" : "0"), length], |
641 |
@$entries]; |
642 |
|
643 |
my (@dirs, @nondirs); |
644 |
|
645 |
my $statgrp = add $grp aio_group sub { |
646 |
$grp->result (\@dirs, \@nondirs); |
647 |
}; |
648 |
|
649 |
limit $statgrp $maxreq; |
650 |
feed $statgrp sub { |
651 |
return unless @$entries; |
652 |
my $entry = pop @$entries; |
653 |
|
654 |
aioreq_pri $pri; |
655 |
add $statgrp aio_stat "$path/$entry/.", sub { |
656 |
if ($_[0] < 0) { |
657 |
push @nondirs, $entry; |
658 |
} else { |
659 |
# need to check for real directory |
660 |
aioreq_pri $pri; |
661 |
add $statgrp aio_lstat "$path/$entry", sub { |
662 |
if (-d _) { |
663 |
push @dirs, $entry; |
664 |
|
665 |
unless (--$ndirs) { |
666 |
push @nondirs, @$entries; |
667 |
feed $statgrp; |
668 |
} |
669 |
} else { |
670 |
push @nondirs, $entry; |
671 |
} |
672 |
} |
673 |
} |
674 |
}; |
675 |
}; |
676 |
}; |
677 |
}; |
678 |
}; |
679 |
|
680 |
$grp |
681 |
} |
682 |
|
683 |
=item aio_fsync $fh, $callback->($status) |
684 |
|
685 |
Asynchronously call fsync on the given filehandle and call the callback |
686 |
with the fsync result code. |
687 |
|
688 |
=item aio_fdatasync $fh, $callback->($status) |
689 |
|
690 |
Asynchronously call fdatasync on the given filehandle and call the |
691 |
callback with the fdatasync result code. |
692 |
|
693 |
If this call isn't available because your OS lacks it or it couldn't be |
694 |
detected, it will be emulated by calling C<fsync> instead. |
695 |
|
696 |
=item aio_group $callback->(...) |
697 |
|
698 |
This is a very special aio request: Instead of doing something, it is a |
699 |
container for other aio requests, which is useful if you want to bundle |
700 |
many requests into a single, composite, request with a definite callback |
701 |
and the ability to cancel the whole request with its subrequests. |
702 |
|
703 |
Returns an object of class L<IO::AIO::GRP>. See its documentation below |
704 |
for more info. |
705 |
|
706 |
Example: |
707 |
|
708 |
my $grp = aio_group sub { |
709 |
print "all stats done\n"; |
710 |
}; |
711 |
|
712 |
add $grp |
713 |
(aio_stat ...), |
714 |
(aio_stat ...), |
715 |
...; |
716 |
|
717 |
=item aio_nop $callback->() |
718 |
|
719 |
This is a special request - it does nothing in itself and is only used for |
720 |
side effects, such as when you want to add a dummy request to a group so |
721 |
that finishing the requests in the group depends on executing the given |
722 |
code. |
723 |
|
724 |
While this request does nothing, it still goes through the execution |
725 |
phase and still requires a worker thread. Thus, the callback will not |
726 |
be executed immediately but only after other requests in the queue have |
727 |
entered their execution phase. This can be used to measure request |
728 |
latency. |
729 |
|
730 |
=item IO::AIO::aio_busy $fractional_seconds, $callback->() *NOT EXPORTED* |
731 |
|
732 |
Mainly used for debugging and benchmarking, this aio request puts one of |
733 |
the request workers to sleep for the given time. |
734 |
|
735 |
While it is theoretically handy to have simple I/O scheduling requests |
736 |
like sleep and file handle readable/writable, the overhead this creates is |
737 |
immense (it blocks a thread for a long time) so do not use this function |
738 |
except to put your application under artificial I/O pressure. |
739 |
|
740 |
=back |
741 |
|
742 |
=head2 IO::AIO::REQ CLASS |
743 |
|
744 |
All non-aggregate C<aio_*> functions return an object of this class when |
745 |
called in non-void context. |
746 |
|
747 |
=over 4 |
748 |
|
749 |
=item cancel $req |
750 |
|
751 |
Cancels the request, if possible. Has the effect of skipping execution |
752 |
when entering the B<execute> state and skipping calling the callback when |
753 |
entering the the B<result> state, but will leave the request otherwise |
754 |
untouched. That means that requests that currently execute will not be |
755 |
stopped and resources held by the request will not be freed prematurely. |
756 |
|
757 |
=item cb $req $callback->(...) |
758 |
|
759 |
Replace (or simply set) the callback registered to the request. |
760 |
|
761 |
=back |
762 |
|
763 |
=head2 IO::AIO::GRP CLASS |
764 |
|
765 |
This class is a subclass of L<IO::AIO::REQ>, so all its methods apply to |
766 |
objects of this class, too. |
767 |
|
768 |
A IO::AIO::GRP object is a special request that can contain multiple other |
769 |
aio requests. |
770 |
|
771 |
You create one by calling the C<aio_group> constructing function with a |
772 |
callback that will be called when all contained requests have entered the |
773 |
C<done> state: |
774 |
|
775 |
my $grp = aio_group sub { |
776 |
print "all requests are done\n"; |
777 |
}; |
778 |
|
779 |
You add requests by calling the C<add> method with one or more |
780 |
C<IO::AIO::REQ> objects: |
781 |
|
782 |
$grp->add (aio_unlink "..."); |
783 |
|
784 |
add $grp aio_stat "...", sub { |
785 |
$_[0] or return $grp->result ("error"); |
786 |
|
787 |
# add another request dynamically, if first succeeded |
788 |
add $grp aio_open "...", sub { |
789 |
$grp->result ("ok"); |
790 |
}; |
791 |
}; |
792 |
|
793 |
This makes it very easy to create composite requests (see the source of |
794 |
C<aio_move> for an application) that work and feel like simple requests. |
795 |
|
796 |
=over 4 |
797 |
|
798 |
=item * The IO::AIO::GRP objects will be cleaned up during calls to |
799 |
C<IO::AIO::poll_cb>, just like any other request. |
800 |
|
801 |
=item * They can be canceled like any other request. Canceling will cancel not |
802 |
only the request itself, but also all requests it contains. |
803 |
|
804 |
=item * They can also can also be added to other IO::AIO::GRP objects. |
805 |
|
806 |
=item * You must not add requests to a group from within the group callback (or |
807 |
any later time). |
808 |
|
809 |
=back |
810 |
|
811 |
Their lifetime, simplified, looks like this: when they are empty, they |
812 |
will finish very quickly. If they contain only requests that are in the |
813 |
C<done> state, they will also finish. Otherwise they will continue to |
814 |
exist. |
815 |
|
816 |
That means after creating a group you have some time to add requests. And |
817 |
in the callbacks of those requests, you can add further requests to the |
818 |
group. And only when all those requests have finished will the the group |
819 |
itself finish. |
820 |
|
821 |
=over 4 |
822 |
|
823 |
=item add $grp ... |
824 |
|
825 |
=item $grp->add (...) |
826 |
|
827 |
Add one or more requests to the group. Any type of L<IO::AIO::REQ> can |
828 |
be added, including other groups, as long as you do not create circular |
829 |
dependencies. |
830 |
|
831 |
Returns all its arguments. |
832 |
|
833 |
=item $grp->cancel_subs |
834 |
|
835 |
Cancel all subrequests and clears any feeder, but not the group request |
836 |
itself. Useful when you queued a lot of events but got a result early. |
837 |
|
838 |
=item $grp->result (...) |
839 |
|
840 |
Set the result value(s) that will be passed to the group callback when all |
841 |
subrequests have finished and set thre groups errno to the current value |
842 |
of errno (just like calling C<errno> without an error number). By default, |
843 |
no argument will be passed and errno is zero. |
844 |
|
845 |
=item $grp->errno ([$errno]) |
846 |
|
847 |
Sets the group errno value to C<$errno>, or the current value of errno |
848 |
when the argument is missing. |
849 |
|
850 |
Every aio request has an associated errno value that is restored when |
851 |
the callback is invoked. This method lets you change this value from its |
852 |
default (0). |
853 |
|
854 |
Calling C<result> will also set errno, so make sure you either set C<$!> |
855 |
before the call to C<result>, or call c<errno> after it. |
856 |
|
857 |
=item feed $grp $callback->($grp) |
858 |
|
859 |
Sets a feeder/generator on this group: every group can have an attached |
860 |
generator that generates requests if idle. The idea behind this is that, |
861 |
although you could just queue as many requests as you want in a group, |
862 |
this might starve other requests for a potentially long time. For |
863 |
example, C<aio_scandir> might generate hundreds of thousands C<aio_stat> |
864 |
requests, delaying any later requests for a long time. |
865 |
|
866 |
To avoid this, and allow incremental generation of requests, you can |
867 |
instead a group and set a feeder on it that generates those requests. The |
868 |
feed callback will be called whenever there are few enough (see C<limit>, |
869 |
below) requests active in the group itself and is expected to queue more |
870 |
requests. |
871 |
|
872 |
The feed callback can queue as many requests as it likes (i.e. C<add> does |
873 |
not impose any limits). |
874 |
|
875 |
If the feed does not queue more requests when called, it will be |
876 |
automatically removed from the group. |
877 |
|
878 |
If the feed limit is C<0>, it will be set to C<2> automatically. |
879 |
|
880 |
Example: |
881 |
|
882 |
# stat all files in @files, but only ever use four aio requests concurrently: |
883 |
|
884 |
my $grp = aio_group sub { print "finished\n" }; |
885 |
limit $grp 4; |
886 |
feed $grp sub { |
887 |
my $file = pop @files |
888 |
or return; |
889 |
|
890 |
add $grp aio_stat $file, sub { ... }; |
891 |
}; |
892 |
|
893 |
=item limit $grp $num |
894 |
|
895 |
Sets the feeder limit for the group: The feeder will be called whenever |
896 |
the group contains less than this many requests. |
897 |
|
898 |
Setting the limit to C<0> will pause the feeding process. |
899 |
|
900 |
=back |
901 |
|
902 |
=head2 SUPPORT FUNCTIONS |
903 |
|
904 |
=head3 EVENT PROCESSING AND EVENT LOOP INTEGRATION |
905 |
|
906 |
=over 4 |
907 |
|
908 |
=item $fileno = IO::AIO::poll_fileno |
909 |
|
910 |
Return the I<request result pipe file descriptor>. This filehandle must be |
911 |
polled for reading by some mechanism outside this module (e.g. Event or |
912 |
select, see below or the SYNOPSIS). If the pipe becomes readable you have |
913 |
to call C<poll_cb> to check the results. |
914 |
|
915 |
See C<poll_cb> for an example. |
916 |
|
917 |
=item IO::AIO::poll_cb |
918 |
|
919 |
Process some outstanding events on the result pipe. You have to call this |
920 |
regularly. Returns the number of events processed. Returns immediately |
921 |
when no events are outstanding. The amount of events processed depends on |
922 |
the settings of C<IO::AIO::max_poll_req> and C<IO::AIO::max_poll_time>. |
923 |
|
924 |
If not all requests were processed for whatever reason, the filehandle |
925 |
will still be ready when C<poll_cb> returns. |
926 |
|
927 |
Example: Install an Event watcher that automatically calls |
928 |
IO::AIO::poll_cb with high priority: |
929 |
|
930 |
Event->io (fd => IO::AIO::poll_fileno, |
931 |
poll => 'r', async => 1, |
932 |
cb => \&IO::AIO::poll_cb); |
933 |
|
934 |
=item IO::AIO::max_poll_reqs $nreqs |
935 |
|
936 |
=item IO::AIO::max_poll_time $seconds |
937 |
|
938 |
These set the maximum number of requests (default C<0>, meaning infinity) |
939 |
that are being processed by C<IO::AIO::poll_cb> in one call, respectively |
940 |
the maximum amount of time (default C<0>, meaning infinity) spent in |
941 |
C<IO::AIO::poll_cb> to process requests (more correctly the mininum amount |
942 |
of time C<poll_cb> is allowed to use). |
943 |
|
944 |
Setting C<max_poll_time> to a non-zero value creates an overhead of one |
945 |
syscall per request processed, which is not normally a problem unless your |
946 |
callbacks are really really fast or your OS is really really slow (I am |
947 |
not mentioning Solaris here). Using C<max_poll_reqs> incurs no overhead. |
948 |
|
949 |
Setting these is useful if you want to ensure some level of |
950 |
interactiveness when perl is not fast enough to process all requests in |
951 |
time. |
952 |
|
953 |
For interactive programs, values such as C<0.01> to C<0.1> should be fine. |
954 |
|
955 |
Example: Install an Event watcher that automatically calls |
956 |
IO::AIO::poll_cb with low priority, to ensure that other parts of the |
957 |
program get the CPU sometimes even under high AIO load. |
958 |
|
959 |
# try not to spend much more than 0.1s in poll_cb |
960 |
IO::AIO::max_poll_time 0.1; |
961 |
|
962 |
# use a low priority so other tasks have priority |
963 |
Event->io (fd => IO::AIO::poll_fileno, |
964 |
poll => 'r', nice => 1, |
965 |
cb => &IO::AIO::poll_cb); |
966 |
|
967 |
=item IO::AIO::poll_wait |
968 |
|
969 |
Wait till the result filehandle becomes ready for reading (simply does a |
970 |
C<select> on the filehandle. This is useful if you want to synchronously |
971 |
wait for some requests to finish). |
972 |
|
973 |
See C<nreqs> for an example. |
974 |
|
975 |
=item IO::AIO::poll |
976 |
|
977 |
Waits until some requests have been handled. |
978 |
|
979 |
Strictly equivalent to: |
980 |
|
981 |
IO::AIO::poll_wait, IO::AIO::poll_cb |
982 |
if IO::AIO::nreqs; |
983 |
|
984 |
=item IO::AIO::flush |
985 |
|
986 |
Wait till all outstanding AIO requests have been handled. |
987 |
|
988 |
Strictly equivalent to: |
989 |
|
990 |
IO::AIO::poll_wait, IO::AIO::poll_cb |
991 |
while IO::AIO::nreqs; |
992 |
|
993 |
=head3 CONTROLLING THE NUMBER OF THREADS |
994 |
|
995 |
=item IO::AIO::min_parallel $nthreads |
996 |
|
997 |
Set the minimum number of AIO threads to C<$nthreads>. The current |
998 |
default is C<8>, which means eight asynchronous operations can execute |
999 |
concurrently at any one time (the number of outstanding requests, |
1000 |
however, is unlimited). |
1001 |
|
1002 |
IO::AIO starts threads only on demand, when an AIO request is queued and |
1003 |
no free thread exists. Please note that queueing up a hundred requests can |
1004 |
create demand for a hundred threads, even if it turns out that everything |
1005 |
is in the cache and could have been processed faster by a single thread. |
1006 |
|
1007 |
It is recommended to keep the number of threads relatively low, as some |
1008 |
Linux kernel versions will scale negatively with the number of threads |
1009 |
(higher parallelity => MUCH higher latency). With current Linux 2.6 |
1010 |
versions, 4-32 threads should be fine. |
1011 |
|
1012 |
Under most circumstances you don't need to call this function, as the |
1013 |
module selects a default that is suitable for low to moderate load. |
1014 |
|
1015 |
=item IO::AIO::max_parallel $nthreads |
1016 |
|
1017 |
Sets the maximum number of AIO threads to C<$nthreads>. If more than the |
1018 |
specified number of threads are currently running, this function kills |
1019 |
them. This function blocks until the limit is reached. |
1020 |
|
1021 |
While C<$nthreads> are zero, aio requests get queued but not executed |
1022 |
until the number of threads has been increased again. |
1023 |
|
1024 |
This module automatically runs C<max_parallel 0> at program end, to ensure |
1025 |
that all threads are killed and that there are no outstanding requests. |
1026 |
|
1027 |
Under normal circumstances you don't need to call this function. |
1028 |
|
1029 |
=item IO::AIO::max_idle $nthreads |
1030 |
|
1031 |
Limit the number of threads (default: 4) that are allowed to idle (i.e., |
1032 |
threads that did not get a request to process within 10 seconds). That |
1033 |
means if a thread becomes idle while C<$nthreads> other threads are also |
1034 |
idle, it will free its resources and exit. |
1035 |
|
1036 |
This is useful when you allow a large number of threads (e.g. 100 or 1000) |
1037 |
to allow for extremely high load situations, but want to free resources |
1038 |
under normal circumstances (1000 threads can easily consume 30MB of RAM). |
1039 |
|
1040 |
The default is probably ok in most situations, especially if thread |
1041 |
creation is fast. If thread creation is very slow on your system you might |
1042 |
want to use larger values. |
1043 |
|
1044 |
=item $oldmaxreqs = IO::AIO::max_outstanding $maxreqs |
1045 |
|
1046 |
This is a very bad function to use in interactive programs because it |
1047 |
blocks, and a bad way to reduce concurrency because it is inexact: Better |
1048 |
use an C<aio_group> together with a feed callback. |
1049 |
|
1050 |
Sets the maximum number of outstanding requests to C<$nreqs>. If you |
1051 |
to queue up more than this number of requests, the next call to the |
1052 |
C<poll_cb> (and C<poll_some> and other functions calling C<poll_cb>) |
1053 |
function will block until the limit is no longer exceeded. |
1054 |
|
1055 |
The default value is very large, so there is no practical limit on the |
1056 |
number of outstanding requests. |
1057 |
|
1058 |
You can still queue as many requests as you want. Therefore, |
1059 |
C<max_oustsanding> is mainly useful in simple scripts (with low values) or |
1060 |
as a stop gap to shield against fatal memory overflow (with large values). |
1061 |
|
1062 |
=head3 STATISTICAL INFORMATION |
1063 |
|
1064 |
=item IO::AIO::nreqs |
1065 |
|
1066 |
Returns the number of requests currently in the ready, execute or pending |
1067 |
states (i.e. for which their callback has not been invoked yet). |
1068 |
|
1069 |
Example: wait till there are no outstanding requests anymore: |
1070 |
|
1071 |
IO::AIO::poll_wait, IO::AIO::poll_cb |
1072 |
while IO::AIO::nreqs; |
1073 |
|
1074 |
=item IO::AIO::nready |
1075 |
|
1076 |
Returns the number of requests currently in the ready state (not yet |
1077 |
executed). |
1078 |
|
1079 |
=item IO::AIO::npending |
1080 |
|
1081 |
Returns the number of requests currently in the pending state (executed, |
1082 |
but not yet processed by poll_cb). |
1083 |
|
1084 |
=back |
1085 |
|
1086 |
=cut |
1087 |
|
1088 |
# support function to convert a fd into a perl filehandle |
1089 |
sub _fd2fh { |
1090 |
return undef if $_[0] < 0; |
1091 |
|
1092 |
# try to generate nice filehandles |
1093 |
my $sym = "IO::AIO::fd#$_[0]"; |
1094 |
local *$sym; |
1095 |
|
1096 |
open *$sym, "+<&=$_[0]" # usually works under any unix |
1097 |
or open *$sym, "<&=$_[0]" # cygwin needs this |
1098 |
or open *$sym, ">&=$_[0]" # or this |
1099 |
or return undef; |
1100 |
|
1101 |
*$sym |
1102 |
} |
1103 |
|
1104 |
min_parallel 8; |
1105 |
|
1106 |
END { |
1107 |
min_parallel 1; |
1108 |
flush; |
1109 |
}; |
1110 |
|
1111 |
1; |
1112 |
|
1113 |
=head2 FORK BEHAVIOUR |
1114 |
|
1115 |
This module should do "the right thing" when the process using it forks: |
1116 |
|
1117 |
Before the fork, IO::AIO enters a quiescent state where no requests |
1118 |
can be added in other threads and no results will be processed. After |
1119 |
the fork the parent simply leaves the quiescent state and continues |
1120 |
request/result processing, while the child frees the request/result queue |
1121 |
(so that the requests started before the fork will only be handled in the |
1122 |
parent). Threads will be started on demand until the limit set in the |
1123 |
parent process has been reached again. |
1124 |
|
1125 |
In short: the parent will, after a short pause, continue as if fork had |
1126 |
not been called, while the child will act as if IO::AIO has not been used |
1127 |
yet. |
1128 |
|
1129 |
=head2 MEMORY USAGE |
1130 |
|
1131 |
Per-request usage: |
1132 |
|
1133 |
Each aio request uses - depending on your architecture - around 100-200 |
1134 |
bytes of memory. In addition, stat requests need a stat buffer (possibly |
1135 |
a few hundred bytes), readdir requires a result buffer and so on. Perl |
1136 |
scalars and other data passed into aio requests will also be locked and |
1137 |
will consume memory till the request has entered the done state. |
1138 |
|
1139 |
This is now awfully much, so queuing lots of requests is not usually a |
1140 |
problem. |
1141 |
|
1142 |
Per-thread usage: |
1143 |
|
1144 |
In the execution phase, some aio requests require more memory for |
1145 |
temporary buffers, and each thread requires a stack and other data |
1146 |
structures (usually around 16k-128k, depending on the OS). |
1147 |
|
1148 |
=head1 KNOWN BUGS |
1149 |
|
1150 |
Known bugs will be fixed in the next release. |
1151 |
|
1152 |
=head1 SEE ALSO |
1153 |
|
1154 |
L<Coro::AIO>. |
1155 |
|
1156 |
=head1 AUTHOR |
1157 |
|
1158 |
Marc Lehmann <schmorp@schmorp.de> |
1159 |
http://home.schmorp.de/ |
1160 |
|
1161 |
=cut |
1162 |
|