1 |
=head1 NAME |
2 |
|
3 |
Coro - real threads in perl |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use Coro; |
8 |
|
9 |
async { |
10 |
# some asynchronous thread of execution |
11 |
print "2\n"; |
12 |
cede; # yield back to main |
13 |
print "4\n"; |
14 |
}; |
15 |
print "1\n"; |
16 |
cede; # yield to coroutine |
17 |
print "3\n"; |
18 |
cede; # and again |
19 |
|
20 |
# use locking |
21 |
use Coro::Semaphore; |
22 |
my $lock = new Coro::Semaphore; |
23 |
my $locked; |
24 |
|
25 |
$lock->down; |
26 |
$locked = 1; |
27 |
$lock->up; |
28 |
|
29 |
=head1 DESCRIPTION |
30 |
|
31 |
For a tutorial-style introduction, please read the L<Coro::Intro> |
32 |
manpage. This manpage mainly contains reference information. |
33 |
|
34 |
This module collection manages coroutines, that is, cooperative |
35 |
threads. Coroutines are similar to kernel threads but don't (in general) |
36 |
run in parallel at the same time even on SMP machines. The specific flavor |
37 |
of coroutine used in this module also guarantees you that it will not |
38 |
switch between coroutines unless necessary, at easily-identified points |
39 |
in your program, so locking and parallel access are rarely an issue, |
40 |
making coroutine programming much safer and easier than using other thread |
41 |
models. |
42 |
|
43 |
Unlike the so-called "Perl threads" (which are not actually real threads |
44 |
but only the windows process emulation ported to unix), Coro provides a |
45 |
full shared address space, which makes communication between coroutines |
46 |
very easy. And coroutines are fast, too: disabling the Windows process |
47 |
emulation code in your perl and using Coro can easily result in a two to |
48 |
four times speed increase for your programs. |
49 |
|
50 |
Coro achieves that by supporting multiple running interpreters that share |
51 |
data, which is especially useful to code pseudo-parallel processes and |
52 |
for event-based programming, such as multiple HTTP-GET requests running |
53 |
concurrently. See L<Coro::AnyEvent> to learn more on how to integrate Coro |
54 |
into an event-based environment. |
55 |
|
56 |
In this module, a coroutines is defined as "callchain + lexical variables |
57 |
+ @_ + $_ + $@ + $/ + C stack), that is, a coroutine has its own |
58 |
callchain, its own set of lexicals and its own set of perls most important |
59 |
global variables (see L<Coro::State> for more configuration and background |
60 |
info). |
61 |
|
62 |
See also the C<SEE ALSO> section at the end of this document - the Coro |
63 |
module family is quite large. |
64 |
|
65 |
=cut |
66 |
|
67 |
package Coro; |
68 |
|
69 |
use strict qw(vars subs); |
70 |
no warnings "uninitialized"; |
71 |
|
72 |
use Coro::State; |
73 |
|
74 |
use base qw(Coro::State Exporter); |
75 |
|
76 |
our $idle; # idle handler |
77 |
our $main; # main coroutine |
78 |
our $current; # current coroutine |
79 |
|
80 |
our $VERSION = "5.0"; |
81 |
|
82 |
our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub); |
83 |
our %EXPORT_TAGS = ( |
84 |
prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)], |
85 |
); |
86 |
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready)); |
87 |
|
88 |
=head1 GLOBAL VARIABLES |
89 |
|
90 |
=over 4 |
91 |
|
92 |
=item $Coro::main |
93 |
|
94 |
This variable stores the coroutine object that represents the main |
95 |
program. While you cna C<ready> it and do most other things you can do to |
96 |
coroutines, it is mainly useful to compare again C<$Coro::current>, to see |
97 |
whether you are running in the main program or not. |
98 |
|
99 |
=cut |
100 |
|
101 |
# $main is now being initialised by Coro::State |
102 |
|
103 |
=item $Coro::current |
104 |
|
105 |
The coroutine object representing the current coroutine (the last |
106 |
coroutine that the Coro scheduler switched to). The initial value is |
107 |
C<$Coro::main> (of course). |
108 |
|
109 |
This variable is B<strictly> I<read-only>. You can take copies of the |
110 |
value stored in it and use it as any other coroutine object, but you must |
111 |
not otherwise modify the variable itself. |
112 |
|
113 |
=cut |
114 |
|
115 |
sub current() { $current } # [DEPRECATED] |
116 |
|
117 |
=item $Coro::idle |
118 |
|
119 |
This variable is mainly useful to integrate Coro into event loops. It is |
120 |
usually better to rely on L<Coro::AnyEvent> or LC<Coro::EV>, as this is |
121 |
pretty low-level functionality. |
122 |
|
123 |
This variable stores a callback that is called whenever the scheduler |
124 |
finds no ready coroutines to run. The default implementation prints |
125 |
"FATAL: deadlock detected" and exits, because the program has no other way |
126 |
to continue. |
127 |
|
128 |
This hook is overwritten by modules such as C<Coro::Timer> and |
129 |
C<Coro::AnyEvent> to wait on an external event that hopefully wake up a |
130 |
coroutine so the scheduler can run it. |
131 |
|
132 |
Note that the callback I<must not>, under any circumstances, block |
133 |
the current coroutine. Normally, this is achieved by having an "idle |
134 |
coroutine" that calls the event loop and then blocks again, and then |
135 |
readying that coroutine in the idle handler. |
136 |
|
137 |
See L<Coro::Event> or L<Coro::AnyEvent> for examples of using this |
138 |
technique. |
139 |
|
140 |
Please note that if your callback recursively invokes perl (e.g. for event |
141 |
handlers), then it must be prepared to be called recursively itself. |
142 |
|
143 |
=cut |
144 |
|
145 |
$idle = sub { |
146 |
require Carp; |
147 |
Carp::croak ("FATAL: deadlock detected"); |
148 |
}; |
149 |
|
150 |
# this coroutine is necessary because a coroutine |
151 |
# cannot destroy itself. |
152 |
our @destroy; |
153 |
our $manager; |
154 |
|
155 |
$manager = new Coro sub { |
156 |
while () { |
157 |
Coro::_cancel shift @destroy |
158 |
while @destroy; |
159 |
|
160 |
&schedule; |
161 |
} |
162 |
}; |
163 |
$manager->{desc} = "[coro manager]"; |
164 |
$manager->prio (PRIO_MAX); |
165 |
|
166 |
=back |
167 |
|
168 |
=head1 SIMPLE COROUTINE CREATION |
169 |
|
170 |
=over 4 |
171 |
|
172 |
=item async { ... } [@args...] |
173 |
|
174 |
Create a new coroutine and return it's coroutine object (usually |
175 |
unused). The coroutine will be put into the ready queue, so |
176 |
it will start running automatically on the next scheduler run. |
177 |
|
178 |
The first argument is a codeblock/closure that should be executed in the |
179 |
coroutine. When it returns argument returns the coroutine is automatically |
180 |
terminated. |
181 |
|
182 |
The remaining arguments are passed as arguments to the closure. |
183 |
|
184 |
See the C<Coro::State::new> constructor for info about the coroutine |
185 |
environment in which coroutines are executed. |
186 |
|
187 |
Calling C<exit> in a coroutine will do the same as calling exit outside |
188 |
the coroutine. Likewise, when the coroutine dies, the program will exit, |
189 |
just as it would in the main program. |
190 |
|
191 |
If you do not want that, you can provide a default C<die> handler, or |
192 |
simply avoid dieing (by use of C<eval>). |
193 |
|
194 |
Example: Create a new coroutine that just prints its arguments. |
195 |
|
196 |
async { |
197 |
print "@_\n"; |
198 |
} 1,2,3,4; |
199 |
|
200 |
=cut |
201 |
|
202 |
sub async(&@) { |
203 |
my $coro = new Coro @_; |
204 |
$coro->ready; |
205 |
$coro |
206 |
} |
207 |
|
208 |
=item async_pool { ... } [@args...] |
209 |
|
210 |
Similar to C<async>, but uses a coroutine pool, so you should not call |
211 |
terminate or join on it (although you are allowed to), and you get a |
212 |
coroutine that might have executed other code already (which can be good |
213 |
or bad :). |
214 |
|
215 |
On the plus side, this function is about twice as fast as creating (and |
216 |
destroying) a completely new coroutine, so if you need a lot of generic |
217 |
coroutines in quick successsion, use C<async_pool>, not C<async>. |
218 |
|
219 |
The code block is executed in an C<eval> context and a warning will be |
220 |
issued in case of an exception instead of terminating the program, as |
221 |
C<async> does. As the coroutine is being reused, stuff like C<on_destroy> |
222 |
will not work in the expected way, unless you call terminate or cancel, |
223 |
which somehow defeats the purpose of pooling (but is fine in the |
224 |
exceptional case). |
225 |
|
226 |
The priority will be reset to C<0> after each run, tracing will be |
227 |
disabled, the description will be reset and the default output filehandle |
228 |
gets restored, so you can change all these. Otherwise the coroutine will |
229 |
be re-used "as-is": most notably if you change other per-coroutine global |
230 |
stuff such as C<$/> you I<must needs> revert that change, which is most |
231 |
simply done by using local as in: C<< local $/ >>. |
232 |
|
233 |
The idle pool size is limited to C<8> idle coroutines (this can be |
234 |
adjusted by changing $Coro::POOL_SIZE), but there can be as many non-idle |
235 |
coros as required. |
236 |
|
237 |
If you are concerned about pooled coroutines growing a lot because a |
238 |
single C<async_pool> used a lot of stackspace you can e.g. C<async_pool |
239 |
{ terminate }> once per second or so to slowly replenish the pool. In |
240 |
addition to that, when the stacks used by a handler grows larger than 32kb |
241 |
(adjustable via $Coro::POOL_RSS) it will also be destroyed. |
242 |
|
243 |
=cut |
244 |
|
245 |
our $POOL_SIZE = 8; |
246 |
our $POOL_RSS = 32 * 1024; |
247 |
our @async_pool; |
248 |
|
249 |
sub pool_handler { |
250 |
while () { |
251 |
eval { |
252 |
&{&_pool_handler} while 1; |
253 |
}; |
254 |
|
255 |
warn $@ if $@; |
256 |
} |
257 |
} |
258 |
|
259 |
=back |
260 |
|
261 |
=head1 STATIC METHODS |
262 |
|
263 |
Static methods are actually functions that implicitly operate on the |
264 |
current coroutine. |
265 |
|
266 |
=over 4 |
267 |
|
268 |
=item schedule |
269 |
|
270 |
Calls the scheduler. The scheduler will find the next coroutine that is |
271 |
to be run from the ready queue and switches to it. The next coroutine |
272 |
to be run is simply the one with the highest priority that is longest |
273 |
in its ready queue. If there is no coroutine ready, it will clal the |
274 |
C<$Coro::idle> hook. |
275 |
|
276 |
Please note that the current coroutine will I<not> be put into the ready |
277 |
queue, so calling this function usually means you will never be called |
278 |
again unless something else (e.g. an event handler) calls C<< ->ready >>, |
279 |
thus waking you up. |
280 |
|
281 |
This makes C<schedule> I<the> generic method to use to block the current |
282 |
coroutine and wait for events: first you remember the current coroutine in |
283 |
a variable, then arrange for some callback of yours to call C<< ->ready |
284 |
>> on that once some event happens, and last you call C<schedule> to put |
285 |
yourself to sleep. Note that a lot of things can wake your coroutine up, |
286 |
so you need to check whether the event indeed happened, e.g. by storing the |
287 |
status in a variable. |
288 |
|
289 |
See B<HOW TO WAIT FOR A CALLBACK>, below, for some ways to wait for callbacks. |
290 |
|
291 |
=item cede |
292 |
|
293 |
"Cede" to other coroutines. This function puts the current coroutine into |
294 |
the ready queue and calls C<schedule>, which has the effect of giving |
295 |
up the current "timeslice" to other coroutines of the same or higher |
296 |
priority. Once your coroutine gets its turn again it will automatically be |
297 |
resumed. |
298 |
|
299 |
This function is often called C<yield> in other languages. |
300 |
|
301 |
=item Coro::cede_notself |
302 |
|
303 |
Works like cede, but is not exported by default and will cede to I<any> |
304 |
coroutine, regardless of priority. This is useful sometimes to ensure |
305 |
progress is made. |
306 |
|
307 |
=item terminate [arg...] |
308 |
|
309 |
Terminates the current coroutine with the given status values (see L<cancel>). |
310 |
|
311 |
=item killall |
312 |
|
313 |
Kills/terminates/cancels all coroutines except the currently running |
314 |
one. This is useful after a fork, either in the child or the parent, as |
315 |
usually only one of them should inherit the running coroutines. |
316 |
|
317 |
Note that while this will try to free some of the main programs resources, |
318 |
you cannot free all of them, so if a coroutine that is not the main |
319 |
program calls this function, there will be some one-time resource leak. |
320 |
|
321 |
=cut |
322 |
|
323 |
sub killall { |
324 |
for (Coro::State::list) { |
325 |
$_->cancel |
326 |
if $_ != $current && UNIVERSAL::isa $_, "Coro"; |
327 |
} |
328 |
} |
329 |
|
330 |
=back |
331 |
|
332 |
=head1 COROUTINE OBJECT METHODS |
333 |
|
334 |
These are the methods you can call on coroutine objects (or to create |
335 |
them). |
336 |
|
337 |
=over 4 |
338 |
|
339 |
=item new Coro \&sub [, @args...] |
340 |
|
341 |
Create a new coroutine and return it. When the sub returns, the coroutine |
342 |
automatically terminates as if C<terminate> with the returned values were |
343 |
called. To make the coroutine run you must first put it into the ready |
344 |
queue by calling the ready method. |
345 |
|
346 |
See C<async> and C<Coro::State::new> for additional info about the |
347 |
coroutine environment. |
348 |
|
349 |
=cut |
350 |
|
351 |
sub _terminate { |
352 |
terminate &{+shift}; |
353 |
} |
354 |
|
355 |
=item $success = $coroutine->ready |
356 |
|
357 |
Put the given coroutine into the end of its ready queue (there is one |
358 |
queue for each priority) and return true. If the coroutine is already in |
359 |
the ready queue, do nothing and return false. |
360 |
|
361 |
This ensures that the scheduler will resume this coroutine automatically |
362 |
once all the coroutines of higher priority and all coroutines of the same |
363 |
priority that were put into the ready queue earlier have been resumed. |
364 |
|
365 |
=item $is_ready = $coroutine->is_ready |
366 |
|
367 |
Return whether the coroutine is currently the ready queue or not, |
368 |
|
369 |
=item $coroutine->cancel (arg...) |
370 |
|
371 |
Terminates the given coroutine and makes it return the given arguments as |
372 |
status (default: the empty list). Never returns if the coroutine is the |
373 |
current coroutine. |
374 |
|
375 |
=cut |
376 |
|
377 |
sub cancel { |
378 |
my $self = shift; |
379 |
|
380 |
if ($current == $self) { |
381 |
terminate @_; |
382 |
} else { |
383 |
$self->{_status} = [@_]; |
384 |
$self->_cancel; |
385 |
} |
386 |
} |
387 |
|
388 |
=item $coroutine->schedule_to |
389 |
|
390 |
Puts the current coroutine to sleep (like C<Coro::schedule>), but instead |
391 |
of continuing with the next coro from the ready queue, always switch to |
392 |
the given coroutine object (regardless of priority etc.). The readyness |
393 |
state of that coroutine isn't changed. |
394 |
|
395 |
This is an advanced method for special cases - I'd love to hear about any |
396 |
uses for this one. |
397 |
|
398 |
=item $coroutine->cede_to |
399 |
|
400 |
Like C<schedule_to>, but puts the current coroutine into the ready |
401 |
queue. This has the effect of temporarily switching to the given |
402 |
coroutine, and continuing some time later. |
403 |
|
404 |
This is an advanced method for special cases - I'd love to hear about any |
405 |
uses for this one. |
406 |
|
407 |
=item $coroutine->throw ([$scalar]) |
408 |
|
409 |
If C<$throw> is specified and defined, it will be thrown as an exception |
410 |
inside the coroutine at the next convenient point in time. Otherwise |
411 |
clears the exception object. |
412 |
|
413 |
Coro will check for the exception each time a schedule-like-function |
414 |
returns, i.e. after each C<schedule>, C<cede>, C<< Coro::Semaphore->down |
415 |
>>, C<< Coro::Handle->readable >> and so on. Most of these functions |
416 |
detect this case and return early in case an exception is pending. |
417 |
|
418 |
The exception object will be thrown "as is" with the specified scalar in |
419 |
C<$@>, i.e. if it is a string, no line number or newline will be appended |
420 |
(unlike with C<die>). |
421 |
|
422 |
This can be used as a softer means than C<cancel> to ask a coroutine to |
423 |
end itself, although there is no guarantee that the exception will lead to |
424 |
termination, and if the exception isn't caught it might well end the whole |
425 |
program. |
426 |
|
427 |
You might also think of C<throw> as being the moral equivalent of |
428 |
C<kill>ing a coroutine with a signal (in this case, a scalar). |
429 |
|
430 |
=item $coroutine->join |
431 |
|
432 |
Wait until the coroutine terminates and return any values given to the |
433 |
C<terminate> or C<cancel> functions. C<join> can be called concurrently |
434 |
from multiple coroutines, and all will be resumed and given the status |
435 |
return once the C<$coroutine> terminates. |
436 |
|
437 |
=cut |
438 |
|
439 |
sub join { |
440 |
my $self = shift; |
441 |
|
442 |
unless ($self->{_status}) { |
443 |
my $current = $current; |
444 |
|
445 |
push @{$self->{_on_destroy}}, sub { |
446 |
$current->ready; |
447 |
undef $current; |
448 |
}; |
449 |
|
450 |
&schedule while $current; |
451 |
} |
452 |
|
453 |
wantarray ? @{$self->{_status}} : $self->{_status}[0]; |
454 |
} |
455 |
|
456 |
=item $coroutine->on_destroy (\&cb) |
457 |
|
458 |
Registers a callback that is called when this coroutine gets destroyed, |
459 |
but before it is joined. The callback gets passed the terminate arguments, |
460 |
if any, and I<must not> die, under any circumstances. |
461 |
|
462 |
=cut |
463 |
|
464 |
sub on_destroy { |
465 |
my ($self, $cb) = @_; |
466 |
|
467 |
push @{ $self->{_on_destroy} }, $cb; |
468 |
} |
469 |
|
470 |
=item $oldprio = $coroutine->prio ($newprio) |
471 |
|
472 |
Sets (or gets, if the argument is missing) the priority of the |
473 |
coroutine. Higher priority coroutines get run before lower priority |
474 |
coroutines. Priorities are small signed integers (currently -4 .. +3), |
475 |
that you can refer to using PRIO_xxx constants (use the import tag :prio |
476 |
to get then): |
477 |
|
478 |
PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN |
479 |
3 > 1 > 0 > -1 > -3 > -4 |
480 |
|
481 |
# set priority to HIGH |
482 |
current->prio(PRIO_HIGH); |
483 |
|
484 |
The idle coroutine ($Coro::idle) always has a lower priority than any |
485 |
existing coroutine. |
486 |
|
487 |
Changing the priority of the current coroutine will take effect immediately, |
488 |
but changing the priority of coroutines in the ready queue (but not |
489 |
running) will only take effect after the next schedule (of that |
490 |
coroutine). This is a bug that will be fixed in some future version. |
491 |
|
492 |
=item $newprio = $coroutine->nice ($change) |
493 |
|
494 |
Similar to C<prio>, but subtract the given value from the priority (i.e. |
495 |
higher values mean lower priority, just as in unix). |
496 |
|
497 |
=item $olddesc = $coroutine->desc ($newdesc) |
498 |
|
499 |
Sets (or gets in case the argument is missing) the description for this |
500 |
coroutine. This is just a free-form string you can associate with a |
501 |
coroutine. |
502 |
|
503 |
This method simply sets the C<< $coroutine->{desc} >> member to the given |
504 |
string. You can modify this member directly if you wish. |
505 |
|
506 |
=cut |
507 |
|
508 |
sub desc { |
509 |
my $old = $_[0]{desc}; |
510 |
$_[0]{desc} = $_[1] if @_ > 1; |
511 |
$old; |
512 |
} |
513 |
|
514 |
sub transfer { |
515 |
require Carp; |
516 |
Carp::croak ("You must not call ->transfer on Coro objects. Use Coro::State objects or the ->schedule_to method. Caught"); |
517 |
} |
518 |
|
519 |
=back |
520 |
|
521 |
=head1 GLOBAL FUNCTIONS |
522 |
|
523 |
=over 4 |
524 |
|
525 |
=item Coro::nready |
526 |
|
527 |
Returns the number of coroutines that are currently in the ready state, |
528 |
i.e. that can be switched to by calling C<schedule> directory or |
529 |
indirectly. The value C<0> means that the only runnable coroutine is the |
530 |
currently running one, so C<cede> would have no effect, and C<schedule> |
531 |
would cause a deadlock unless there is an idle handler that wakes up some |
532 |
coroutines. |
533 |
|
534 |
=item my $guard = Coro::guard { ... } |
535 |
|
536 |
This creates and returns a guard object. Nothing happens until the object |
537 |
gets destroyed, in which case the codeblock given as argument will be |
538 |
executed. This is useful to free locks or other resources in case of a |
539 |
runtime error or when the coroutine gets canceled, as in both cases the |
540 |
guard block will be executed. The guard object supports only one method, |
541 |
C<< ->cancel >>, which will keep the codeblock from being executed. |
542 |
|
543 |
Example: set some flag and clear it again when the coroutine gets canceled |
544 |
or the function returns: |
545 |
|
546 |
sub do_something { |
547 |
my $guard = Coro::guard { $busy = 0 }; |
548 |
$busy = 1; |
549 |
|
550 |
# do something that requires $busy to be true |
551 |
} |
552 |
|
553 |
=cut |
554 |
|
555 |
sub guard(&) { |
556 |
bless \(my $cb = $_[0]), "Coro::guard" |
557 |
} |
558 |
|
559 |
sub Coro::guard::cancel { |
560 |
${$_[0]} = sub { }; |
561 |
} |
562 |
|
563 |
sub Coro::guard::DESTROY { |
564 |
${$_[0]}->(); |
565 |
} |
566 |
|
567 |
|
568 |
=item unblock_sub { ... } |
569 |
|
570 |
This utility function takes a BLOCK or code reference and "unblocks" it, |
571 |
returning a new coderef. Unblocking means that calling the new coderef |
572 |
will return immediately without blocking, returning nothing, while the |
573 |
original code ref will be called (with parameters) from within another |
574 |
coroutine. |
575 |
|
576 |
The reason this function exists is that many event libraries (such as the |
577 |
venerable L<Event|Event> module) are not coroutine-safe (a weaker form |
578 |
of thread-safety). This means you must not block within event callbacks, |
579 |
otherwise you might suffer from crashes or worse. The only event library |
580 |
currently known that is safe to use without C<unblock_sub> is L<EV>. |
581 |
|
582 |
This function allows your callbacks to block by executing them in another |
583 |
coroutine where it is safe to block. One example where blocking is handy |
584 |
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to |
585 |
disk, for example. |
586 |
|
587 |
In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when |
588 |
creating event callbacks that want to block. |
589 |
|
590 |
If your handler does not plan to block (e.g. simply sends a message to |
591 |
another coroutine, or puts some other coroutine into the ready queue), |
592 |
there is no reason to use C<unblock_sub>. |
593 |
|
594 |
Note that you also need to use C<unblock_sub> for any other callbacks that |
595 |
are indirectly executed by any C-based event loop. For example, when you |
596 |
use a module that uses L<AnyEvent> (and you use L<Coro::AnyEvent>) and it |
597 |
provides callbacks that are the result of some event callback, then you |
598 |
must not block either, or use C<unblock_sub>. |
599 |
|
600 |
=cut |
601 |
|
602 |
our @unblock_queue; |
603 |
|
604 |
# we create a special coro because we want to cede, |
605 |
# to reduce pressure on the coro pool (because most callbacks |
606 |
# return immediately and can be reused) and because we cannot cede |
607 |
# inside an event callback. |
608 |
our $unblock_scheduler = new Coro sub { |
609 |
while () { |
610 |
while (my $cb = pop @unblock_queue) { |
611 |
&async_pool (@$cb); |
612 |
|
613 |
# for short-lived callbacks, this reduces pressure on the coro pool |
614 |
# as the chance is very high that the async_poll coro will be back |
615 |
# in the idle state when cede returns |
616 |
cede; |
617 |
} |
618 |
schedule; # sleep well |
619 |
} |
620 |
}; |
621 |
$unblock_scheduler->{desc} = "[unblock_sub scheduler]"; |
622 |
|
623 |
sub unblock_sub(&) { |
624 |
my $cb = shift; |
625 |
|
626 |
sub { |
627 |
unshift @unblock_queue, [$cb, @_]; |
628 |
$unblock_scheduler->ready; |
629 |
} |
630 |
} |
631 |
|
632 |
=item $cb = Coro::rouse_cb |
633 |
|
634 |
Create and return a "rouse callback". That's a code reference that, when |
635 |
called, will save its arguments and notify the owner coroutine of the |
636 |
callback. |
637 |
|
638 |
See the next function. |
639 |
|
640 |
=item @args = Coro::rouse_wait [$cb] |
641 |
|
642 |
Wait for the specified rouse callback (or the last one tht was created in |
643 |
this coroutine). |
644 |
|
645 |
As soon as the callback is invoked (or when the calback was invoked before |
646 |
C<rouse_wait>), it will return a copy of the arguments originally passed |
647 |
to the rouse callback. |
648 |
|
649 |
See the section B<HOW TO WAIT FOR A CALLBACK> for an actual usage example. |
650 |
|
651 |
=back |
652 |
|
653 |
=cut |
654 |
|
655 |
1; |
656 |
|
657 |
=head1 HOW TO WAIT FOR A CALLBACK |
658 |
|
659 |
It is very common for a coroutine to wait for some callback to be |
660 |
called. This occurs naturally when you use coroutines in an otherwise |
661 |
event-based program, or when you use event-based libraries. |
662 |
|
663 |
These typically register a callback for some event, and call that callback |
664 |
when the event occured. In a coroutine, however, you typically want to |
665 |
just wait for the event, simplyifying things. |
666 |
|
667 |
For example C<< AnyEvent->child >> registers a callback to be called when |
668 |
a specific child has exited: |
669 |
|
670 |
my $child_watcher = AnyEvent->child (pid => $pid, cb => sub { ... }); |
671 |
|
672 |
But from withina coroutine, you often just want to write this: |
673 |
|
674 |
my $status = wait_for_child $pid; |
675 |
|
676 |
Coro offers two functions specifically designed to make this easy, |
677 |
C<Coro::rouse_cb> and C<Coro::rouse_wait>. |
678 |
|
679 |
The first function, C<rouse_cb>, generates and returns a callback that, |
680 |
when invoked, will save it's arguments and notify the coroutine that |
681 |
created the callback. |
682 |
|
683 |
The second function, C<rouse_wait>, waits for the callback to be called |
684 |
(by calling C<schedule> to go to sleep) and returns the arguments |
685 |
originally passed to the callback. |
686 |
|
687 |
Using these functions, it becomes easy to write the C<wait_for_child> |
688 |
function mentioned above: |
689 |
|
690 |
sub wait_for_child($) { |
691 |
my ($pid) = @_; |
692 |
|
693 |
my $watcher = AnyEvent->child (pid => $pid, cb => Coro::rouse_cb); |
694 |
|
695 |
my ($rpid, $rstatus) = Coro::rouse_wait; |
696 |
$rstatus |
697 |
} |
698 |
|
699 |
In the case where C<rouse_cb> and C<rouse_wait> are not flexible enough, |
700 |
you can roll your own, using C<schedule>: |
701 |
|
702 |
sub wait_for_child($) { |
703 |
my ($pid) = @_; |
704 |
|
705 |
# store the current coroutine in $current, |
706 |
# and provide result variables for the closure passed to ->child |
707 |
my $current = $Coro::current; |
708 |
my ($done, $rstatus); |
709 |
|
710 |
# pass a closure to ->child |
711 |
my $watcher = AnyEvent->child (pid => $pid, cb => sub { |
712 |
$rstatus = $_[1]; # remember rstatus |
713 |
$done = 1; # mark $rstatus as valud |
714 |
}); |
715 |
|
716 |
# wait until the closure has been called |
717 |
schedule while !$done; |
718 |
|
719 |
$rstatus |
720 |
} |
721 |
|
722 |
|
723 |
=head1 BUGS/LIMITATIONS |
724 |
|
725 |
=over 4 |
726 |
|
727 |
=item fork with pthread backend |
728 |
|
729 |
When Coro is compiled using the pthread backend (which isn't recommended |
730 |
but required on many BSDs as their libcs are completely broken), then |
731 |
coroutines will not survive a fork. There is no known workaround except to |
732 |
fix your libc and use a saner backend. |
733 |
|
734 |
=item perl process emulation ("threads") |
735 |
|
736 |
This module is not perl-pseudo-thread-safe. You should only ever use this |
737 |
module from the same thread (this requirement might be removed in the |
738 |
future to allow per-thread schedulers, but Coro::State does not yet allow |
739 |
this). I recommend disabling thread support and using processes, as having |
740 |
the windows process emulation enabled under unix roughly halves perl |
741 |
performance, even when not used. |
742 |
|
743 |
=item coroutine switching not signal safe |
744 |
|
745 |
You must not switch to another coroutine from within a signal handler |
746 |
(only relevant with %SIG - most event libraries provide safe signals). |
747 |
|
748 |
That means you I<MUST NOT> call any function that might "block" the |
749 |
current coroutine - C<cede>, C<schedule> C<< Coro::Semaphore->down >> or |
750 |
anything that calls those. Everything else, including calling C<ready>, |
751 |
works. |
752 |
|
753 |
=back |
754 |
|
755 |
|
756 |
=head1 SEE ALSO |
757 |
|
758 |
Event-Loop integration: L<Coro::AnyEvent>, L<Coro::EV>, L<Coro::Event>. |
759 |
|
760 |
Debugging: L<Coro::Debug>. |
761 |
|
762 |
Support/Utility: L<Coro::Specific>, L<Coro::Util>. |
763 |
|
764 |
Locking/IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, |
765 |
L<Coro::SemaphoreSet>, L<Coro::RWLock>. |
766 |
|
767 |
IO/Timers: L<Coro::Timer>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::AIO>. |
768 |
|
769 |
Compatibility: L<Coro::LWP> (but see also L<AnyEvent::HTTP> for |
770 |
a better-working alternative), L<Coro::BDB>, L<Coro::Storable>, |
771 |
L<Coro::Select>. |
772 |
|
773 |
XS API: L<Coro::MakeMaker>. |
774 |
|
775 |
Low level Configuration, Coroutine Environment: L<Coro::State>. |
776 |
|
777 |
=head1 AUTHOR |
778 |
|
779 |
Marc Lehmann <schmorp@schmorp.de> |
780 |
http://home.schmorp.de/ |
781 |
|
782 |
=cut |
783 |
|