| 1 |
=head1 NAME |
| 2 |
|
| 3 |
AnyEvent::MP::Transport - actual transport protocol handler |
| 4 |
|
| 5 |
=head1 SYNOPSIS |
| 6 |
|
| 7 |
use AnyEvent::MP::Transport; |
| 8 |
|
| 9 |
=head1 DESCRIPTION |
| 10 |
|
| 11 |
This module implements (and documents) the actual transport protocol for |
| 12 |
AEMP. |
| 13 |
|
| 14 |
See the "PROTOCOL" section below if you want to write another client for |
| 15 |
this protocol. |
| 16 |
|
| 17 |
=head1 FUNCTIONS/METHODS |
| 18 |
|
| 19 |
=over 4 |
| 20 |
|
| 21 |
=cut |
| 22 |
|
| 23 |
package AnyEvent::MP::Transport; |
| 24 |
|
| 25 |
use common::sense; |
| 26 |
|
| 27 |
use Scalar::Util (); |
| 28 |
use List::Util (); |
| 29 |
use MIME::Base64 (); |
| 30 |
use Storable (); |
| 31 |
use JSON::XS (); |
| 32 |
|
| 33 |
use Digest::MD6 (); |
| 34 |
use Digest::HMAC_MD6 (); |
| 35 |
|
| 36 |
use AE (); |
| 37 |
use AnyEvent::Socket (); |
| 38 |
use AnyEvent::Handle 4.92 (); |
| 39 |
|
| 40 |
use AnyEvent::MP::Config (); |
| 41 |
|
| 42 |
our $PROTOCOL_VERSION = 0; |
| 43 |
|
| 44 |
=item $listener = mp_listener $host, $port, <constructor-args> |
| 45 |
|
| 46 |
Creates a listener on the given host/port using |
| 47 |
C<AnyEvent::Socket::tcp_server>. |
| 48 |
|
| 49 |
See C<new>, below, for constructor arguments. |
| 50 |
|
| 51 |
Defaults for peerhost, peerport and fh are provided. |
| 52 |
|
| 53 |
=cut |
| 54 |
|
| 55 |
sub mp_server($$;%) { |
| 56 |
my ($host, $port, %arg) = @_; |
| 57 |
|
| 58 |
AnyEvent::Socket::tcp_server $host, $port, sub { |
| 59 |
my ($fh, $host, $port) = @_; |
| 60 |
|
| 61 |
my $tp = new AnyEvent::MP::Transport |
| 62 |
fh => $fh, |
| 63 |
peerhost => $host, |
| 64 |
peerport => $port, |
| 65 |
%arg, |
| 66 |
; |
| 67 |
$tp->{keepalive} = $tp; |
| 68 |
}, delete $arg{prepare} |
| 69 |
} |
| 70 |
|
| 71 |
=item $guard = mp_connect $host, $port, <constructor-args>, $cb->($transport) |
| 72 |
|
| 73 |
=cut |
| 74 |
|
| 75 |
sub mp_connect { |
| 76 |
my $release = pop; |
| 77 |
my ($host, $port, @args) = @_; |
| 78 |
|
| 79 |
my $state; |
| 80 |
|
| 81 |
$state = AnyEvent::Socket::tcp_connect $host, $port, my$x=sub { |
| 82 |
my ($fh, $nhost, $nport) = @_; |
| 83 |
|
| 84 |
return $release->() unless $fh; |
| 85 |
|
| 86 |
$state = new AnyEvent::MP::Transport |
| 87 |
fh => $fh, |
| 88 |
peername => $host, |
| 89 |
peerhost => $nhost, |
| 90 |
peerport => $nport, |
| 91 |
release => $release, |
| 92 |
@args, |
| 93 |
; |
| 94 |
}; |
| 95 |
|
| 96 |
\$state |
| 97 |
} |
| 98 |
|
| 99 |
=item new AnyEvent::MP::Transport |
| 100 |
|
| 101 |
# immediately starts negotiation |
| 102 |
my $transport = new AnyEvent::MP::Transport |
| 103 |
# mandatory |
| 104 |
fh => $filehandle, |
| 105 |
local_id => $identifier, |
| 106 |
on_recv => sub { receive-callback }, |
| 107 |
on_error => sub { error-callback }, |
| 108 |
|
| 109 |
# optional |
| 110 |
on_eof => sub { clean-close-callback }, |
| 111 |
on_connect => sub { successful-connect-callback }, |
| 112 |
greeting => { key => value }, |
| 113 |
|
| 114 |
# tls support |
| 115 |
tls_ctx => AnyEvent::TLS, |
| 116 |
peername => $peername, # for verification |
| 117 |
; |
| 118 |
|
| 119 |
=cut |
| 120 |
|
| 121 |
our @FRAMINGS = qw(json storable); # the framing types we accept and send, in order of preference |
| 122 |
our @AUTH_SND = qw(tls_md6_64_256 hmac_md6_64_256); # auth types we send |
| 123 |
our @AUTH_RCV = (@AUTH_SND, qw(tls_anon cleartext)); # auth types we accept |
| 124 |
|
| 125 |
#AnyEvent::Handle::register_write_type mp_record => sub { |
| 126 |
#}; |
| 127 |
|
| 128 |
sub new { |
| 129 |
my ($class, %arg) = @_; |
| 130 |
|
| 131 |
my $self = bless \%arg, $class; |
| 132 |
|
| 133 |
$self->{queue} = []; |
| 134 |
|
| 135 |
{ |
| 136 |
Scalar::Util::weaken (my $self = $self); |
| 137 |
|
| 138 |
my $config = AnyEvent::MP::Config::config; |
| 139 |
|
| 140 |
my $timeout = $self->{timeout} || $config->{monitor_timeout}; |
| 141 |
|
| 142 |
$self->{secret} = $config->{secret} |
| 143 |
unless exists $self->{secret}; |
| 144 |
|
| 145 |
my $secret = $self->{secret}; |
| 146 |
|
| 147 |
if (exists $config->{cert}) { |
| 148 |
$self->{tls_ctx} = { |
| 149 |
sslv2 => 0, |
| 150 |
sslv3 => 0, |
| 151 |
tlsv1 => 1, |
| 152 |
verify => 1, |
| 153 |
cert => $config->{cert}, |
| 154 |
ca_cert => $config->{cert}, |
| 155 |
verify_require_client_cert => 1, |
| 156 |
}; |
| 157 |
} |
| 158 |
|
| 159 |
$self->{hdl} = new AnyEvent::Handle |
| 160 |
fh => delete $self->{fh}, |
| 161 |
autocork => 1, |
| 162 |
no_delay => 1, |
| 163 |
keepalive => 1, |
| 164 |
on_error => sub { |
| 165 |
$self->error ($_[2]); |
| 166 |
}, |
| 167 |
rtimeout => $timeout, |
| 168 |
peername => delete $self->{peername}, |
| 169 |
; |
| 170 |
|
| 171 |
my $greeting_kv = $self->{greeting} ||= {}; |
| 172 |
|
| 173 |
$self->{local_node} ||= $AnyEvent::MP::Kernel::NODE; |
| 174 |
|
| 175 |
$greeting_kv->{tls} = "1.0" if $self->{tls_ctx}; |
| 176 |
$greeting_kv->{provider} = "AE-$AnyEvent::MP::Kernel::VERSION"; |
| 177 |
$greeting_kv->{peeraddr} = AnyEvent::Socket::format_hostport $self->{peerhost}, $self->{peerport}; |
| 178 |
$greeting_kv->{timeout} = $self->{timeout}; |
| 179 |
|
| 180 |
# send greeting |
| 181 |
my $lgreeting1 = "aemp;$PROTOCOL_VERSION" |
| 182 |
. ";$self->{local_node}" |
| 183 |
. ";" . (join ",", @AUTH_RCV) |
| 184 |
. ";" . (join ",", @FRAMINGS) |
| 185 |
. (join "", map ";$_=$greeting_kv->{$_}", keys %$greeting_kv); |
| 186 |
|
| 187 |
my $lgreeting2 = MIME::Base64::encode_base64 AnyEvent::MP::Kernel::nonce (66), ""; |
| 188 |
|
| 189 |
$self->{hdl}->push_write ("$lgreeting1\012$lgreeting2\012"); |
| 190 |
|
| 191 |
# expect greeting |
| 192 |
$self->{hdl}->rbuf_max (4 * 1024); |
| 193 |
$self->{hdl}->push_read (line => sub { |
| 194 |
my $rgreeting1 = $_[1]; |
| 195 |
|
| 196 |
my ($aemp, $version, $rnode, $auths, $framings, @kv) = split /;/, $rgreeting1; |
| 197 |
|
| 198 |
if ($aemp ne "aemp") { |
| 199 |
return $self->error ("unparsable greeting"); |
| 200 |
} elsif ($version != $PROTOCOL_VERSION) { |
| 201 |
return $self->error ("version mismatch (we: $PROTOCOL_VERSION, they: $version)"); |
| 202 |
} elsif ($rnode eq $self->{local_node}) { |
| 203 |
AnyEvent::MP::Global::avoid_seed ($self->{seed}) |
| 204 |
if exists $self->{seed}; |
| 205 |
|
| 206 |
return $self->error ("I refuse to talk to myself"); |
| 207 |
} elsif ($AnyEvent::MP::Kernel::NODE{$rnode} && $AnyEvent::MP::Kernel::NODE{$rnode}{transport}) { |
| 208 |
return $self->error ("$rnode already connected, not connecting again."); |
| 209 |
} |
| 210 |
|
| 211 |
$self->{remote_node} = $rnode; |
| 212 |
|
| 213 |
$self->{remote_greeting} = { |
| 214 |
map /^([^=]+)(?:=(.*))?/ ? ($1 => $2) : (), |
| 215 |
@kv |
| 216 |
}; |
| 217 |
|
| 218 |
# read nonce |
| 219 |
$self->{hdl}->push_read (line => sub { |
| 220 |
my $rgreeting2 = $_[1]; |
| 221 |
|
| 222 |
"$lgreeting1\012$lgreeting2" ne "$rgreeting1\012$rgreeting2" # echo attack? |
| 223 |
or return $self->error ("authentication error, echo attack?"); |
| 224 |
|
| 225 |
my $tls = $self->{tls_ctx} && 1 == int $self->{remote_greeting}{tls}; |
| 226 |
|
| 227 |
my $s_auth; |
| 228 |
for my $auth_ (split /,/, $auths) { |
| 229 |
if (grep $auth_ eq $_, @AUTH_SND and ($auth_ !~ /^tls_/ or $tls)) { |
| 230 |
$s_auth = $auth_; |
| 231 |
last; |
| 232 |
} |
| 233 |
} |
| 234 |
|
| 235 |
defined $s_auth |
| 236 |
or return $self->error ("$auths: no common auth type supported"); |
| 237 |
|
| 238 |
my $s_framing; |
| 239 |
for my $framing_ (split /,/, $framings) { |
| 240 |
if (grep $framing_ eq $_, @FRAMINGS) { |
| 241 |
$s_framing = $framing_; |
| 242 |
last; |
| 243 |
} |
| 244 |
} |
| 245 |
|
| 246 |
defined $s_framing |
| 247 |
or return $self->error ("$framings: no common framing method supported"); |
| 248 |
|
| 249 |
my $key; |
| 250 |
my $lauth; |
| 251 |
|
| 252 |
if ($tls) { |
| 253 |
$self->{tls} = $lgreeting2 lt $rgreeting2 ? "connect" : "accept"; |
| 254 |
$self->{hdl}->starttls ($self->{tls}, $self->{tls_ctx}); |
| 255 |
|
| 256 |
$lauth = |
| 257 |
$s_auth eq "tls_anon" ? "" |
| 258 |
: $s_auth eq "tls_md6_64_256" ? Digest::MD6::md6_hex "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012" |
| 259 |
: return $self->error ("$s_auth: fatal, selected unsupported snd auth method"); |
| 260 |
|
| 261 |
} elsif (length $secret) { |
| 262 |
return $self->error ("$s_auth: fatal, selected unsupported snd auth method") |
| 263 |
unless $s_auth eq "hmac_md6_64_256"; # hardcoded atm. |
| 264 |
|
| 265 |
$key = Digest::MD6::md6 $secret; |
| 266 |
# we currently only support hmac_md6_64_256 |
| 267 |
$lauth = Digest::HMAC_MD6::hmac_md6_hex $key, "$lgreeting1\012$lgreeting2\012$rgreeting1\012$rgreeting2\012", 64, 256; |
| 268 |
|
| 269 |
} else { |
| 270 |
return $self->error ("unable to handshake TLS and no shared secret configured"); |
| 271 |
} |
| 272 |
|
| 273 |
$self->{hdl}->push_write ("$s_auth;$lauth;$s_framing\012"); |
| 274 |
|
| 275 |
# read the authentication response |
| 276 |
$self->{hdl}->push_read (line => sub { |
| 277 |
my ($hdl, $rline) = @_; |
| 278 |
|
| 279 |
my ($auth_method, $rauth2, $r_framing) = split /;/, $rline; |
| 280 |
|
| 281 |
my $rauth = |
| 282 |
$auth_method eq "hmac_md6_64_256" ? Digest::HMAC_MD6::hmac_md6_hex $key, "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012", 64, 256 |
| 283 |
: $auth_method eq "cleartext" ? unpack "H*", $secret |
| 284 |
: $auth_method eq "tls_anon" ? ($tls ? "" : "\012\012") # \012\012 never matches |
| 285 |
: $auth_method eq "tls_md6_64_256" ? ($tls ? Digest::MD6::md6_hex "$rgreeting1\012$rgreeting2\012$lgreeting1\012$lgreeting2\012" : "\012\012") |
| 286 |
: return $self->error ("$auth_method: fatal, selected unsupported rcv auth method"); |
| 287 |
|
| 288 |
if ($rauth2 ne $rauth) { |
| 289 |
return $self->error ("authentication failure/shared secret mismatch"); |
| 290 |
} |
| 291 |
|
| 292 |
$self->{s_framing} = $s_framing; |
| 293 |
|
| 294 |
$hdl->rbuf_max (undef); |
| 295 |
|
| 296 |
# we rely on TCP retransmit timeouts and keepalives |
| 297 |
$self->{hdl}->rtimeout (undef); |
| 298 |
|
| 299 |
# except listener-less nodes, they need to continuously probe |
| 300 |
unless (@$AnyEvent::MP::Kernel::LISTENER) { |
| 301 |
$self->{hdl}->wtimeout ($timeout); |
| 302 |
$self->{hdl}->on_wtimeout (sub { $self->send ([]) }); |
| 303 |
} |
| 304 |
|
| 305 |
$self->{remote_greeting}{untrusted} = 1 |
| 306 |
if $auth_method eq "tls_anon"; |
| 307 |
|
| 308 |
my $queue = delete $self->{queue}; # we are connected |
| 309 |
|
| 310 |
$self->connected; |
| 311 |
|
| 312 |
# send queued messages |
| 313 |
$self->send ($_) |
| 314 |
for @$queue; |
| 315 |
|
| 316 |
# receive handling |
| 317 |
my $src_node = $self->{node}; |
| 318 |
my $rmsg; $rmsg = $self->{rmsg} = sub { |
| 319 |
$_[0]->push_read ($r_framing => $rmsg); |
| 320 |
|
| 321 |
local $AnyEvent::MP::Kernel::SRCNODE = $src_node; |
| 322 |
AnyEvent::MP::Kernel::_inject (@{ $_[1] }); |
| 323 |
}; |
| 324 |
$hdl->push_read ($r_framing => $rmsg); |
| 325 |
|
| 326 |
Scalar::Util::weaken $rmsg; |
| 327 |
Scalar::Util::weaken $src_node; |
| 328 |
}); |
| 329 |
}); |
| 330 |
}); |
| 331 |
} |
| 332 |
|
| 333 |
$self |
| 334 |
} |
| 335 |
|
| 336 |
sub error { |
| 337 |
my ($self, $msg) = @_; |
| 338 |
|
| 339 |
delete $self->{keepalive}; |
| 340 |
|
| 341 |
# $AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} $msg");#d# |
| 342 |
|
| 343 |
$self->{node}->transport_error (transport_error => $self->{node}{id}, $msg) |
| 344 |
if $self->{node} && $self->{node}{transport} == $self; |
| 345 |
|
| 346 |
(delete $self->{release})->() |
| 347 |
if exists $self->{release}; |
| 348 |
|
| 349 |
# $AnyEvent::MP::Kernel::WARN->(7, "$self->{peerhost}:$self->{peerport}: $msg"); |
| 350 |
$self->destroy; |
| 351 |
} |
| 352 |
|
| 353 |
sub connected { |
| 354 |
my ($self) = @_; |
| 355 |
|
| 356 |
delete $self->{keepalive}; |
| 357 |
|
| 358 |
(delete $self->{release})->() |
| 359 |
if exists $self->{release}; |
| 360 |
|
| 361 |
$AnyEvent::MP::Kernel::WARN->(9, "$self->{peerhost}:$self->{peerport} connected as $self->{remote_node}"); |
| 362 |
|
| 363 |
my $node = AnyEvent::MP::Kernel::add_node ($self->{remote_node}); |
| 364 |
Scalar::Util::weaken ($self->{node} = $node); |
| 365 |
$node->transport_connect ($self); |
| 366 |
} |
| 367 |
|
| 368 |
sub send { |
| 369 |
$_[0]{hdl}->push_write ($_[0]{s_framing} => $_[1]); |
| 370 |
} |
| 371 |
|
| 372 |
sub destroy { |
| 373 |
my ($self) = @_; |
| 374 |
|
| 375 |
(delete $self->{release})->() |
| 376 |
if exists $self->{release}; |
| 377 |
|
| 378 |
$self->{hdl}->destroy |
| 379 |
if $self->{hdl}; |
| 380 |
} |
| 381 |
|
| 382 |
sub DESTROY { |
| 383 |
my ($self) = @_; |
| 384 |
|
| 385 |
$self->destroy; |
| 386 |
} |
| 387 |
|
| 388 |
=back |
| 389 |
|
| 390 |
=head1 PROTOCOL |
| 391 |
|
| 392 |
The AEMP protocol is relatively simple, and consists of three phases which |
| 393 |
are symmetrical for both sides: greeting (followed by optionally switching |
| 394 |
to TLS mode), authentication and packet exchange. |
| 395 |
|
| 396 |
The protocol is designed to allow both full-text and binary streams. |
| 397 |
|
| 398 |
The greeting consists of two text lines that are ended by either an ASCII |
| 399 |
CR LF pair, or a single ASCII LF (recommended). |
| 400 |
|
| 401 |
=head2 GREETING |
| 402 |
|
| 403 |
All the lines until after authentication must not exceed 4kb in length, |
| 404 |
including line delimiter. Afterwards there is no limit on the packet size |
| 405 |
that can be received. |
| 406 |
|
| 407 |
=head3 First Greeting Line |
| 408 |
|
| 409 |
Example: |
| 410 |
|
| 411 |
aemp;0;rain;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;timeout=12;peeraddr=10.0.0.1:48082 |
| 412 |
|
| 413 |
The first line contains strings separated (not ended) by C<;> |
| 414 |
characters. The first five strings are fixed by the protocol, the |
| 415 |
remaining strings are C<KEY=VALUE> pairs. None of them may contain C<;> |
| 416 |
characters themselves (when escaping is needed, use C<%3b> to represent |
| 417 |
C<;> and C<%25> to represent C<%>)- |
| 418 |
|
| 419 |
The fixed strings are: |
| 420 |
|
| 421 |
=over 4 |
| 422 |
|
| 423 |
=item protocol identification |
| 424 |
|
| 425 |
The constant C<aemp> to identify this protocol. |
| 426 |
|
| 427 |
=item protocol version |
| 428 |
|
| 429 |
The protocol version supported by this end, currently C<0>. If the |
| 430 |
versions don't match then no communication is possible. Minor extensions |
| 431 |
are supposed to be handled through additional key-value pairs. |
| 432 |
|
| 433 |
=item the node ID |
| 434 |
|
| 435 |
This is the node ID of the connecting node. |
| 436 |
|
| 437 |
=item the acceptable authentication methods |
| 438 |
|
| 439 |
A comma-separated list of authentication methods supported by the |
| 440 |
node. Note that AnyEvent::MP supports a C<hex_secret> authentication |
| 441 |
method that accepts a clear-text password (hex-encoded), but will not use |
| 442 |
this authentication method itself. |
| 443 |
|
| 444 |
The receiving side should choose the first authentication method it |
| 445 |
supports. |
| 446 |
|
| 447 |
=item the acceptable framing formats |
| 448 |
|
| 449 |
A comma-separated list of packet encoding/framing formats understood. The |
| 450 |
receiving side should choose the first framing format it supports for |
| 451 |
sending packets (which might be different from the format it has to accept). |
| 452 |
|
| 453 |
=back |
| 454 |
|
| 455 |
The remaining arguments are C<KEY=VALUE> pairs. The following key-value |
| 456 |
pairs are known at this time: |
| 457 |
|
| 458 |
=over 4 |
| 459 |
|
| 460 |
=item provider=<module-version> |
| 461 |
|
| 462 |
The software provider for this implementation. For AnyEvent::MP, this is |
| 463 |
C<AE-0.0> or whatever version it currently is at. |
| 464 |
|
| 465 |
=item peeraddr=<host>:<port> |
| 466 |
|
| 467 |
The peer address (socket address of the other side) as seen locally. |
| 468 |
|
| 469 |
=item tls=<major>.<minor> |
| 470 |
|
| 471 |
Indicates that the other side supports TLS (version should be 1.0) and |
| 472 |
wishes to do a TLS handshake. |
| 473 |
|
| 474 |
=back |
| 475 |
|
| 476 |
=head3 Second Greeting Line |
| 477 |
|
| 478 |
After this greeting line there will be a second line containing a |
| 479 |
cryptographic nonce, i.e. random data of high quality. To keep the |
| 480 |
protocol text-only, these are usually 32 base64-encoded octets, but |
| 481 |
it could be anything that doesn't contain any ASCII CR or ASCII LF |
| 482 |
characters. |
| 483 |
|
| 484 |
I<< The two nonces B<must> be different, and an aemp implementation |
| 485 |
B<must> check and fail when they are identical >>. |
| 486 |
|
| 487 |
Example of a nonce line (yes, it's random-looking because it is random |
| 488 |
data): |
| 489 |
|
| 490 |
2XYhdG7/O6epFa4wuP0ujAEx1rXYWRcOypjUYK7eF6yWAQr7gwIN9m/2+mVvBrTPXz5GJDgfGm9d8QRABAbmAP/s |
| 491 |
|
| 492 |
=head2 TLS handshake |
| 493 |
|
| 494 |
I<< If, after the handshake, both sides indicate interest in TLS, then the |
| 495 |
connection B<must> use TLS, or fail to continue. >> |
| 496 |
|
| 497 |
Both sides compare their nonces, and the side who sent the lower nonce |
| 498 |
value ("string" comparison on the raw octet values) becomes the client, |
| 499 |
and the one with the higher nonce the server. |
| 500 |
|
| 501 |
=head2 AUTHENTICATION PHASE |
| 502 |
|
| 503 |
After the greeting is received (and the optional TLS handshake), |
| 504 |
the authentication phase begins, which consists of sending a single |
| 505 |
C<;>-separated line with three fixed strings and any number of |
| 506 |
C<KEY=VALUE> pairs. |
| 507 |
|
| 508 |
The three fixed strings are: |
| 509 |
|
| 510 |
=over 4 |
| 511 |
|
| 512 |
=item the authentication method chosen |
| 513 |
|
| 514 |
This must be one of the methods offered by the other side in the greeting. |
| 515 |
|
| 516 |
Note that all methods starting with C<tls_> are only valid I<iff> TLS was |
| 517 |
successfully handshaked (and to be secure the implementation must enforce |
| 518 |
this). |
| 519 |
|
| 520 |
The currently supported authentication methods are: |
| 521 |
|
| 522 |
=over 4 |
| 523 |
|
| 524 |
=item cleartext |
| 525 |
|
| 526 |
This is simply the shared secret, lowercase-hex-encoded. This method is of |
| 527 |
course very insecure if TLS is not used (and not completely secure even |
| 528 |
if TLS is used), which is why this module will accept, but not generate, |
| 529 |
cleartext auth replies. |
| 530 |
|
| 531 |
=item hmac_md6_64_256 |
| 532 |
|
| 533 |
This method uses an MD6 HMAC with 64 bit blocksize and 256 bit hash, and |
| 534 |
requires a shared secret. It is the preferred auth method when a shared |
| 535 |
secret is available. |
| 536 |
|
| 537 |
First, the shared secret is hashed with MD6: |
| 538 |
|
| 539 |
key = MD6 (secret) |
| 540 |
|
| 541 |
This secret is then used to generate the "local auth reply", by taking |
| 542 |
the two local greeting lines and the two remote greeting lines (without |
| 543 |
line endings), appending \012 to all of them, concatenating them and |
| 544 |
calculating the MD6 HMAC with the key: |
| 545 |
|
| 546 |
lauth = HMAC_MD6 key, "lgreeting1\012lgreeting2\012rgreeting1\012rgreeting2\012" |
| 547 |
|
| 548 |
This authentication token is then lowercase-hex-encoded and sent to the |
| 549 |
other side. |
| 550 |
|
| 551 |
Then the remote auth reply is generated using the same method, but local |
| 552 |
and remote greeting lines swapped: |
| 553 |
|
| 554 |
rauth = HMAC_MD6 key, "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 555 |
|
| 556 |
This is the token that is expected from the other side. |
| 557 |
|
| 558 |
=item tls_anon |
| 559 |
|
| 560 |
This type is only valid I<iff> TLS was enabled and the TLS handshake |
| 561 |
was successful. It has no authentication data, as the server/client |
| 562 |
certificate was successfully verified. |
| 563 |
|
| 564 |
This authentication type is somewhat insecure, as it allows a |
| 565 |
man-in-the-middle attacker to change some of the connection parameters |
| 566 |
(such as the framing format), although there is no known attack that |
| 567 |
exploits this in a way that is worse than just denying the service. |
| 568 |
|
| 569 |
By default, this implementation accepts but never generates this auth |
| 570 |
reply. |
| 571 |
|
| 572 |
=item tls_md6_64_256 |
| 573 |
|
| 574 |
This type is only valid I<iff> TLS was enabled and the TLS handshake was |
| 575 |
successful. |
| 576 |
|
| 577 |
This authentication type simply calculates: |
| 578 |
|
| 579 |
lauth = MD6 "rgreeting1\012rgreeting2\012lgreeting1\012lgreeting2\012" |
| 580 |
|
| 581 |
and lowercase-hex encodes the result and sends it as authentication |
| 582 |
data. No shared secret is required (authentication is done by TLS). The |
| 583 |
checksum exists only to make tinkering with the greeting hard. |
| 584 |
|
| 585 |
=back |
| 586 |
|
| 587 |
=item the authentication data |
| 588 |
|
| 589 |
The authentication data itself, usually base64 or hex-encoded data, see |
| 590 |
above. |
| 591 |
|
| 592 |
=item the framing protocol chosen |
| 593 |
|
| 594 |
This must be one of the framing protocols offered by the other side in the |
| 595 |
greeting. Each side must accept the choice of the other side, and generate |
| 596 |
packets in the format it chose itself. |
| 597 |
|
| 598 |
=back |
| 599 |
|
| 600 |
Example of an authentication reply: |
| 601 |
|
| 602 |
hmac_md6_64_256;363d5175df38bd9eaddd3f6ca18aa1c0c4aa22f0da245ac638d048398c26b8d3;json |
| 603 |
|
| 604 |
=head2 DATA PHASE |
| 605 |
|
| 606 |
After this, packets get exchanged using the chosen framing protocol. It is |
| 607 |
quite possible that both sides use a different framing protocol. |
| 608 |
|
| 609 |
=head2 FULL EXAMPLE |
| 610 |
|
| 611 |
This is an actual protocol dump of a handshake, followed by a single data |
| 612 |
packet. The greater than/less than lines indicate the direction of the |
| 613 |
transfer only. |
| 614 |
|
| 615 |
> aemp;0;anon/57Cs1CggVJjzYaQp13XXg4;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.17:4040 |
| 616 |
> yLgdG1ov/02shVkVQer3wzeuywZK+oraTdEQBmIqWHaegxSGDG4g+HqogLQbvdypFOsoDWJ1Sh4ImV4DMhvUBwTK |
| 617 |
|
| 618 |
< aemp;0;ruth;tls_md6_64_256,hmac_md6_64_256,tls_anon,cleartext;json,storable;provider=AE-0.8;timeout=12;peeraddr=10.0.0.1:37108 |
| 619 |
< +xMQXP8ElfNmuvEhsmcp+s2wCJOuQAsPxSg3d2Ewhs6gBnJz+ypVdWJ/wAVrXqlIJfLeVS/CBy4gEGkyWHSuVb1L |
| 620 |
|
| 621 |
> hmac_md6_64_256;5ad913855742ae5a03a5aeb7eafa4c78629de136bed6acd73eea36c9e98df44a;json |
| 622 |
|
| 623 |
< hmac_md6_64_256;84cd590976f794914c2ca26dac3a207a57a6798b9171289c114de07cf0c20401;json |
| 624 |
< ["","AnyEvent::MP::_spawn","57Cs1CggVJjzYaQp13XXg4.c","AnyEvent::MP::Global::connect",0,"anon/57Cs1CggVJjzYaQp13XXg4"] |
| 625 |
... |
| 626 |
|
| 627 |
The shared secret in use was C<8ugxrtw6H5tKnfPWfaSr4HGhE8MoJXmzTT1BWq7sLutNcD0IbXprQlZjIbl7MBKoeklG3IEfY9GlJthC0pENzk>. |
| 628 |
|
| 629 |
=head2 MONITORING |
| 630 |
|
| 631 |
Monitoring the connection itself is transport-specific. For TCP, all |
| 632 |
connection monitoring is currently left to TCP retransmit time-outs |
| 633 |
on a busy link, and TCP keepalive (which should be enabled) for idle |
| 634 |
connections. |
| 635 |
|
| 636 |
This is not sufficient for listener-less nodes, however: they need |
| 637 |
to regularly send data (30 seconds, or the monitoring interval, is |
| 638 |
recommended), so TCP actively probes. |
| 639 |
|
| 640 |
Future implementations of AnyEvent::Transport might query the kernel TCP |
| 641 |
buffer after a write timeout occurs, and if it is non-empty, shut down the |
| 642 |
connections, but this is an area of future research :) |
| 643 |
|
| 644 |
=head2 NODE PROTOCOL |
| 645 |
|
| 646 |
The transport simply transfers messages, but to implement a full node, a |
| 647 |
special node port must exist that understands a number of requests. |
| 648 |
|
| 649 |
If you are interested in implementing this, drop us a note so we finish |
| 650 |
the documentation. |
| 651 |
|
| 652 |
=head1 SEE ALSO |
| 653 |
|
| 654 |
L<AnyEvent::MP>. |
| 655 |
|
| 656 |
=head1 AUTHOR |
| 657 |
|
| 658 |
Marc Lehmann <schmorp@schmorp.de> |
| 659 |
http://home.schmorp.de/ |
| 660 |
|
| 661 |
=cut |
| 662 |
|
| 663 |
1 |
| 664 |
|
