#!/opt/bin/perl

# inspired by treescan by Jamie Lokier <jamie@imbolc.ucc.ie>
# about 40% faster than the original version (on my fs and raid :)

use Getopt::Long;
use IO::AIO;

Getopt::Long::Configure ("bundling", "no_ignore_case", "require_order");

my ($opt_silent, $opt_print0, $opt_stat);

GetOptions
   "quiet|q"  => \$opt_silent,
   "print0|0" => \$opt_print0,
   "stat|s"   => \$opt_stat,
;

@ARGV = "." unless @ARGV;

sub printfn {
   my ($path, $files, $suffix) = @_;

   if ($opt_print0) {
      print map "$path/$_$suffix\0", @$files;
   } elsif (!$opt_silent) {
      print map "$path/$_$suffix\n", @$files;
   }
}

sub scan {
   my ($path) = @_;

   aio_scandir $path, 8, sub {
      my ($dirs, $files) = @_;

      if ($opt_stat) {
         aio_stat "$path/$_" for @$files;
      }

      for (@$dirs) {
         printfn $path, $dirs, "/";
         &scan ("$path/$_")
      }

      printfn $path, $files;
   };
}

IO::AIO::max_outstanding 64;
IO::AIO::min_parallel 32;

for my $seed (@ARGV) {
   $seed =~ s/\/+$//;
   aio_lstat "$seed/.", sub {
      scan $seed if -d _;
   };
}

IO::AIO::flush;