[ViewVC] Annotation of: cvs/cfmaps/cfmap2png

#!/opt/bin/perl

# cfarch2png - convert crossfire maps to png+metadata
# Copyright (C) 2005      Marc Lehmann <gvpe@schmorp.de>
#
# CFARCH2PNG is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; either version 2 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with gvpe; if not, write to the Free Software
# Foundation, Inc. 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

# tower of stars: missing craters?

our $VERSION = '1.2';

use strict;

use Storable;
use List::Util qw(max);

use Gtk2;

#init Gtk2::Gdk;

my $LIB = $ENV{CROSSFIRE_LIBDIR}
   or die "\$CROSSFIRE_LIBDIR must be set\n";

sub T (){ 32 }

sub read_pak($) {
   my ($path) = @_;

   eval {
      -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %pak;

      open my $fh, "<:raw", $path
         or die "$_[0]: $!";
      while (<$fh>) {
         my ($type, $id, $len, $path) = split;
         $path =~ s/.*\///;
         read $fh, $pak{$path}, $len;
      }

      Storable::nstore \%pak, "$path.pst";

      \%pak
   }
}

sub read_smooth($) {
   my ($path) = @_;

   eval {
      -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %smooth;

      open my $fh, "<:raw", $path
         or die "$path: $!";
      while (<$fh>) {
         next if /^\s*($|#)/;

         $smooth{$1} = $2 if /^(\S+)\s+(\S+)$/;
      }

      Storable::nstore \%smooth, "$path.pst";
      utime +(stat $path)[8,9], "$path.pst";

      \%smooth
   }
}

sub read_arch($;$) {
   my ($path, $cache) = @_;

   eval {
      $cache
      && -M "$path.pst" < -M $path
      && Storable::retrieve "$path.pst"
   } or do {
      my %arc;
      my ($more, $prev);

      open my $fh, "<:raw", $path
         or die "$path: $!";

      my $parse_block; $parse_block = sub {
         my %arc = @_;

         while (<$fh>) {
            s/\s+$//;
            if (/^end$/i) {
               last;
            } elsif (/^arch (\S+)$/) {
               push @{ $arc{inventory} }, $parse_block->(_name => $1);
            } elsif (/^lore$/) {
               while (<$fh>) {
                  last if /^endlore\s*$/i;
                  $arc{lore} .= $_;
               }
            } elsif (/^msg$/) {
               while (<$fh>) {
                  last if /^endmsg\s*$/i;
                  $arc{msg} .= $_;
               }
            } elsif (/^(\S+)\s*(.*)$/) {
               $arc{lc $1} = $2;
            } elsif (/^\s*($|#)/) {
               #
            } else {
               warn "$path: unparsable line '$_' in arch $arc{_name}";
            }
         }

         \%arc
      };

      while (<$fh>) {
         s/\s+$//;
         if (/^more$/i) {
            $more = $prev;
         } elsif (/^object (\S+)$/i) {
            my $name = $1;
            my $arc = $parse_block->(_name => $name);

            if ($more) {
               $more->{more} = $arc;
            } else {
               $arc{$name} = $arc;
            }
            
            $prev = $arc;
            $more = undef;
         } elsif (/^arch (\S+)$/i) {
            push @{ $arc{arch} }, $parse_block->(_name => $1);
         } elsif (/^\s*($|#)/) {
            #
         } else {
            warn "$path: unparseable top-level line '$_'";
         }
      }

      undef $parse_block; # work around bug in perl not freeing $fh etc.

      if ($cache) {
         Storable::nstore \%arc, "$path.pst";
         utime +(stat $path)[8,9], "$path.pst";
      }

      \%arc
   }
}

my $arch   = read_arch   "$LIB/archetypes", 1;
my $tile   = read_pak    "$LIB/crossfire.0";
my $smooth = read_smooth "$LIB/smooth";

sub tile($) {
   my $name = $_[0];

   my $pb = $tile->{$name}
      or return;

   unless (ref $pb) {
      my $file = "/tmp/map2png.$$~";

      open my $fh, ">:raw", $file
         or die "$file: $!";
      print $fh $pb;
      close $fh;

      $pb = $tile->{$name} = new_from_file Gtk2::Gdk::Pixbuf $file;
      unlink $file;
   }

   $pb
}

sub cfmap_render($;$) {
   my ($mapa, $mapname) = @_;

   my %meta;

   my ($mapx, $mapy);

   my $map;

   for (@{ $mapa->{arch} }) {
      my ($x, $y) = ($_->{x}, $_->{y});

      if ($_->{_name} eq "map") {
         $meta{info} = $_;

         $mapx = $_->{width}  || $x;
         $mapy = $_->{height} || $y;
      } else {
         push @{ $map->[$x][$y] }, $_;

         # arch map is unreliable w.r.t. width and height
         $mapx = $x + 1 if $mapx <= $x;
         $mapy = $y + 1 if $mapy <= $y;
         #$mapx = $a->{x} + 1, warn "$mapname: arch '$a->{_name}' outside map width at ($a->{x}|$a->{y})\n" if $mapx <= $a->{x};
         #$mapy = $a->{y} + 1, warn "$mapname: arch '$a->{_name}' outside map height at ($a->{x}|$a->{y})\n" if $mapy <= $a->{y};
      }
   }

   $meta{width}  = $mapx;
   $meta{height} = $mapy;

   my %draw_info;
   my %map_info;

   # first pass, gather face stacking order, border and corner info
   for my $x (0 .. $mapx - 1) {
      my $col = $map->[$x];
      for my $y (0 .. $mapy - 1) {
         my $as = $col->[$y] || [];

         my $minsmooth = 0;

         for my $layer (0 .. $#$as) {
            my $a = $as->[$layer];

            my $o = $arch->{$a->{_name}}
               or (warn "$mapname: arch '$a->{_name}' not found at ($x|$y)\n"), next;

            my $smoothlevel = exists $a->{smoothlevel} ? $a->{smoothlevel} : $o->{smoothlevel};

            # hack to ensure somewhat correct ordering in case of conflicting
            # smoothlevel/stacking order
            $smoothlevel = $minsmooth + 0.01 if $minsmooth >= $smoothlevel;
            $minsmooth = $smoothlevel;
            
            #my $is_floor = exists $a->{is_floor}    ? $a->{is_floor}    : $o->{is_floor};
            my $level = $smoothlevel + $layer * 256;

            $level -= 100 * 256 if $o->{_name} eq "blocked";

            while ($o) {
               my $face = $a->{face} || $o->{face};

               my $pb = tile $face
                  or (warn "$mapname: face '$face' not found for arch '$a->{_name}' at ($x|$y)\n"), last;

               my $mx = $x + $o->{x};
               my $my = $y + $o->{y};

               last if 0 > $mx || $mx >= $mapx
                    || 0 > $my || $my >= $mapy;

               # this is very ugly (some tiles are 32x33 or worse)
               my $bigface = $pb->get_width >= T*2 || $pb->get_height >= T*2;

               my $dx = $bigface ? $o->{x} : 0;
               my $dy = $bigface ? $o->{y} : 0;

               push @{ $map_info{$level}{$mx, $my} }, $a;

               $draw_info{$level}{$face}{$mx, $my} |= 0x2000 | (($dx + 128) << 24) | (($dy + 128) << 16);

               if (my $sface = $smooth->{$face}) {
                  $bigface and die "can't handle bigfaces with smoothing ($face)\n";

                  # full tile
                  $draw_info{$smoothlevel}{$sface}{$mx    , $my    } |= 0x1000;

                  # borders
                  $draw_info{$smoothlevel}{$sface}{$mx + 1, $my    } |= 0x0031;
                  $draw_info{$smoothlevel}{$sface}{$mx    , $my + 1} |= 0x0092;
                  $draw_info{$smoothlevel}{$sface}{$mx - 1, $my    } |= 0x0064;
                  $draw_info{$smoothlevel}{$sface}{$mx    , $my - 1} |= 0x00c8;

                  # corners
                  $draw_info{$smoothlevel}{$sface}{$mx + 1, $my + 1} |= 0x0100;
                  $draw_info{$smoothlevel}{$sface}{$mx - 1, $my + 1} |= 0x0200;
                  $draw_info{$smoothlevel}{$sface}{$mx - 1, $my - 1} |= 0x0400;
                  $draw_info{$smoothlevel}{$sface}{$mx + 1, $my - 1} |= 0x0800;
               }

               $o = $o->{more};
               $level = ($layer + 1000) * 2; # put "big things" on top, no matter what
            }
         }
      }
   }

   my $map_pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, $mapx * T, $mapy * T
         or die;
   $map_pb->fill (0xffffff00);

   # second pass, render the map
   for my $level (sort { $a <=> $b } keys %draw_info) {
      my $v = $draw_info{$level};
      while (my ($sface, $info) = each %$v) {
         my $pb = tile $sface
            or die "no smooth face $sface\n";

         while (my ($xy, $bits) = each %$info) {
            my ($x, $y) = split $;, $xy;

            next if $x < 0 || $x >= $mapx
                 || $y < 0 || $y >= $mapy;

            # bits is xxxx xxxx yyyy yyyy __fn cccc CCCC bbbb
            # f  full tile draw with x|y bigface displacement
            # n  do not draw borders&corners
            # c  draw these corners, but...
            # C  ... not these
            # b  draw these borders

            if ($bits & 0x2000) {
               my $dx = (($bits >> 24) & 0xff) - 128;
               my $dy = (($bits >> 16) & 0xff) - 128;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $dx) * T, ($y - $dy) * T, 1, 1,
                  "nearest",
                  255
               );
            }

            unless ($bits & 0x1000) {
               my $border = $bits & 0xf;
               my $corner = ($bits >> 8) & ~($bits >> 4) & 0xf;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $border) * T, $y * T, 1, 1,
                  "nearest",
                  255
               ) if $border;

               $pb->composite ($map_pb,
                  $x * T, $y * T,
                  T, T,
                  ($x - $corner) * T, ($y - 1) * T, 1, 1,
                  "nearest",
                  255
               ) if $corner;
            }
         }
      }
   }

   # third pass, gather meta info
   for my $level (sort { $a <=> $b } keys %map_info) {
      my $info = $map_info{$level};

         while (my ($xy, $as) = each %$info) {
            my ($x, $y) = split $;, $xy;

            next if $x < 0 || $x >= $mapx
                 || $y < 0 || $y >= $mapy;

            push @{ $meta{map}[$x][$y] }, $_ for @$as;
         }
   }

   ($map_pb, \%meta)
}

