=head1 NAME

common::sense - save a tree AND a kitten, use common::sense!

=head1 SYNOPSIS

 use common::sense;

 # roughly the same as, with much lower memory usage:
 #
 # use strict qw(vars subs);
 # use feature qw(say state switch);
 # no warnings;

=head1 DESCRIPTION

This module implements some sane defaults for Perl programs, as defined by
two typical (or not so typical - use your common sense) specimens of
Perl coders.

=over 4

=item use strict qw(subs vars)

Using C<use strict> is definitely common sense, but C<use strict
'refs'> definitely overshoots it's usefulness. After almost two
decades of Perl hacking, we decided that it does more harm than being
useful. Specifically, constructs like these:

   @{ $var->[0] }

Must be written like this, when C<use strict 'refs'> is in scope, and
C<$var> can legally be C<undef>:

   @{ $var->[0] || [] }

This is annoying, and doesn't shield against obvious mistakes such as
using C<"">, so one would even have to write:

   @{ defined $var->[0] ? $var->[0] :  [] }

... which nobody with a bit of common sense would consider
writing. Curiously enough, sometimes, perl is not so strict, as this works
even with C<use strict> in scope:

   for (@{ $var->[0] }) { ...

If that isnt hipocrasy! And all that from a mere program!

=item use feature qw(say state given)

We found it annoying that we always have to enable extra features. If
something breaks because it didn't anticipate future changes, so be
it. 5.10 broke almost all our XS modules and nobody cared either - and few
modules that are no longer maintained work with newer versions of Perl,
regardless of use feature.

If your code isn'talive, it's dead, jim.

=item no warnings

The dreaded warnings. Even worse, the horribly dreaded C<-w> switch. Even
though we don't care if other people use warnings (and certainly there are
useful ones), a lot of warnings simply go against the spirit of Perl, most
prominently, the warnings related to C<undef>. There is nothing wrong with
C<undef>: it has well-defined semantics, it is useful, and spitting out
warnings you never asked for is just evil.

So every module needs C<no warnings> to avoid somebody accidentally using
C<-w> and forcing his bad standards on our code. No will do.

(Also, why isn't this a C<use feature> switch? Adding warnings is
apparently considered O.K., even if it breaks your programs).

=item much less memory

Just using all those pragmas together waste <blink>I<< B<776> kilobytes

>></blink> of precious memory in my perl, for I<every single perl process

using our code>, which on our machines, is a lot. In comparison, this
module only uses I<< B<four> >> kilobytes (I even had to write it out so
it looks like more) of memory on the same platform.

The money/time/effort/electricity invested in these gigabytes (probably
petabytes globally!) of wasted memory could easily save 42 trees, and a
kitten!

=cut

package common::sense;

our $VERSION = '0.03';

sub import {
   # no warnings
   ${^WARNING_BITS} ^= ${^WARNING_BITS};

   # use strict vars subs
   $^H |= 0x00000600;

   # use feature
   $^H{feature_switch} =
   $^H{feature_say}    =
   $^H{feature_state}  = 1;
}

=cut

1;

=back

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut