1 |
=head1 NAME |
2 |
|
3 |
AnyEvent::MP - erlang-style multi-processing/message-passing framework |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use AnyEvent::MP; |
8 |
|
9 |
$NODE # contains this node's node ID |
10 |
NODE # returns this node's node ID |
11 |
|
12 |
$SELF # receiving/own port id in rcv callbacks |
13 |
|
14 |
# initialise the node so it can send/receive messages |
15 |
configure; |
16 |
|
17 |
# ports are message destinations |
18 |
|
19 |
# sending messages |
20 |
snd $port, type => data...; |
21 |
snd $port, @msg; |
22 |
snd @msg_with_first_element_being_a_port; |
23 |
|
24 |
# creating/using ports, the simple way |
25 |
my $simple_port = port { my @msg = @_ }; |
26 |
|
27 |
# creating/using ports, tagged message matching |
28 |
my $port = port; |
29 |
rcv $port, ping => sub { snd $_[0], "pong" }; |
30 |
rcv $port, pong => sub { warn "pong received\n" }; |
31 |
|
32 |
# create a port on another node |
33 |
my $port = spawn $node, $initfunc, @initdata; |
34 |
|
35 |
# monitoring |
36 |
mon $localport, $cb->(@msg) # callback is invoked on death |
37 |
mon $localport, $otherport # kill otherport on abnormal death |
38 |
mon $localport, $otherport, @msg # send message on death |
39 |
|
40 |
=head1 CURRENT STATUS |
41 |
|
42 |
bin/aemp - stable. |
43 |
AnyEvent::MP - stable API, should work. |
44 |
AnyEvent::MP::Intro - explains most concepts. |
45 |
AnyEvent::MP::Kernel - mostly stable API. |
46 |
AnyEvent::MP::Global - stable API. |
47 |
|
48 |
=head1 DESCRIPTION |
49 |
|
50 |
This module (-family) implements a simple message passing framework. |
51 |
|
52 |
Despite its simplicity, you can securely message other processes running |
53 |
on the same or other hosts, and you can supervise entities remotely. |
54 |
|
55 |
For an introduction to this module family, see the L<AnyEvent::MP::Intro> |
56 |
manual page and the examples under F<eg/>. |
57 |
|
58 |
=head1 CONCEPTS |
59 |
|
60 |
=over 4 |
61 |
|
62 |
=item port |
63 |
|
64 |
Not to be confused with a TCP port, a "port" is something you can send |
65 |
messages to (with the C<snd> function). |
66 |
|
67 |
Ports allow you to register C<rcv> handlers that can match all or just |
68 |
some messages. Messages send to ports will not be queued, regardless of |
69 |
anything was listening for them or not. |
70 |
|
71 |
=item port ID - C<nodeid#portname> |
72 |
|
73 |
A port ID is the concatenation of a node ID, a hash-mark (C<#>) as |
74 |
separator, and a port name (a printable string of unspecified format). |
75 |
|
76 |
=item node |
77 |
|
78 |
A node is a single process containing at least one port - the node port, |
79 |
which enables nodes to manage each other remotely, and to create new |
80 |
ports. |
81 |
|
82 |
Nodes are either public (have one or more listening ports) or private |
83 |
(no listening ports). Private nodes cannot talk to other private nodes |
84 |
currently. |
85 |
|
86 |
=item node ID - C<[A-Z_][a-zA-Z0-9_\-.:]*> |
87 |
|
88 |
A node ID is a string that uniquely identifies the node within a |
89 |
network. Depending on the configuration used, node IDs can look like a |
90 |
hostname, a hostname and a port, or a random string. AnyEvent::MP itself |
91 |
doesn't interpret node IDs in any way. |
92 |
|
93 |
=item binds - C<ip:port> |
94 |
|
95 |
Nodes can only talk to each other by creating some kind of connection to |
96 |
each other. To do this, nodes should listen on one or more local transport |
97 |
endpoints - binds. Currently, only standard C<ip:port> specifications can |
98 |
be used, which specify TCP ports to listen on. |
99 |
|
100 |
=item seed nodes |
101 |
|
102 |
When a node starts, it knows nothing about the network. To teach the node |
103 |
about the network it first has to contact some other node within the |
104 |
network. This node is called a seed. |
105 |
|
106 |
Apart from the fact that other nodes know them as seed nodes and they have |
107 |
to have fixed listening addresses, seed nodes are perfectly normal nodes - |
108 |
any node can function as a seed node for others. |
109 |
|
110 |
In addition to discovering the network, seed nodes are also used to |
111 |
maintain the network and to connect nodes that otherwise would have |
112 |
trouble connecting. They form the backbone of an AnyEvent::MP network. |
113 |
|
114 |
Seed nodes are expected to be long-running, and at least one seed node |
115 |
should always be available. They should also be relatively responsive - a |
116 |
seed node that blocks for long periods will slow down everybody else. |
117 |
|
118 |
=item seeds - C<host:port> |
119 |
|
120 |
Seeds are transport endpoint(s) (usually a hostname/IP address and a |
121 |
TCP port) of nodes that should be used as seed nodes. |
122 |
|
123 |
The nodes listening on those endpoints are expected to be long-running, |
124 |
and at least one of those should always be available. When nodes run out |
125 |
of connections (e.g. due to a network error), they try to re-establish |
126 |
connections to some seednodes again to join the network. |
127 |
|
128 |
=back |
129 |
|
130 |
=head1 VARIABLES/FUNCTIONS |
131 |
|
132 |
=over 4 |
133 |
|
134 |
=cut |
135 |
|
136 |
package AnyEvent::MP; |
137 |
|
138 |
use AnyEvent::MP::Kernel; |
139 |
|
140 |
use common::sense; |
141 |
|
142 |
use Carp (); |
143 |
|
144 |
use AE (); |
145 |
|
146 |
use base "Exporter"; |
147 |
|
148 |
our $VERSION = $AnyEvent::MP::Kernel::VERSION; |
149 |
|
150 |
our @EXPORT = qw( |
151 |
NODE $NODE *SELF node_of after |
152 |
configure |
153 |
snd rcv mon mon_guard kil psub spawn cal |
154 |
port |
155 |
); |
156 |
|
157 |
our $SELF; |
158 |
|
159 |
sub _self_die() { |
160 |
my $msg = $@; |
161 |
$msg =~ s/\n+$// unless ref $msg; |
162 |
kil $SELF, die => $msg; |
163 |
} |
164 |
|
165 |
=item $thisnode = NODE / $NODE |
166 |
|
167 |
The C<NODE> function returns, and the C<$NODE> variable contains, the node |
168 |
ID of the node running in the current process. This value is initialised by |
169 |
a call to C<configure>. |
170 |
|
171 |
=item $nodeid = node_of $port |
172 |
|
173 |
Extracts and returns the node ID from a port ID or a node ID. |
174 |
|
175 |
=item configure $profile, key => value... |
176 |
|
177 |
=item configure key => value... |
178 |
|
179 |
Before a node can talk to other nodes on the network (i.e. enter |
180 |
"distributed mode") it has to configure itself - the minimum a node needs |
181 |
to know is its own name, and optionally it should know the addresses of |
182 |
some other nodes in the network to discover other nodes. |
183 |
|
184 |
This function configures a node - it must be called exactly once (or |
185 |
never) before calling other AnyEvent::MP functions. |
186 |
|
187 |
=over 4 |
188 |
|
189 |
=item step 1, gathering configuration from profiles |
190 |
|
191 |
The function first looks up a profile in the aemp configuration (see the |
192 |
L<aemp> commandline utility). The profile name can be specified via the |
193 |
named C<profile> parameter or can simply be the first parameter). If it is |
194 |
missing, then the nodename (F<uname -n>) will be used as profile name. |
195 |
|
196 |
The profile data is then gathered as follows: |
197 |
|
198 |
First, all remaining key => value pairs (all of which are conveniently |
199 |
undocumented at the moment) will be interpreted as configuration |
200 |
data. Then they will be overwritten by any values specified in the global |
201 |
default configuration (see the F<aemp> utility), then the chain of |
202 |
profiles chosen by the profile name (and any C<parent> attributes). |
203 |
|
204 |
That means that the values specified in the profile have highest priority |
205 |
and the values specified directly via C<configure> have lowest priority, |
206 |
and can only be used to specify defaults. |
207 |
|
208 |
If the profile specifies a node ID, then this will become the node ID of |
209 |
this process. If not, then the profile name will be used as node ID. The |
210 |
special node ID of C<anon/> will be replaced by a random node ID. |
211 |
|
212 |
=item step 2, bind listener sockets |
213 |
|
214 |
The next step is to look up the binds in the profile, followed by binding |
215 |
aemp protocol listeners on all binds specified (it is possible and valid |
216 |
to have no binds, meaning that the node cannot be contacted form the |
217 |
outside. This means the node cannot talk to other nodes that also have no |
218 |
binds, but it can still talk to all "normal" nodes). |
219 |
|
220 |
If the profile does not specify a binds list, then a default of C<*> is |
221 |
used, meaning the node will bind on a dynamically-assigned port on every |
222 |
local IP address it finds. |
223 |
|
224 |
=item step 3, connect to seed nodes |
225 |
|
226 |
As the last step, the seeds list from the profile is passed to the |
227 |
L<AnyEvent::MP::Global> module, which will then use it to keep |
228 |
connectivity with at least one node at any point in time. |
229 |
|
230 |
=back |
231 |
|
232 |
Example: become a distributed node using the local node name as profile. |
233 |
This should be the most common form of invocation for "daemon"-type nodes. |
234 |
|
235 |
configure |
236 |
|
237 |
Example: become an anonymous node. This form is often used for commandline |
238 |
clients. |
239 |
|
240 |
configure nodeid => "anon/"; |
241 |
|
242 |
Example: configure a node using a profile called seed, which si suitable |
243 |
for a seed node as it binds on all local addresses on a fixed port (4040, |
244 |
customary for aemp). |
245 |
|
246 |
# use the aemp commandline utility |
247 |
# aemp profile seed nodeid anon/ binds '*:4040' |
248 |
|
249 |
# then use it |
250 |
configure profile => "seed"; |
251 |
|
252 |
# or simply use aemp from the shell again: |
253 |
# aemp run profile seed |
254 |
|
255 |
# or provide a nicer-to-remember nodeid |
256 |
# aemp run profile seed nodeid "$(hostname)" |
257 |
|
258 |
=item $SELF |
259 |
|
260 |
Contains the current port id while executing C<rcv> callbacks or C<psub> |
261 |
blocks. |
262 |
|
263 |
=item *SELF, SELF, %SELF, @SELF... |
264 |
|
265 |
Due to some quirks in how perl exports variables, it is impossible to |
266 |
just export C<$SELF>, all the symbols named C<SELF> are exported by this |
267 |
module, but only C<$SELF> is currently used. |
268 |
|
269 |
=item snd $port, type => @data |
270 |
|
271 |
=item snd $port, @msg |
272 |
|
273 |
Send the given message to the given port, which can identify either a |
274 |
local or a remote port, and must be a port ID. |
275 |
|
276 |
While the message can be almost anything, it is highly recommended to |
277 |
use a string as first element (a port ID, or some word that indicates a |
278 |
request type etc.) and to consist if only simple perl values (scalars, |
279 |
arrays, hashes) - if you think you need to pass an object, think again. |
280 |
|
281 |
The message data logically becomes read-only after a call to this |
282 |
function: modifying any argument (or values referenced by them) is |
283 |
forbidden, as there can be considerable time between the call to C<snd> |
284 |
and the time the message is actually being serialised - in fact, it might |
285 |
never be copied as within the same process it is simply handed to the |
286 |
receiving port. |
287 |
|
288 |
The type of data you can transfer depends on the transport protocol: when |
289 |
JSON is used, then only strings, numbers and arrays and hashes consisting |
290 |
of those are allowed (no objects). When Storable is used, then anything |
291 |
that Storable can serialise and deserialise is allowed, and for the local |
292 |
node, anything can be passed. Best rely only on the common denominator of |
293 |
these. |
294 |
|
295 |
=item $local_port = port |
296 |
|
297 |
Create a new local port object and returns its port ID. Initially it has |
298 |
no callbacks set and will throw an error when it receives messages. |
299 |
|
300 |
=item $local_port = port { my @msg = @_ } |
301 |
|
302 |
Creates a new local port, and returns its ID. Semantically the same as |
303 |
creating a port and calling C<rcv $port, $callback> on it. |
304 |
|
305 |
The block will be called for every message received on the port, with the |
306 |
global variable C<$SELF> set to the port ID. Runtime errors will cause the |
307 |
port to be C<kil>ed. The message will be passed as-is, no extra argument |
308 |
(i.e. no port ID) will be passed to the callback. |
309 |
|
310 |
If you want to stop/destroy the port, simply C<kil> it: |
311 |
|
312 |
my $port = port { |
313 |
my @msg = @_; |
314 |
... |
315 |
kil $SELF; |
316 |
}; |
317 |
|
318 |
=cut |
319 |
|
320 |
sub rcv($@); |
321 |
|
322 |
sub _kilme { |
323 |
die "received message on port without callback"; |
324 |
} |
325 |
|
326 |
sub port(;&) { |
327 |
my $id = "$UNIQ." . $ID++; |
328 |
my $port = "$NODE#$id"; |
329 |
|
330 |
rcv $port, shift || \&_kilme; |
331 |
|
332 |
$port |
333 |
} |
334 |
|
335 |
=item rcv $local_port, $callback->(@msg) |
336 |
|
337 |
Replaces the default callback on the specified port. There is no way to |
338 |
remove the default callback: use C<sub { }> to disable it, or better |
339 |
C<kil> the port when it is no longer needed. |
340 |
|
341 |
The global C<$SELF> (exported by this module) contains C<$port> while |
342 |
executing the callback. Runtime errors during callback execution will |
343 |
result in the port being C<kil>ed. |
344 |
|
345 |
The default callback received all messages not matched by a more specific |
346 |
C<tag> match. |
347 |
|
348 |
=item rcv $local_port, tag => $callback->(@msg_without_tag), ... |
349 |
|
350 |
Register (or replace) callbacks to be called on messages starting with the |
351 |
given tag on the given port (and return the port), or unregister it (when |
352 |
C<$callback> is C<$undef> or missing). There can only be one callback |
353 |
registered for each tag. |
354 |
|
355 |
The original message will be passed to the callback, after the first |
356 |
element (the tag) has been removed. The callback will use the same |
357 |
environment as the default callback (see above). |
358 |
|
359 |
Example: create a port and bind receivers on it in one go. |
360 |
|
361 |
my $port = rcv port, |
362 |
msg1 => sub { ... }, |
363 |
msg2 => sub { ... }, |
364 |
; |
365 |
|
366 |
Example: create a port, bind receivers and send it in a message elsewhere |
367 |
in one go: |
368 |
|
369 |
snd $otherport, reply => |
370 |
rcv port, |
371 |
msg1 => sub { ... }, |
372 |
... |
373 |
; |
374 |
|
375 |
Example: temporarily register a rcv callback for a tag matching some port |
376 |
(e.g. for a rpc reply) and unregister it after a message was received. |
377 |
|
378 |
rcv $port, $otherport => sub { |
379 |
my @reply = @_; |
380 |
|
381 |
rcv $SELF, $otherport; |
382 |
}; |
383 |
|
384 |
=cut |
385 |
|
386 |
sub rcv($@) { |
387 |
my $port = shift; |
388 |
my ($nodeid, $portid) = split /#/, $port, 2; |
389 |
|
390 |
$NODE{$nodeid} == $NODE{""} |
391 |
or Carp::croak "$port: rcv can only be called on local ports, caught"; |
392 |
|
393 |
while (@_) { |
394 |
if (ref $_[0]) { |
395 |
if (my $self = $PORT_DATA{$portid}) { |
396 |
"AnyEvent::MP::Port" eq ref $self |
397 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
398 |
|
399 |
$self->[2] = shift; |
400 |
} else { |
401 |
my $cb = shift; |
402 |
$PORT{$portid} = sub { |
403 |
local $SELF = $port; |
404 |
eval { &$cb }; _self_die if $@; |
405 |
}; |
406 |
} |
407 |
} elsif (defined $_[0]) { |
408 |
my $self = $PORT_DATA{$portid} ||= do { |
409 |
my $self = bless [$PORT{$port} || sub { }, { }, $port], "AnyEvent::MP::Port"; |
410 |
|
411 |
$PORT{$portid} = sub { |
412 |
local $SELF = $port; |
413 |
|
414 |
if (my $cb = $self->[1]{$_[0]}) { |
415 |
shift; |
416 |
eval { &$cb }; _self_die if $@; |
417 |
} else { |
418 |
&{ $self->[0] }; |
419 |
} |
420 |
}; |
421 |
|
422 |
$self |
423 |
}; |
424 |
|
425 |
"AnyEvent::MP::Port" eq ref $self |
426 |
or Carp::croak "$port: rcv can only be called on message matching ports, caught"; |
427 |
|
428 |
my ($tag, $cb) = splice @_, 0, 2; |
429 |
|
430 |
if (defined $cb) { |
431 |
$self->[1]{$tag} = $cb; |
432 |
} else { |
433 |
delete $self->[1]{$tag}; |
434 |
} |
435 |
} |
436 |
} |
437 |
|
438 |
$port |
439 |
} |
440 |
|
441 |
=item $closure = psub { BLOCK } |
442 |
|
443 |
Remembers C<$SELF> and creates a closure out of the BLOCK. When the |
444 |
closure is executed, sets up the environment in the same way as in C<rcv> |
445 |
callbacks, i.e. runtime errors will cause the port to get C<kil>ed. |
446 |
|
447 |
This is useful when you register callbacks from C<rcv> callbacks: |
448 |
|
449 |
rcv delayed_reply => sub { |
450 |
my ($delay, @reply) = @_; |
451 |
my $timer = AE::timer $delay, 0, psub { |
452 |
snd @reply, $SELF; |
453 |
}; |
454 |
}; |
455 |
|
456 |
=cut |
457 |
|
458 |
sub psub(&) { |
459 |
my $cb = shift; |
460 |
|
461 |
my $port = $SELF |
462 |
or Carp::croak "psub can only be called from within rcv or psub callbacks, not"; |
463 |
|
464 |
sub { |
465 |
local $SELF = $port; |
466 |
|
467 |
if (wantarray) { |
468 |
my @res = eval { &$cb }; |
469 |
_self_die if $@; |
470 |
@res |
471 |
} else { |
472 |
my $res = eval { &$cb }; |
473 |
_self_die if $@; |
474 |
$res |
475 |
} |
476 |
} |
477 |
} |
478 |
|
479 |
=item $guard = mon $port, $cb->(@reason) # call $cb when $port dies |
480 |
|
481 |
=item $guard = mon $port, $rcvport # kill $rcvport when $port dies |
482 |
|
483 |
=item $guard = mon $port # kill $SELF when $port dies |
484 |
|
485 |
=item $guard = mon $port, $rcvport, @msg # send a message when $port dies |
486 |
|
487 |
Monitor the given port and do something when the port is killed or |
488 |
messages to it were lost, and optionally return a guard that can be used |
489 |
to stop monitoring again. |
490 |
|
491 |
In the first form (callback), the callback is simply called with any |
492 |
number of C<@reason> elements (no @reason means that the port was deleted |
493 |
"normally"). Note also that I<< the callback B<must> never die >>, so use |
494 |
C<eval> if unsure. |
495 |
|
496 |
In the second form (another port given), the other port (C<$rcvport>) |
497 |
will be C<kil>'ed with C<@reason>, if a @reason was specified, i.e. on |
498 |
"normal" kils nothing happens, while under all other conditions, the other |
499 |
port is killed with the same reason. |
500 |
|
501 |
The third form (kill self) is the same as the second form, except that |
502 |
C<$rvport> defaults to C<$SELF>. |
503 |
|
504 |
In the last form (message), a message of the form C<@msg, @reason> will be |
505 |
C<snd>. |
506 |
|
507 |
Monitoring-actions are one-shot: once messages are lost (and a monitoring |
508 |
alert was raised), they are removed and will not trigger again. |
509 |
|
510 |
As a rule of thumb, monitoring requests should always monitor a port from |
511 |
a local port (or callback). The reason is that kill messages might get |
512 |
lost, just like any other message. Another less obvious reason is that |
513 |
even monitoring requests can get lost (for example, when the connection |
514 |
to the other node goes down permanently). When monitoring a port locally |
515 |
these problems do not exist. |
516 |
|
517 |
C<mon> effectively guarantees that, in the absence of hardware failures, |
518 |
after starting the monitor, either all messages sent to the port will |
519 |
arrive, or the monitoring action will be invoked after possible message |
520 |
loss has been detected. No messages will be lost "in between" (after |
521 |
the first lost message no further messages will be received by the |
522 |
port). After the monitoring action was invoked, further messages might get |
523 |
delivered again. |
524 |
|
525 |
Inter-host-connection timeouts and monitoring depend on the transport |
526 |
used. The only transport currently implemented is TCP, and AnyEvent::MP |
527 |
relies on TCP to detect node-downs (this can take 10-15 minutes on a |
528 |
non-idle connection, and usually around two hours for idle connections). |
529 |
|
530 |
This means that monitoring is good for program errors and cleaning up |
531 |
stuff eventually, but they are no replacement for a timeout when you need |
532 |
to ensure some maximum latency. |
533 |
|
534 |
Example: call a given callback when C<$port> is killed. |
535 |
|
536 |
mon $port, sub { warn "port died because of <@_>\n" }; |
537 |
|
538 |
Example: kill ourselves when C<$port> is killed abnormally. |
539 |
|
540 |
mon $port; |
541 |
|
542 |
Example: send us a restart message when another C<$port> is killed. |
543 |
|
544 |
mon $port, $self => "restart"; |
545 |
|
546 |
=cut |
547 |
|
548 |
sub mon { |
549 |
my ($nodeid, $port) = split /#/, shift, 2; |
550 |
|
551 |
my $node = $NODE{$nodeid} || add_node $nodeid; |
552 |
|
553 |
my $cb = @_ ? shift : $SELF || Carp::croak 'mon: called with one argument only, but $SELF not set,'; |
554 |
|
555 |
unless (ref $cb) { |
556 |
if (@_) { |
557 |
# send a kill info message |
558 |
my (@msg) = ($cb, @_); |
559 |
$cb = sub { snd @msg, @_ }; |
560 |
} else { |
561 |
# simply kill other port |
562 |
my $port = $cb; |
563 |
$cb = sub { kil $port, @_ if @_ }; |
564 |
} |
565 |
} |
566 |
|
567 |
$node->monitor ($port, $cb); |
568 |
|
569 |
defined wantarray |
570 |
and ($cb += 0, AnyEvent::Util::guard { $node->unmonitor ($port, $cb) }) |
571 |
} |
572 |
|
573 |
=item $guard = mon_guard $port, $ref, $ref... |
574 |
|
575 |
Monitors the given C<$port> and keeps the passed references. When the port |
576 |
is killed, the references will be freed. |
577 |
|
578 |
Optionally returns a guard that will stop the monitoring. |
579 |
|
580 |
This function is useful when you create e.g. timers or other watchers and |
581 |
want to free them when the port gets killed (note the use of C<psub>): |
582 |
|
583 |
$port->rcv (start => sub { |
584 |
my $timer; $timer = mon_guard $port, AE::timer 1, 1, psub { |
585 |
undef $timer if 0.9 < rand; |
586 |
}); |
587 |
}); |
588 |
|
589 |
=cut |
590 |
|
591 |
sub mon_guard { |
592 |
my ($port, @refs) = @_; |
593 |
|
594 |
#TODO: mon-less form? |
595 |
|
596 |
mon $port, sub { 0 && @refs } |
597 |
} |
598 |
|
599 |
=item kil $port[, @reason] |
600 |
|
601 |
Kill the specified port with the given C<@reason>. |
602 |
|
603 |
If no C<@reason> is specified, then the port is killed "normally" (ports |
604 |
monitoring other ports will not necessarily die because a port dies |
605 |
"normally"). |
606 |
|
607 |
Otherwise, linked ports get killed with the same reason (second form of |
608 |
C<mon>, see above). |
609 |
|
610 |
Runtime errors while evaluating C<rcv> callbacks or inside C<psub> blocks |
611 |
will be reported as reason C<< die => $@ >>. |
612 |
|
613 |
Transport/communication errors are reported as C<< transport_error => |
614 |
$message >>. |
615 |
|
616 |
=cut |
617 |
|
618 |
=item $port = spawn $node, $initfunc[, @initdata] |
619 |
|
620 |
Creates a port on the node C<$node> (which can also be a port ID, in which |
621 |
case it's the node where that port resides). |
622 |
|
623 |
The port ID of the newly created port is returned immediately, and it is |
624 |
possible to immediately start sending messages or to monitor the port. |
625 |
|
626 |
After the port has been created, the init function is called on the remote |
627 |
node, in the same context as a C<rcv> callback. This function must be a |
628 |
fully-qualified function name (e.g. C<MyApp::Chat::Server::init>). To |
629 |
specify a function in the main program, use C<::name>. |
630 |
|
631 |
If the function doesn't exist, then the node tries to C<require> |
632 |
the package, then the package above the package and so on (e.g. |
633 |
C<MyApp::Chat::Server>, C<MyApp::Chat>, C<MyApp>) until the function |
634 |
exists or it runs out of package names. |
635 |
|
636 |
The init function is then called with the newly-created port as context |
637 |
object (C<$SELF>) and the C<@initdata> values as arguments. It I<must> |
638 |
call one of the C<rcv> functions to set callbacks on C<$SELF>, otherwise |
639 |
the port might not get created. |
640 |
|
641 |
A common idiom is to pass a local port, immediately monitor the spawned |
642 |
port, and in the remote init function, immediately monitor the passed |
643 |
local port. This two-way monitoring ensures that both ports get cleaned up |
644 |
when there is a problem. |
645 |
|
646 |
C<spawn> guarantees that the C<$initfunc> has no visible effects on the |
647 |
caller before C<spawn> returns (by delaying invocation when spawn is |
648 |
called for the local node). |
649 |
|
650 |
Example: spawn a chat server port on C<$othernode>. |
651 |
|
652 |
# this node, executed from within a port context: |
653 |
my $server = spawn $othernode, "MyApp::Chat::Server::connect", $SELF; |
654 |
mon $server; |
655 |
|
656 |
# init function on C<$othernode> |
657 |
sub connect { |
658 |
my ($srcport) = @_; |
659 |
|
660 |
mon $srcport; |
661 |
|
662 |
rcv $SELF, sub { |
663 |
... |
664 |
}; |
665 |
} |
666 |
|
667 |
=cut |
668 |
|
669 |
sub _spawn { |
670 |
my $port = shift; |
671 |
my $init = shift; |
672 |
|
673 |
# rcv will create the actual port |
674 |
local $SELF = "$NODE#$port"; |
675 |
eval { |
676 |
&{ load_func $init } |
677 |
}; |
678 |
_self_die if $@; |
679 |
} |
680 |
|
681 |
sub spawn(@) { |
682 |
my ($nodeid, undef) = split /#/, shift, 2; |
683 |
|
684 |
my $id = "$RUNIQ." . $ID++; |
685 |
|
686 |
$_[0] =~ /::/ |
687 |
or Carp::croak "spawn init function must be a fully-qualified name, caught"; |
688 |
|
689 |
snd_to_func $nodeid, "AnyEvent::MP::_spawn" => $id, @_; |
690 |
|
691 |
"$nodeid#$id" |
692 |
} |
693 |
|
694 |
=item after $timeout, @msg |
695 |
|
696 |
=item after $timeout, $callback |
697 |
|
698 |
Either sends the given message, or call the given callback, after the |
699 |
specified number of seconds. |
700 |
|
701 |
This is simply a utility function that comes in handy at times - the |
702 |
AnyEvent::MP author is not convinced of the wisdom of having it, though, |
703 |
so it may go away in the future. |
704 |
|
705 |
=cut |
706 |
|
707 |
sub after($@) { |
708 |
my ($timeout, @action) = @_; |
709 |
|
710 |
my $t; $t = AE::timer $timeout, 0, sub { |
711 |
undef $t; |
712 |
ref $action[0] |
713 |
? $action[0]() |
714 |
: snd @action; |
715 |
}; |
716 |
} |
717 |
|
718 |
=item cal $port, @msg, $callback[, $timeout] |
719 |
|
720 |
A simple form of RPC - sends a message to the given C<$port> with the |
721 |
given contents (C<@msg>), but adds a reply port to the message. |
722 |
|
723 |
The reply port is created temporarily just for the purpose of receiving |
724 |
the reply, and will be C<kil>ed when no longer needed. |
725 |
|
726 |
A reply message sent to the port is passed to the C<$callback> as-is. |
727 |
|
728 |
If an optional time-out (in seconds) is given and it is not C<undef>, |
729 |
then the callback will be called without any arguments after the time-out |
730 |
elapsed and the port is C<kil>ed. |
731 |
|
732 |
If no time-out is given, then the local port will monitor the remote port |
733 |
instead, so it eventually gets cleaned-up. |
734 |
|
735 |
Currently this function returns the temporary port, but this "feature" |
736 |
might go in future versions unless you can make a convincing case that |
737 |
this is indeed useful for something. |
738 |
|
739 |
=cut |
740 |
|
741 |
sub cal(@) { |
742 |
my $timeout = ref $_[-1] ? undef : pop; |
743 |
my $cb = pop; |
744 |
|
745 |
my $port = port { |
746 |
undef $timeout; |
747 |
kil $SELF; |
748 |
&$cb; |
749 |
}; |
750 |
|
751 |
if (defined $timeout) { |
752 |
$timeout = AE::timer $timeout, 0, sub { |
753 |
undef $timeout; |
754 |
kil $port; |
755 |
$cb->(); |
756 |
}; |
757 |
} else { |
758 |
mon $_[0], sub { |
759 |
kil $port; |
760 |
$cb->(); |
761 |
}; |
762 |
} |
763 |
|
764 |
push @_, $port; |
765 |
&snd; |
766 |
|
767 |
$port |
768 |
} |
769 |
|
770 |
=back |
771 |
|
772 |
=head1 AnyEvent::MP vs. Distributed Erlang |
773 |
|
774 |
AnyEvent::MP got lots of its ideas from distributed Erlang (Erlang node |
775 |
== aemp node, Erlang process == aemp port), so many of the documents and |
776 |
programming techniques employed by Erlang apply to AnyEvent::MP. Here is a |
777 |
sample: |
778 |
|
779 |
http://www.erlang.se/doc/programming_rules.shtml |
780 |
http://erlang.org/doc/getting_started/part_frame.html # chapters 3 and 4 |
781 |
http://erlang.org/download/erlang-book-part1.pdf # chapters 5 and 6 |
782 |
http://erlang.org/download/armstrong_thesis_2003.pdf # chapters 4 and 5 |
783 |
|
784 |
Despite the similarities, there are also some important differences: |
785 |
|
786 |
=over 4 |
787 |
|
788 |
=item * Node IDs are arbitrary strings in AEMP. |
789 |
|
790 |
Erlang relies on special naming and DNS to work everywhere in the same |
791 |
way. AEMP relies on each node somehow knowing its own address(es) (e.g. by |
792 |
configuration or DNS), but will otherwise discover other odes itself. |
793 |
|
794 |
=item * Erlang has a "remote ports are like local ports" philosophy, AEMP |
795 |
uses "local ports are like remote ports". |
796 |
|
797 |
The failure modes for local ports are quite different (runtime errors |
798 |
only) then for remote ports - when a local port dies, you I<know> it dies, |
799 |
when a connection to another node dies, you know nothing about the other |
800 |
port. |
801 |
|
802 |
Erlang pretends remote ports are as reliable as local ports, even when |
803 |
they are not. |
804 |
|
805 |
AEMP encourages a "treat remote ports differently" philosophy, with local |
806 |
ports being the special case/exception, where transport errors cannot |
807 |
occur. |
808 |
|
809 |
=item * Erlang uses processes and a mailbox, AEMP does not queue. |
810 |
|
811 |
Erlang uses processes that selectively receive messages, and therefore |
812 |
needs a queue. AEMP is event based, queuing messages would serve no |
813 |
useful purpose. For the same reason the pattern-matching abilities of |
814 |
AnyEvent::MP are more limited, as there is little need to be able to |
815 |
filter messages without dequeuing them. |
816 |
|
817 |
(But see L<Coro::MP> for a more Erlang-like process model on top of AEMP). |
818 |
|
819 |
=item * Erlang sends are synchronous, AEMP sends are asynchronous. |
820 |
|
821 |
Sending messages in Erlang is synchronous and blocks the process (and |
822 |
so does not need a queue that can overflow). AEMP sends are immediate, |
823 |
connection establishment is handled in the background. |
824 |
|
825 |
=item * Erlang suffers from silent message loss, AEMP does not. |
826 |
|
827 |
Erlang makes few guarantees on messages delivery - messages can get lost |
828 |
without any of the processes realising it (i.e. you send messages a, b, |
829 |
and c, and the other side only receives messages a and c). |
830 |
|
831 |
AEMP guarantees correct ordering, and the guarantee that after one message |
832 |
is lost, all following ones sent to the same port are lost as well, until |
833 |
monitoring raises an error, so there are no silent "holes" in the message |
834 |
sequence. |
835 |
|
836 |
=item * Erlang can send messages to the wrong port, AEMP does not. |
837 |
|
838 |
In Erlang it is quite likely that a node that restarts reuses a process ID |
839 |
known to other nodes for a completely different process, causing messages |
840 |
destined for that process to end up in an unrelated process. |
841 |
|
842 |
AEMP never reuses port IDs, so old messages or old port IDs floating |
843 |
around in the network will not be sent to an unrelated port. |
844 |
|
845 |
=item * Erlang uses unprotected connections, AEMP uses secure |
846 |
authentication and can use TLS. |
847 |
|
848 |
AEMP can use a proven protocol - TLS - to protect connections and |
849 |
securely authenticate nodes. |
850 |
|
851 |
=item * The AEMP protocol is optimised for both text-based and binary |
852 |
communications. |
853 |
|
854 |
The AEMP protocol, unlike the Erlang protocol, supports both programming |
855 |
language independent text-only protocols (good for debugging) and binary, |
856 |
language-specific serialisers (e.g. Storable). By default, unless TLS is |
857 |
used, the protocol is actually completely text-based. |
858 |
|
859 |
It has also been carefully designed to be implementable in other languages |
860 |
with a minimum of work while gracefully degrading functionality to make the |
861 |
protocol simple. |
862 |
|
863 |
=item * AEMP has more flexible monitoring options than Erlang. |
864 |
|
865 |
In Erlang, you can chose to receive I<all> exit signals as messages |
866 |
or I<none>, there is no in-between, so monitoring single processes is |
867 |
difficult to implement. Monitoring in AEMP is more flexible than in |
868 |
Erlang, as one can choose between automatic kill, exit message or callback |
869 |
on a per-process basis. |
870 |
|
871 |
=item * Erlang tries to hide remote/local connections, AEMP does not. |
872 |
|
873 |
Monitoring in Erlang is not an indicator of process death/crashes, in the |
874 |
same way as linking is (except linking is unreliable in Erlang). |
875 |
|
876 |
In AEMP, you don't "look up" registered port names or send to named ports |
877 |
that might or might not be persistent. Instead, you normally spawn a port |
878 |
on the remote node. The init function monitors you, and you monitor the |
879 |
remote port. Since both monitors are local to the node, they are much more |
880 |
reliable (no need for C<spawn_link>). |
881 |
|
882 |
This also saves round-trips and avoids sending messages to the wrong port |
883 |
(hard to do in Erlang). |
884 |
|
885 |
=back |
886 |
|
887 |
=head1 RATIONALE |
888 |
|
889 |
=over 4 |
890 |
|
891 |
=item Why strings for port and node IDs, why not objects? |
892 |
|
893 |
We considered "objects", but found that the actual number of methods |
894 |
that can be called are quite low. Since port and node IDs travel over |
895 |
the network frequently, the serialising/deserialising would add lots of |
896 |
overhead, as well as having to keep a proxy object everywhere. |
897 |
|
898 |
Strings can easily be printed, easily serialised etc. and need no special |
899 |
procedures to be "valid". |
900 |
|
901 |
And as a result, a miniport consists of a single closure stored in a |
902 |
global hash - it can't become much cheaper. |
903 |
|
904 |
=item Why favour JSON, why not a real serialising format such as Storable? |
905 |
|
906 |
In fact, any AnyEvent::MP node will happily accept Storable as framing |
907 |
format, but currently there is no way to make a node use Storable by |
908 |
default (although all nodes will accept it). |
909 |
|
910 |
The default framing protocol is JSON because a) JSON::XS is many times |
911 |
faster for small messages and b) most importantly, after years of |
912 |
experience we found that object serialisation is causing more problems |
913 |
than it solves: Just like function calls, objects simply do not travel |
914 |
easily over the network, mostly because they will always be a copy, so you |
915 |
always have to re-think your design. |
916 |
|
917 |
Keeping your messages simple, concentrating on data structures rather than |
918 |
objects, will keep your messages clean, tidy and efficient. |
919 |
|
920 |
=back |
921 |
|
922 |
=head1 SEE ALSO |
923 |
|
924 |
L<AnyEvent::MP::Intro> - a gentle introduction. |
925 |
|
926 |
L<AnyEvent::MP::Kernel> - more, lower-level, stuff. |
927 |
|
928 |
L<AnyEvent::MP::Global> - network maintainance and port groups, to find |
929 |
your applications. |
930 |
|
931 |
L<AnyEvent::MP::LogCatcher> - simple service to display log messages from |
932 |
all nodes. |
933 |
|
934 |
L<AnyEvent>. |
935 |
|
936 |
=head1 AUTHOR |
937 |
|
938 |
Marc Lehmann <schmorp@schmorp.de> |
939 |
http://home.schmorp.de/ |
940 |
|
941 |
=cut |
942 |
|
943 |
1 |
944 |
|