for my $file (@ARGV) {
   my $mapa = read_arch $file;
   my ($pb, $meta) = cfmap_render $mapa, $file;
   $pb->save ("$file.png~~", "png");
   system "convert", "$file.png~~", "-filter" => "lanczos", "-geometry" => "3.125%", "-quality" => 85, "$file.jpg";
   #system "mogrify", "-colors" => 65536, "$file.png~"; # destroys transparency
   system "pngcrush", "-q", "-m" => 7, "-rem", "alla", "-cc", "-reduce", "$file.png~~", "$file.png~";
#   system "pngnq <\Q$file.png~\E >\Q$file.png\E";
   unlink "$file.png~~";
   Storable::nstore $meta, "$file.pst";
   utime +(stat $file)[8,9], "$file.pst";
   utime +(stat $file)[8,9], "$file.png~";
   rename "$file.png~", "$file.png";
}


Revision:	1.16
Committed:	Mon Dec 12 01:37:11 2005 UTC (18 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.15:	+27 -13 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	#!/opt/bin/perl
2
3	root	1.8	# cfarch2png - convert crossfire maps to png+metadata
4			# Copyright (C) 2005 Marc Lehmann <gvpe@schmorp.de>
5			#
6			# CFARCH2PNG is free software; you can redistribute it and/or modify
7			# it under the terms of the GNU General Public License as published by
8			# the Free Software Foundation; either version 2 of the License, or
9			# (at your option) any later version.
10			#
11			# This program is distributed in the hope that it will be useful,
12			# but WITHOUT ANY WARRANTY; without even the implied warranty of
13			# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14			# GNU General Public License for more details.
15			#
16			# You should have received a copy of the GNU General Public License
17			# along with gvpe; if not, write to the Free Software
18			# Foundation, Inc. 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
19
20	root	1.1	# tower of stars: missing craters?
21
22	root	1.16	our $VERSION = '1.2';
23	root	1.9
24	root	1.1	use strict;
25
26			use Storable;
27			use List::Util qw(max);
28
29			use Gtk2;
30
31			#init Gtk2::Gdk;
32
33			my $LIB = $ENV{CROSSFIRE_LIBDIR}
34			or die "\$CROSSFIRE_LIBDIR must be set\n";
35
36			sub T (){ 32 }
37
38			sub read_pak($) {
39			my ($path) = @_;
40
41			eval {
42			-M "$path.pst" < -M $path
43			&& Storable::retrieve "$path.pst"
44			} or do {
45			my %pak;
46
47			open my $fh, "<:raw", $path
48			or die "$_[0]: $!";
49			while (<$fh>) {
50			my ($type, $id, $len, $path) = split;
51			$path =~ s/.*\///;
52			read $fh, $pak{$path}, $len;
53			}
54
55			Storable::nstore \%pak, "$path.pst";
56
57			\%pak
58			}
59			}
60
61			sub read_smooth($) {
62			my ($path) = @_;
63
64			eval {
65			-M "$path.pst" < -M $path
66			&& Storable::retrieve "$path.pst"
67			} or do {
68			my %smooth;
69
70			open my $fh, "<:raw", $path
71			or die "$path: $!";
72			while (<$fh>) {
73			next if /^\s*($\|#)/;
74
75			$smooth{$1} = $2 if /^(\S+)\s+(\S+)$/;
76			}
77
78			Storable::nstore \%smooth, "$path.pst";
79	root	1.16	utime +(stat $path)[8,9], "$path.pst";
80	root	1.1
81			\%smooth
82			}
83			}
84
85			sub read_arch($;$) {
86			my ($path, $cache) = @_;
87
88			eval {
89			$cache
90			&& -M "$path.pst" < -M $path
91			&& Storable::retrieve "$path.pst"
92			} or do {
93			my %arc;
94			my ($more, $prev);
95
96			open my $fh, "<:raw", $path
97			or die "$path: $!";
98
99			my $parse_block; $parse_block = sub {
100			my %arc = @_;
101
102			while (<$fh>) {
103			s/\s+$//;
104			if (/^end$/i) {
105			last;
106			} elsif (/^arch (\S+)$/) {
107	root	1.3	push @{ $arc{inventory} }, $parse_block->(_name => $1);
108	root	1.4	} elsif (/^lore$/) {
109			while (<$fh>) {
110			last if /^endlore\s*$/i;
111			$arc{lore} .= $_;
112			}
113	root	1.1	} elsif (/^msg$/) {
114			while (<$fh>) {
115			last if /^endmsg\s*$/i;
116			$arc{msg} .= $_;
117			}
118			} elsif (/^(\S+)\s(.)$/) {
119			$arc{lc $1} = $2;
120			} elsif (/^\s*($\|#)/) {
121			#
122			} else {
123			warn "$path: unparsable line '$_' in arch $arc{_name}";
124			}
125			}
126
127			\%arc
128			};
129
130			while (<$fh>) {
131			s/\s+$//;
132			if (/^more$/i) {
133			$more = $prev;
134			} elsif (/^object (\S+)$/i) {
135			my $name = $1;
136			my $arc = $parse_block->(_name => $name);
137
138	root	1.4	if ($more) {
139			$more->{more} = $arc;
140			} else {
141			$arc{$name} = $arc;
142			}
143	root	1.1
144			$prev = $arc;
145			$more = undef;
146			} elsif (/^arch (\S+)$/i) {
147			push @{ $arc{arch} }, $parse_block->(_name => $1);
148			} elsif (/^\s*($\|#)/) {
149			#
150			} else {
151			warn "$path: unparseable top-level line '$_'";
152			}
153			}
154
155			undef $parse_block; # work around bug in perl not freeing $fh etc.
156
157	root	1.16	if ($cache) {
158			Storable::nstore \%arc, "$path.pst";
159			utime +(stat $path)[8,9], "$path.pst";
160			}
161	root	1.1
162			\%arc
163			}
164			}
165
166			my $arch = read_arch "$LIB/archetypes", 1;
167			my $tile = read_pak "$LIB/crossfire.0";
168			my $smooth = read_smooth "$LIB/smooth";
169
170			sub tile($) {
171			my $name = $_[0];
172
173			my $pb = $tile->{$name}
174			or return;
175
176			unless (ref $pb) {
177			my $file = "/tmp/map2png.$$~";
178
179			open my $fh, ">:raw", $file
180			or die "$file: $!";
181			print $fh $pb;
182			close $fh;
183
184			$pb = $tile->{$name} = new_from_file Gtk2::Gdk::Pixbuf $file;
185			unlink $file;
186			}
187
188			$pb
189			}
190
191			sub cfmap_render($;$) {
192			my ($mapa, $mapname) = @_;
193
194			my %meta;
195
196			my ($mapx, $mapy);
197
198	root	1.10	my $map;
199	root	1.1
200			for (@{ $mapa->{arch} }) {
201	root	1.10	my ($x, $y) = ($_->{x}, $_->{y});
202
203	root	1.1	if ($_->{_name} eq "map") {
204			$meta{info} = $_;
205
206	root	1.10	$mapx = $_->{width} \|\| $x;
207			$mapy = $_->{height} \|\| $y;
208	root	1.1	} else {
209	root	1.10	push @{ $map->[$x][$y] }, $_;
210	root	1.1
211			# arch map is unreliable w.r.t. width and height
212	root	1.10	$mapx = $x + 1 if $mapx <= $x;
213			$mapy = $y + 1 if $mapy <= $y;
214	root	1.1	#$mapx = $a->{x} + 1, warn "$mapname: arch '$a->{_name}' outside map width at ($a->{x}\|$a->{y})\n" if $mapx <= $a->{x};
215			#$mapy = $a->{y} + 1, warn "$mapname: arch '$a->{_name}' outside map height at ($a->{x}\|$a->{y})\n" if $mapy <= $a->{y};
216			}
217			}
218
219			$meta{width} = $mapx;
220			$meta{height} = $mapy;
221
222			my %draw_info;
223	root	1.10	my %map_info;
224	root	1.1
225			# first pass, gather face stacking order, border and corner info
226			for my $x (0 .. $mapx - 1) {
227			my $col = $map->[$x];
228			for my $y (0 .. $mapy - 1) {
229			my $as = $col->[$y] \|\| [];
230	root	1.16
231			my $minsmooth = 0;
232
233	root	1.1	for my $layer (0 .. $#$as) {
234			my $a = $as->[$layer];
235
236	root	1.3	my $o = $arch->{$a->{_name}}
237	root	1.1	or (warn "$mapname: arch '$a->{_name}' not found at ($x\|$y)\n"), next;
238
239	root	1.5	my $smoothlevel = exists $a->{smoothlevel} ? $a->{smoothlevel} : $o->{smoothlevel};
240	root	1.16
241			# hack to ensure somewhat correct ordering in case of conflicting
242			# smoothlevel/stacking order
243			$smoothlevel = $minsmooth + 0.01 if $minsmooth >= $smoothlevel;
244			$minsmooth = $smoothlevel;
245
246			#my $is_floor = exists $a->{is_floor} ? $a->{is_floor} : $o->{is_floor};
247			my $level = $smoothlevel + $layer * 256;
248
249			$level -= 100 * 256 if $o->{_name} eq "blocked";
250	root	1.1
251	root	1.5	while ($o) {
252			my $face = $a->{face} \|\| $o->{face};
253	root	1.1
254	root	1.5	my $pb = tile $face
255			or (warn "$mapname: face '$face' not found for arch '$a->{_name}' at ($x\|$y)\n"), last;
256	root	1.1
257			my $mx = $x + $o->{x};
258			my $my = $y + $o->{y};
259
260	root	1.2	last if 0 > $mx \|\| $mx >= $mapx
261			\|\| 0 > $my \|\| $my >= $mapy;
262	root	1.1
263			# this is very ugly (some tiles are 32x33 or worse)
264			my $bigface = $pb->get_width >= T2 \|\| $pb->get_height >= T2;
265
266	root	1.10	my $dx = $bigface ? $o->{x} : 0;
267			my $dy = $bigface ? $o->{y} : 0;
268
269			push @{ $map_info{$level}{$mx, $my} }, $a;
270
271			$draw_info{$level}{$face}{$mx, $my} \|= 0x2000 \| (($dx + 128) << 24) \| (($dy + 128) << 16);
272
273	root	1.5	if (my $sface = $smooth->{$face}) {
274			$bigface and die "can't handle bigfaces with smoothing ($face)\n";
275	root	1.1
276			# full tile
277	root	1.3	$draw_info{$smoothlevel}{$sface}{$mx , $my } \|= 0x1000;
278	root	1.1
279			# borders
280	root	1.3	$draw_info{$smoothlevel}{$sface}{$mx + 1, $my } \|= 0x0031;
281			$draw_info{$smoothlevel}{$sface}{$mx , $my + 1} \|= 0x0092;
282			$draw_info{$smoothlevel}{$sface}{$mx - 1, $my } \|= 0x0064;
283			$draw_info{$smoothlevel}{$sface}{$mx , $my - 1} \|= 0x00c8;
284	root	1.1
285			# corners
286	root	1.3	$draw_info{$smoothlevel}{$sface}{$mx + 1, $my + 1} \|= 0x0100;
287			$draw_info{$smoothlevel}{$sface}{$mx - 1, $my + 1} \|= 0x0200;
288			$draw_info{$smoothlevel}{$sface}{$mx - 1, $my - 1} \|= 0x0400;
289			$draw_info{$smoothlevel}{$sface}{$mx + 1, $my - 1} \|= 0x0800;
290	root	1.1	}
291
292			$o = $o->{more};
293	root	1.16	$level = ($layer + 1000) * 2; # put "big things" on top, no matter what
294	root	1.1	}
295			}
296			}
297			}
298
299			my $map_pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, $mapx * T, $mapy * T
300			or die;
301	root	1.7	$map_pb->fill (0xffffff00);
302	root	1.1
303	root	1.10	# second pass, render the map
304	root	1.1	for my $level (sort { $a <=> $b } keys %draw_info) {
305			my $v = $draw_info{$level};
306			while (my ($sface, $info) = each %$v) {
307			my $pb = tile $sface
308			or die "no smooth face $sface\n";
309
310			while (my ($xy, $bits) = each %$info) {
311			my ($x, $y) = split $;, $xy;
312
313			next if $x < 0 \|\| $x >= $mapx
314			\|\| $y < 0 \|\| $y >= $mapy;
315
316	root	1.13	# bits is xxxx xxxx yyyy yyyy __fn cccc CCCC bbbb
317			# f full tile draw with x\|y bigface displacement
318			# n do not draw borders&corners
319			# c draw these corners, but...
320			# C ... not these
321	root	1.1	# b draw these borders
322
323			if ($bits & 0x2000) {
324			my $dx = (($bits >> 24) & 0xff) - 128;
325			my $dy = (($bits >> 16) & 0xff) - 128;
326
327			$pb->composite ($map_pb,
328			$x * T, $y * T,
329			T, T,
330			($x - $dx) * T, ($y - $dy) * T, 1, 1,
331			"nearest",
332			255
333			);
334			}
335
336			unless ($bits & 0x1000) {
337			my $border = $bits & 0xf;
338			my $corner = ($bits >> 8) & ~($bits >> 4) & 0xf;
339
340			$pb->composite ($map_pb,
341			$x * T, $y * T,
342			T, T,
343			($x - $border) * T, $y * T, 1, 1,
344			"nearest",
345			255
346			) if $border;
347
348			$pb->composite ($map_pb,
349			$x * T, $y * T,
350			T, T,
351			($x - $corner) * T, ($y - 1) * T, 1, 1,
352			"nearest",
353			255
354			) if $corner;
355			}
356			}
357			}
358			}
359
360	root	1.10	# third pass, gather meta info
361			for my $level (sort { $a <=> $b } keys %map_info) {
362			my $info = $map_info{$level};
363
364			while (my ($xy, $as) = each %$info) {
365			my ($x, $y) = split $;, $xy;
366
367			next if $x < 0 \|\| $x >= $mapx
368			\|\| $y < 0 \|\| $y >= $mapy;
369
370			push @{ $meta{map}[$x][$y] }, $_ for @$as;
371			}
372			}
373
374	root	1.1	($map_pb, \%meta)
375			}
376
377			for my $file (@ARGV) {
378			my $mapa = read_arch $file;
379			my ($pb, $meta) = cfmap_render $mapa, $file;
380	root	1.16	$pb->save ("$file.png~~", "png");
381			system "convert", "$file.png~~", "-filter" => "lanczos", "-geometry" => "3.125%", "-quality" => 85, "$file.jpg";
382	root	1.6	#system "mogrify", "-colors" => 65536, "$file.png~"; # destroys transparency
383	root	1.16	system "pngcrush", "-q", "-m" => 7, "-rem", "alla", "-cc", "-reduce", "$file.png~~", "$file.png~";
384	root	1.15	# system "pngnq <\Q$file.png~\E >\Q$file.png\E";
385	root	1.16	unlink "$file.png~~";
386	root	1.1	Storable::nstore $meta, "$file.pst";
387	root	1.16	utime +(stat $file)[8,9], "$file.pst";
388			utime +(stat $file)[8,9], "$file.png~";
389			rename "$file.png~", "$file.png";
390	root	1.1	}
391
392
393
394
395
396