| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::MP::Transport - actual transport protocol handler |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::MP::Transport; |
| 8 |
|
| 9 |
=head1 DESCRIPTION |
| 10 |
|
| 11 |
This module implements (and documents) the actual transport protocol for |
| 12 |
AEMP. |
| 13 |
|
| 14 |
See the "PROTOCOL" section below if you want to write another client for |
| 15 |
this protocol. |
| 16 |
|
| 17 |
=head1 FUNCTIONS/METHODS |
| 18 |
|
| 19 |
=over 4 |
| 20 |
|
| 21 |
=cut |
| 22 |
|
| 23 |
package AnyEvent::MP::Transport; |
| 24 |
|
| 25 |
use common::sense; |
| 26 |
|
| 27 |
use Scalar::Util (); |
| 28 |
use List::Util (); |
| 29 |
use MIME::Base64 (); |
| 30 |
use Storable (); |
| 31 |
use JSON::XS (); |
| 32 |
|
| 33 |
use Digest::MD6 (); |
| 34 |
use Digest::HMAC_MD6 (); |
| 35 |
|
| 36 |
use AE (); |
| 37 |
use AnyEvent::Socket (); |
| 38 |
use AnyEvent::Handle 4.92 (); |
| 39 |
|
| 40 |
use AnyEvent::MP::Config (); |
| 41 |
|
| 42 |
our $PROTOCOL_VERSION = 0; |
| 43 |
|
| 44 |
=item $listener = mp_listener $host, $port, <constructor-args> |
| 45 |
|
| 46 |
Creates a listener on the given host/port using |
| 47 |
C<AnyEvent::Socket::tcp_server>. |
| 48 |
|
| 49 |
See C<new>, below, for constructor arguments. |
| 50 |
|
| 51 |
Defaults for peerhost, peerport and fh are provided. |
| 52 |
|
| 53 |
=cut |
| 54 |
|
| 55 |
sub mp_server($$;%) { |
| 56 |
my ($host, $port, %arg) = @_; |
| 57 |
|
| 58 |
AnyEvent::Socket::tcp_server $host, $port, sub { |
| 59 |
my ($fh, $host, $port) = @_; |
| 60 |
|
| 61 |
my $tp = new AnyEvent::MP::Transport |
| 62 |
fh => $fh, |
| 63 |
peerhost => $host, |
| 64 |
peerport => $port, |
| 65 |
%arg, |
| 66 |
; |
| 67 |
$tp->{keepalive} = $tp; |
| 68 |
}, delete $arg{prepare} |
| 69 |
} |
| 70 |
|
| 71 |
=item $guard = mp_connect $host, $port, <constructor-args>, $cb->($transport) |
| 72 |
|
| 73 |
=cut |
| 74 |
|
| 75 |
sub mp_connect { |
| 76 |
my $release = pop; |
| 77 |
my ($host, $port, @args) = @_; |
| 78 |
|
| 79 |
my $state; |
| 80 |
|
| 81 |
$state = AnyEvent::Socket::tcp_connect $host, $port, my$x=sub { |
| 82 |
my ($fh, $nhost, $nport) = @_; |
| 83 |
|
| 84 |
return $release->() unless $fh; |
| 85 |
|
| 86 |
$state = new AnyEvent::MP::Transport |
| 87 |
fh => $fh, |
| 88 |
peername => $host, |
| 89 |
peerhost => $nhost, |
| 90 |
peerport => $nport, |
| 91 |
release => $release, |
| 92 |
@args, |
| 93 |
; |
| 94 |
}; |
| 95 |
|
| 96 |
\$state |
| 97 |
} |
| 98 |
|
| 99 |
=item new AnyEvent::MP::Transport |
| 100 |
|
| 101 |
# immediately starts negotiation |
| 102 |
my $transport = new AnyEvent::MP::Transport |
| 103 |
# mandatory |
| 104 |
fh => $filehandle, |
| 105 |
local_id => $identifier, |
| 106 |
on_recv => sub { receive-callback }, |
| 107 |
on_error => sub { error-callback }, |
| 108 |
|
| 109 |
# optional |
| 110 |
on_eof => sub { clean-close-callback }, |
| 111 |
on_connect => sub { successful-connect-callback }, |
| 112 |
greeting => { key => value }, |
| 113 |
|
| 114 |
# tls support |
| 115 |
tls_ctx => AnyEvent::TLS, |
| 116 |
peername => $peername, # for verification |
| 117 |
; |
| 118 |
|
| 119 |
=cut |
| 120 |
|
| 121 |
sub LATENCY() { 3 } # assumed max. network latency |
| 122 |
|
| 123 |
our @FRAMINGS = qw(json storable); # the framing types we accept and send, in order of preference |
| 124 |
our @AUTH_SND = qw(tls_md6_64_256 hmac_md6_64_256); # auth types we send |
| 125 |
our @AUTH_RCV = (@AUTH_SND, qw(tls_anon cleartext)); # auth types we accept |
| 126 |
|
| 127 |
#AnyEvent::Handle::register_write_type mp_record => sub { |
| 128 |
#}; |
| 129 |
|
| 130 |
sub new { |
| 131 |
my ($class, %arg) = @_; |
| 132 |
|
| 133 |
my $self = bless \%arg, $class; |
| 134 |
|
| 135 |
$self->{queue} = []; |
| 136 |
|
| 137 |
{ |
| 138 |
Scalar::Util::weaken (my $self = $self); |
| 139 |
|
| 140 |
my $config = AnyEvent::MP::Config::config; |
| 141 |
|
| 142 |
my $latency = $config->{network_latency} || LATENCY; |
| 143 |
|
| 144 |
$self->{secret} = $config->{secret} |
| 145 |
unless exists $self->{secret}; |
| 146 |
|
| 147 |
$self->{timeout} = $config->{monitor_timeout} || $AnyEvent::MP::Kernel::MONITOR_TIMEOUT |
| 148 |
unless exists $self->{timeout}; |
| 149 |
|
| 150 |
$self->{timeout} -= $latency; |
| 151 |
|
| 152 |
$self->{timeout} = 1 + $latency |
| 153 |
if $self->{timeout} < 1 + $latency; |
| 154 |
|
| 155 |
my $secret = $self->{secret}; |
| 156 |
|
| 157 |
if (exists $config->{cert}) { |
| 158 |
$self->{tls_ctx} = { |
| 159 |
sslv2 => 0, |
| 160 |
sslv3 => 0, |
| 161 |
tlsv1 => 1, |
| 162 |
verify => 1, |
| 163 |
cert => $config->{cert}, |
| 164 |
ca_cert => $config->{cert}, |
| 165 |
verify_require_client_cert => 1, |
| 166 |
}; |
| 167 |
} |
| 168 |
|
| 169 |
$self->{hdl} = new AnyEvent::Handle |
| 170 |
fh => delete $self->{fh}, |
| 171 |
autocork => 1, |
| 172 |
no_delay => 1, |
| 173 |
on_error => sub { |
| 174 |
$self->error ($_[2]); |
| 175 |
}, |
| 176 |
rtimeout => $latency, |
| 177 |
peername => delete $self->{peername}, |
| 178 |
; |
| 179 |
|
| 180 |
my $greeting_kv = $self->{greeting} ||= {}; |
| 181 |
|
| 182 |
$self->{local_node} ||= $AnyEvent::MP::Kernel::NODE; |
| 183 |
|
| 184 |
$greeting_kv->{tls} = "1.0" if $self->{tls_ctx}; |
| 185 |
$greeting_kv->{provider} = "AE-$AnyEvent::MP::Kernel::VERSION"; |
| 186 |
$greeting_kv->{peeraddr} = AnyEvent::Socket::format_hostport $self->{peerhost}, $self->{peerport}; |
| 187 |
$greeting_kv->{timeout} = $self->{timeout}; |
| 188 |
|
| 189 |
# send greeting |
| 190 |
my $lgreeting1 = "aemp;$PROTOCOL_VERSION" |
| 191 |
. ";$self->{local_node}" |
| 192 |
. ";" . (join ",", @AUTH_RCV) |
| 193 |
. ";" . (join ",", @FRAMINGS) |
| 194 |
. (join "", map ";$_=$greeting_kv->{$_}", keys %$greeting_kv); |
| 195 |
|
| 196 |
my $lgreeting2 = MIME::Base64::encode_base64 AnyEvent::MP::Kernel::nonce (66), ""; |
| 197 |
|
| 198 |
$self->{hdl}->push_write ("$lgreeting1\012$lgreeting2\012"); |
| 199 |
|
| 200 |
# expect greeting |
| 201 |
$self->{hdl}->rbuf_max (4 * 1024); |
| 202 |
$self->{hdl}->push_read (line => sub { |
| 203 |
my $rgreeting1 = $_[1]; |
| 204 |
|
| 205 |
my ($aemp, $version, $rnode, $auths, $framings, @kv) = split /;/, $rgreeting1; |
| 206 |
|
| 207 |
if ($aemp ne "aemp") { |
| 208 |
return $self->error ("unparsable greeting"); |
| 209 |
} elsif ($version != $PROTOCOL_VERSION) { |
| 210 |
return $self->error ("version mismatch (we: $PROTOCOL_VERSION, they: $version)"); |
| 211 |
} elsif ($rnode eq $self->{local_node}) { |
| 212 |
AnyEvent::MP::Global::avoid_seed ($self->{seed}) |
| 213 |
if exists $self->{seed}; |
| 214 |
|
| 215 |
return $self->error ("I refuse to talk to myself"); |
| 216 |
} elsif ($AnyEvent::MP::Kernel::NODE{$rnode} && $AnyEvent::MP::Kernel::NODE{$rnode}{transport}) { |
| 217 |
return $self->error ("$rnode already connected, not connecting again."); |
| 218 |
} |
| 219 |
|
| 220 |
$self->{remote_node} = $rnode; |
| 221 |
|
| 222 |
$self->{remote_greeting} = { |
| 223 |
map /^([^=]+)(?:=(.*))?/ ? ($1 => $2) : (), |
| 224 |
@kv |
| 225 |
}; |
| 226 |
|
| 227 |
# read nonce |
| 228 |
$self->{hdl}->push_read (line => sub { |
| 229 |
my $rgreeting2 = $_[1]; |
| 230 |
|
| 231 |
"$lgreeting1\012$lgreeting2" ne "$rgreeting1\012$rgreeting2" # echo attack? |
| 232 |
or return $self->error ("authentication error, echo attack?"); |
| 233 |
|
| 234 |
my $tls = $self->{tls_ctx} && 1 == int $self->{remote_greeting}{tls}; |
| 235 |
|
| 236 |
my $s_auth; |
| 237 |
for my $auth_ (split /,/, $auths) { |
| 238 |
if (grep $auth_ eq $_, @AUTH_SND and ($auth_ !~ /^tls_/ or $tls)) { |
| 239 |
$s_auth = $auth_; |
| 240 |
last; |
| 241 |
} |
| 242 |
} |
| 243 |
|
| 244 |
defined $s_auth |
| 245 |
or return $self->error ("$auths: no common auth type supported"); |
| 246 |
|
| 247 |
my $s_framing; |
| 248 |
for my $framing_ (split /,/, $framings) { |
| 249 |
if (grep $framing_ eq $_, @FRAMINGS) { |
| 250 |
$s_framing = $framing_; |
| 251 |
last; |
| 252 |
} |
| 253 |
} |
| 254 |
|
| 255 |
defined $s_framing |
| 256 |
or return $self->error ("$framings: no common framing method supported"); |
| 257 |
|
| 258 |
my $key; |
| 259 |
my $lauth; |
| 260 |
|
| 261 |
if ($tls) { |
| 262 |
$self->{tls} = $lgreeting2 lt $rgreeting2 ? "connect" : "accept"; |
| 263 |
$self->{hdl}->starttls ($self->{tls}, $self->{tls_ctx}); |
| 264 |
|
| 265 |
$lauth = |
| 266 |
$s_auth eq "tls_anon" ? "" |
| 267 |
: $s_auth eq "tls_md6_64_256" ? Digest::MD6::md6_hex "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012" |
| 268 |
: return $self->error ("$s_auth: fatal, selected unsupported snd auth method"); |
| 269 |
|
| 270 |
} elsif (length $secret) { |
| 271 |
return $self->error ("$s_auth: fatal, selected unsupported snd auth method") |
| 272 |
unless $s_auth eq "hmac_md6_64_256"; # hardcoded atm. |
| 273 |
|
| 274 |
$key = Digest::MD6::md6 $secret; |
| 275 |
# we currently only support hmac_md6_64_256 |
| 276 |
$lauth = Digest::HMAC_MD6::hmac_md6_hex $key, "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012", 64, 256; |
| 277 |
|
| 278 |
} else { |
| 279 |
return $self->error ("unable to handshake TLS and no shared secret configured"); |
| 280 |
} |
| 281 |
|
| 282 |
$self->{hdl}->push_write ("$s_auth;$lauth;$s_framing\012"); |
| 283 |
|
| 284 |
# read the authentication response |
| 285 |
$self->{hdl}->push_read (line => sub { |
| 286 |
my ($hdl, $rline) = @_; |
| 287 |
|
| 288 |
my ($auth_method, $rauth2, $r_framing) = split /;/, $rline; |
| 289 |
|
| 290 |
my $rauth = |
| 291 |
$auth_method eq "hmac_md6_64_256" ? Digest::HMAC_MD6::hmac_md6_hex $key, "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012", 64, 256 |
| 292 |
: $auth_method eq "cleartext" ? unpack "H*", $secret |
| 293 |
: $auth_method eq "tls_anon" ? ($tls ? "" : "\012\012") # \012\012 never matches |
| 294 |
: $auth_method eq "tls_md6_64_256" ? ($tls ? Digest::MD6::md6_hex "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012" : "\012\012") |
| 295 |
: return $self->error ("$auth_method: fatal, selected unsupported rcv auth method"); |
| 296 |
|
| 297 |
if ($rauth2 ne $rauth) { |
| 298 |
return $self->error ("authentication failure/shared secret mismatch"); |
| 299 |
} |
| 300 |
|
| 301 |
$self->{s_framing} = $s_framing; |
| 302 |
|
| 303 |
$hdl->rbuf_max (undef); |
| 304 |
my $queue = delete $self->{queue}; # we are connected |
| 305 |
|
| 306 |
$self->{hdl}->rtimeout ($self->{remote_greeting}{timeout}); |
| 307 |
$self->{hdl}->wtimeout ($self->{timeout} - LATENCY); |
| 308 |
$self->{hdl}->on_wtimeout (sub { $self->send ([]) }); |
| 309 |
|
| 310 |
$self->connected; |
| 311 |
|
| 312 |
# send queued messages |
| 313 |
$self->send ($_) |
| 314 |
for @$queue; |
| 315 |
|
| 316 |
# receive handling |
| 317 |
my $src_node = $self->{node}; |
| 318 |
my $rmsg; $rmsg = $self->{rmsg} = sub { |
| 319 |
$_[0]->push_read ($r_framing => $rmsg); |
| 320 |
|
| 321 |
local $AnyEvent::MP::Kernel::SRCNODE = $src_node; |
| 322 |
AnyEvent::MP::Kernel::_inject (@{ $_[1] }); |
| 323 |
}; |
| 324 |
$hdl->push_read ($r_framing => $rmsg); |
| 325 |
|
| 326 |
Scalar::Util::weaken $rmsg; |
| 327 |
Scalar::Util::weaken $src_node; |
| 328 |
}); |
| 329 |
}); |
| 330 |
}); |
| 331 |
} |
| 332 |
|
| 333 |
$self |
| 334 |
} |
| 335 |
|
| 336 |
sub error { |
| 337 |
my ($self, $msg) = @_; |
| 338 |
|
| 339 |
delete $self->{keepalive}; |
| 340 |
|
| 341 |
# $AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} $msg");#d# |
| 342 |
|
| 343 |
$self->{node}->transport_error (transport_error => $self->{node}{id}, $msg) |
| 344 |
if $self->{node} && $self->{node}{transport} == $self; |
| 345 |
|
| 346 |
(delete $self->{release})->() |
| 347 |
if exists $self->{release}; |
| 348 |
|
| 349 |
# $AnyEvent::MP::Kernel::WARN->(7, "$self->{peerhost}:$self->{peerport}: $msg"); |
| 350 |
$self->destroy; |
| 351 |
} |
| 352 |
|
| 353 |
sub connected { |
| 354 |
my ($self) = @_; |
| 355 |
|
| 356 |
delete $self->{keepalive}; |
| 357 |
|
| 358 |
(delete $self->{release})->() |
| 359 |
if exists $self->{release}; |
| 360 |
|
| 361 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} connected as $self->{remote_node}"); |
| 362 |
|
| 363 |
my $node = AnyEvent::MP::Kernel::add_node ($self->{remote_node}); |
| 364 |
Scalar::Util::weaken ($self->{node} = $node); |
| 365 |
$node->transport_connect ($self); |
| 366 |
} |
| 367 |
|
| 368 |
sub send { |
| 369 |
$_[0]{hdl}->push_write ($_[0]{s_framing} => $_[1]); |
| 370 |
} |
| 371 |
|
| 372 |
sub destroy { |
| 373 |
my ($self) = @_; |
| 374 |
|
| 375 |
(delete $self->{release})->() |
| 376 |
if exists $self->{release}; |
| 377 |
|
| 378 |
$self->{hdl}->destroy |
| 379 |
if $self->{hdl}; |
| 380 |
} |
| 381 |
|
| 382 |
sub DESTROY { |
| 383 |
my ($self) = @_; |
| 384 |
|
| 385 |
$self->destroy; |
| 386 |
} |
| 387 |
|
| 388 |
=back |
| 389 |
|
| 390 |
=head1 PROTOCOL |
| 391 |
|
| 392 |
The AEMP protocol is relatively simple, and consists of three phases which |
| 393 |
are symmetrical for both sides: greeting (followed by optionally switching |
| 394 |
to TLS mode), authentication and packet exchange. |
| 395 |
|
| 396 |
The protocol is designed to allow both full-text and binary streams. |
| 397 |
|
| 398 |
The greeting consists of two text lines that are ended by either an ASCII |
| 399 |
CR LF pair, or a single ASCII LF (recommended). |
| 400 |
|
| 401 |
=head2 GREETING |
| 402 |
|
| 403 |
All the lines until after authentication must not exceed 4kb in length, |
| 404 |
including line delimiter. Afterwards there is no limit on the packet size |
| 405 |
that can be received. |
| 406 |
|
| 407 |
=head3 First Greeting Line |
| 408 |
|
| 409 |
Example: |
| 410 |
|
| 411 |
aemp;0;rain;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;timeout=12;peeraddr=10.0.0.1:48082 |
| 412 |
|
| 413 |
The first line contains strings separated (not ended) by C<;> |
| 414 |
characters. The first five strings are fixed by the protocol, the |
| 415 |
remaining strings are C<KEY=VALUE> pairs. None of them may contain C<;> |
| 416 |
characters themselves (when escaping is needed, use C<%3b> to represent |
| 417 |
C<;> and C<%25> to represent C<%>)- |
| 418 |
|
| 419 |
The fixed strings are: |
| 420 |
|
| 421 |
=over 4 |
| 422 |
|
| 423 |
=item protocol identification |
| 424 |
|
| 425 |
The constant C<aemp> to identify this protocol. |
| 426 |
|
| 427 |
=item protocol version |
| 428 |
|
| 429 |
The protocol version supported by this end, currently C<0>. If the |
| 430 |
versions don't match then no communication is possible. Minor extensions |
| 431 |
are supposed to be handled through additional key-value pairs. |
| 432 |
|
| 433 |
=item the node ID |
| 434 |
|
| 435 |
This is the node ID of the connecting node. |
| 436 |
|
| 437 |
=item the acceptable authentication methods |
| 438 |
|
| 439 |
A comma-separated list of authentication methods supported by the |
| 440 |
node. Note that AnyEvent::MP supports a C<hex_secret> authentication |
| 441 |
method that accepts a clear-text password (hex-encoded), but will not use |
| 442 |
this authentication method itself. |
| 443 |
|
| 444 |
The receiving side should choose the first authentication method it |
| 445 |
supports. |
| 446 |
|
| 447 |
=item the acceptable framing formats |
| 448 |
|
| 449 |
A comma-separated list of packet encoding/framing formats understood. The |
| 450 |
receiving side should choose the first framing format it supports for |
| 451 |
sending packets (which might be different from the format it has to accept). |
| 452 |
|
| 453 |
=back |
| 454 |
|
| 455 |
The remaining arguments are C<KEY=VALUE> pairs. The following key-value |
| 456 |
pairs are known at this time: |
| 457 |
|
| 458 |
=over 4 |
| 459 |
|
| 460 |
=item timeout=<seconds> |
| 461 |
|
| 462 |
The amount of time after which this node should be detected as dead unless |
| 463 |
some data has been received. The node is responsible to send traffic |
| 464 |
reasonably more often than this interval (such as every timeout minus five |
| 465 |
seconds). |
| 466 |
|
| 467 |
=item provider=<module-version> |
| 468 |
|
| 469 |
The software provider for this implementation. For AnyEvent::MP, this is |
| 470 |
C<AE-0.0> or whatever version it currently is at. |
| 471 |
|
| 472 |
=item peeraddr=<host>:<port> |
| 473 |
|
| 474 |
The peer address (socket address of the other side) as seen locally. |
| 475 |
|
| 476 |
=item tls=<major>.<minor> |
| 477 |
|
| 478 |
Indicates that the other side supports TLS (version should be 1.0) and |
| 479 |
wishes to do a TLS handshake. |
| 480 |
|
| 481 |
=back |
| 482 |
|
| 483 |
=head3 Second Greeting Line |
| 484 |
|
| 485 |
After this greeting line there will be a second line containing a |
| 486 |
cryptographic nonce, i.e. random data of high quality. To keep the |
| 487 |
protocol text-only, these are usually 32 base64-encoded octets, but |
| 488 |
it could be anything that doesn't contain any ASCII CR or ASCII LF |
| 489 |
characters. |
| 490 |
|
| 491 |
I<< The two nonces B<must> be different, and an aemp implementation |
| 492 |
B<must> check and fail when they are identical >>. |
| 493 |
|
| 494 |
Example of a nonce line (yes, it's random-looking because it is random |
| 495 |
data): |
| 496 |
|
| 497 |
2XYhdG7/O6epFa4wuP0ujAEx1rXYWRcOypjUYK7eF6yWAQr7gwIN9m/2+mVvBrTPXz5GJDgfGm9d8QRABAbmAP/s |
| 498 |
|
| 499 |
=head2 TLS handshake |
| 500 |
|
| 501 |
I<< If, after the handshake, both sides indicate interest in TLS, then the |
| 502 |
connection B<must> use TLS, or fail to continue. >> |
| 503 |
|
| 504 |
Both sides compare their nonces, and the side who sent the lower nonce |
| 505 |
value ("string" comparison on the raw octet values) becomes the client, |
| 506 |
and the one with the higher nonce the server. |
| 507 |
|
| 508 |
=head2 AUTHENTICATION PHASE |
| 509 |
|
| 510 |
After the greeting is received (and the optional TLS handshake), |
| 511 |
the authentication phase begins, which consists of sending a single |
| 512 |
C<;>-separated line with three fixed strings and any number of |
| 513 |
C<KEY=VALUE> pairs. |
| 514 |
|
| 515 |
The three fixed strings are: |
| 516 |
|
| 517 |
=over 4 |
| 518 |
|
| 519 |
=item the authentication method chosen |
| 520 |
|
| 521 |
This must be one of the methods offered by the other side in the greeting. |
| 522 |
|
| 523 |
Note that all methods starting with C<tls_> are only valid I<iff> TLS was |
| 524 |
successfully handshaked (and to be secure the implementation must enforce |
| 525 |
this). |
| 526 |
|
| 527 |
The currently supported authentication methods are: |
| 528 |
|
| 529 |
=over 4 |
| 530 |
|
| 531 |
=item cleartext |
| 532 |
|
| 533 |
This is simply the shared secret, lowercase-hex-encoded. This method is of |
| 534 |
course very insecure if TLS is not used (and not completely secure even |
| 535 |
if TLS is used), which is why this module will accept, but not generate, |
| 536 |
cleartext auth replies. |
| 537 |
|
| 538 |
=item hmac_md6_64_256 |
| 539 |
|
| 540 |
This method uses an MD6 HMAC with 64 bit blocksize and 256 bit hash, and |
| 541 |
requires a shared secret. It is the preferred auth method when a shared |
| 542 |
secret is available. |
| 543 |
|
| 544 |
First, the shared secret is hashed with MD6: |
| 545 |
|
| 546 |
key = MD6 (secret) |
| 547 |
|
| 548 |
This secret is then used to generate the "local auth reply", by taking |
| 549 |
the two local greeting lines and the two remote greeting lines (without |
| 550 |
line endings), appending \012 to all of them, concatenating them and |
| 551 |
calculating the MD6 HMAC with the key: |
| 552 |
|
| 553 |
lauth = HMAC_MD6 key, "lgreeting1\012lgreeting2\012rgreeting1\012rgreeting2\012" |
| 554 |
|
| 555 |
This authentication token is then lowercase-hex-encoded and sent to the |
| 556 |
other side. |
| 557 |
|
| 558 |
Then the remote auth reply is generated using the same method, but local |
| 559 |
and remote greeting lines swapped: |
| 560 |
|
| 561 |
rauth = HMAC_MD6 key, "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 562 |
|
| 563 |
This is the token that is expected from the other side. |
| 564 |
|
| 565 |
=item tls_anon |
| 566 |
|
| 567 |
This type is only valid I<iff> TLS was enabled and the TLS handshake |
| 568 |
was successful. It has no authentication data, as the server/client |
| 569 |
certificate was successfully verified. |
| 570 |
|
| 571 |
This authentication type is somewhat insecure, as it allows a |
| 572 |
man-in-the-middle attacker to change some of the connection parameters |
| 573 |
(such as the framing format), although there is no known attack that |
| 574 |
exploits this in a way that is worse than just denying the service. |
| 575 |
|
| 576 |
By default, this implementation accepts but never generates this auth |
| 577 |
reply. |
| 578 |
|
| 579 |
=item tls_md6_64_256 |
| 580 |
|
| 581 |
This type is only valid I<iff> TLS was enabled and the TLS handshake was |
| 582 |
successful. |
| 583 |
|
| 584 |
This authentication type simply calculates: |
| 585 |
|
| 586 |
lauth = MD6 "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 587 |
|
| 588 |
and lowercase-hex encodes the result and sends it as authentication |
| 589 |
data. No shared secret is required (authentication is done by TLS). The |
| 590 |
checksum exists only to make tinkering with the greeting hard. |
| 591 |
|
| 592 |
=back |
| 593 |
|
| 594 |
=item the authentication data |
| 595 |
|
| 596 |
The authentication data itself, usually base64 or hex-encoded data, see |
| 597 |
above. |
| 598 |
|
| 599 |
=item the framing protocol chosen |
| 600 |
|
| 601 |
This must be one of the framing protocols offered by the other side in the |
| 602 |
greeting. Each side must accept the choice of the other side, and generate |
| 603 |
packets in the format it chose itself. |
| 604 |
|
| 605 |
=back |
| 606 |
|
| 607 |
Example of an authentication reply: |
| 608 |
|
| 609 |
hmac_md6_64_256;363d5175df38bd9eaddd3f6ca18aa1c0c4aa22f0da245ac638d048398c26b8d3;json |
| 610 |
|
| 611 |
=head2 DATA PHASE |
| 612 |
|
| 613 |
After this, packets get exchanged using the chosen framing protocol. It is |
| 614 |
quite possible that both sides use a different framing protocol. |
| 615 |
|
| 616 |
=head2 FULL EXAMPLE |
| 617 |
|
| 618 |
This is an actual protocol dump of a handshake, followed by a single data |
| 619 |
packet. The greater than/less than lines indicate the direction of the |
| 620 |
transfer only. |
| 621 |
|
| 622 |
> aemp;0;anon/57Cs1CggVJjzYaQp13XXg4;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.17:4040 |
| 623 |
> yLgdG1ov/02shVkVQer3wzeuywZK+oraTdEQBmIqWHaegxSGDG4g+HqogLQbvdypFOsoDWJ1Sh4ImV4DMhvUBwTK |
| 624 |
|
| 625 |
< aemp;0;ruth;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.1:37108 |
| 626 |
< +xMQXP8ElfNmuvEhsmcp+s2wCJOuQAsPxSg3d2Ewhs6gBnJz+ypVdWJ/wAVrXqlIJfLeVS/CBy4gEGkyWHSuVb1L |
| 627 |
|
| 628 |
> hmac_md6_64_256;5ad913855742ae5a03a5aeb7eafa4c78629de136bed6acd73eea36c9e98df44a;json |
| 629 |
|
| 630 |
< hmac_md6_64_256;84cd590976f794914c2ca26dac3a207a57a6798b9171289c114de07cf0c20401;json |
| 631 |
< ["","AnyEvent::MP::_spawn","57Cs1CggVJjzYaQp13XXg4.c","AnyEvent::MP::Global::connect",0,"anon/57Cs1CggVJjzYaQp13XXg4"] |
| 632 |
... |
| 633 |
|
| 634 |
The shared secret in use was C<8ugxrtw6H5tKnfPWfaSr4HGhE8MoJXmzTT1BWq7sLutNcD0IbXprQlZjIbl7MBKoeklG3IEfY9GlJthC0pENzk>. |
| 635 |
|
| 636 |
=head1 SEE ALSO |
| 637 |
|
| 638 |
L<AnyEvent::MP>. |
| 639 |
|
| 640 |
=head1 AUTHOR |
| 641 |
|
| 642 |
Marc Lehmann <schmorp@schmorp.de> |
| 643 |
http://home.schmorp.de/ |
| 644 |
|
| 645 |
=cut |
| 646 |
|
| 647 |
1 |
| 648 |
|
