ViewVC Help
View File | Revision Log | Show Annotations | Download File
/cvs/IO-AIO/AIO.pm
Revision: 1.297
Committed: Thu Nov 29 19:53:46 2018 UTC (5 years, 6 months ago) by root
Branch: MAIN
Changes since 1.296: +6 -3 lines
Log Message:
*** empty log message ***

File Contents

# Content
1 =head1 NAME
2
3 IO::AIO - Asynchronous/Advanced Input/Output
4
5 =head1 SYNOPSIS
6
7 use IO::AIO;
8
9 aio_open "/etc/passwd", IO::AIO::O_RDONLY, 0, sub {
10 my $fh = shift
11 or die "/etc/passwd: $!";
12 ...
13 };
14
15 aio_unlink "/tmp/file", sub { };
16
17 aio_read $fh, 30000, 1024, $buffer, 0, sub {
18 $_[0] > 0 or die "read error: $!";
19 };
20
21 # version 2+ has request and group objects
22 use IO::AIO 2;
23
24 aioreq_pri 4; # give next request a very high priority
25 my $req = aio_unlink "/tmp/file", sub { };
26 $req->cancel; # cancel request if still in queue
27
28 my $grp = aio_group sub { print "all stats done\n" };
29 add $grp aio_stat "..." for ...;
30
31 =head1 DESCRIPTION
32
33 This module implements asynchronous I/O using whatever means your
34 operating system supports. It is implemented as an interface to C<libeio>
35 (L<http://software.schmorp.de/pkg/libeio.html>).
36
37 Asynchronous means that operations that can normally block your program
38 (e.g. reading from disk) will be done asynchronously: the operation
39 will still block, but you can do something else in the meantime. This
40 is extremely useful for programs that need to stay interactive even
41 when doing heavy I/O (GUI programs, high performance network servers
42 etc.), but can also be used to easily do operations in parallel that are
43 normally done sequentially, e.g. stat'ing many files, which is much faster
44 on a RAID volume or over NFS when you do a number of stat operations
45 concurrently.
46
47 While most of this works on all types of file descriptors (for
48 example sockets), using these functions on file descriptors that
49 support nonblocking operation (again, sockets, pipes etc.) is
50 very inefficient. Use an event loop for that (such as the L<EV>
51 module): IO::AIO will naturally fit into such an event loop itself.
52
53 In this version, a number of threads are started that execute your
54 requests and signal their completion. You don't need thread support
55 in perl, and the threads created by this module will not be visible
56 to perl. In the future, this module might make use of the native aio
57 functions available on many operating systems. However, they are often
58 not well-supported or restricted (GNU/Linux doesn't allow them on normal
59 files currently, for example), and they would only support aio_read and
60 aio_write, so the remaining functionality would have to be implemented
61 using threads anyway.
62
63 In addition to asynchronous I/O, this module also exports some rather
64 arcane interfaces, such as C<madvise> or linux's C<splice> system call,
65 which is why the C<A> in C<AIO> can also mean I<advanced>.
66
67 Although the module will work in the presence of other (Perl-) threads,
68 it is currently not reentrant in any way, so use appropriate locking
69 yourself, always call C<poll_cb> from within the same thread, or never
70 call C<poll_cb> (or other C<aio_> functions) recursively.
71
72 =head2 EXAMPLE
73
74 This is a simple example that uses the EV module and loads
75 F</etc/passwd> asynchronously:
76
77 use EV;
78 use IO::AIO;
79
80 # register the IO::AIO callback with EV
81 my $aio_w = EV::io IO::AIO::poll_fileno, EV::READ, \&IO::AIO::poll_cb;
82
83 # queue the request to open /etc/passwd
84 aio_open "/etc/passwd", IO::AIO::O_RDONLY, 0, sub {
85 my $fh = shift
86 or die "error while opening: $!";
87
88 # stat'ing filehandles is generally non-blocking
89 my $size = -s $fh;
90
91 # queue a request to read the file
92 my $contents;
93 aio_read $fh, 0, $size, $contents, 0, sub {
94 $_[0] == $size
95 or die "short read: $!";
96
97 close $fh;
98
99 # file contents now in $contents
100 print $contents;
101
102 # exit event loop and program
103 EV::break;
104 };
105 };
106
107 # possibly queue up other requests, or open GUI windows,
108 # check for sockets etc. etc.
109
110 # process events as long as there are some:
111 EV::run;
112
113 =head1 REQUEST ANATOMY AND LIFETIME
114
115 Every C<aio_*> function creates a request. which is a C data structure not
116 directly visible to Perl.
117
118 If called in non-void context, every request function returns a Perl
119 object representing the request. In void context, nothing is returned,
120 which saves a bit of memory.
121
122 The perl object is a fairly standard ref-to-hash object. The hash contents
123 are not used by IO::AIO so you are free to store anything you like in it.
124
125 During their existance, aio requests travel through the following states,
126 in order:
127
128 =over 4
129
130 =item ready
131
132 Immediately after a request is created it is put into the ready state,
133 waiting for a thread to execute it.
134
135 =item execute
136
137 A thread has accepted the request for processing and is currently
138 executing it (e.g. blocking in read).
139
140 =item pending
141
142 The request has been executed and is waiting for result processing.
143
144 While request submission and execution is fully asynchronous, result
145 processing is not and relies on the perl interpreter calling C<poll_cb>
146 (or another function with the same effect).
147
148 =item result
149
150 The request results are processed synchronously by C<poll_cb>.
151
152 The C<poll_cb> function will process all outstanding aio requests by
153 calling their callbacks, freeing memory associated with them and managing
154 any groups they are contained in.
155
156 =item done
157
158 Request has reached the end of its lifetime and holds no resources anymore
159 (except possibly for the Perl object, but its connection to the actual
160 aio request is severed and calling its methods will either do nothing or
161 result in a runtime error).
162
163 =back
164
165 =cut
166
167 package IO::AIO;
168
169 use Carp ();
170
171 use common::sense;
172
173 use base 'Exporter';
174
175 BEGIN {
176 our $VERSION = 4.6;
177
178 our @AIO_REQ = qw(aio_sendfile aio_seek aio_read aio_write aio_open aio_close
179 aio_stat aio_lstat aio_unlink aio_rmdir aio_readdir aio_readdirx
180 aio_scandir aio_symlink aio_readlink aio_realpath aio_fcntl aio_ioctl
181 aio_sync aio_fsync aio_syncfs aio_fdatasync aio_sync_file_range
182 aio_pathsync aio_readahead aio_fiemap aio_allocate
183 aio_rename aio_rename2 aio_link aio_move aio_copy aio_group
184 aio_nop aio_mknod aio_load aio_rmtree aio_mkdir aio_chown
185 aio_chmod aio_utime aio_truncate
186 aio_msync aio_mtouch aio_mlock aio_mlockall
187 aio_statvfs
188 aio_slurp
189 aio_wd);
190
191 our @EXPORT = (@AIO_REQ, qw(aioreq_pri aioreq_nice));
192 our @EXPORT_OK = qw(poll_fileno poll_cb poll_wait flush
193 min_parallel max_parallel max_idle idle_timeout
194 nreqs nready npending nthreads
195 max_poll_time max_poll_reqs
196 sendfile fadvise madvise
197 mmap munmap mremap munlock munlockall);
198
199 push @AIO_REQ, qw(aio_busy); # not exported
200
201 @IO::AIO::GRP::ISA = 'IO::AIO::REQ';
202
203 require XSLoader;
204 XSLoader::load ("IO::AIO", $VERSION);
205 }
206
207 =head1 FUNCTIONS
208
209 =head2 QUICK OVERVIEW
210
211 This section simply lists the prototypes most of the functions for
212 quick reference. See the following sections for function-by-function
213 documentation.
214
215 aio_wd $pathname, $callback->($wd)
216 aio_open $pathname, $flags, $mode, $callback->($fh)
217 aio_close $fh, $callback->($status)
218 aio_seek $fh,$offset,$whence, $callback->($offs)
219 aio_read $fh,$offset,$length, $data,$dataoffset, $callback->($retval)
220 aio_write $fh,$offset,$length, $data,$dataoffset, $callback->($retval)
221 aio_sendfile $out_fh, $in_fh, $in_offset, $length, $callback->($retval)
222 aio_readahead $fh,$offset,$length, $callback->($retval)
223 aio_stat $fh_or_path, $callback->($status)
224 aio_lstat $fh, $callback->($status)
225 aio_statvfs $fh_or_path, $callback->($statvfs)
226 aio_utime $fh_or_path, $atime, $mtime, $callback->($status)
227 aio_chown $fh_or_path, $uid, $gid, $callback->($status)
228 aio_chmod $fh_or_path, $mode, $callback->($status)
229 aio_truncate $fh_or_path, $offset, $callback->($status)
230 aio_allocate $fh, $mode, $offset, $len, $callback->($status)
231 aio_fiemap $fh, $start, $length, $flags, $count, $cb->(\@extents)
232 aio_unlink $pathname, $callback->($status)
233 aio_mknod $pathname, $mode, $dev, $callback->($status)
234 aio_link $srcpath, $dstpath, $callback->($status)
235 aio_symlink $srcpath, $dstpath, $callback->($status)
236 aio_readlink $pathname, $callback->($link)
237 aio_realpath $pathname, $callback->($path)
238 aio_rename $srcpath, $dstpath, $callback->($status)
239 aio_rename2 $srcpath, $dstpath, $flags, $callback->($status)
240 aio_mkdir $pathname, $mode, $callback->($status)
241 aio_rmdir $pathname, $callback->($status)
242 aio_readdir $pathname, $callback->($entries)
243 aio_readdirx $pathname, $flags, $callback->($entries, $flags)
244 IO::AIO::READDIR_DENTS IO::AIO::READDIR_DIRS_FIRST
245 IO::AIO::READDIR_STAT_ORDER IO::AIO::READDIR_FOUND_UNKNOWN
246 aio_scandir $pathname, $maxreq, $callback->($dirs, $nondirs)
247 aio_load $pathname, $data, $callback->($status)
248 aio_copy $srcpath, $dstpath, $callback->($status)
249 aio_move $srcpath, $dstpath, $callback->($status)
250 aio_rmtree $pathname, $callback->($status)
251 aio_fcntl $fh, $cmd, $arg, $callback->($status)
252 aio_ioctl $fh, $request, $buf, $callback->($status)
253 aio_sync $callback->($status)
254 aio_syncfs $fh, $callback->($status)
255 aio_fsync $fh, $callback->($status)
256 aio_fdatasync $fh, $callback->($status)
257 aio_sync_file_range $fh, $offset, $nbytes, $flags, $callback->($status)
258 aio_pathsync $pathname, $callback->($status)
259 aio_msync $scalar, $offset = 0, $length = undef, flags = MS_SYNC, $callback->($status)
260 aio_mtouch $scalar, $offset = 0, $length = undef, flags = 0, $callback->($status)
261 aio_mlock $scalar, $offset = 0, $length = undef, $callback->($status)
262 aio_mlockall $flags, $callback->($status)
263 aio_group $callback->(...)
264 aio_nop $callback->()
265
266 $prev_pri = aioreq_pri [$pri]
267 aioreq_nice $pri_adjust
268
269 IO::AIO::poll_wait
270 IO::AIO::poll_cb
271 IO::AIO::poll
272 IO::AIO::flush
273 IO::AIO::max_poll_reqs $nreqs
274 IO::AIO::max_poll_time $seconds
275 IO::AIO::min_parallel $nthreads
276 IO::AIO::max_parallel $nthreads
277 IO::AIO::max_idle $nthreads
278 IO::AIO::idle_timeout $seconds
279 IO::AIO::max_outstanding $maxreqs
280 IO::AIO::nreqs
281 IO::AIO::nready
282 IO::AIO::npending
283 $nfd = IO::AIO::get_fdlimit [EXPERIMENTAL]
284 IO::AIO::min_fdlimit $nfd [EXPERIMENTAL]
285
286 IO::AIO::sendfile $ofh, $ifh, $offset, $count
287 IO::AIO::fadvise $fh, $offset, $len, $advice
288 IO::AIO::mmap $scalar, $length, $prot, $flags[, $fh[, $offset]]
289 IO::AIO::munmap $scalar
290 IO::AIO::mremap $scalar, $new_length, $flags[, $new_address]
291 IO::AIO::madvise $scalar, $offset, $length, $advice
292 IO::AIO::mprotect $scalar, $offset, $length, $protect
293 IO::AIO::munlock $scalar, $offset = 0, $length = undef
294 IO::AIO::munlockall
295
296 =head2 API NOTES
297
298 All the C<aio_*> calls are more or less thin wrappers around the syscall
299 with the same name (sans C<aio_>). The arguments are similar or identical,
300 and they all accept an additional (and optional) C<$callback> argument
301 which must be a code reference. This code reference will be called after
302 the syscall has been executed in an asynchronous fashion. The results
303 of the request will be passed as arguments to the callback (and, if an
304 error occured, in C<$!>) - for most requests the syscall return code (e.g.
305 most syscalls return C<-1> on error, unlike perl, which usually delivers
306 "false").
307
308 Some requests (such as C<aio_readdir>) pass the actual results and
309 communicate failures by passing C<undef>.
310
311 All functions expecting a filehandle keep a copy of the filehandle
312 internally until the request has finished.
313
314 All functions return request objects of type L<IO::AIO::REQ> that allow
315 further manipulation of those requests while they are in-flight.
316
317 The pathnames you pass to these routines I<should> be absolute. The
318 reason for this is that at the time the request is being executed, the
319 current working directory could have changed. Alternatively, you can
320 make sure that you never change the current working directory anywhere
321 in the program and then use relative paths. You can also take advantage
322 of IO::AIOs working directory abstraction, that lets you specify paths
323 relative to some previously-opened "working directory object" - see the
324 description of the C<IO::AIO::WD> class later in this document.
325
326 To encode pathnames as octets, either make sure you either: a) always pass
327 in filenames you got from outside (command line, readdir etc.) without
328 tinkering, b) are in your native filesystem encoding, c) use the Encode
329 module and encode your pathnames to the locale (or other) encoding in
330 effect in the user environment, d) use Glib::filename_from_unicode on
331 unicode filenames or e) use something else to ensure your scalar has the
332 correct contents.
333
334 This works, btw. independent of the internal UTF-8 bit, which IO::AIO
335 handles correctly whether it is set or not.
336
337 =head2 AIO REQUEST FUNCTIONS
338
339 =over 4
340
341 =item $prev_pri = aioreq_pri [$pri]
342
343 Returns the priority value that would be used for the next request and, if
344 C<$pri> is given, sets the priority for the next aio request.
345
346 The default priority is C<0>, the minimum and maximum priorities are C<-4>
347 and C<4>, respectively. Requests with higher priority will be serviced
348 first.
349
350 The priority will be reset to C<0> after each call to one of the C<aio_*>
351 functions.
352
353 Example: open a file with low priority, then read something from it with
354 higher priority so the read request is serviced before other low priority
355 open requests (potentially spamming the cache):
356
357 aioreq_pri -3;
358 aio_open ..., sub {
359 return unless $_[0];
360
361 aioreq_pri -2;
362 aio_read $_[0], ..., sub {
363 ...
364 };
365 };
366
367
368 =item aioreq_nice $pri_adjust
369
370 Similar to C<aioreq_pri>, but subtracts the given value from the current
371 priority, so the effect is cumulative.
372
373
374 =item aio_open $pathname, $flags, $mode, $callback->($fh)
375
376 Asynchronously open or create a file and call the callback with a newly
377 created filehandle for the file (or C<undef> in case of an error).
378
379 The pathname passed to C<aio_open> must be absolute. See API NOTES, above,
380 for an explanation.
381
382 The C<$flags> argument is a bitmask. See the C<Fcntl> module for a
383 list. They are the same as used by C<sysopen>.
384
385 Likewise, C<$mode> specifies the mode of the newly created file, if it
386 didn't exist and C<O_CREAT> has been given, just like perl's C<sysopen>,
387 except that it is mandatory (i.e. use C<0> if you don't create new files,
388 and C<0666> or C<0777> if you do). Note that the C<$mode> will be modified
389 by the umask in effect then the request is being executed, so better never
390 change the umask.
391
392 Example:
393
394 aio_open "/etc/passwd", IO::AIO::O_RDONLY, 0, sub {
395 if ($_[0]) {
396 print "open successful, fh is $_[0]\n";
397 ...
398 } else {
399 die "open failed: $!\n";
400 }
401 };
402
403 In addition to all the common open modes/flags (C<O_RDONLY>, C<O_WRONLY>,
404 C<O_RDWR>, C<O_CREAT>, C<O_TRUNC>, C<O_EXCL> and C<O_APPEND>), the
405 following POSIX and non-POSIX constants are available (missing ones on
406 your system are, as usual, C<0>):
407
408 C<O_ASYNC>, C<O_DIRECT>, C<O_NOATIME>, C<O_CLOEXEC>, C<O_NOCTTY>, C<O_NOFOLLOW>,
409 C<O_NONBLOCK>, C<O_EXEC>, C<O_SEARCH>, C<O_DIRECTORY>, C<O_DSYNC>,
410 C<O_RSYNC>, C<O_SYNC>, C<O_PATH>, C<O_TMPFILE>, C<O_TTY_INIT> and C<O_ACCMODE>.
411
412
413 =item aio_close $fh, $callback->($status)
414
415 Asynchronously close a file and call the callback with the result
416 code.
417
418 Unfortunately, you can't do this to perl. Perl I<insists> very strongly on
419 closing the file descriptor associated with the filehandle itself.
420
421 Therefore, C<aio_close> will not close the filehandle - instead it will
422 use dup2 to overwrite the file descriptor with the write-end of a pipe
423 (the pipe fd will be created on demand and will be cached).
424
425 Or in other words: the file descriptor will be closed, but it will not be
426 free for reuse until the perl filehandle is closed.
427
428 =cut
429
430 =item aio_seek $fh, $offset, $whence, $callback->($offs)
431
432 Seeks the filehandle to the new C<$offset>, similarly to perl's
433 C<sysseek>. The C<$whence> can use the traditional values (C<0> for
434 C<IO::AIO::SEEK_SET>, C<1> for C<IO::AIO::SEEK_CUR> or C<2> for
435 C<IO::AIO::SEEK_END>).
436
437 The resulting absolute offset will be passed to the callback, or C<-1> in
438 case of an error.
439
440 In theory, the C<$whence> constants could be different than the
441 corresponding values from L<Fcntl>, but perl guarantees they are the same,
442 so don't panic.
443
444 As a GNU/Linux (and maybe Solaris) extension, also the constants
445 C<IO::AIO::SEEK_DATA> and C<IO::AIO::SEEK_HOLE> are available, if they
446 could be found. No guarantees about suitability for use in C<aio_seek> or
447 Perl's C<sysseek> can be made though, although I would naively assume they
448 "just work".
449
450 =item aio_read $fh,$offset,$length, $data,$dataoffset, $callback->($retval)
451
452 =item aio_write $fh,$offset,$length, $data,$dataoffset, $callback->($retval)
453
454 Reads or writes C<$length> bytes from or to the specified C<$fh> and
455 C<$offset> into the scalar given by C<$data> and offset C<$dataoffset> and
456 calls the callback with the actual number of bytes transferred (or -1 on
457 error, just like the syscall).
458
459 C<aio_read> will, like C<sysread>, shrink or grow the C<$data> scalar to
460 offset plus the actual number of bytes read.
461
462 If C<$offset> is undefined, then the current file descriptor offset will
463 be used (and updated), otherwise the file descriptor offset will not be
464 changed by these calls.
465
466 If C<$length> is undefined in C<aio_write>, use the remaining length of
467 C<$data>.
468
469 If C<$dataoffset> is less than zero, it will be counted from the end of
470 C<$data>.
471
472 The C<$data> scalar I<MUST NOT> be modified in any way while the request
473 is outstanding. Modifying it can result in segfaults or World War III (if
474 the necessary/optional hardware is installed).
475
476 Example: Read 15 bytes at offset 7 into scalar C<$buffer>, starting at
477 offset C<0> within the scalar:
478
479 aio_read $fh, 7, 15, $buffer, 0, sub {
480 $_[0] > 0 or die "read error: $!";
481 print "read $_[0] bytes: <$buffer>\n";
482 };
483
484
485 =item aio_sendfile $out_fh, $in_fh, $in_offset, $length, $callback->($retval)
486
487 Tries to copy C<$length> bytes from C<$in_fh> to C<$out_fh>. It starts
488 reading at byte offset C<$in_offset>, and starts writing at the current
489 file offset of C<$out_fh>. Because of that, it is not safe to issue more
490 than one C<aio_sendfile> per C<$out_fh>, as they will interfere with each
491 other. The same C<$in_fh> works fine though, as this function does not
492 move or use the file offset of C<$in_fh>.
493
494 Please note that C<aio_sendfile> can read more bytes from C<$in_fh> than
495 are written, and there is no way to find out how many more bytes have been
496 read from C<aio_sendfile> alone, as C<aio_sendfile> only provides the
497 number of bytes written to C<$out_fh>. Only if the result value equals
498 C<$length> one can assume that C<$length> bytes have been read.
499
500 Unlike with other C<aio_> functions, it makes a lot of sense to use
501 C<aio_sendfile> on non-blocking sockets, as long as one end (typically
502 the C<$in_fh>) is a file - the file I/O will then be asynchronous, while
503 the socket I/O will be non-blocking. Note, however, that you can run
504 into a trap where C<aio_sendfile> reads some data with readahead, then
505 fails to write all data, and when the socket is ready the next time, the
506 data in the cache is already lost, forcing C<aio_sendfile> to again hit
507 the disk. Explicit C<aio_read> + C<aio_write> let's you better control
508 resource usage.
509
510 This call tries to make use of a native C<sendfile>-like syscall to
511 provide zero-copy operation. For this to work, C<$out_fh> should refer to
512 a socket, and C<$in_fh> should refer to an mmap'able file.
513
514 If a native sendfile cannot be found or it fails with C<ENOSYS>,
515 C<EINVAL>, C<ENOTSUP>, C<EOPNOTSUPP>, C<EAFNOSUPPORT>, C<EPROTOTYPE> or
516 C<ENOTSOCK>, it will be emulated, so you can call C<aio_sendfile> on any
517 type of filehandle regardless of the limitations of the operating system.
518
519 As native sendfile syscalls (as practically any non-POSIX interface hacked
520 together in a hurry to improve benchmark numbers) tend to be rather buggy
521 on many systems, this implementation tries to work around some known bugs
522 in Linux and FreeBSD kernels (probably others, too), but that might fail,
523 so you really really should check the return value of C<aio_sendfile> -
524 fewer bytes than expected might have been transferred.
525
526
527 =item aio_readahead $fh,$offset,$length, $callback->($retval)
528
529 C<aio_readahead> populates the page cache with data from a file so that
530 subsequent reads from that file will not block on disk I/O. The C<$offset>
531 argument specifies the starting point from which data is to be read and
532 C<$length> specifies the number of bytes to be read. I/O is performed in
533 whole pages, so that offset is effectively rounded down to a page boundary
534 and bytes are read up to the next page boundary greater than or equal to
535 (off-set+length). C<aio_readahead> does not read beyond the end of the
536 file. The current file offset of the file is left unchanged.
537
538 If that syscall doesn't exist (likely if your kernel isn't Linux) it will
539 be emulated by simply reading the data, which would have a similar effect.
540
541
542 =item aio_stat $fh_or_path, $callback->($status)
543
544 =item aio_lstat $fh, $callback->($status)
545
546 Works almost exactly like perl's C<stat> or C<lstat> in void context. The
547 callback will be called after the stat and the results will be available
548 using C<stat _> or C<-s _> and other tests (with the exception of C<-B>
549 and C<-T>).
550
551 The pathname passed to C<aio_stat> must be absolute. See API NOTES, above,
552 for an explanation.
553
554 Currently, the stats are always 64-bit-stats, i.e. instead of returning an
555 error when stat'ing a large file, the results will be silently truncated
556 unless perl itself is compiled with large file support.
557
558 To help interpret the mode and dev/rdev stat values, IO::AIO offers the
559 following constants and functions (if not implemented, the constants will
560 be C<0> and the functions will either C<croak> or fall back on traditional
561 behaviour).
562
563 C<S_IFMT>, C<S_IFIFO>, C<S_IFCHR>, C<S_IFBLK>, C<S_IFLNK>, C<S_IFREG>,
564 C<S_IFDIR>, C<S_IFWHT>, C<S_IFSOCK>, C<IO::AIO::major $dev_t>,
565 C<IO::AIO::minor $dev_t>, C<IO::AIO::makedev $major, $minor>.
566
567 To access higher resolution stat timestamps, see L<SUBSECOND STAT TIME
568 ACCESS>.
569
570 Example: Print the length of F</etc/passwd>:
571
572 aio_stat "/etc/passwd", sub {
573 $_[0] and die "stat failed: $!";
574 print "size is ", -s _, "\n";
575 };
576
577
578 =item aio_statvfs $fh_or_path, $callback->($statvfs)
579
580 Works like the POSIX C<statvfs> or C<fstatvfs> syscalls, depending on
581 whether a file handle or path was passed.
582
583 On success, the callback is passed a hash reference with the following
584 members: C<bsize>, C<frsize>, C<blocks>, C<bfree>, C<bavail>, C<files>,
585 C<ffree>, C<favail>, C<fsid>, C<flag> and C<namemax>. On failure, C<undef>
586 is passed.
587
588 The following POSIX IO::AIO::ST_* constants are defined: C<ST_RDONLY> and
589 C<ST_NOSUID>.
590
591 The following non-POSIX IO::AIO::ST_* flag masks are defined to
592 their correct value when available, or to C<0> on systems that do
593 not support them: C<ST_NODEV>, C<ST_NOEXEC>, C<ST_SYNCHRONOUS>,
594 C<ST_MANDLOCK>, C<ST_WRITE>, C<ST_APPEND>, C<ST_IMMUTABLE>, C<ST_NOATIME>,
595 C<ST_NODIRATIME> and C<ST_RELATIME>.
596
597 Example: stat C</wd> and dump out the data if successful.
598
599 aio_statvfs "/wd", sub {
600 my $f = $_[0]
601 or die "statvfs: $!";
602
603 use Data::Dumper;
604 say Dumper $f;
605 };
606
607 # result:
608 {
609 bsize => 1024,
610 bfree => 4333064312,
611 blocks => 10253828096,
612 files => 2050765568,
613 flag => 4096,
614 favail => 2042092649,
615 bavail => 4333064312,
616 ffree => 2042092649,
617 namemax => 255,
618 frsize => 1024,
619 fsid => 1810
620 }
621
622 =item aio_utime $fh_or_path, $atime, $mtime, $callback->($status)
623
624 Works like perl's C<utime> function (including the special case of $atime
625 and $mtime being undef). Fractional times are supported if the underlying
626 syscalls support them.
627
628 When called with a pathname, uses utimensat(2) or utimes(2) if available,
629 otherwise utime(2). If called on a file descriptor, uses futimens(2)
630 or futimes(2) if available, otherwise returns ENOSYS, so this is not
631 portable.
632
633 Examples:
634
635 # set atime and mtime to current time (basically touch(1)):
636 aio_utime "path", undef, undef;
637 # set atime to current time and mtime to beginning of the epoch:
638 aio_utime "path", time, undef; # undef==0
639
640
641 =item aio_chown $fh_or_path, $uid, $gid, $callback->($status)
642
643 Works like perl's C<chown> function, except that C<undef> for either $uid
644 or $gid is being interpreted as "do not change" (but -1 can also be used).
645
646 Examples:
647
648 # same as "chown root path" in the shell:
649 aio_chown "path", 0, -1;
650 # same as above:
651 aio_chown "path", 0, undef;
652
653
654 =item aio_truncate $fh_or_path, $offset, $callback->($status)
655
656 Works like truncate(2) or ftruncate(2).
657
658
659 =item aio_allocate $fh, $mode, $offset, $len, $callback->($status)
660
661 Allocates or frees disk space according to the C<$mode> argument. See the
662 linux C<fallocate> documentation for details.
663
664 C<$mode> is usually C<0> or C<IO::AIO::FALLOC_FL_KEEP_SIZE> to allocate
665 space, or C<IO::AIO::FALLOC_FL_PUNCH_HOLE | IO::AIO::FALLOC_FL_KEEP_SIZE>,
666 to deallocate a file range.
667
668 IO::AIO also supports C<FALLOC_FL_COLLAPSE_RANGE>, to remove a range
669 (without leaving a hole), C<FALLOC_FL_ZERO_RANGE>, to zero a range,
670 C<FALLOC_FL_INSERT_RANGE> to insert a range and C<FALLOC_FL_UNSHARE_RANGE>
671 to unshare shared blocks (see your L<fallocate(2)> manpage).
672
673 The file system block size used by C<fallocate> is presumably the
674 C<f_bsize> returned by C<statvfs>, but different filesystems and filetypes
675 can dictate other limitations.
676
677 If C<fallocate> isn't available or cannot be emulated (currently no
678 emulation will be attempted), passes C<-1> and sets C<$!> to C<ENOSYS>.
679
680
681 =item aio_chmod $fh_or_path, $mode, $callback->($status)
682
683 Works like perl's C<chmod> function.
684
685
686 =item aio_unlink $pathname, $callback->($status)
687
688 Asynchronously unlink (delete) a file and call the callback with the
689 result code.
690
691
692 =item aio_mknod $pathname, $mode, $dev, $callback->($status)
693
694 [EXPERIMENTAL]
695
696 Asynchronously create a device node (or fifo). See mknod(2).
697
698 The only (POSIX-) portable way of calling this function is:
699
700 aio_mknod $pathname, IO::AIO::S_IFIFO | $mode, 0, sub { ...
701
702 See C<aio_stat> for info about some potentially helpful extra constants
703 and functions.
704
705 =item aio_link $srcpath, $dstpath, $callback->($status)
706
707 Asynchronously create a new link to the existing object at C<$srcpath> at
708 the path C<$dstpath> and call the callback with the result code.
709
710
711 =item aio_symlink $srcpath, $dstpath, $callback->($status)
712
713 Asynchronously create a new symbolic link to the existing object at C<$srcpath> at
714 the path C<$dstpath> and call the callback with the result code.
715
716
717 =item aio_readlink $pathname, $callback->($link)
718
719 Asynchronously read the symlink specified by C<$path> and pass it to
720 the callback. If an error occurs, nothing or undef gets passed to the
721 callback.
722
723
724 =item aio_realpath $pathname, $callback->($path)
725
726 Asynchronously make the path absolute and resolve any symlinks in
727 C<$path>. The resulting path only consists of directories (same as
728 L<Cwd::realpath>).
729
730 This request can be used to get the absolute path of the current working
731 directory by passing it a path of F<.> (a single dot).
732
733
734 =item aio_rename $srcpath, $dstpath, $callback->($status)
735
736 Asynchronously rename the object at C<$srcpath> to C<$dstpath>, just as
737 rename(2) and call the callback with the result code.
738
739 On systems that support the AIO::WD working directory abstraction
740 natively, the case C<[$wd, "."]> as C<$srcpath> is specialcased - instead
741 of failing, C<rename> is called on the absolute path of C<$wd>.
742
743
744 =item aio_rename2 $srcpath, $dstpath, $flags, $callback->($status)
745
746 Basically a version of C<aio_rename> with an additional C<$flags>
747 argument. Calling this with C<$flags=0> is the same as calling
748 C<aio_rename>.
749
750 Non-zero flags are currently only supported on GNU/Linux systems that
751 support renameat2. Other systems fail with C<ENOSYS> in this case.
752
753 The following constants are available (missing ones are, as usual C<0>),
754 see renameat2(2) for details:
755
756 C<IO::AIO::RENAME_NOREPLACE>, C<IO::AIO::RENAME_EXCHANGE>
757 and C<IO::AIO::RENAME_WHITEOUT>.
758
759
760 =item aio_mkdir $pathname, $mode, $callback->($status)
761
762 Asynchronously mkdir (create) a directory and call the callback with
763 the result code. C<$mode> will be modified by the umask at the time the
764 request is executed, so do not change your umask.
765
766
767 =item aio_rmdir $pathname, $callback->($status)
768
769 Asynchronously rmdir (delete) a directory and call the callback with the
770 result code.
771
772 On systems that support the AIO::WD working directory abstraction
773 natively, the case C<[$wd, "."]> is specialcased - instead of failing,
774 C<rmdir> is called on the absolute path of C<$wd>.
775
776
777 =item aio_readdir $pathname, $callback->($entries)
778
779 Unlike the POSIX call of the same name, C<aio_readdir> reads an entire
780 directory (i.e. opendir + readdir + closedir). The entries will not be
781 sorted, and will B<NOT> include the C<.> and C<..> entries.
782
783 The callback is passed a single argument which is either C<undef> or an
784 array-ref with the filenames.
785
786
787 =item aio_readdirx $pathname, $flags, $callback->($entries, $flags)
788
789 Quite similar to C<aio_readdir>, but the C<$flags> argument allows one to
790 tune behaviour and output format. In case of an error, C<$entries> will be
791 C<undef>.
792
793 The flags are a combination of the following constants, ORed together (the
794 flags will also be passed to the callback, possibly modified):
795
796 =over 4
797
798 =item IO::AIO::READDIR_DENTS
799
800 Normally the callback gets an arrayref consisting of names only (as
801 with C<aio_readdir>). If this flag is set, then the callback gets an
802 arrayref with C<[$name, $type, $inode]> arrayrefs, each describing a
803 single directory entry in more detail:
804
805 C<$name> is the name of the entry.
806
807 C<$type> is one of the C<IO::AIO::DT_xxx> constants:
808
809 C<IO::AIO::DT_UNKNOWN>, C<IO::AIO::DT_FIFO>, C<IO::AIO::DT_CHR>, C<IO::AIO::DT_DIR>,
810 C<IO::AIO::DT_BLK>, C<IO::AIO::DT_REG>, C<IO::AIO::DT_LNK>, C<IO::AIO::DT_SOCK>,
811 C<IO::AIO::DT_WHT>.
812
813 C<IO::AIO::DT_UNKNOWN> means just that: readdir does not know. If you need
814 to know, you have to run stat yourself. Also, for speed/memory reasons,
815 the C<$type> scalars are read-only: you must not modify them.
816
817 C<$inode> is the inode number (which might not be exact on systems with 64
818 bit inode numbers and 32 bit perls). This field has unspecified content on
819 systems that do not deliver the inode information.
820
821 =item IO::AIO::READDIR_DIRS_FIRST
822
823 When this flag is set, then the names will be returned in an order where
824 likely directories come first, in optimal stat order. This is useful when
825 you need to quickly find directories, or you want to find all directories
826 while avoiding to stat() each entry.
827
828 If the system returns type information in readdir, then this is used
829 to find directories directly. Otherwise, likely directories are names
830 beginning with ".", or otherwise names with no dots, of which names with
831 short names are tried first.
832
833 =item IO::AIO::READDIR_STAT_ORDER
834
835 When this flag is set, then the names will be returned in an order
836 suitable for stat()'ing each one. That is, when you plan to stat() most or
837 all files in the given directory, then the returned order will likely be
838 faster.
839
840 If both this flag and C<IO::AIO::READDIR_DIRS_FIRST> are specified,
841 then the likely dirs come first, resulting in a less optimal stat order
842 for stat'ing all entries, but likely a more optimal order for finding
843 subdirectories.
844
845 =item IO::AIO::READDIR_FOUND_UNKNOWN
846
847 This flag should not be set when calling C<aio_readdirx>. Instead, it
848 is being set by C<aio_readdirx>, when any of the C<$type>'s found were
849 C<IO::AIO::DT_UNKNOWN>. The absence of this flag therefore indicates that all
850 C<$type>'s are known, which can be used to speed up some algorithms.
851
852 =back
853
854
855 =item aio_slurp $pathname, $offset, $length, $data, $callback->($status)
856
857 Opens, reads and closes the given file. The data is put into C<$data>,
858 which is resized as required.
859
860 If C<$offset> is negative, then it is counted from the end of the file.
861
862 If C<$length> is zero, then the remaining length of the file is
863 used. Also, in this case, the same limitations to modifying C<$data> apply
864 as when IO::AIO::mmap is used, i.e. it must only be modified in-place
865 with C<substr>. If the size of the file is known, specifying a non-zero
866 C<$length> results in a performance advantage.
867
868 This request is similar to the older C<aio_load> request, but since it is
869 a single request, it might be more efficient to use.
870
871 Example: load F</etc/passwd> into C<$passwd>.
872
873 my $passwd;
874 aio_slurp "/etc/passwd", 0, 0, $passwd, sub {
875 $_[0] >= 0
876 or die "/etc/passwd: $!\n";
877
878 printf "/etc/passwd is %d bytes long, and contains:\n", length $passwd;
879 print $passwd;
880 };
881 IO::AIO::flush;
882
883
884 =item aio_load $pathname, $data, $callback->($status)
885
886 This is a composite request that tries to fully load the given file into
887 memory. Status is the same as with aio_read.
888
889 Using C<aio_slurp> might be more efficient, as it is a single request.
890
891 =cut
892
893 sub aio_load($$;$) {
894 my ($path, undef, $cb) = @_;
895 my $data = \$_[1];
896
897 my $pri = aioreq_pri;
898 my $grp = aio_group $cb;
899
900 aioreq_pri $pri;
901 add $grp aio_open $path, O_RDONLY, 0, sub {
902 my $fh = shift
903 or return $grp->result (-1);
904
905 aioreq_pri $pri;
906 add $grp aio_read $fh, 0, (-s $fh), $$data, 0, sub {
907 $grp->result ($_[0]);
908 };
909 };
910
911 $grp
912 }
913
914 =item aio_copy $srcpath, $dstpath, $callback->($status)
915
916 Try to copy the I<file> (directories not supported as either source or
917 destination) from C<$srcpath> to C<$dstpath> and call the callback with
918 a status of C<0> (ok) or C<-1> (error, see C<$!>).
919
920 Existing destination files will be truncated.
921
922 This is a composite request that creates the destination file with
923 mode 0200 and copies the contents of the source file into it using
924 C<aio_sendfile>, followed by restoring atime, mtime, access mode and
925 uid/gid, in that order.
926
927 If an error occurs, the partial destination file will be unlinked, if
928 possible, except when setting atime, mtime, access mode and uid/gid, where
929 errors are being ignored.
930
931 =cut
932
933 sub aio_copy($$;$) {
934 my ($src, $dst, $cb) = @_;
935
936 my $pri = aioreq_pri;
937 my $grp = aio_group $cb;
938
939 aioreq_pri $pri;
940 add $grp aio_open $src, O_RDONLY, 0, sub {
941 if (my $src_fh = $_[0]) {
942 my @stat = stat $src_fh; # hmm, might block over nfs?
943
944 aioreq_pri $pri;
945 add $grp aio_open $dst, O_CREAT | O_WRONLY | O_TRUNC, 0200, sub {
946 if (my $dst_fh = $_[0]) {
947 aioreq_pri $pri;
948 add $grp aio_sendfile $dst_fh, $src_fh, 0, $stat[7], sub {
949 if ($_[0] == $stat[7]) {
950 $grp->result (0);
951 close $src_fh;
952
953 my $ch = sub {
954 aioreq_pri $pri;
955 add $grp aio_chmod $dst_fh, $stat[2] & 07777, sub {
956 aioreq_pri $pri;
957 add $grp aio_chown $dst_fh, $stat[4], $stat[5], sub {
958 aioreq_pri $pri;
959 add $grp aio_close $dst_fh;
960 }
961 };
962 };
963
964 aioreq_pri $pri;
965 add $grp aio_utime $dst_fh, $stat[8], $stat[9], sub {
966 if ($_[0] < 0 && $! == ENOSYS) {
967 aioreq_pri $pri;
968 add $grp aio_utime $dst, $stat[8], $stat[9], $ch;
969 } else {
970 $ch->();
971 }
972 };
973 } else {
974 $grp->result (-1);
975 close $src_fh;
976 close $dst_fh;
977
978 aioreq $pri;
979 add $grp aio_unlink $dst;
980 }
981 };
982 } else {
983 $grp->result (-1);
984 }
985 },
986
987 } else {
988 $grp->result (-1);
989 }
990 };
991
992 $grp
993 }
994
995 =item aio_move $srcpath, $dstpath, $callback->($status)
996
997 Try to move the I<file> (directories not supported as either source or
998 destination) from C<$srcpath> to C<$dstpath> and call the callback with
999 a status of C<0> (ok) or C<-1> (error, see C<$!>).
1000
1001 This is a composite request that tries to rename(2) the file first; if
1002 rename fails with C<EXDEV>, it copies the file with C<aio_copy> and, if
1003 that is successful, unlinks the C<$srcpath>.
1004
1005 =cut
1006
1007 sub aio_move($$;$) {
1008 my ($src, $dst, $cb) = @_;
1009
1010 my $pri = aioreq_pri;
1011 my $grp = aio_group $cb;
1012
1013 aioreq_pri $pri;
1014 add $grp aio_rename $src, $dst, sub {
1015 if ($_[0] && $! == EXDEV) {
1016 aioreq_pri $pri;
1017 add $grp aio_copy $src, $dst, sub {
1018 $grp->result ($_[0]);
1019
1020 unless ($_[0]) {
1021 aioreq_pri $pri;
1022 add $grp aio_unlink $src;
1023 }
1024 };
1025 } else {
1026 $grp->result ($_[0]);
1027 }
1028 };
1029
1030 $grp
1031 }
1032
1033 =item aio_scandir $pathname, $maxreq, $callback->($dirs, $nondirs)
1034
1035 Scans a directory (similar to C<aio_readdir>) but additionally tries to
1036 efficiently separate the entries of directory C<$path> into two sets of
1037 names, directories you can recurse into (directories), and ones you cannot
1038 recurse into (everything else, including symlinks to directories).
1039
1040 C<aio_scandir> is a composite request that generates many sub requests.
1041 C<$maxreq> specifies the maximum number of outstanding aio requests that
1042 this function generates. If it is C<< <= 0 >>, then a suitable default
1043 will be chosen (currently 4).
1044
1045 On error, the callback is called without arguments, otherwise it receives
1046 two array-refs with path-relative entry names.
1047
1048 Example:
1049
1050 aio_scandir $dir, 0, sub {
1051 my ($dirs, $nondirs) = @_;
1052 print "real directories: @$dirs\n";
1053 print "everything else: @$nondirs\n";
1054 };
1055
1056 Implementation notes.
1057
1058 The C<aio_readdir> cannot be avoided, but C<stat()>'ing every entry can.
1059
1060 If readdir returns file type information, then this is used directly to
1061 find directories.
1062
1063 Otherwise, after reading the directory, the modification time, size etc.
1064 of the directory before and after the readdir is checked, and if they
1065 match (and isn't the current time), the link count will be used to decide
1066 how many entries are directories (if >= 2). Otherwise, no knowledge of the
1067 number of subdirectories will be assumed.
1068
1069 Then entries will be sorted into likely directories a non-initial dot
1070 currently) and likely non-directories (see C<aio_readdirx>). Then every
1071 entry plus an appended C</.> will be C<stat>'ed, likely directories first,
1072 in order of their inode numbers. If that succeeds, it assumes that the
1073 entry is a directory or a symlink to directory (which will be checked
1074 separately). This is often faster than stat'ing the entry itself because
1075 filesystems might detect the type of the entry without reading the inode
1076 data (e.g. ext2fs filetype feature), even on systems that cannot return
1077 the filetype information on readdir.
1078
1079 If the known number of directories (link count - 2) has been reached, the
1080 rest of the entries is assumed to be non-directories.
1081
1082 This only works with certainty on POSIX (= UNIX) filesystems, which
1083 fortunately are the vast majority of filesystems around.
1084
1085 It will also likely work on non-POSIX filesystems with reduced efficiency
1086 as those tend to return 0 or 1 as link counts, which disables the
1087 directory counting heuristic.
1088
1089 =cut
1090
1091 sub aio_scandir($$;$) {
1092 my ($path, $maxreq, $cb) = @_;
1093
1094 my $pri = aioreq_pri;
1095
1096 my $grp = aio_group $cb;
1097
1098 $maxreq = 4 if $maxreq <= 0;
1099
1100 # get a wd object
1101 aioreq_pri $pri;
1102 add $grp aio_wd $path, sub {
1103 $_[0]
1104 or return $grp->result ();
1105
1106 my $wd = [shift, "."];
1107
1108 # stat once
1109 aioreq_pri $pri;
1110 add $grp aio_stat $wd, sub {
1111 return $grp->result () if $_[0];
1112 my $now = time;
1113 my $hash1 = join ":", (stat _)[0,1,3,7,9];
1114
1115 # read the directory entries
1116 aioreq_pri $pri;
1117 add $grp aio_readdirx $wd, READDIR_DIRS_FIRST, sub {
1118 my $entries = shift
1119 or return $grp->result ();
1120
1121 # stat the dir another time
1122 aioreq_pri $pri;
1123 add $grp aio_stat $wd, sub {
1124 my $hash2 = join ":", (stat _)[0,1,3,7,9];
1125
1126 my $ndirs;
1127
1128 # take the slow route if anything looks fishy
1129 if ($hash1 ne $hash2 or (stat _)[9] == $now) {
1130 $ndirs = -1;
1131 } else {
1132 # if nlink == 2, we are finished
1133 # for non-posix-fs's, we rely on nlink < 2
1134 $ndirs = (stat _)[3] - 2
1135 or return $grp->result ([], $entries);
1136 }
1137
1138 my (@dirs, @nondirs);
1139
1140 my $statgrp = add $grp aio_group sub {
1141 $grp->result (\@dirs, \@nondirs);
1142 };
1143
1144 limit $statgrp $maxreq;
1145 feed $statgrp sub {
1146 return unless @$entries;
1147 my $entry = shift @$entries;
1148
1149 aioreq_pri $pri;
1150 $wd->[1] = "$entry/.";
1151 add $statgrp aio_stat $wd, sub {
1152 if ($_[0] < 0) {
1153 push @nondirs, $entry;
1154 } else {
1155 # need to check for real directory
1156 aioreq_pri $pri;
1157 $wd->[1] = $entry;
1158 add $statgrp aio_lstat $wd, sub {
1159 if (-d _) {
1160 push @dirs, $entry;
1161
1162 unless (--$ndirs) {
1163 push @nondirs, @$entries;
1164 feed $statgrp;
1165 }
1166 } else {
1167 push @nondirs, $entry;
1168 }
1169 }
1170 }
1171 };
1172 };
1173 };
1174 };
1175 };
1176 };
1177
1178 $grp
1179 }
1180
1181 =item aio_rmtree $pathname, $callback->($status)
1182
1183 Delete a directory tree starting (and including) C<$path>, return the
1184 status of the final C<rmdir> only. This is a composite request that
1185 uses C<aio_scandir> to recurse into and rmdir directories, and unlink
1186 everything else.
1187
1188 =cut
1189
1190 sub aio_rmtree;
1191 sub aio_rmtree($;$) {
1192 my ($path, $cb) = @_;
1193
1194 my $pri = aioreq_pri;
1195 my $grp = aio_group $cb;
1196
1197 aioreq_pri $pri;
1198 add $grp aio_scandir $path, 0, sub {
1199 my ($dirs, $nondirs) = @_;
1200
1201 my $dirgrp = aio_group sub {
1202 add $grp aio_rmdir $path, sub {
1203 $grp->result ($_[0]);
1204 };
1205 };
1206
1207 (aioreq_pri $pri), add $dirgrp aio_rmtree "$path/$_" for @$dirs;
1208 (aioreq_pri $pri), add $dirgrp aio_unlink "$path/$_" for @$nondirs;
1209
1210 add $grp $dirgrp;
1211 };
1212
1213 $grp
1214 }
1215
1216 =item aio_fcntl $fh, $cmd, $arg, $callback->($status)
1217
1218 =item aio_ioctl $fh, $request, $buf, $callback->($status)
1219
1220 These work just like the C<fcntl> and C<ioctl> built-in functions, except
1221 they execute asynchronously and pass the return value to the callback.
1222
1223 Both calls can be used for a lot of things, some of which make more sense
1224 to run asynchronously in their own thread, while some others make less
1225 sense. For example, calls that block waiting for external events, such
1226 as locking, will also lock down an I/O thread while it is waiting, which
1227 can deadlock the whole I/O system. At the same time, there might be no
1228 alternative to using a thread to wait.
1229
1230 So in general, you should only use these calls for things that do
1231 (filesystem) I/O, not for things that wait for other events (network,
1232 other processes), although if you are careful and know what you are doing,
1233 you still can.
1234
1235 The following constants are available (missing ones are, as usual C<0>):
1236
1237 C<F_DUPFD_CLOEXEC>,
1238
1239 C<F_OFD_GETLK>, C<F_OFD_SETLK>, C<F_OFD_GETLKW>,
1240
1241 C<FIFREEZE>, C<FITHAW>, C<FITRIM>, C<FICLONE>, C<FICLONERANGE>, C<FIDEDUPERANGE>.
1242
1243 C<FS_IOC_GETFLAGS>, C<FS_IOC_SETFLAGS>, C<FS_IOC_GETVERSION>, C<FS_IOC_SETVERSION>,
1244 C<FS_IOC_FIEMAP>.
1245
1246 C<FS_IOC_FSGETXATTR>, C<FS_IOC_FSSETXATTR>, C<FS_IOC_SET_ENCRYPTION_POLICY>,
1247 C<FS_IOC_GET_ENCRYPTION_PWSALT>, C<FS_IOC_GET_ENCRYPTION_POLICY>, C<FS_KEY_DESCRIPTOR_SIZE>.
1248
1249 C<FS_SECRM_FL>, C<FS_UNRM_FL>, C<FS_COMPR_FL>, C<FS_SYNC_FL>, C<FS_IMMUTABLE_FL>,
1250 C<FS_APPEND_FL>, C<FS_NODUMP_FL>, C<FS_NOATIME_FL>, C<FS_DIRTY_FL>,
1251 C<FS_COMPRBLK_FL>, C<FS_NOCOMP_FL>, C<FS_ENCRYPT_FL>, C<FS_BTREE_FL>,
1252 C<FS_INDEX_FL>, C<FS_JOURNAL_DATA_FL>, C<FS_NOTAIL_FL>, C<FS_DIRSYNC_FL>, C<FS_TOPDIR_FL>,
1253 C<FS_FL_USER_MODIFIABLE>.
1254
1255 C<FS_XFLAG_REALTIME>, C<FS_XFLAG_PREALLOC>, C<FS_XFLAG_IMMUTABLE>, C<FS_XFLAG_APPEND>,
1256 C<FS_XFLAG_SYNC>, C<FS_XFLAG_NOATIME>, C<FS_XFLAG_NODUMP>, C<FS_XFLAG_RTINHERIT>,
1257 C<FS_XFLAG_PROJINHERIT>, C<FS_XFLAG_NOSYMLINKS>, C<FS_XFLAG_EXTSIZE>, C<FS_XFLAG_EXTSZINHERIT>,
1258 C<FS_XFLAG_NODEFRAG>, C<FS_XFLAG_FILESTREAM>, C<FS_XFLAG_DAX>, C<FS_XFLAG_HASATTR>,
1259
1260 =item aio_sync $callback->($status)
1261
1262 Asynchronously call sync and call the callback when finished.
1263
1264 =item aio_fsync $fh, $callback->($status)
1265
1266 Asynchronously call fsync on the given filehandle and call the callback
1267 with the fsync result code.
1268
1269 =item aio_fdatasync $fh, $callback->($status)
1270
1271 Asynchronously call fdatasync on the given filehandle and call the
1272 callback with the fdatasync result code.
1273
1274 If this call isn't available because your OS lacks it or it couldn't be
1275 detected, it will be emulated by calling C<fsync> instead.
1276
1277 =item aio_syncfs $fh, $callback->($status)
1278
1279 Asynchronously call the syncfs syscall to sync the filesystem associated
1280 to the given filehandle and call the callback with the syncfs result
1281 code. If syncfs is not available, calls sync(), but returns C<-1> and sets
1282 errno to C<ENOSYS> nevertheless.
1283
1284 =item aio_sync_file_range $fh, $offset, $nbytes, $flags, $callback->($status)
1285
1286 Sync the data portion of the file specified by C<$offset> and C<$length>
1287 to disk (but NOT the metadata), by calling the Linux-specific
1288 sync_file_range call. If sync_file_range is not available or it returns
1289 ENOSYS, then fdatasync or fsync is being substituted.
1290
1291 C<$flags> can be a combination of C<IO::AIO::SYNC_FILE_RANGE_WAIT_BEFORE>,
1292 C<IO::AIO::SYNC_FILE_RANGE_WRITE> and
1293 C<IO::AIO::SYNC_FILE_RANGE_WAIT_AFTER>: refer to the sync_file_range
1294 manpage for details.
1295
1296 =item aio_pathsync $pathname, $callback->($status)
1297
1298 This request tries to open, fsync and close the given path. This is a
1299 composite request intended to sync directories after directory operations
1300 (E.g. rename). This might not work on all operating systems or have any
1301 specific effect, but usually it makes sure that directory changes get
1302 written to disc. It works for anything that can be opened for read-only,
1303 not just directories.
1304
1305 Future versions of this function might fall back to other methods when
1306 C<fsync> on the directory fails (such as calling C<sync>).
1307
1308 Passes C<0> when everything went ok, and C<-1> on error.
1309
1310 =cut
1311
1312 sub aio_pathsync($;$) {
1313 my ($path, $cb) = @_;
1314
1315 my $pri = aioreq_pri;
1316 my $grp = aio_group $cb;
1317
1318 aioreq_pri $pri;
1319 add $grp aio_open $path, O_RDONLY, 0, sub {
1320 my ($fh) = @_;
1321 if ($fh) {
1322 aioreq_pri $pri;
1323 add $grp aio_fsync $fh, sub {
1324 $grp->result ($_[0]);
1325
1326 aioreq_pri $pri;
1327 add $grp aio_close $fh;
1328 };
1329 } else {
1330 $grp->result (-1);
1331 }
1332 };
1333
1334 $grp
1335 }
1336
1337 =item aio_msync $scalar, $offset = 0, $length = undef, flags = MS_SYNC, $callback->($status)
1338
1339 This is a rather advanced IO::AIO call, which only works on mmap(2)ed
1340 scalars (see the C<IO::AIO::mmap> function, although it also works on data
1341 scalars managed by the L<Sys::Mmap> or L<Mmap> modules, note that the
1342 scalar must only be modified in-place while an aio operation is pending on
1343 it).
1344
1345 It calls the C<msync> function of your OS, if available, with the memory
1346 area starting at C<$offset> in the string and ending C<$length> bytes
1347 later. If C<$length> is negative, counts from the end, and if C<$length>
1348 is C<undef>, then it goes till the end of the string. The flags can be
1349 either C<IO::AIO::MS_ASYNC> or C<IO::AIO::MS_SYNC>, plus an optional
1350 C<IO::AIO::MS_INVALIDATE>.
1351
1352 =item aio_mtouch $scalar, $offset = 0, $length = undef, flags = 0, $callback->($status)
1353
1354 This is a rather advanced IO::AIO call, which works best on mmap(2)ed
1355 scalars.
1356
1357 It touches (reads or writes) all memory pages in the specified
1358 range inside the scalar. All caveats and parameters are the same
1359 as for C<aio_msync>, above, except for flags, which must be either
1360 C<0> (which reads all pages and ensures they are instantiated) or
1361 C<IO::AIO::MT_MODIFY>, which modifies the memory pages (by reading and
1362 writing an octet from it, which dirties the page).
1363
1364 =item aio_mlock $scalar, $offset = 0, $length = undef, $callback->($status)
1365
1366 This is a rather advanced IO::AIO call, which works best on mmap(2)ed
1367 scalars.
1368
1369 It reads in all the pages of the underlying storage into memory (if any)
1370 and locks them, so they are not getting swapped/paged out or removed.
1371
1372 If C<$length> is undefined, then the scalar will be locked till the end.
1373
1374 On systems that do not implement C<mlock>, this function returns C<-1>
1375 and sets errno to C<ENOSYS>.
1376
1377 Note that the corresponding C<munlock> is synchronous and is
1378 documented under L<MISCELLANEOUS FUNCTIONS>.
1379
1380 Example: open a file, mmap and mlock it - both will be undone when
1381 C<$data> gets destroyed.
1382
1383 open my $fh, "<", $path or die "$path: $!";
1384 my $data;
1385 IO::AIO::mmap $data, -s $fh, IO::AIO::PROT_READ, IO::AIO::MAP_SHARED, $fh;
1386 aio_mlock $data; # mlock in background
1387
1388 =item aio_mlockall $flags, $callback->($status)
1389
1390 Calls the C<mlockall> function with the given C<$flags> (a
1391 combination of C<IO::AIO::MCL_CURRENT>, C<IO::AIO::MCL_FUTURE> and
1392 C<IO::AIO::MCL_ONFAULT>).
1393
1394 On systems that do not implement C<mlockall>, this function returns C<-1>
1395 and sets errno to C<ENOSYS>. Similarly, flag combinations not supported
1396 by the system result in a return value of C<-1> with errno being set to
1397 C<EINVAL>.
1398
1399 Note that the corresponding C<munlockall> is synchronous and is
1400 documented under L<MISCELLANEOUS FUNCTIONS>.
1401
1402 Example: asynchronously lock all current and future pages into memory.
1403
1404 aio_mlockall IO::AIO::MCL_FUTURE;
1405
1406 =item aio_fiemap $fh, $start, $length, $flags, $count, $cb->(\@extents)
1407
1408 Queries the extents of the given file (by calling the Linux C<FIEMAP>
1409 ioctl, see L<http://cvs.schmorp.de/IO-AIO/doc/fiemap.txt> for details). If
1410 the ioctl is not available on your OS, then this request will fail with
1411 C<ENOSYS>.
1412
1413 C<$start> is the starting offset to query extents for, C<$length> is the
1414 size of the range to query - if it is C<undef>, then the whole file will
1415 be queried.
1416
1417 C<$flags> is a combination of flags (C<IO::AIO::FIEMAP_FLAG_SYNC> or
1418 C<IO::AIO::FIEMAP_FLAG_XATTR> - C<IO::AIO::FIEMAP_FLAGS_COMPAT> is also
1419 exported), and is normally C<0> or C<IO::AIO::FIEMAP_FLAG_SYNC> to query
1420 the data portion.
1421
1422 C<$count> is the maximum number of extent records to return. If it is
1423 C<undef>, then IO::AIO queries all extents of the range. As a very special
1424 case, if it is C<0>, then the callback receives the number of extents
1425 instead of the extents themselves (which is unreliable, see below).
1426
1427 If an error occurs, the callback receives no arguments. The special
1428 C<errno> value C<IO::AIO::EBADR> is available to test for flag errors.
1429
1430 Otherwise, the callback receives an array reference with extent
1431 structures. Each extent structure is an array reference itself, with the
1432 following members:
1433
1434 [$logical, $physical, $length, $flags]
1435
1436 Flags is any combination of the following flag values (typically either C<0>
1437 or C<IO::AIO::FIEMAP_EXTENT_LAST> (1)):
1438
1439 C<IO::AIO::FIEMAP_EXTENT_LAST>, C<IO::AIO::FIEMAP_EXTENT_UNKNOWN>,
1440 C<IO::AIO::FIEMAP_EXTENT_DELALLOC>, C<IO::AIO::FIEMAP_EXTENT_ENCODED>,
1441 C<IO::AIO::FIEMAP_EXTENT_DATA_ENCRYPTED>, C<IO::AIO::FIEMAP_EXTENT_NOT_ALIGNED>,
1442 C<IO::AIO::FIEMAP_EXTENT_DATA_INLINE>, C<IO::AIO::FIEMAP_EXTENT_DATA_TAIL>,
1443 C<IO::AIO::FIEMAP_EXTENT_UNWRITTEN>, C<IO::AIO::FIEMAP_EXTENT_MERGED> or
1444 C<IO::AIO::FIEMAP_EXTENT_SHARED>.
1445
1446 At the time of this writing (Linux 3.2), this request is unreliable unless
1447 C<$count> is C<undef>, as the kernel has all sorts of bugs preventing
1448 it to return all extents of a range for files with a large number of
1449 extents. The code (only) works around all these issues if C<$count> is
1450 C<undef>.
1451
1452 =item aio_group $callback->(...)
1453
1454 This is a very special aio request: Instead of doing something, it is a
1455 container for other aio requests, which is useful if you want to bundle
1456 many requests into a single, composite, request with a definite callback
1457 and the ability to cancel the whole request with its subrequests.
1458
1459 Returns an object of class L<IO::AIO::GRP>. See its documentation below
1460 for more info.
1461
1462 Example:
1463
1464 my $grp = aio_group sub {
1465 print "all stats done\n";
1466 };
1467
1468 add $grp
1469 (aio_stat ...),
1470 (aio_stat ...),
1471 ...;
1472
1473 =item aio_nop $callback->()
1474
1475 This is a special request - it does nothing in itself and is only used for
1476 side effects, such as when you want to add a dummy request to a group so
1477 that finishing the requests in the group depends on executing the given
1478 code.
1479
1480 While this request does nothing, it still goes through the execution
1481 phase and still requires a worker thread. Thus, the callback will not
1482 be executed immediately but only after other requests in the queue have
1483 entered their execution phase. This can be used to measure request
1484 latency.
1485
1486 =item IO::AIO::aio_busy $fractional_seconds, $callback->() *NOT EXPORTED*
1487
1488 Mainly used for debugging and benchmarking, this aio request puts one of
1489 the request workers to sleep for the given time.
1490
1491 While it is theoretically handy to have simple I/O scheduling requests
1492 like sleep and file handle readable/writable, the overhead this creates is
1493 immense (it blocks a thread for a long time) so do not use this function
1494 except to put your application under artificial I/O pressure.
1495
1496 =back
1497
1498
1499 =head2 IO::AIO::WD - multiple working directories
1500
1501 Your process only has one current working directory, which is used by all
1502 threads. This makes it hard to use relative paths (some other component
1503 could call C<chdir> at any time, and it is hard to control when the path
1504 will be used by IO::AIO).
1505
1506 One solution for this is to always use absolute paths. This usually works,
1507 but can be quite slow (the kernel has to walk the whole path on every
1508 access), and can also be a hassle to implement.
1509
1510 Newer POSIX systems have a number of functions (openat, fdopendir,
1511 futimensat and so on) that make it possible to specify working directories
1512 per operation.
1513
1514 For portability, and because the clowns who "designed", or shall I write,
1515 perpetrated this new interface were obviously half-drunk, this abstraction
1516 cannot be perfect, though.
1517
1518 IO::AIO allows you to convert directory paths into a so-called IO::AIO::WD
1519 object. This object stores the canonicalised, absolute version of the
1520 path, and on systems that allow it, also a directory file descriptor.
1521
1522 Everywhere where a pathname is accepted by IO::AIO (e.g. in C<aio_stat>
1523 or C<aio_unlink>), one can specify an array reference with an IO::AIO::WD
1524 object and a pathname instead (or the IO::AIO::WD object alone, which
1525 gets interpreted as C<[$wd, "."]>). If the pathname is absolute, the
1526 IO::AIO::WD object is ignored, otherwise the pathname is resolved relative
1527 to that IO::AIO::WD object.
1528
1529 For example, to get a wd object for F</etc> and then stat F<passwd>
1530 inside, you would write:
1531
1532 aio_wd "/etc", sub {
1533 my $etcdir = shift;
1534
1535 # although $etcdir can be undef on error, there is generally no reason
1536 # to check for errors here, as aio_stat will fail with ENOENT
1537 # when $etcdir is undef.
1538
1539 aio_stat [$etcdir, "passwd"], sub {
1540 # yay
1541 };
1542 };
1543
1544 The fact that C<aio_wd> is a request and not a normal function shows that
1545 creating an IO::AIO::WD object is itself a potentially blocking operation,
1546 which is why it is done asynchronously.
1547
1548 To stat the directory obtained with C<aio_wd> above, one could write
1549 either of the following three request calls:
1550
1551 aio_lstat "/etc" , sub { ... # pathname as normal string
1552 aio_lstat [$wd, "."], sub { ... # "." relative to $wd (i.e. $wd itself)
1553 aio_lstat $wd , sub { ... # shorthand for the previous
1554
1555 As with normal pathnames, IO::AIO keeps a copy of the working directory
1556 object and the pathname string, so you could write the following without
1557 causing any issues due to C<$path> getting reused:
1558
1559 my $path = [$wd, undef];
1560
1561 for my $name (qw(abc def ghi)) {
1562 $path->[1] = $name;
1563 aio_stat $path, sub {
1564 # ...
1565 };
1566 }
1567
1568 There are some caveats: when directories get renamed (or deleted), the
1569 pathname string doesn't change, so will point to the new directory (or
1570 nowhere at all), while the directory fd, if available on the system,
1571 will still point to the original directory. Most functions accepting a
1572 pathname will use the directory fd on newer systems, and the string on
1573 older systems. Some functions (such as C<aio_realpath>) will always rely on
1574 the string form of the pathname.
1575
1576 So this functionality is mainly useful to get some protection against
1577 C<chdir>, to easily get an absolute path out of a relative path for future
1578 reference, and to speed up doing many operations in the same directory
1579 (e.g. when stat'ing all files in a directory).
1580
1581 The following functions implement this working directory abstraction:
1582
1583 =over 4
1584
1585 =item aio_wd $pathname, $callback->($wd)
1586
1587 Asynchonously canonicalise the given pathname and convert it to an
1588 IO::AIO::WD object representing it. If possible and supported on the
1589 system, also open a directory fd to speed up pathname resolution relative
1590 to this working directory.
1591
1592 If something goes wrong, then C<undef> is passwd to the callback instead
1593 of a working directory object and C<$!> is set appropriately. Since
1594 passing C<undef> as working directory component of a pathname fails the
1595 request with C<ENOENT>, there is often no need for error checking in the
1596 C<aio_wd> callback, as future requests using the value will fail in the
1597 expected way.
1598
1599 =item IO::AIO::CWD
1600
1601 This is a compiletime constant (object) that represents the process
1602 current working directory.
1603
1604 Specifying this object as working directory object for a pathname is as if
1605 the pathname would be specified directly, without a directory object. For
1606 example, these calls are functionally identical:
1607
1608 aio_stat "somefile", sub { ... };
1609 aio_stat [IO::AIO::CWD, "somefile"], sub { ... };
1610
1611 =back
1612
1613 To recover the path associated with an IO::AIO::WD object, you can use
1614 C<aio_realpath>:
1615
1616 aio_realpath $wd, sub {
1617 warn "path is $_[0]\n";
1618 };
1619
1620 Currently, C<aio_statvfs> always, and C<aio_rename> and C<aio_rmdir>
1621 sometimes, fall back to using an absolue path.
1622
1623 =head2 IO::AIO::REQ CLASS
1624
1625 All non-aggregate C<aio_*> functions return an object of this class when
1626 called in non-void context.
1627
1628 =over 4
1629
1630 =item cancel $req
1631
1632 Cancels the request, if possible. Has the effect of skipping execution
1633 when entering the B<execute> state and skipping calling the callback when
1634 entering the the B<result> state, but will leave the request otherwise
1635 untouched (with the exception of readdir). That means that requests that
1636 currently execute will not be stopped and resources held by the request
1637 will not be freed prematurely.
1638
1639 =item cb $req $callback->(...)
1640
1641 Replace (or simply set) the callback registered to the request.
1642
1643 =back
1644
1645 =head2 IO::AIO::GRP CLASS
1646
1647 This class is a subclass of L<IO::AIO::REQ>, so all its methods apply to
1648 objects of this class, too.
1649
1650 A IO::AIO::GRP object is a special request that can contain multiple other
1651 aio requests.
1652
1653 You create one by calling the C<aio_group> constructing function with a
1654 callback that will be called when all contained requests have entered the
1655 C<done> state:
1656
1657 my $grp = aio_group sub {
1658 print "all requests are done\n";
1659 };
1660
1661 You add requests by calling the C<add> method with one or more
1662 C<IO::AIO::REQ> objects:
1663
1664 $grp->add (aio_unlink "...");
1665
1666 add $grp aio_stat "...", sub {
1667 $_[0] or return $grp->result ("error");
1668
1669 # add another request dynamically, if first succeeded
1670 add $grp aio_open "...", sub {
1671 $grp->result ("ok");
1672 };
1673 };
1674
1675 This makes it very easy to create composite requests (see the source of
1676 C<aio_move> for an application) that work and feel like simple requests.
1677
1678 =over 4
1679
1680 =item * The IO::AIO::GRP objects will be cleaned up during calls to
1681 C<IO::AIO::poll_cb>, just like any other request.
1682
1683 =item * They can be canceled like any other request. Canceling will cancel not
1684 only the request itself, but also all requests it contains.
1685
1686 =item * They can also can also be added to other IO::AIO::GRP objects.
1687
1688 =item * You must not add requests to a group from within the group callback (or
1689 any later time).
1690
1691 =back
1692
1693 Their lifetime, simplified, looks like this: when they are empty, they
1694 will finish very quickly. If they contain only requests that are in the
1695 C<done> state, they will also finish. Otherwise they will continue to
1696 exist.
1697
1698 That means after creating a group you have some time to add requests
1699 (precisely before the callback has been invoked, which is only done within
1700 the C<poll_cb>). And in the callbacks of those requests, you can add
1701 further requests to the group. And only when all those requests have
1702 finished will the the group itself finish.
1703
1704 =over 4
1705
1706 =item add $grp ...
1707
1708 =item $grp->add (...)
1709
1710 Add one or more requests to the group. Any type of L<IO::AIO::REQ> can
1711 be added, including other groups, as long as you do not create circular
1712 dependencies.
1713
1714 Returns all its arguments.
1715
1716 =item $grp->cancel_subs
1717
1718 Cancel all subrequests and clears any feeder, but not the group request
1719 itself. Useful when you queued a lot of events but got a result early.
1720
1721 The group request will finish normally (you cannot add requests to the
1722 group).
1723
1724 =item $grp->result (...)
1725
1726 Set the result value(s) that will be passed to the group callback when all
1727 subrequests have finished and set the groups errno to the current value
1728 of errno (just like calling C<errno> without an error number). By default,
1729 no argument will be passed and errno is zero.
1730
1731 =item $grp->errno ([$errno])
1732
1733 Sets the group errno value to C<$errno>, or the current value of errno
1734 when the argument is missing.
1735
1736 Every aio request has an associated errno value that is restored when
1737 the callback is invoked. This method lets you change this value from its
1738 default (0).
1739
1740 Calling C<result> will also set errno, so make sure you either set C<$!>
1741 before the call to C<result>, or call c<errno> after it.
1742
1743 =item feed $grp $callback->($grp)
1744
1745 Sets a feeder/generator on this group: every group can have an attached
1746 generator that generates requests if idle. The idea behind this is that,
1747 although you could just queue as many requests as you want in a group,
1748 this might starve other requests for a potentially long time. For example,
1749 C<aio_scandir> might generate hundreds of thousands of C<aio_stat>
1750 requests, delaying any later requests for a long time.
1751
1752 To avoid this, and allow incremental generation of requests, you can
1753 instead a group and set a feeder on it that generates those requests. The
1754 feed callback will be called whenever there are few enough (see C<limit>,
1755 below) requests active in the group itself and is expected to queue more
1756 requests.
1757
1758 The feed callback can queue as many requests as it likes (i.e. C<add> does
1759 not impose any limits).
1760
1761 If the feed does not queue more requests when called, it will be
1762 automatically removed from the group.
1763
1764 If the feed limit is C<0> when this method is called, it will be set to
1765 C<2> automatically.
1766
1767 Example:
1768
1769 # stat all files in @files, but only ever use four aio requests concurrently:
1770
1771 my $grp = aio_group sub { print "finished\n" };
1772 limit $grp 4;
1773 feed $grp sub {
1774 my $file = pop @files
1775 or return;
1776
1777 add $grp aio_stat $file, sub { ... };
1778 };
1779
1780 =item limit $grp $num
1781
1782 Sets the feeder limit for the group: The feeder will be called whenever
1783 the group contains less than this many requests.
1784
1785 Setting the limit to C<0> will pause the feeding process.
1786
1787 The default value for the limit is C<0>, but note that setting a feeder
1788 automatically bumps it up to C<2>.
1789
1790 =back
1791
1792
1793 =head2 SUPPORT FUNCTIONS
1794
1795 =head3 EVENT PROCESSING AND EVENT LOOP INTEGRATION
1796
1797 =over 4
1798
1799 =item $fileno = IO::AIO::poll_fileno
1800
1801 Return the I<request result pipe file descriptor>. This filehandle must be
1802 polled for reading by some mechanism outside this module (e.g. EV, Glib,
1803 select and so on, see below or the SYNOPSIS). If the pipe becomes readable
1804 you have to call C<poll_cb> to check the results.
1805
1806 See C<poll_cb> for an example.
1807
1808 =item IO::AIO::poll_cb
1809
1810 Process some requests that have reached the result phase (i.e. they have
1811 been executed but the results are not yet reported). You have to call
1812 this "regularly" to finish outstanding requests.
1813
1814 Returns C<0> if all events could be processed (or there were no
1815 events to process), or C<-1> if it returned earlier for whatever
1816 reason. Returns immediately when no events are outstanding. The amount
1817 of events processed depends on the settings of C<IO::AIO::max_poll_req>,
1818 C<IO::AIO::max_poll_time> and C<IO::AIO::max_outstanding>.
1819
1820 If not all requests were processed for whatever reason, the poll file
1821 descriptor will still be ready when C<poll_cb> returns, so normally you
1822 don't have to do anything special to have it called later.
1823
1824 Apart from calling C<IO::AIO::poll_cb> when the event filehandle becomes
1825 ready, it can be beneficial to call this function from loops which submit
1826 a lot of requests, to make sure the results get processed when they become
1827 available and not just when the loop is finished and the event loop takes
1828 over again. This function returns very fast when there are no outstanding
1829 requests.
1830
1831 Example: Install an Event watcher that automatically calls
1832 IO::AIO::poll_cb with high priority (more examples can be found in the
1833 SYNOPSIS section, at the top of this document):
1834
1835 Event->io (fd => IO::AIO::poll_fileno,
1836 poll => 'r', async => 1,
1837 cb => \&IO::AIO::poll_cb);
1838
1839 =item IO::AIO::poll_wait
1840
1841 Wait until either at least one request is in the result phase or no
1842 requests are outstanding anymore.
1843
1844 This is useful if you want to synchronously wait for some requests to
1845 become ready, without actually handling them.
1846
1847 See C<nreqs> for an example.
1848
1849 =item IO::AIO::poll
1850
1851 Waits until some requests have been handled.
1852
1853 Returns the number of requests processed, but is otherwise strictly
1854 equivalent to:
1855
1856 IO::AIO::poll_wait, IO::AIO::poll_cb
1857
1858 =item IO::AIO::flush
1859
1860 Wait till all outstanding AIO requests have been handled.
1861
1862 Strictly equivalent to:
1863
1864 IO::AIO::poll_wait, IO::AIO::poll_cb
1865 while IO::AIO::nreqs;
1866
1867 This function can be useful at program aborts, to make sure outstanding
1868 I/O has been done (C<IO::AIO> uses an C<END> block which already calls
1869 this function on normal exits), or when you are merely using C<IO::AIO>
1870 for its more advanced functions, rather than for async I/O, e.g.:
1871
1872 my ($dirs, $nondirs);
1873 IO::AIO::aio_scandir "/tmp", 0, sub { ($dirs, $nondirs) = @_ };
1874 IO::AIO::flush;
1875 # $dirs, $nondirs are now set
1876
1877 =item IO::AIO::max_poll_reqs $nreqs
1878
1879 =item IO::AIO::max_poll_time $seconds
1880
1881 These set the maximum number of requests (default C<0>, meaning infinity)
1882 that are being processed by C<IO::AIO::poll_cb> in one call, respectively
1883 the maximum amount of time (default C<0>, meaning infinity) spent in
1884 C<IO::AIO::poll_cb> to process requests (more correctly the mininum amount
1885 of time C<poll_cb> is allowed to use).
1886
1887 Setting C<max_poll_time> to a non-zero value creates an overhead of one
1888 syscall per request processed, which is not normally a problem unless your
1889 callbacks are really really fast or your OS is really really slow (I am
1890 not mentioning Solaris here). Using C<max_poll_reqs> incurs no overhead.
1891
1892 Setting these is useful if you want to ensure some level of
1893 interactiveness when perl is not fast enough to process all requests in
1894 time.
1895
1896 For interactive programs, values such as C<0.01> to C<0.1> should be fine.
1897
1898 Example: Install an Event watcher that automatically calls
1899 IO::AIO::poll_cb with low priority, to ensure that other parts of the
1900 program get the CPU sometimes even under high AIO load.
1901
1902 # try not to spend much more than 0.1s in poll_cb
1903 IO::AIO::max_poll_time 0.1;
1904
1905 # use a low priority so other tasks have priority
1906 Event->io (fd => IO::AIO::poll_fileno,
1907 poll => 'r', nice => 1,
1908 cb => &IO::AIO::poll_cb);
1909
1910 =back
1911
1912
1913 =head3 CONTROLLING THE NUMBER OF THREADS
1914
1915 =over
1916
1917 =item IO::AIO::min_parallel $nthreads
1918
1919 Set the minimum number of AIO threads to C<$nthreads>. The current
1920 default is C<8>, which means eight asynchronous operations can execute
1921 concurrently at any one time (the number of outstanding requests,
1922 however, is unlimited).
1923
1924 IO::AIO starts threads only on demand, when an AIO request is queued and
1925 no free thread exists. Please note that queueing up a hundred requests can
1926 create demand for a hundred threads, even if it turns out that everything
1927 is in the cache and could have been processed faster by a single thread.
1928
1929 It is recommended to keep the number of threads relatively low, as some
1930 Linux kernel versions will scale negatively with the number of threads
1931 (higher parallelity => MUCH higher latency). With current Linux 2.6
1932 versions, 4-32 threads should be fine.
1933
1934 Under most circumstances you don't need to call this function, as the
1935 module selects a default that is suitable for low to moderate load.
1936
1937 =item IO::AIO::max_parallel $nthreads
1938
1939 Sets the maximum number of AIO threads to C<$nthreads>. If more than the
1940 specified number of threads are currently running, this function kills
1941 them. This function blocks until the limit is reached.
1942
1943 While C<$nthreads> are zero, aio requests get queued but not executed
1944 until the number of threads has been increased again.
1945
1946 This module automatically runs C<max_parallel 0> at program end, to ensure
1947 that all threads are killed and that there are no outstanding requests.
1948
1949 Under normal circumstances you don't need to call this function.
1950
1951 =item IO::AIO::max_idle $nthreads
1952
1953 Limit the number of threads (default: 4) that are allowed to idle
1954 (i.e., threads that did not get a request to process within the idle
1955 timeout (default: 10 seconds). That means if a thread becomes idle while
1956 C<$nthreads> other threads are also idle, it will free its resources and
1957 exit.
1958
1959 This is useful when you allow a large number of threads (e.g. 100 or 1000)
1960 to allow for extremely high load situations, but want to free resources
1961 under normal circumstances (1000 threads can easily consume 30MB of RAM).
1962
1963 The default is probably ok in most situations, especially if thread
1964 creation is fast. If thread creation is very slow on your system you might
1965 want to use larger values.
1966
1967 =item IO::AIO::idle_timeout $seconds
1968
1969 Sets the minimum idle timeout (default 10) after which worker threads are
1970 allowed to exit. SEe C<IO::AIO::max_idle>.
1971
1972 =item IO::AIO::max_outstanding $maxreqs
1973
1974 Sets the maximum number of outstanding requests to C<$nreqs>. If
1975 you do queue up more than this number of requests, the next call to
1976 C<IO::AIO::poll_cb> (and other functions calling C<poll_cb>, such as
1977 C<IO::AIO::flush> or C<IO::AIO::poll>) will block until the limit is no
1978 longer exceeded.
1979
1980 In other words, this setting does not enforce a queue limit, but can be
1981 used to make poll functions block if the limit is exceeded.
1982
1983 This is a very bad function to use in interactive programs because it
1984 blocks, and a bad way to reduce concurrency because it is inexact: Better
1985 use an C<aio_group> together with a feed callback.
1986
1987 Its main use is in scripts without an event loop - when you want to stat
1988 a lot of files, you can write something like this:
1989
1990 IO::AIO::max_outstanding 32;
1991
1992 for my $path (...) {
1993 aio_stat $path , ...;
1994 IO::AIO::poll_cb;
1995 }
1996
1997 IO::AIO::flush;
1998
1999 The call to C<poll_cb> inside the loop will normally return instantly, but
2000 as soon as more thna C<32> reqeusts are in-flight, it will block until
2001 some requests have been handled. This keeps the loop from pushing a large
2002 number of C<aio_stat> requests onto the queue.
2003
2004 The default value for C<max_outstanding> is very large, so there is no
2005 practical limit on the number of outstanding requests.
2006
2007 =back
2008
2009
2010 =head3 STATISTICAL INFORMATION
2011
2012 =over
2013
2014 =item IO::AIO::nreqs
2015
2016 Returns the number of requests currently in the ready, execute or pending
2017 states (i.e. for which their callback has not been invoked yet).
2018
2019 Example: wait till there are no outstanding requests anymore:
2020
2021 IO::AIO::poll_wait, IO::AIO::poll_cb
2022 while IO::AIO::nreqs;
2023
2024 =item IO::AIO::nready
2025
2026 Returns the number of requests currently in the ready state (not yet
2027 executed).
2028
2029 =item IO::AIO::npending
2030
2031 Returns the number of requests currently in the pending state (executed,
2032 but not yet processed by poll_cb).
2033
2034 =back
2035
2036
2037 =head3 SUBSECOND STAT TIME ACCESS
2038
2039 Both C<aio_stat>/C<aio_lstat> and perl's C<stat>/C<lstat> functions can
2040 generally find access/modification and change times with subsecond time
2041 accuracy of the system supports it, but perl's built-in functions only
2042 return the integer part.
2043
2044 The following functions return the timestamps of the most recent
2045 stat with subsecond precision on most systems and work both after
2046 C<aio_stat>/C<aio_lstat> and perl's C<stat>/C<lstat> calls. Their return
2047 value is only meaningful after a successful C<stat>/C<lstat> call, or
2048 during/after a successful C<aio_stat>/C<aio_lstat> callback.
2049
2050 This is similar to the L<Time::HiRes> C<stat> functions, but can return
2051 full resolution without rounding and work with standard perl C<stat>,
2052 alleviating the need to call the special C<Time::HiRes> functions, which
2053 do not act like their perl counterparts.
2054
2055 On operating systems or file systems where subsecond time resolution is
2056 not supported or could not be detected, a fractional part of C<0> is
2057 returned, so it is always safe to call these functions.
2058
2059 =over 4
2060
2061 =item $seconds = IO::AIO::st_atime, IO::AIO::st_mtime, IO::AIO::st_ctime, IO::AIO::st_btime
2062
2063 Return the access, modication, change or birth time, respectively,
2064 including fractional part. Due to the limited precision of floating point,
2065 the accuracy on most platforms is only a bit better than milliseconds
2066 for times around now - see the I<nsec> function family, below, for full
2067 accuracy.
2068
2069 File birth time is only available when the OS and perl support it (on
2070 FreeBSD and NetBSD at the time of this writing, although support is
2071 adaptive, so if your OS/perl gains support, IO::AIO can take avdantage of
2072 it). On systems where it isn't available, C<0> is currently returned, but
2073 this might change to C<undef> in a future version.
2074
2075 =item ($atime, $mtime, $ctime, $btime, ...) = IO::AIO::st_xtime
2076
2077 Returns access, modification, change and birth time all in one go, and
2078 maybe more times in the future version.
2079
2080 =item $nanoseconds = IO::AIO::st_atimensec, IO::AIO::st_mtimensec, IO::AIO::st_ctimensec, IO::AIO::st_btimensec
2081
2082 Return the fractional access, modifcation, change or birth time, in nanoseconds,
2083 as an integer in the range C<0> to C<999999999>.
2084
2085 Note that no accessors are provided for access, modification and
2086 change times - you need to get those from C<stat _> if required (C<int
2087 IO::AIO::st_atime> and so on will I<not> generally give you the correct
2088 value).
2089
2090 =item $seconds = IO::AIO::st_btimesec
2091
2092 The (integral) seconds part of the file birth time, if available.
2093
2094 =item ($atime, $mtime, $ctime, $btime, ...) = IO::AIO::st_xtimensec
2095
2096 Like the functions above, but returns all four times in one go (and maybe
2097 more in future versions).
2098
2099 =item $counter = IO::AIO::st_gen
2100
2101 Returns the generation counter (in practice this is just a random number)
2102 of the file. This is only available on platforms which have this member in
2103 their C<struct stat> (most BSDs at the time of this writing) and generally
2104 only to the root usert. If unsupported, C<0> is returned, but this might
2105 change to C<undef> in a future version.
2106
2107 =back
2108
2109 Example: print the high resolution modification time of F</etc>, using
2110 C<stat>, and C<IO::AIO::aio_stat>.
2111
2112 if (stat "/etc") {
2113 printf "stat(/etc) mtime: %f\n", IO::AIO::st_mtime;
2114 }
2115
2116 IO::AIO::aio_stat "/etc", sub {
2117 $_[0]
2118 and return;
2119
2120 printf "aio_stat(/etc) mtime: %d.%09d\n", (stat _)[9], IO::AIO::st_mtimensec;
2121 };
2122
2123 IO::AIO::flush;
2124
2125 Output of the awbove on my system, showing reduced and full accuracy:
2126
2127 stat(/etc) mtime: 1534043702.020808
2128 aio_stat(/etc) mtime: 1534043702.020807792
2129
2130
2131 =head3 MISCELLANEOUS FUNCTIONS
2132
2133 IO::AIO implements some functions that are useful when you want to use
2134 some "Advanced I/O" function not available to in Perl, without going the
2135 "Asynchronous I/O" route. Many of these have an asynchronous C<aio_*>
2136 counterpart.
2137
2138 =over 4
2139
2140 =item $numfd = IO::AIO::get_fdlimit
2141
2142 This function is I<EXPERIMENTAL> and subject to change.
2143
2144 Tries to find the current file descriptor limit and returns it, or
2145 C<undef> and sets C<$!> in case of an error. The limit is one larger than
2146 the highest valid file descriptor number.
2147
2148 =item IO::AIO::min_fdlimit [$numfd]
2149
2150 This function is I<EXPERIMENTAL> and subject to change.
2151
2152 Try to increase the current file descriptor limit(s) to at least C<$numfd>
2153 by changing the soft or hard file descriptor resource limit. If C<$numfd>
2154 is missing, it will try to set a very high limit, although this is not
2155 recommended when you know the actual minimum that you require.
2156
2157 If the limit cannot be raised enough, the function makes a best-effort
2158 attempt to increase the limit as much as possible, using various
2159 tricks, while still failing. You can query the resulting limit using
2160 C<IO::AIO::get_fdlimit>.
2161
2162 If an error occurs, returns C<undef> and sets C<$!>, otherwise returns
2163 true.
2164
2165 =item IO::AIO::sendfile $ofh, $ifh, $offset, $count
2166
2167 Calls the C<eio_sendfile_sync> function, which is like C<aio_sendfile>,
2168 but is blocking (this makes most sense if you know the input data is
2169 likely cached already and the output filehandle is set to non-blocking
2170 operations).
2171
2172 Returns the number of bytes copied, or C<-1> on error.
2173
2174 =item IO::AIO::fadvise $fh, $offset, $len, $advice
2175
2176 Simply calls the C<posix_fadvise> function (see its
2177 manpage for details). The following advice constants are
2178 available: C<IO::AIO::FADV_NORMAL>, C<IO::AIO::FADV_SEQUENTIAL>,
2179 C<IO::AIO::FADV_RANDOM>, C<IO::AIO::FADV_NOREUSE>,
2180 C<IO::AIO::FADV_WILLNEED>, C<IO::AIO::FADV_DONTNEED>.
2181
2182 On systems that do not implement C<posix_fadvise>, this function returns
2183 ENOSYS, otherwise the return value of C<posix_fadvise>.
2184
2185 =item IO::AIO::madvise $scalar, $offset, $len, $advice
2186
2187 Simply calls the C<posix_madvise> function (see its
2188 manpage for details). The following advice constants are
2189 available: C<IO::AIO::MADV_NORMAL>, C<IO::AIO::MADV_SEQUENTIAL>,
2190 C<IO::AIO::MADV_RANDOM>, C<IO::AIO::MADV_WILLNEED>,
2191 C<IO::AIO::MADV_DONTNEED>.
2192
2193 If C<$offset> is negative, counts from the end. If C<$length> is negative,
2194 the remaining length of the C<$scalar> is used. If possible, C<$length>
2195 will be reduced to fit into the C<$scalar>.
2196
2197 On systems that do not implement C<posix_madvise>, this function returns
2198 ENOSYS, otherwise the return value of C<posix_madvise>.
2199
2200 =item IO::AIO::mprotect $scalar, $offset, $len, $protect
2201
2202 Simply calls the C<mprotect> function on the preferably AIO::mmap'ed
2203 $scalar (see its manpage for details). The following protect
2204 constants are available: C<IO::AIO::PROT_NONE>, C<IO::AIO::PROT_READ>,
2205 C<IO::AIO::PROT_WRITE>, C<IO::AIO::PROT_EXEC>.
2206
2207 If C<$offset> is negative, counts from the end. If C<$length> is negative,
2208 the remaining length of the C<$scalar> is used. If possible, C<$length>
2209 will be reduced to fit into the C<$scalar>.
2210
2211 On systems that do not implement C<mprotect>, this function returns
2212 ENOSYS, otherwise the return value of C<mprotect>.
2213
2214 =item IO::AIO::mmap $scalar, $length, $prot, $flags, $fh[, $offset]
2215
2216 Memory-maps a file (or anonymous memory range) and attaches it to the
2217 given C<$scalar>, which will act like a string scalar. Returns true on
2218 success, and false otherwise.
2219
2220 The scalar must exist, but its contents do not matter - this means you
2221 cannot use a nonexistant array or hash element. When in doubt, C<undef>
2222 the scalar first.
2223
2224 The only operations allowed on the mmapped scalar are C<substr>/C<vec>,
2225 which don't change the string length, and most read-only operations such
2226 as copying it or searching it with regexes and so on.
2227
2228 Anything else is unsafe and will, at best, result in memory leaks.
2229
2230 The memory map associated with the C<$scalar> is automatically removed
2231 when the C<$scalar> is undef'd or destroyed, or when the C<IO::AIO::mmap>
2232 or C<IO::AIO::munmap> functions are called on it.
2233
2234 This calls the C<mmap>(2) function internally. See your system's manual
2235 page for details on the C<$length>, C<$prot> and C<$flags> parameters.
2236
2237 The C<$length> must be larger than zero and smaller than the actual
2238 filesize.
2239
2240 C<$prot> is a combination of C<IO::AIO::PROT_NONE>, C<IO::AIO::PROT_EXEC>,
2241 C<IO::AIO::PROT_READ> and/or C<IO::AIO::PROT_WRITE>,
2242
2243 C<$flags> can be a combination of
2244 C<IO::AIO::MAP_SHARED> or
2245 C<IO::AIO::MAP_PRIVATE>,
2246 or a number of system-specific flags (when not available, the are C<0>):
2247 C<IO::AIO::MAP_ANONYMOUS> (which is set to C<MAP_ANON> if your system only provides this constant),
2248 C<IO::AIO::MAP_LOCKED>,
2249 C<IO::AIO::MAP_NORESERVE>,
2250 C<IO::AIO::MAP_POPULATE>,
2251 C<IO::AIO::MAP_NONBLOCK>,
2252 C<IO::AIO::MAP_FIXED>,
2253 C<IO::AIO::MAP_GROWSDOWN>,
2254 C<IO::AIO::MAP_32BIT>,
2255 C<IO::AIO::MAP_HUGETLB> or
2256 C<IO::AIO::MAP_STACK>.
2257
2258 If C<$fh> is C<undef>, then a file descriptor of C<-1> is passed.
2259
2260 C<$offset> is the offset from the start of the file - it generally must be
2261 a multiple of C<IO::AIO::PAGESIZE> and defaults to C<0>.
2262
2263 Example:
2264
2265 use Digest::MD5;
2266 use IO::AIO;
2267
2268 open my $fh, "<verybigfile"
2269 or die "$!";
2270
2271 IO::AIO::mmap my $data, -s $fh, IO::AIO::PROT_READ, IO::AIO::MAP_SHARED, $fh
2272 or die "verybigfile: $!";
2273
2274 my $fast_md5 = md5 $data;
2275
2276 =item IO::AIO::munmap $scalar
2277
2278 Removes a previous mmap and undefines the C<$scalar>.
2279
2280 =item IO::AIO::mremap $scalar, $new_length, $flags = MREMAP_MAYMOVE[, $new_address = 0]
2281
2282 Calls the Linux-specific mremap(2) system call. The C<$scalar> must have
2283 been mapped by C<IO::AIO::mmap>, and C<$flags> must currently either be
2284 C<0> or C<IO::AIO::MREMAP_MAYMOVE>.
2285
2286 Returns true if successful, and false otherwise. If the underlying mmapped
2287 region has changed address, then the true value has the numerical value
2288 C<1>, otherwise it has the numerical value C<0>:
2289
2290 my $success = IO::AIO::mremap $mmapped, 8192, IO::AIO::MREMAP_MAYMOVE
2291 or die "mremap: $!";
2292
2293 if ($success*1) {
2294 warn "scalar has chanegd address in memory\n";
2295 }
2296
2297 C<IO::AIO::MREMAP_FIXED> and the C<$new_address> argument are currently
2298 implemented, but not supported and might go away in a future version.
2299
2300 On systems where this call is not supported or is not emulated, this call
2301 returns falls and sets C<$!> to C<ENOSYS>.
2302
2303 =item IO::AIO::munlock $scalar, $offset = 0, $length = undef
2304
2305 Calls the C<munlock> function, undoing the effects of a previous
2306 C<aio_mlock> call (see its description for details).
2307
2308 =item IO::AIO::munlockall
2309
2310 Calls the C<munlockall> function.
2311
2312 On systems that do not implement C<munlockall>, this function returns
2313 ENOSYS, otherwise the return value of C<munlockall>.
2314
2315 =item IO::AIO::splice $r_fh, $r_off, $w_fh, $w_off, $length, $flags
2316
2317 Calls the GNU/Linux C<splice(2)> syscall, if available. If C<$r_off> or
2318 C<$w_off> are C<undef>, then C<NULL> is passed for these, otherwise they
2319 should be the file offset.
2320
2321 C<$r_fh> and C<$w_fh> should not refer to the same file, as splice might
2322 silently corrupt the data in this case.
2323
2324 The following symbol flag values are available: C<IO::AIO::SPLICE_F_MOVE>,
2325 C<IO::AIO::SPLICE_F_NONBLOCK>, C<IO::AIO::SPLICE_F_MORE> and
2326 C<IO::AIO::SPLICE_F_GIFT>.
2327
2328 See the C<splice(2)> manpage for details.
2329
2330 =item IO::AIO::tee $r_fh, $w_fh, $length, $flags
2331
2332 Calls the GNU/Linux C<tee(2)> syscall, see its manpage and the
2333 description for C<IO::AIO::splice> above for details.
2334
2335 =item $actual_size = IO::AIO::pipesize $r_fh[, $new_size]
2336
2337 Attempts to query or change the pipe buffer size. Obviously works only
2338 on pipes, and currently works only on GNU/Linux systems, and fails with
2339 C<-1>/C<ENOSYS> everywhere else. If anybody knows how to influence pipe buffer
2340 size on other systems, drop me a note.
2341
2342 =item ($rfh, $wfh) = IO::AIO::pipe2 [$flags]
2343
2344 This is a direct interface to the Linux L<pipe2(2)> system call. If
2345 C<$flags> is missing or C<0>, then this should be the same as a call to
2346 perl's built-in C<pipe> function and create a new pipe, and works on
2347 systems that lack the pipe2 syscall. On win32, this case invokes C<_pipe
2348 (..., 4096, O_BINARY)>.
2349
2350 If C<$flags> is non-zero, it tries to invoke the pipe2 system call with
2351 the given flags (Linux 2.6.27, glibc 2.9).
2352
2353 On success, the read and write file handles are returned.
2354
2355 On error, nothing will be returned. If the pipe2 syscall is missing and
2356 C<$flags> is non-zero, fails with C<ENOSYS>.
2357
2358 Please refer to L<pipe2(2)> for more info on the C<$flags>, but at the
2359 time of this writing, C<IO::AIO::O_CLOEXEC>, C<IO::AIO::O_NONBLOCK> and
2360 C<IO::AIO::O_DIRECT> (Linux 3.4, for packet-based pipes) were supported.
2361
2362 Example: create a pipe race-free w.r.t. threads and fork:
2363
2364 my ($rfh, $wfh) = IO::AIO::pipe2 IO::AIO::O_CLOEXEC
2365 or die "pipe2: $!\n";
2366
2367 =item $fh = IO::AIO::eventfd [$initval, [$flags]]
2368
2369 This is a direct interface to the Linux L<eventfd(2)> system call. The
2370 (unhelpful) defaults for C<$initval> and C<$flags> are C<0> for both.
2371
2372 On success, the new eventfd filehandle is returned, otherwise returns
2373 C<undef>. If the eventfd syscall is missing, fails with C<ENOSYS>.
2374
2375 Please refer to L<eventfd(2)> for more info on this call.
2376
2377 The following symbol flag values are available: C<IO::AIO::EFD_CLOEXEC>,
2378 C<IO::AIO::EFD_NONBLOCK> and C<IO::AIO::EFD_SEMAPHORE> (Linux 2.6.30).
2379
2380 Example: create a new eventfd filehandle:
2381
2382 $fh = IO::AIO::eventfd 0, IO::AIO::O_CLOEXEC
2383 or die "eventfd: $!\n";
2384
2385 =item $fh = IO::AIO::timerfd_create $clockid[, $flags]
2386
2387 This is a direct interface to the Linux L<timerfd_create(2)> system call. The
2388 (unhelpful) default for C<$flags> is C<0>.
2389
2390 On success, the new timerfd filehandle is returned, otherwise returns
2391 C<undef>. If the eventfd syscall is missing, fails with C<ENOSYS>.
2392
2393 Please refer to L<timerfd_create(2)> for more info on this call.
2394
2395 The following C<$clockid> values are
2396 available: C<IO::AIO::CLOCK_REALTIME>, C<IO::AIO::CLOCK_MONOTONIC>
2397 C<IO::AIO::CLOCK_CLOCK_BOOTTIME> (Linux 3.15)
2398 C<IO::AIO::CLOCK_CLOCK_REALTIME_ALARM> (Linux 3.11) and
2399 C<IO::AIO::CLOCK_CLOCK_BOOTTIME_ALARM> (Linux 3.11).
2400
2401 The following C<$flags> values are available (Linux
2402 2.6.27): C<IO::AIO::TFD_NONBLOCK> and C<IO::AIO::TFD_CLOEXEC>.
2403
2404 Example: create a new timerfd and set it to one-second repeated alarms,
2405 then wait for two alarms:
2406
2407 my $fh = IO::AIO::timerfd_create IO::AIO::CLOCK_BOOTTIME, IO::AIO::TFD_CLOEXEC
2408 or die "timerfd_create: $!\n";
2409
2410 defined IO::AIO::timerfd_settime $fh, 0, 1, 1
2411 or die "timerfd_settime: $!\n";
2412
2413 for (1..2) {
2414 8 == sysread $fh, my $buf, 8
2415 or die "timerfd read failure\n";
2416
2417 printf "number of expirations (likely 1): %d\n",
2418 unpack "Q", $buf;
2419 }
2420
2421 =item ($cur_interval, $cur_value) = IO::AIO::timerfd_settime $fh, $flags, $new_interval, $nbw_value
2422
2423 This is a direct interface to the Linux L<timerfd_settime(2)> system
2424 call. Please refer to its manpage for more info on this call.
2425
2426 The new itimerspec is specified using two (possibly fractional) second
2427 values, C<$new_interval> and C<$new_value>).
2428
2429 On success, the current interval and value are returned (as per
2430 C<timerfd_gettime>). On failure, the empty list is returned.
2431
2432 The following C<$flags> values are
2433 available: C<IO::AIO::TFD_TIMER_ABSTIME> and
2434 C<IO::AIO::TFD_TIMER_CANCEL_ON_SET>.
2435
2436 See C<IO::AIO::timerfd_create> for a full example.
2437
2438 =item ($cur_interval, $cur_value) = IO::AIO::timerfd_gettime $fh
2439
2440 This is a direct interface to the Linux L<timerfd_gettime(2)> system
2441 call. Please refer to its manpage for more info on this call.
2442
2443 On success, returns the current values of interval and value for the given
2444 timerfd (as potentially fractional second values). On failure, the empty
2445 list is returned.
2446
2447 =back
2448
2449 =cut
2450
2451 min_parallel 8;
2452
2453 END { flush }
2454
2455 1;
2456
2457 =head1 EVENT LOOP INTEGRATION
2458
2459 It is recommended to use L<AnyEvent::AIO> to integrate IO::AIO
2460 automatically into many event loops:
2461
2462 # AnyEvent integration (EV, Event, Glib, Tk, POE, urxvt, pureperl...)
2463 use AnyEvent::AIO;
2464
2465 You can also integrate IO::AIO manually into many event loops, here are
2466 some examples of how to do this:
2467
2468 # EV integration
2469 my $aio_w = EV::io IO::AIO::poll_fileno, EV::READ, \&IO::AIO::poll_cb;
2470
2471 # Event integration
2472 Event->io (fd => IO::AIO::poll_fileno,
2473 poll => 'r',
2474 cb => \&IO::AIO::poll_cb);
2475
2476 # Glib/Gtk2 integration
2477 add_watch Glib::IO IO::AIO::poll_fileno,
2478 in => sub { IO::AIO::poll_cb; 1 };
2479
2480 # Tk integration
2481 Tk::Event::IO->fileevent (IO::AIO::poll_fileno, "",
2482 readable => \&IO::AIO::poll_cb);
2483
2484 # Danga::Socket integration
2485 Danga::Socket->AddOtherFds (IO::AIO::poll_fileno =>
2486 \&IO::AIO::poll_cb);
2487
2488 =head2 FORK BEHAVIOUR
2489
2490 Usage of pthreads in a program changes the semantics of fork
2491 considerably. Specifically, only async-safe functions can be called after
2492 fork. Perl doesn't know about this, so in general, you cannot call fork
2493 with defined behaviour in perl if pthreads are involved. IO::AIO uses
2494 pthreads, so this applies, but many other extensions and (for inexplicable
2495 reasons) perl itself often is linked against pthreads, so this limitation
2496 applies to quite a lot of perls.
2497
2498 This module no longer tries to fight your OS, or POSIX. That means IO::AIO
2499 only works in the process that loaded it. Forking is fully supported, but
2500 using IO::AIO in the child is not.
2501
2502 You might get around by not I<using> IO::AIO before (or after)
2503 forking. You could also try to call the L<IO::AIO::reinit> function in the
2504 child:
2505
2506 =over 4
2507
2508 =item IO::AIO::reinit
2509
2510 Abandons all current requests and I/O threads and simply reinitialises all
2511 data structures. This is not an operation supported by any standards, but
2512 happens to work on GNU/Linux and some newer BSD systems.
2513
2514 The only reasonable use for this function is to call it after forking, if
2515 C<IO::AIO> was used in the parent. Calling it while IO::AIO is active in
2516 the process will result in undefined behaviour. Calling it at any time
2517 will also result in any undefined (by POSIX) behaviour.
2518
2519 =back
2520
2521 =head2 LINUX-SPECIFIC CALLS
2522
2523 When a call is documented as "linux-specific" then this means it
2524 originated on GNU/Linux. C<IO::AIO> will usually try to autodetect the
2525 availability and compatibility of such calls regardless of the platform
2526 it is compiled on, so platforms such as FreeBSD which often implement
2527 these calls will work. When in doubt, call them and see if they fail wth
2528 C<ENOSYS>.
2529
2530 =head2 MEMORY USAGE
2531
2532 Per-request usage:
2533
2534 Each aio request uses - depending on your architecture - around 100-200
2535 bytes of memory. In addition, stat requests need a stat buffer (possibly
2536 a few hundred bytes), readdir requires a result buffer and so on. Perl
2537 scalars and other data passed into aio requests will also be locked and
2538 will consume memory till the request has entered the done state.
2539
2540 This is not awfully much, so queuing lots of requests is not usually a
2541 problem.
2542
2543 Per-thread usage:
2544
2545 In the execution phase, some aio requests require more memory for
2546 temporary buffers, and each thread requires a stack and other data
2547 structures (usually around 16k-128k, depending on the OS).
2548
2549 =head1 KNOWN BUGS
2550
2551 Known bugs will be fixed in the next release :)
2552
2553 =head1 KNOWN ISSUES
2554
2555 Calls that try to "import" foreign memory areas (such as C<IO::AIO::mmap>
2556 or C<IO::AIO::aio_slurp>) do not work with generic lvalues, such as
2557 non-created hash slots or other scalars I didn't think of. It's best to
2558 avoid such and either use scalar variables or making sure that the scalar
2559 exists (e.g. by storing C<undef>) and isn't "funny" (e.g. tied).
2560
2561 I am not sure anything can be done about this, so this is considered a
2562 known issue, rather than a bug.
2563
2564 =head1 SEE ALSO
2565
2566 L<AnyEvent::AIO> for easy integration into event loops, L<Coro::AIO> for a
2567 more natural syntax.
2568
2569 =head1 AUTHOR
2570
2571 Marc Lehmann <schmorp@schmorp.de>
2572 http://home.schmorp.de/
2573
2574 =cut
2575