1 |
=head1 NAME |
2 |
|
3 |
Coro - coroutine process abstraction |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use Coro; |
8 |
|
9 |
async { |
10 |
# some asynchronous thread of execution |
11 |
}; |
12 |
|
13 |
# alternatively create an async process like this: |
14 |
|
15 |
sub some_func : Coro { |
16 |
# some more async code |
17 |
} |
18 |
|
19 |
cede; |
20 |
|
21 |
=head1 DESCRIPTION |
22 |
|
23 |
This module collection manages coroutines. Coroutines are similar to |
24 |
threads but don't run in parallel. |
25 |
|
26 |
In this module, coroutines are defined as "callchain + lexical variables |
27 |
+ @_ + $_ + $@ + $^W + C stack), that is, a coroutine has it's own |
28 |
callchain, it's own set of lexicals and it's own set of perl's most |
29 |
important global variables. |
30 |
|
31 |
=cut |
32 |
|
33 |
package Coro; |
34 |
|
35 |
use strict; |
36 |
no warnings "uninitialized"; |
37 |
|
38 |
use Coro::State; |
39 |
|
40 |
use base qw(Coro::State Exporter); |
41 |
|
42 |
our $idle; # idle handler |
43 |
our $main; # main coroutine |
44 |
our $current; # current coroutine |
45 |
|
46 |
our $VERSION = '2.5'; |
47 |
|
48 |
our @EXPORT = qw(async cede schedule terminate current); |
49 |
our %EXPORT_TAGS = ( |
50 |
prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)], |
51 |
); |
52 |
our @EXPORT_OK = @{$EXPORT_TAGS{prio}}; |
53 |
|
54 |
{ |
55 |
my @async; |
56 |
my $init; |
57 |
|
58 |
# this way of handling attributes simply is NOT scalable ;() |
59 |
sub import { |
60 |
no strict 'refs'; |
61 |
|
62 |
Coro->export_to_level(1, @_); |
63 |
|
64 |
my $old = *{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"}{CODE}; |
65 |
*{(caller)[0]."::MODIFY_CODE_ATTRIBUTES"} = sub { |
66 |
my ($package, $ref) = (shift, shift); |
67 |
my @attrs; |
68 |
for (@_) { |
69 |
if ($_ eq "Coro") { |
70 |
push @async, $ref; |
71 |
unless ($init++) { |
72 |
eval q{ |
73 |
sub INIT { |
74 |
&async(pop @async) while @async; |
75 |
} |
76 |
}; |
77 |
} |
78 |
} else { |
79 |
push @attrs, $_; |
80 |
} |
81 |
} |
82 |
return $old ? $old->($package, $ref, @attrs) : @attrs; |
83 |
}; |
84 |
} |
85 |
|
86 |
} |
87 |
|
88 |
=over 4 |
89 |
|
90 |
=item $main |
91 |
|
92 |
This coroutine represents the main program. |
93 |
|
94 |
=cut |
95 |
|
96 |
$main = new Coro; |
97 |
|
98 |
=item $current (or as function: current) |
99 |
|
100 |
The current coroutine (the last coroutine switched to). The initial value |
101 |
is C<$main> (of course). |
102 |
|
103 |
This variable is B<strictly> I<read-only>. It is provided for performance |
104 |
reasons. If performance is not essentiel you are encouraged to use the |
105 |
C<Coro::current> function instead. |
106 |
|
107 |
=cut |
108 |
|
109 |
# maybe some other module used Coro::Specific before... |
110 |
if ($current) { |
111 |
$main->{specific} = $current->{specific}; |
112 |
} |
113 |
|
114 |
$current = $main; |
115 |
|
116 |
sub current() { $current } |
117 |
|
118 |
=item $idle |
119 |
|
120 |
A callback that is called whenever the scheduler finds no ready coroutines |
121 |
to run. The default implementation prints "FATAL: deadlock detected" and |
122 |
exits. |
123 |
|
124 |
This hook is overwritten by modules such as C<Coro::Timer> and |
125 |
C<Coro::Event> to wait on an external event that hopefully wakes up some |
126 |
coroutine. |
127 |
|
128 |
=cut |
129 |
|
130 |
$idle = sub { |
131 |
print STDERR "FATAL: deadlock detected\n"; |
132 |
exit (51); |
133 |
}; |
134 |
|
135 |
# this coroutine is necessary because a coroutine |
136 |
# cannot destroy itself. |
137 |
my @destroy; |
138 |
my $manager; |
139 |
$manager = new Coro sub { |
140 |
while () { |
141 |
# by overwriting the state object with the manager we destroy it |
142 |
# while still being able to schedule this coroutine (in case it has |
143 |
# been readied multiple times. this is harmless since the manager |
144 |
# can be called as many times as neccessary and will always |
145 |
# remove itself from the runqueue |
146 |
while (@destroy) { |
147 |
my $coro = pop @destroy; |
148 |
$coro->{status} ||= []; |
149 |
$_->ready for @{delete $coro->{join} || []}; |
150 |
|
151 |
# the next line destroys the coro state, but keeps the |
152 |
# process itself intact (we basically make it a zombie |
153 |
# process that always runs the manager thread, so it's possible |
154 |
# to transfer() to this process). |
155 |
$coro->_clone_state_from ($manager); |
156 |
} |
157 |
&schedule; |
158 |
} |
159 |
}; |
160 |
|
161 |
# static methods. not really. |
162 |
|
163 |
=back |
164 |
|
165 |
=head2 STATIC METHODS |
166 |
|
167 |
Static methods are actually functions that operate on the current process only. |
168 |
|
169 |
=over 4 |
170 |
|
171 |
=item async { ... } [@args...] |
172 |
|
173 |
Create a new asynchronous process and return it's process object |
174 |
(usually unused). When the sub returns the new process is automatically |
175 |
terminated. |
176 |
|
177 |
When the coroutine dies, the program will exit, just as in the main |
178 |
program. |
179 |
|
180 |
# create a new coroutine that just prints its arguments |
181 |
async { |
182 |
print "@_\n"; |
183 |
} 1,2,3,4; |
184 |
|
185 |
=cut |
186 |
|
187 |
sub async(&@) { |
188 |
my $pid = new Coro @_; |
189 |
$pid->ready; |
190 |
$pid |
191 |
} |
192 |
|
193 |
=item schedule |
194 |
|
195 |
Calls the scheduler. Please note that the current process will not be put |
196 |
into the ready queue, so calling this function usually means you will |
197 |
never be called again. |
198 |
|
199 |
=cut |
200 |
|
201 |
=item cede |
202 |
|
203 |
"Cede" to other processes. This function puts the current process into the |
204 |
ready queue and calls C<schedule>, which has the effect of giving up the |
205 |
current "timeslice" to other coroutines of the same or higher priority. |
206 |
|
207 |
=cut |
208 |
|
209 |
=item terminate [arg...] |
210 |
|
211 |
Terminates the current process with the given status values (see L<cancel>). |
212 |
|
213 |
=cut |
214 |
|
215 |
sub terminate { |
216 |
$current->cancel (@_); |
217 |
} |
218 |
|
219 |
=back |
220 |
|
221 |
# dynamic methods |
222 |
|
223 |
=head2 PROCESS METHODS |
224 |
|
225 |
These are the methods you can call on process objects. |
226 |
|
227 |
=over 4 |
228 |
|
229 |
=item new Coro \&sub [, @args...] |
230 |
|
231 |
Create a new process and return it. When the sub returns the process |
232 |
automatically terminates as if C<terminate> with the returned values were |
233 |
called. To make the process run you must first put it into the ready queue |
234 |
by calling the ready method. |
235 |
|
236 |
=cut |
237 |
|
238 |
sub _new_coro { |
239 |
$current->_clear_idle_sp; # set the idle sp on the following cede |
240 |
_set_cede_self; # ensures that cede cede's us first |
241 |
cede; |
242 |
terminate &{+shift}; |
243 |
} |
244 |
|
245 |
sub new { |
246 |
my $class = shift; |
247 |
|
248 |
$class->SUPER::new (\&_new_coro, @_) |
249 |
} |
250 |
|
251 |
=item $process->ready |
252 |
|
253 |
Put the given process into the ready queue. |
254 |
|
255 |
=cut |
256 |
|
257 |
=item $process->cancel (arg...) |
258 |
|
259 |
Terminates the given process and makes it return the given arguments as |
260 |
status (default: the empty list). |
261 |
|
262 |
=cut |
263 |
|
264 |
sub cancel { |
265 |
my $self = shift; |
266 |
$self->{status} = [@_]; |
267 |
push @destroy, $self; |
268 |
$manager->ready; |
269 |
&schedule if $current == $self; |
270 |
} |
271 |
|
272 |
=item $process->join |
273 |
|
274 |
Wait until the coroutine terminates and return any values given to the |
275 |
C<terminate> or C<cancel> functions. C<join> can be called multiple times |
276 |
from multiple processes. |
277 |
|
278 |
=cut |
279 |
|
280 |
sub join { |
281 |
my $self = shift; |
282 |
unless ($self->{status}) { |
283 |
push @{$self->{join}}, $current; |
284 |
&schedule; |
285 |
} |
286 |
wantarray ? @{$self->{status}} : $self->{status}[0]; |
287 |
} |
288 |
|
289 |
=item $oldprio = $process->prio ($newprio) |
290 |
|
291 |
Sets (or gets, if the argument is missing) the priority of the |
292 |
process. Higher priority processes get run before lower priority |
293 |
processes. Priorities are small signed integers (currently -4 .. +3), |
294 |
that you can refer to using PRIO_xxx constants (use the import tag :prio |
295 |
to get then): |
296 |
|
297 |
PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN |
298 |
3 > 1 > 0 > -1 > -3 > -4 |
299 |
|
300 |
# set priority to HIGH |
301 |
current->prio(PRIO_HIGH); |
302 |
|
303 |
The idle coroutine ($Coro::idle) always has a lower priority than any |
304 |
existing coroutine. |
305 |
|
306 |
Changing the priority of the current process will take effect immediately, |
307 |
but changing the priority of processes in the ready queue (but not |
308 |
running) will only take effect after the next schedule (of that |
309 |
process). This is a bug that will be fixed in some future version. |
310 |
|
311 |
=item $newprio = $process->nice ($change) |
312 |
|
313 |
Similar to C<prio>, but subtract the given value from the priority (i.e. |
314 |
higher values mean lower priority, just as in unix). |
315 |
|
316 |
=item $olddesc = $process->desc ($newdesc) |
317 |
|
318 |
Sets (or gets in case the argument is missing) the description for this |
319 |
process. This is just a free-form string you can associate with a process. |
320 |
|
321 |
=cut |
322 |
|
323 |
sub desc { |
324 |
my $old = $_[0]{desc}; |
325 |
$_[0]{desc} = $_[1] if @_ > 1; |
326 |
$old; |
327 |
} |
328 |
|
329 |
=back |
330 |
|
331 |
=cut |
332 |
|
333 |
1; |
334 |
|
335 |
=head1 BUGS/LIMITATIONS |
336 |
|
337 |
- you must make very sure that no coro is still active on global |
338 |
destruction. very bad things might happen otherwise (usually segfaults). |
339 |
|
340 |
- this module is not thread-safe. You should only ever use this module |
341 |
from the same thread (this requirement might be losened in the future |
342 |
to allow per-thread schedulers, but Coro::State does not yet allow |
343 |
this). |
344 |
|
345 |
=head1 SEE ALSO |
346 |
|
347 |
Support/Utility: L<Coro::Cont>, L<Coro::Specific>, L<Coro::State>, L<Coro::Util>. |
348 |
|
349 |
Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, L<Coro::SemaphoreSet>, L<Coro::RWLock>. |
350 |
|
351 |
Event/IO: L<Coro::Timer>, L<Coro::Event>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::Select>. |
352 |
|
353 |
Embedding: L<Coro:MakeMaker> |
354 |
|
355 |
=head1 AUTHOR |
356 |
|
357 |
Marc Lehmann <schmorp@schmorp.de> |
358 |
http://home.schmorp.de/ |
359 |
|
360 |
=cut |
361 |
|