1 |
=head1 NAME |
2 |
|
3 |
Coro - the only real threads in perl |
4 |
|
5 |
=head1 SYNOPSIS |
6 |
|
7 |
use Coro; |
8 |
|
9 |
async { |
10 |
# some asynchronous thread of execution |
11 |
print "2\n"; |
12 |
cede; # yield back to main |
13 |
print "4\n"; |
14 |
}; |
15 |
print "1\n"; |
16 |
cede; # yield to coro |
17 |
print "3\n"; |
18 |
cede; # and again |
19 |
|
20 |
# use locking |
21 |
use Coro::Semaphore; |
22 |
my $lock = new Coro::Semaphore; |
23 |
my $locked; |
24 |
|
25 |
$lock->down; |
26 |
$locked = 1; |
27 |
$lock->up; |
28 |
|
29 |
=head1 DESCRIPTION |
30 |
|
31 |
For a tutorial-style introduction, please read the L<Coro::Intro> |
32 |
manpage. This manpage mainly contains reference information. |
33 |
|
34 |
This module collection manages continuations in general, most often in |
35 |
the form of cooperative threads (also called coros, or simply "coro" |
36 |
in the documentation). They are similar to kernel threads but don't (in |
37 |
general) run in parallel at the same time even on SMP machines. The |
38 |
specific flavor of thread offered by this module also guarantees you that |
39 |
it will not switch between threads unless necessary, at easily-identified |
40 |
points in your program, so locking and parallel access are rarely an |
41 |
issue, making thread programming much safer and easier than using other |
42 |
thread models. |
43 |
|
44 |
Unlike the so-called "Perl threads" (which are not actually real threads |
45 |
but only the windows process emulation (see section of same name for |
46 |
more details) ported to UNIX, and as such act as processes), Coro |
47 |
provides a full shared address space, which makes communication between |
48 |
threads very easy. And coro threads are fast, too: disabling the Windows |
49 |
process emulation code in your perl and using Coro can easily result in |
50 |
a two to four times speed increase for your programs. A parallel matrix |
51 |
multiplication benchmark (very communication-intensive) runs over 300 |
52 |
times faster on a single core than perls pseudo-threads on a quad core |
53 |
using all four cores. |
54 |
|
55 |
Coro achieves that by supporting multiple running interpreters that share |
56 |
data, which is especially useful to code pseudo-parallel processes and |
57 |
for event-based programming, such as multiple HTTP-GET requests running |
58 |
concurrently. See L<Coro::AnyEvent> to learn more on how to integrate Coro |
59 |
into an event-based environment. |
60 |
|
61 |
In this module, a thread is defined as "callchain + lexical variables + |
62 |
some package variables + C stack), that is, a thread has its own callchain, |
63 |
its own set of lexicals and its own set of perls most important global |
64 |
variables (see L<Coro::State> for more configuration and background info). |
65 |
|
66 |
See also the C<SEE ALSO> section at the end of this document - the Coro |
67 |
module family is quite large. |
68 |
|
69 |
=head1 CORO THREAD LIFE CYCLE |
70 |
|
71 |
During the long and exciting (or not) life of a coro thread, it goes |
72 |
through a number of states: |
73 |
|
74 |
=over 4 |
75 |
|
76 |
=item 1. Creation |
77 |
|
78 |
The first thing in the life of a coro thread is it's creation - |
79 |
obviously. The typical way to create a thread is to call the C<async |
80 |
BLOCK> function: |
81 |
|
82 |
async { |
83 |
# thread code goes here |
84 |
}; |
85 |
|
86 |
You can also pass arguments, which are put in C<@_>: |
87 |
|
88 |
async { |
89 |
print $_[1]; # prints 2 |
90 |
} 1, 2, 3; |
91 |
|
92 |
This creates a new coro thread and puts it into the ready queue, meaning |
93 |
it will run as soon as the CPU is free for it. |
94 |
|
95 |
C<async> will return a coro object - you can store this for future |
96 |
reference or ignore it, the thread itself will keep a reference to it's |
97 |
thread object - threads are alive on their own. |
98 |
|
99 |
Another way to create a thread is to call the C<new> constructor with a |
100 |
code-reference: |
101 |
|
102 |
new Coro sub { |
103 |
# thread code goes here |
104 |
}, @optional_arguments; |
105 |
|
106 |
This is quite similar to calling C<async>, but the important difference is |
107 |
that the new thread is not put into the ready queue, so the thread will |
108 |
not run until somebody puts it there. C<async> is, therefore, identical to |
109 |
this sequence: |
110 |
|
111 |
my $coro = new Coro sub { |
112 |
# thread code goes here |
113 |
}; |
114 |
$coro->ready; |
115 |
return $coro; |
116 |
|
117 |
=item 2. Startup |
118 |
|
119 |
When a new coro thread is created, only a copy of the code reference |
120 |
and the arguments are stored, no extra memory for stacks and so on is |
121 |
allocated, keeping the coro thread in a low-memory state. |
122 |
|
123 |
Only when it actually starts executing will all the resources be finally |
124 |
allocated. |
125 |
|
126 |
The optional arguments specified at coro creation are available in C<@_>, |
127 |
similar to function calls. |
128 |
|
129 |
=item 3. Running / Blocking |
130 |
|
131 |
A lot can happen after the coro thread has started running. Quite usually, |
132 |
it will not run to the end in one go (because you could use a function |
133 |
instead), but it will give up the CPU regularly because it waits for |
134 |
external events. |
135 |
|
136 |
As long as a coro thread runs, it's coro object is available in the global |
137 |
variable C<$Coro::current>. |
138 |
|
139 |
The low-level way to give up the CPU is to call the scheduler, which |
140 |
selects a new coro thread to run: |
141 |
|
142 |
Coro::schedule; |
143 |
|
144 |
Since running threads are not in the ready queue, calling the scheduler |
145 |
without doing anything else will block the coro thread forever - you need |
146 |
to arrange either for the coro to put woken up (readied) by some other |
147 |
event or some other thread, or you can put it into the ready queue before |
148 |
scheduling: |
149 |
|
150 |
# this is exactly what Coro::cede does |
151 |
$Coro::current->ready; |
152 |
Coro::schedule; |
153 |
|
154 |
All the higher-level synchronisation methods (Coro::Semaphore, |
155 |
Coro::rouse_*...) are actually implemented via C<< ->ready >> and C<< |
156 |
Coro::schedule >>. |
157 |
|
158 |
While the coro thread is running it also might get assigned a C-level |
159 |
thread, or the C-level thread might be unassigned from it, as the Coro |
160 |
runtime wishes. A C-level thread needs to be assigned when your perl |
161 |
thread calls into some C-level function and that function in turn calls |
162 |
perl and perl then wants to switch coroutines. This happens most often |
163 |
when you run an event loop and block in the callback, or when perl |
164 |
itself calls some function such as C<AUTOLOAD> or methods via the C<tie> |
165 |
mechanism. |
166 |
|
167 |
=item 4. Termination |
168 |
|
169 |
Many threads actually terminate after some time. There are a number of |
170 |
ways to terminate a coro thread, the simplest is returning from the |
171 |
top-level code reference: |
172 |
|
173 |
async { |
174 |
# after returning from here, the coro thread is terminated |
175 |
}; |
176 |
|
177 |
async { |
178 |
return if 0.5 < rand; # terminate a little earlier, maybe |
179 |
print "got a chance to print this\n"; |
180 |
# or here |
181 |
}; |
182 |
|
183 |
Any values returned from the coroutine can be recovered using C<< ->join |
184 |
>>: |
185 |
|
186 |
my $coro = async { |
187 |
"hello, world\n" # return a string |
188 |
}; |
189 |
|
190 |
my $hello_world = $coro->join; |
191 |
|
192 |
print $hello_world; |
193 |
|
194 |
Another way to terminate is to call C<< Coro::terminate >>, which at any |
195 |
subroutine call nesting level: |
196 |
|
197 |
async { |
198 |
Coro::terminate "return value 1", "return value 2"; |
199 |
}; |
200 |
|
201 |
And yet another way is to C<< ->cancel >> the coro thread from another |
202 |
thread: |
203 |
|
204 |
my $coro = async { |
205 |
exit 1; |
206 |
}; |
207 |
|
208 |
$coro->cancel; # an also accept values for ->join to retrieve |
209 |
|
210 |
Cancellation I<can> be dangerous - it's a bit like calling C<exit> without |
211 |
actually exiting, and might leave C libraries and XS modules in a weird |
212 |
state. Unlike other thread implementations, however, Coro is exceptionally |
213 |
safe with regards to cancellation, as perl will always be in a consistent |
214 |
state. |
215 |
|
216 |
So, cancelling a thread that runs in an XS event loop might not be the |
217 |
best idea, but any other combination that deals with perl only (cancelling |
218 |
when a thread is in a C<tie> method or an C<AUTOLOAD> for example) is |
219 |
safe. |
220 |
|
221 |
=item 5. Cleanup |
222 |
|
223 |
Threads will allocate various resources. Most but not all will be returned |
224 |
when a thread terminates, during clean-up. |
225 |
|
226 |
Cleanup is quite similar to throwing an uncaught exception: perl will |
227 |
work it's way up through all subroutine calls and blocks. On it's way, it |
228 |
will release all C<my> variables, undo all C<local>'s and free any other |
229 |
resources truly local to the thread. |
230 |
|
231 |
So, a common way to free resources is to keep them referenced only by my |
232 |
variables: |
233 |
|
234 |
async { |
235 |
my $big_cache = new Cache ...; |
236 |
}; |
237 |
|
238 |
If there are no other references, then the C<$big_cache> object will be |
239 |
freed when the thread terminates, regardless of how it does so. |
240 |
|
241 |
What it does C<NOT> do is unlock any Coro::Semaphores or similar |
242 |
resources, but that's where the C<guard> methods come in handy: |
243 |
|
244 |
my $sem = new Coro::Semaphore; |
245 |
|
246 |
async { |
247 |
my $lock_guard = $sem->guard; |
248 |
# if we reutrn, or die or get cancelled, here, |
249 |
# then the semaphore will be "up"ed. |
250 |
}; |
251 |
|
252 |
The C<Guard::guard> function comes in handy for any custom cleanup you |
253 |
might want to do: |
254 |
|
255 |
async { |
256 |
my $window = new Gtk2::Window "toplevel"; |
257 |
# The window will not be cleaned up automatically, even when $window |
258 |
# gets freed, so use a guard to ensure it's destruction |
259 |
# in case of an error: |
260 |
my $window_guard = Guard::guard { $window->destroy }; |
261 |
|
262 |
# we are safe here |
263 |
}; |
264 |
|
265 |
Last not least, C<local> can often be handy, too, e.g. when temporarily |
266 |
replacing the coro thread description: |
267 |
|
268 |
sub myfunction { |
269 |
local $Coro::current->{desc} = "inside myfunction(@_)"; |
270 |
|
271 |
# if we return or die here, the description will be restored |
272 |
} |
273 |
|
274 |
=item 6. Viva La Zombie Muerte |
275 |
|
276 |
Even after a thread has terminated and cleaned up it's resources, the coro |
277 |
object still is there and stores the return values of the thread. Only in |
278 |
this state will the coro object be "reference counted" in the normal perl |
279 |
sense: the thread code keeps a reference to it when it is active, but not |
280 |
after it has terminated. |
281 |
|
282 |
The means the coro object gets freed automatically when the thread has |
283 |
terminated and cleaned up and there arenot other references. |
284 |
|
285 |
If there are, the coro object will stay around, and you can call C<< |
286 |
->join >> as many times as you wish to retrieve the result values: |
287 |
|
288 |
async { |
289 |
print "hi\n"; |
290 |
1 |
291 |
}; |
292 |
|
293 |
# run the async above, and free everything before returning |
294 |
# from Coro::cede: |
295 |
Coro::cede; |
296 |
|
297 |
{ |
298 |
my $coro = async { |
299 |
print "hi\n"; |
300 |
1 |
301 |
}; |
302 |
|
303 |
# run the async above, and clean up, but do not free the coro |
304 |
# object: |
305 |
Coro::cede; |
306 |
|
307 |
# optionally retrieve the result values |
308 |
my @results = $coro->join; |
309 |
|
310 |
# now $coro goes out of scope, and presumably gets freed |
311 |
}; |
312 |
|
313 |
=back |
314 |
|
315 |
=cut |
316 |
|
317 |
package Coro; |
318 |
|
319 |
use common::sense; |
320 |
|
321 |
use Carp (); |
322 |
|
323 |
use Guard (); |
324 |
|
325 |
use Coro::State; |
326 |
|
327 |
use base qw(Coro::State Exporter); |
328 |
|
329 |
our $idle; # idle handler |
330 |
our $main; # main coro |
331 |
our $current; # current coro |
332 |
|
333 |
our $VERSION = 5.372; |
334 |
|
335 |
our @EXPORT = qw(async async_pool cede schedule terminate current unblock_sub rouse_cb rouse_wait); |
336 |
our %EXPORT_TAGS = ( |
337 |
prio => [qw(PRIO_MAX PRIO_HIGH PRIO_NORMAL PRIO_LOW PRIO_IDLE PRIO_MIN)], |
338 |
); |
339 |
our @EXPORT_OK = (@{$EXPORT_TAGS{prio}}, qw(nready)); |
340 |
|
341 |
=head1 GLOBAL VARIABLES |
342 |
|
343 |
=over 4 |
344 |
|
345 |
=item $Coro::main |
346 |
|
347 |
This variable stores the Coro object that represents the main |
348 |
program. While you cna C<ready> it and do most other things you can do to |
349 |
coro, it is mainly useful to compare again C<$Coro::current>, to see |
350 |
whether you are running in the main program or not. |
351 |
|
352 |
=cut |
353 |
|
354 |
# $main is now being initialised by Coro::State |
355 |
|
356 |
=item $Coro::current |
357 |
|
358 |
The Coro object representing the current coro (the last |
359 |
coro that the Coro scheduler switched to). The initial value is |
360 |
C<$Coro::main> (of course). |
361 |
|
362 |
This variable is B<strictly> I<read-only>. You can take copies of the |
363 |
value stored in it and use it as any other Coro object, but you must |
364 |
not otherwise modify the variable itself. |
365 |
|
366 |
=cut |
367 |
|
368 |
sub current() { $current } # [DEPRECATED] |
369 |
|
370 |
=item $Coro::idle |
371 |
|
372 |
This variable is mainly useful to integrate Coro into event loops. It is |
373 |
usually better to rely on L<Coro::AnyEvent> or L<Coro::EV>, as this is |
374 |
pretty low-level functionality. |
375 |
|
376 |
This variable stores a Coro object that is put into the ready queue when |
377 |
there are no other ready threads (without invoking any ready hooks). |
378 |
|
379 |
The default implementation dies with "FATAL: deadlock detected.", followed |
380 |
by a thread listing, because the program has no other way to continue. |
381 |
|
382 |
This hook is overwritten by modules such as C<Coro::EV> and |
383 |
C<Coro::AnyEvent> to wait on an external event that hopefully wakes up a |
384 |
coro so the scheduler can run it. |
385 |
|
386 |
See L<Coro::EV> or L<Coro::AnyEvent> for examples of using this technique. |
387 |
|
388 |
=cut |
389 |
|
390 |
# ||= because other modules could have provided their own by now |
391 |
$idle ||= new Coro sub { |
392 |
require Coro::Debug; |
393 |
die "FATAL: deadlock detected.\n" |
394 |
. Coro::Debug::ps_listing (); |
395 |
}; |
396 |
|
397 |
# this coro is necessary because a coro |
398 |
# cannot destroy itself. |
399 |
our @destroy; |
400 |
our $manager; |
401 |
|
402 |
$manager = new Coro sub { |
403 |
while () { |
404 |
_destroy shift @destroy |
405 |
while @destroy; |
406 |
|
407 |
&schedule; |
408 |
} |
409 |
}; |
410 |
$manager->{desc} = "[coro manager]"; |
411 |
$manager->prio (PRIO_MAX); |
412 |
|
413 |
=back |
414 |
|
415 |
=head1 SIMPLE CORO CREATION |
416 |
|
417 |
=over 4 |
418 |
|
419 |
=item async { ... } [@args...] |
420 |
|
421 |
Create a new coro and return its Coro object (usually |
422 |
unused). The coro will be put into the ready queue, so |
423 |
it will start running automatically on the next scheduler run. |
424 |
|
425 |
The first argument is a codeblock/closure that should be executed in the |
426 |
coro. When it returns argument returns the coro is automatically |
427 |
terminated. |
428 |
|
429 |
The remaining arguments are passed as arguments to the closure. |
430 |
|
431 |
See the C<Coro::State::new> constructor for info about the coro |
432 |
environment in which coro are executed. |
433 |
|
434 |
Calling C<exit> in a coro will do the same as calling exit outside |
435 |
the coro. Likewise, when the coro dies, the program will exit, |
436 |
just as it would in the main program. |
437 |
|
438 |
If you do not want that, you can provide a default C<die> handler, or |
439 |
simply avoid dieing (by use of C<eval>). |
440 |
|
441 |
Example: Create a new coro that just prints its arguments. |
442 |
|
443 |
async { |
444 |
print "@_\n"; |
445 |
} 1,2,3,4; |
446 |
|
447 |
=item async_pool { ... } [@args...] |
448 |
|
449 |
Similar to C<async>, but uses a coro pool, so you should not call |
450 |
terminate or join on it (although you are allowed to), and you get a |
451 |
coro that might have executed other code already (which can be good |
452 |
or bad :). |
453 |
|
454 |
On the plus side, this function is about twice as fast as creating (and |
455 |
destroying) a completely new coro, so if you need a lot of generic |
456 |
coros in quick successsion, use C<async_pool>, not C<async>. |
457 |
|
458 |
The code block is executed in an C<eval> context and a warning will be |
459 |
issued in case of an exception instead of terminating the program, as |
460 |
C<async> does. As the coro is being reused, stuff like C<on_destroy> |
461 |
will not work in the expected way, unless you call terminate or cancel, |
462 |
which somehow defeats the purpose of pooling (but is fine in the |
463 |
exceptional case). |
464 |
|
465 |
The priority will be reset to C<0> after each run, tracing will be |
466 |
disabled, the description will be reset and the default output filehandle |
467 |
gets restored, so you can change all these. Otherwise the coro will |
468 |
be re-used "as-is": most notably if you change other per-coro global |
469 |
stuff such as C<$/> you I<must needs> revert that change, which is most |
470 |
simply done by using local as in: C<< local $/ >>. |
471 |
|
472 |
The idle pool size is limited to C<8> idle coros (this can be |
473 |
adjusted by changing $Coro::POOL_SIZE), but there can be as many non-idle |
474 |
coros as required. |
475 |
|
476 |
If you are concerned about pooled coros growing a lot because a |
477 |
single C<async_pool> used a lot of stackspace you can e.g. C<async_pool |
478 |
{ terminate }> once per second or so to slowly replenish the pool. In |
479 |
addition to that, when the stacks used by a handler grows larger than 32kb |
480 |
(adjustable via $Coro::POOL_RSS) it will also be destroyed. |
481 |
|
482 |
=cut |
483 |
|
484 |
our $POOL_SIZE = 8; |
485 |
our $POOL_RSS = 32 * 1024; |
486 |
our @async_pool; |
487 |
|
488 |
sub pool_handler { |
489 |
while () { |
490 |
eval { |
491 |
&{&_pool_handler} while 1; |
492 |
}; |
493 |
|
494 |
warn $@ if $@; |
495 |
} |
496 |
} |
497 |
|
498 |
=back |
499 |
|
500 |
=head1 STATIC METHODS |
501 |
|
502 |
Static methods are actually functions that implicitly operate on the |
503 |
current coro. |
504 |
|
505 |
=over 4 |
506 |
|
507 |
=item schedule |
508 |
|
509 |
Calls the scheduler. The scheduler will find the next coro that is |
510 |
to be run from the ready queue and switches to it. The next coro |
511 |
to be run is simply the one with the highest priority that is longest |
512 |
in its ready queue. If there is no coro ready, it will call the |
513 |
C<$Coro::idle> hook. |
514 |
|
515 |
Please note that the current coro will I<not> be put into the ready |
516 |
queue, so calling this function usually means you will never be called |
517 |
again unless something else (e.g. an event handler) calls C<< ->ready >>, |
518 |
thus waking you up. |
519 |
|
520 |
This makes C<schedule> I<the> generic method to use to block the current |
521 |
coro and wait for events: first you remember the current coro in |
522 |
a variable, then arrange for some callback of yours to call C<< ->ready |
523 |
>> on that once some event happens, and last you call C<schedule> to put |
524 |
yourself to sleep. Note that a lot of things can wake your coro up, |
525 |
so you need to check whether the event indeed happened, e.g. by storing the |
526 |
status in a variable. |
527 |
|
528 |
See B<HOW TO WAIT FOR A CALLBACK>, below, for some ways to wait for callbacks. |
529 |
|
530 |
=item cede |
531 |
|
532 |
"Cede" to other coros. This function puts the current coro into |
533 |
the ready queue and calls C<schedule>, which has the effect of giving |
534 |
up the current "timeslice" to other coros of the same or higher |
535 |
priority. Once your coro gets its turn again it will automatically be |
536 |
resumed. |
537 |
|
538 |
This function is often called C<yield> in other languages. |
539 |
|
540 |
=item Coro::cede_notself |
541 |
|
542 |
Works like cede, but is not exported by default and will cede to I<any> |
543 |
coro, regardless of priority. This is useful sometimes to ensure |
544 |
progress is made. |
545 |
|
546 |
=item terminate [arg...] |
547 |
|
548 |
Terminates the current coro with the given status values (see |
549 |
L<cancel>). The values will not be copied, but referenced directly. |
550 |
|
551 |
=item Coro::on_enter BLOCK, Coro::on_leave BLOCK |
552 |
|
553 |
These function install enter and leave winders in the current scope. The |
554 |
enter block will be executed when on_enter is called and whenever the |
555 |
current coro is re-entered by the scheduler, while the leave block is |
556 |
executed whenever the current coro is blocked by the scheduler, and |
557 |
also when the containing scope is exited (by whatever means, be it exit, |
558 |
die, last etc.). |
559 |
|
560 |
I<Neither invoking the scheduler, nor exceptions, are allowed within those |
561 |
BLOCKs>. That means: do not even think about calling C<die> without an |
562 |
eval, and do not even think of entering the scheduler in any way. |
563 |
|
564 |
Since both BLOCKs are tied to the current scope, they will automatically |
565 |
be removed when the current scope exits. |
566 |
|
567 |
These functions implement the same concept as C<dynamic-wind> in scheme |
568 |
does, and are useful when you want to localise some resource to a specific |
569 |
coro. |
570 |
|
571 |
They slow down thread switching considerably for coros that use them |
572 |
(about 40% for a BLOCK with a single assignment, so thread switching is |
573 |
still reasonably fast if the handlers are fast). |
574 |
|
575 |
These functions are best understood by an example: The following function |
576 |
will change the current timezone to "Antarctica/South_Pole", which |
577 |
requires a call to C<tzset>, but by using C<on_enter> and C<on_leave>, |
578 |
which remember/change the current timezone and restore the previous |
579 |
value, respectively, the timezone is only changed for the coro that |
580 |
installed those handlers. |
581 |
|
582 |
use POSIX qw(tzset); |
583 |
|
584 |
async { |
585 |
my $old_tz; # store outside TZ value here |
586 |
|
587 |
Coro::on_enter { |
588 |
$old_tz = $ENV{TZ}; # remember the old value |
589 |
|
590 |
$ENV{TZ} = "Antarctica/South_Pole"; |
591 |
tzset; # enable new value |
592 |
}; |
593 |
|
594 |
Coro::on_leave { |
595 |
$ENV{TZ} = $old_tz; |
596 |
tzset; # restore old value |
597 |
}; |
598 |
|
599 |
# at this place, the timezone is Antarctica/South_Pole, |
600 |
# without disturbing the TZ of any other coro. |
601 |
}; |
602 |
|
603 |
This can be used to localise about any resource (locale, uid, current |
604 |
working directory etc.) to a block, despite the existance of other |
605 |
coros. |
606 |
|
607 |
Another interesting example implements time-sliced multitasking using |
608 |
interval timers (this could obviously be optimised, but does the job): |
609 |
|
610 |
# "timeslice" the given block |
611 |
sub timeslice(&) { |
612 |
use Time::HiRes (); |
613 |
|
614 |
Coro::on_enter { |
615 |
# on entering the thread, we set an VTALRM handler to cede |
616 |
$SIG{VTALRM} = sub { cede }; |
617 |
# and then start the interval timer |
618 |
Time::HiRes::setitimer &Time::HiRes::ITIMER_VIRTUAL, 0.01, 0.01; |
619 |
}; |
620 |
Coro::on_leave { |
621 |
# on leaving the thread, we stop the interval timer again |
622 |
Time::HiRes::setitimer &Time::HiRes::ITIMER_VIRTUAL, 0, 0; |
623 |
}; |
624 |
|
625 |
&{+shift}; |
626 |
} |
627 |
|
628 |
# use like this: |
629 |
timeslice { |
630 |
# The following is an endless loop that would normally |
631 |
# monopolise the process. Since it runs in a timesliced |
632 |
# environment, it will regularly cede to other threads. |
633 |
while () { } |
634 |
}; |
635 |
|
636 |
|
637 |
=item killall |
638 |
|
639 |
Kills/terminates/cancels all coros except the currently running one. |
640 |
|
641 |
Note that while this will try to free some of the main interpreter |
642 |
resources if the calling coro isn't the main coro, but one |
643 |
cannot free all of them, so if a coro that is not the main coro |
644 |
calls this function, there will be some one-time resource leak. |
645 |
|
646 |
=cut |
647 |
|
648 |
sub killall { |
649 |
for (Coro::State::list) { |
650 |
$_->cancel |
651 |
if $_ != $current && UNIVERSAL::isa $_, "Coro"; |
652 |
} |
653 |
} |
654 |
|
655 |
=back |
656 |
|
657 |
=head1 CORO OBJECT METHODS |
658 |
|
659 |
These are the methods you can call on coro objects (or to create |
660 |
them). |
661 |
|
662 |
=over 4 |
663 |
|
664 |
=item new Coro \&sub [, @args...] |
665 |
|
666 |
Create a new coro and return it. When the sub returns, the coro |
667 |
automatically terminates as if C<terminate> with the returned values were |
668 |
called. To make the coro run you must first put it into the ready |
669 |
queue by calling the ready method. |
670 |
|
671 |
See C<async> and C<Coro::State::new> for additional info about the |
672 |
coro environment. |
673 |
|
674 |
=cut |
675 |
|
676 |
sub _coro_run { |
677 |
terminate &{+shift}; |
678 |
} |
679 |
|
680 |
=item $success = $coro->ready |
681 |
|
682 |
Put the given coro into the end of its ready queue (there is one |
683 |
queue for each priority) and return true. If the coro is already in |
684 |
the ready queue, do nothing and return false. |
685 |
|
686 |
This ensures that the scheduler will resume this coro automatically |
687 |
once all the coro of higher priority and all coro of the same |
688 |
priority that were put into the ready queue earlier have been resumed. |
689 |
|
690 |
=item $coro->suspend |
691 |
|
692 |
Suspends the specified coro. A suspended coro works just like any other |
693 |
coro, except that the scheduler will not select a suspended coro for |
694 |
execution. |
695 |
|
696 |
Suspending a coro can be useful when you want to keep the coro from |
697 |
running, but you don't want to destroy it, or when you want to temporarily |
698 |
freeze a coro (e.g. for debugging) to resume it later. |
699 |
|
700 |
A scenario for the former would be to suspend all (other) coros after a |
701 |
fork and keep them alive, so their destructors aren't called, but new |
702 |
coros can be created. |
703 |
|
704 |
=item $coro->resume |
705 |
|
706 |
If the specified coro was suspended, it will be resumed. Note that when |
707 |
the coro was in the ready queue when it was suspended, it might have been |
708 |
unreadied by the scheduler, so an activation might have been lost. |
709 |
|
710 |
To avoid this, it is best to put a suspended coro into the ready queue |
711 |
unconditionally, as every synchronisation mechanism must protect itself |
712 |
against spurious wakeups, and the one in the Coro family certainly do |
713 |
that. |
714 |
|
715 |
=item $is_ready = $coro->is_ready |
716 |
|
717 |
Returns true iff the Coro object is in the ready queue. Unless the Coro |
718 |
object gets destroyed, it will eventually be scheduled by the scheduler. |
719 |
|
720 |
=item $is_running = $coro->is_running |
721 |
|
722 |
Returns true iff the Coro object is currently running. Only one Coro object |
723 |
can ever be in the running state (but it currently is possible to have |
724 |
multiple running Coro::States). |
725 |
|
726 |
=item $is_suspended = $coro->is_suspended |
727 |
|
728 |
Returns true iff this Coro object has been suspended. Suspended Coros will |
729 |
not ever be scheduled. |
730 |
|
731 |
=item $coro->cancel (arg...) |
732 |
|
733 |
Terminates the given Coro object and makes it return the given arguments as |
734 |
status (default: an empty list). Never returns if the Coro is the |
735 |
current Coro. |
736 |
|
737 |
The arguments are not copied, but instead will be referenced directly |
738 |
(e.g. if you pass C<$var> and after the call change that variable, then |
739 |
you might change the return values passed to e.g. C<join>, so don't do |
740 |
that). |
741 |
|
742 |
The resources of the Coro are usually freed (or destructed) before this |
743 |
call returns, but this can be delayed for an indefinite amount of time, as |
744 |
in some cases the manager thread has to run first to actually destruct the |
745 |
Coro object. |
746 |
|
747 |
=item $coro->schedule_to |
748 |
|
749 |
Puts the current coro to sleep (like C<Coro::schedule>), but instead |
750 |
of continuing with the next coro from the ready queue, always switch to |
751 |
the given coro object (regardless of priority etc.). The readyness |
752 |
state of that coro isn't changed. |
753 |
|
754 |
This is an advanced method for special cases - I'd love to hear about any |
755 |
uses for this one. |
756 |
|
757 |
=item $coro->cede_to |
758 |
|
759 |
Like C<schedule_to>, but puts the current coro into the ready |
760 |
queue. This has the effect of temporarily switching to the given |
761 |
coro, and continuing some time later. |
762 |
|
763 |
This is an advanced method for special cases - I'd love to hear about any |
764 |
uses for this one. |
765 |
|
766 |
=item $coro->throw ([$scalar]) |
767 |
|
768 |
If C<$throw> is specified and defined, it will be thrown as an exception |
769 |
inside the coro at the next convenient point in time. Otherwise |
770 |
clears the exception object. |
771 |
|
772 |
Coro will check for the exception each time a schedule-like-function |
773 |
returns, i.e. after each C<schedule>, C<cede>, C<< Coro::Semaphore->down |
774 |
>>, C<< Coro::Handle->readable >> and so on. Most of these functions |
775 |
detect this case and return early in case an exception is pending. |
776 |
|
777 |
The exception object will be thrown "as is" with the specified scalar in |
778 |
C<$@>, i.e. if it is a string, no line number or newline will be appended |
779 |
(unlike with C<die>). |
780 |
|
781 |
This can be used as a softer means than C<cancel> to ask a coro to |
782 |
end itself, although there is no guarantee that the exception will lead to |
783 |
termination, and if the exception isn't caught it might well end the whole |
784 |
program. |
785 |
|
786 |
You might also think of C<throw> as being the moral equivalent of |
787 |
C<kill>ing a coro with a signal (in this case, a scalar). |
788 |
|
789 |
=item $coro->join |
790 |
|
791 |
Wait until the coro terminates and return any values given to the |
792 |
C<terminate> or C<cancel> functions. C<join> can be called concurrently |
793 |
from multiple coro, and all will be resumed and given the status |
794 |
return once the C<$coro> terminates. |
795 |
|
796 |
=cut |
797 |
|
798 |
sub join { |
799 |
my $self = shift; |
800 |
|
801 |
unless ($self->{_status}) { |
802 |
my $current = $current; |
803 |
|
804 |
push @{$self->{_on_destroy}}, sub { |
805 |
$current->ready; |
806 |
undef $current; |
807 |
}; |
808 |
|
809 |
&schedule while $current; |
810 |
} |
811 |
|
812 |
wantarray ? @{$self->{_status}} : $self->{_status}[0]; |
813 |
} |
814 |
|
815 |
=item $coro->on_destroy (\&cb) |
816 |
|
817 |
Registers a callback that is called when this coro thread gets destroyed, |
818 |
but before it is joined. The callback gets passed the terminate arguments, |
819 |
if any, and I<must not> die, under any circumstances. |
820 |
|
821 |
There can be any number of C<on_destroy> callbacks per coro. |
822 |
|
823 |
=cut |
824 |
|
825 |
sub on_destroy { |
826 |
my ($self, $cb) = @_; |
827 |
|
828 |
push @{ $self->{_on_destroy} }, $cb; |
829 |
} |
830 |
|
831 |
=item $oldprio = $coro->prio ($newprio) |
832 |
|
833 |
Sets (or gets, if the argument is missing) the priority of the |
834 |
coro thread. Higher priority coro get run before lower priority |
835 |
coros. Priorities are small signed integers (currently -4 .. +3), |
836 |
that you can refer to using PRIO_xxx constants (use the import tag :prio |
837 |
to get then): |
838 |
|
839 |
PRIO_MAX > PRIO_HIGH > PRIO_NORMAL > PRIO_LOW > PRIO_IDLE > PRIO_MIN |
840 |
3 > 1 > 0 > -1 > -3 > -4 |
841 |
|
842 |
# set priority to HIGH |
843 |
current->prio (PRIO_HIGH); |
844 |
|
845 |
The idle coro thread ($Coro::idle) always has a lower priority than any |
846 |
existing coro. |
847 |
|
848 |
Changing the priority of the current coro will take effect immediately, |
849 |
but changing the priority of a coro in the ready queue (but not running) |
850 |
will only take effect after the next schedule (of that coro). This is a |
851 |
bug that will be fixed in some future version. |
852 |
|
853 |
=item $newprio = $coro->nice ($change) |
854 |
|
855 |
Similar to C<prio>, but subtract the given value from the priority (i.e. |
856 |
higher values mean lower priority, just as in UNIX's nice command). |
857 |
|
858 |
=item $olddesc = $coro->desc ($newdesc) |
859 |
|
860 |
Sets (or gets in case the argument is missing) the description for this |
861 |
coro thread. This is just a free-form string you can associate with a |
862 |
coro. |
863 |
|
864 |
This method simply sets the C<< $coro->{desc} >> member to the given |
865 |
string. You can modify this member directly if you wish, and in fact, this |
866 |
is often preferred to indicate major processing states that cna then be |
867 |
seen for example in a L<Coro::Debug> session: |
868 |
|
869 |
sub my_long_function { |
870 |
local $Coro::current->{desc} = "now in my_long_function"; |
871 |
... |
872 |
$Coro::current->{desc} = "my_long_function: phase 1"; |
873 |
... |
874 |
$Coro::current->{desc} = "my_long_function: phase 2"; |
875 |
... |
876 |
} |
877 |
|
878 |
=cut |
879 |
|
880 |
sub desc { |
881 |
my $old = $_[0]{desc}; |
882 |
$_[0]{desc} = $_[1] if @_ > 1; |
883 |
$old; |
884 |
} |
885 |
|
886 |
sub transfer { |
887 |
require Carp; |
888 |
Carp::croak ("You must not call ->transfer on Coro objects. Use Coro::State objects or the ->schedule_to method. Caught"); |
889 |
} |
890 |
|
891 |
=back |
892 |
|
893 |
=head1 GLOBAL FUNCTIONS |
894 |
|
895 |
=over 4 |
896 |
|
897 |
=item Coro::nready |
898 |
|
899 |
Returns the number of coro that are currently in the ready state, |
900 |
i.e. that can be switched to by calling C<schedule> directory or |
901 |
indirectly. The value C<0> means that the only runnable coro is the |
902 |
currently running one, so C<cede> would have no effect, and C<schedule> |
903 |
would cause a deadlock unless there is an idle handler that wakes up some |
904 |
coro. |
905 |
|
906 |
=item my $guard = Coro::guard { ... } |
907 |
|
908 |
This function still exists, but is deprecated. Please use the |
909 |
C<Guard::guard> function instead. |
910 |
|
911 |
=cut |
912 |
|
913 |
BEGIN { *guard = \&Guard::guard } |
914 |
|
915 |
=item unblock_sub { ... } |
916 |
|
917 |
This utility function takes a BLOCK or code reference and "unblocks" it, |
918 |
returning a new coderef. Unblocking means that calling the new coderef |
919 |
will return immediately without blocking, returning nothing, while the |
920 |
original code ref will be called (with parameters) from within another |
921 |
coro. |
922 |
|
923 |
The reason this function exists is that many event libraries (such as |
924 |
the venerable L<Event|Event> module) are not thread-safe (a weaker form |
925 |
of reentrancy). This means you must not block within event callbacks, |
926 |
otherwise you might suffer from crashes or worse. The only event library |
927 |
currently known that is safe to use without C<unblock_sub> is L<EV> (but |
928 |
you might still run into deadlocks if all event loops are blocked). |
929 |
|
930 |
Coro will try to catch you when you block in the event loop |
931 |
("FATAL:$Coro::IDLE blocked itself"), but this is just best effort and |
932 |
only works when you do not run your own event loop. |
933 |
|
934 |
This function allows your callbacks to block by executing them in another |
935 |
coro where it is safe to block. One example where blocking is handy |
936 |
is when you use the L<Coro::AIO|Coro::AIO> functions to save results to |
937 |
disk, for example. |
938 |
|
939 |
In short: simply use C<unblock_sub { ... }> instead of C<sub { ... }> when |
940 |
creating event callbacks that want to block. |
941 |
|
942 |
If your handler does not plan to block (e.g. simply sends a message to |
943 |
another coro, or puts some other coro into the ready queue), there is |
944 |
no reason to use C<unblock_sub>. |
945 |
|
946 |
Note that you also need to use C<unblock_sub> for any other callbacks that |
947 |
are indirectly executed by any C-based event loop. For example, when you |
948 |
use a module that uses L<AnyEvent> (and you use L<Coro::AnyEvent>) and it |
949 |
provides callbacks that are the result of some event callback, then you |
950 |
must not block either, or use C<unblock_sub>. |
951 |
|
952 |
=cut |
953 |
|
954 |
our @unblock_queue; |
955 |
|
956 |
# we create a special coro because we want to cede, |
957 |
# to reduce pressure on the coro pool (because most callbacks |
958 |
# return immediately and can be reused) and because we cannot cede |
959 |
# inside an event callback. |
960 |
our $unblock_scheduler = new Coro sub { |
961 |
while () { |
962 |
while (my $cb = pop @unblock_queue) { |
963 |
&async_pool (@$cb); |
964 |
|
965 |
# for short-lived callbacks, this reduces pressure on the coro pool |
966 |
# as the chance is very high that the async_poll coro will be back |
967 |
# in the idle state when cede returns |
968 |
cede; |
969 |
} |
970 |
schedule; # sleep well |
971 |
} |
972 |
}; |
973 |
$unblock_scheduler->{desc} = "[unblock_sub scheduler]"; |
974 |
|
975 |
sub unblock_sub(&) { |
976 |
my $cb = shift; |
977 |
|
978 |
sub { |
979 |
unshift @unblock_queue, [$cb, @_]; |
980 |
$unblock_scheduler->ready; |
981 |
} |
982 |
} |
983 |
|
984 |
=item $cb = rouse_cb |
985 |
|
986 |
Create and return a "rouse callback". That's a code reference that, |
987 |
when called, will remember a copy of its arguments and notify the owner |
988 |
coro of the callback. |
989 |
|
990 |
See the next function. |
991 |
|
992 |
=item @args = rouse_wait [$cb] |
993 |
|
994 |
Wait for the specified rouse callback (or the last one that was created in |
995 |
this coro). |
996 |
|
997 |
As soon as the callback is invoked (or when the callback was invoked |
998 |
before C<rouse_wait>), it will return the arguments originally passed to |
999 |
the rouse callback. In scalar context, that means you get the I<last> |
1000 |
argument, just as if C<rouse_wait> had a C<return ($a1, $a2, $a3...)> |
1001 |
statement at the end. |
1002 |
|
1003 |
See the section B<HOW TO WAIT FOR A CALLBACK> for an actual usage example. |
1004 |
|
1005 |
=back |
1006 |
|
1007 |
=cut |
1008 |
|
1009 |
for my $module (qw(Channel RWLock Semaphore SemaphoreSet Signal Specific)) { |
1010 |
my $old = defined &{"Coro::$module\::new"} && \&{"Coro::$module\::new"}; |
1011 |
|
1012 |
*{"Coro::$module\::new"} = sub { |
1013 |
require "Coro/$module.pm"; |
1014 |
|
1015 |
# some modules have their new predefined in State.xs, some don't |
1016 |
*{"Coro::$module\::new"} = $old |
1017 |
if $old; |
1018 |
|
1019 |
goto &{"Coro::$module\::new"}; |
1020 |
}; |
1021 |
} |
1022 |
|
1023 |
1; |
1024 |
|
1025 |
=head1 HOW TO WAIT FOR A CALLBACK |
1026 |
|
1027 |
It is very common for a coro to wait for some callback to be |
1028 |
called. This occurs naturally when you use coro in an otherwise |
1029 |
event-based program, or when you use event-based libraries. |
1030 |
|
1031 |
These typically register a callback for some event, and call that callback |
1032 |
when the event occured. In a coro, however, you typically want to |
1033 |
just wait for the event, simplyifying things. |
1034 |
|
1035 |
For example C<< AnyEvent->child >> registers a callback to be called when |
1036 |
a specific child has exited: |
1037 |
|
1038 |
my $child_watcher = AnyEvent->child (pid => $pid, cb => sub { ... }); |
1039 |
|
1040 |
But from within a coro, you often just want to write this: |
1041 |
|
1042 |
my $status = wait_for_child $pid; |
1043 |
|
1044 |
Coro offers two functions specifically designed to make this easy, |
1045 |
C<Coro::rouse_cb> and C<Coro::rouse_wait>. |
1046 |
|
1047 |
The first function, C<rouse_cb>, generates and returns a callback that, |
1048 |
when invoked, will save its arguments and notify the coro that |
1049 |
created the callback. |
1050 |
|
1051 |
The second function, C<rouse_wait>, waits for the callback to be called |
1052 |
(by calling C<schedule> to go to sleep) and returns the arguments |
1053 |
originally passed to the callback. |
1054 |
|
1055 |
Using these functions, it becomes easy to write the C<wait_for_child> |
1056 |
function mentioned above: |
1057 |
|
1058 |
sub wait_for_child($) { |
1059 |
my ($pid) = @_; |
1060 |
|
1061 |
my $watcher = AnyEvent->child (pid => $pid, cb => Coro::rouse_cb); |
1062 |
|
1063 |
my ($rpid, $rstatus) = Coro::rouse_wait; |
1064 |
$rstatus |
1065 |
} |
1066 |
|
1067 |
In the case where C<rouse_cb> and C<rouse_wait> are not flexible enough, |
1068 |
you can roll your own, using C<schedule>: |
1069 |
|
1070 |
sub wait_for_child($) { |
1071 |
my ($pid) = @_; |
1072 |
|
1073 |
# store the current coro in $current, |
1074 |
# and provide result variables for the closure passed to ->child |
1075 |
my $current = $Coro::current; |
1076 |
my ($done, $rstatus); |
1077 |
|
1078 |
# pass a closure to ->child |
1079 |
my $watcher = AnyEvent->child (pid => $pid, cb => sub { |
1080 |
$rstatus = $_[1]; # remember rstatus |
1081 |
$done = 1; # mark $rstatus as valud |
1082 |
}); |
1083 |
|
1084 |
# wait until the closure has been called |
1085 |
schedule while !$done; |
1086 |
|
1087 |
$rstatus |
1088 |
} |
1089 |
|
1090 |
|
1091 |
=head1 BUGS/LIMITATIONS |
1092 |
|
1093 |
=over 4 |
1094 |
|
1095 |
=item fork with pthread backend |
1096 |
|
1097 |
When Coro is compiled using the pthread backend (which isn't recommended |
1098 |
but required on many BSDs as their libcs are completely broken), then |
1099 |
coro will not survive a fork. There is no known workaround except to |
1100 |
fix your libc and use a saner backend. |
1101 |
|
1102 |
=item perl process emulation ("threads") |
1103 |
|
1104 |
This module is not perl-pseudo-thread-safe. You should only ever use this |
1105 |
module from the first thread (this requirement might be removed in the |
1106 |
future to allow per-thread schedulers, but Coro::State does not yet allow |
1107 |
this). I recommend disabling thread support and using processes, as having |
1108 |
the windows process emulation enabled under unix roughly halves perl |
1109 |
performance, even when not used. |
1110 |
|
1111 |
=item coro switching is not signal safe |
1112 |
|
1113 |
You must not switch to another coro from within a signal handler (only |
1114 |
relevant with %SIG - most event libraries provide safe signals), I<unless> |
1115 |
you are sure you are not interrupting a Coro function. |
1116 |
|
1117 |
That means you I<MUST NOT> call any function that might "block" the |
1118 |
current coro - C<cede>, C<schedule> C<< Coro::Semaphore->down >> or |
1119 |
anything that calls those. Everything else, including calling C<ready>, |
1120 |
works. |
1121 |
|
1122 |
=back |
1123 |
|
1124 |
|
1125 |
=head1 WINDOWS PROCESS EMULATION |
1126 |
|
1127 |
A great many people seem to be confused about ithreads (for example, Chip |
1128 |
Salzenberg called me unintelligent, incapable, stupid and gullible, |
1129 |
while in the same mail making rather confused statements about perl |
1130 |
ithreads (for example, that memory or files would be shared), showing his |
1131 |
lack of understanding of this area - if it is hard to understand for Chip, |
1132 |
it is probably not obvious to everybody). |
1133 |
|
1134 |
What follows is an ultra-condensed version of my talk about threads in |
1135 |
scripting languages given on the perl workshop 2009: |
1136 |
|
1137 |
The so-called "ithreads" were originally implemented for two reasons: |
1138 |
first, to (badly) emulate unix processes on native win32 perls, and |
1139 |
secondly, to replace the older, real thread model ("5.005-threads"). |
1140 |
|
1141 |
It does that by using threads instead of OS processes. The difference |
1142 |
between processes and threads is that threads share memory (and other |
1143 |
state, such as files) between threads within a single process, while |
1144 |
processes do not share anything (at least not semantically). That |
1145 |
means that modifications done by one thread are seen by others, while |
1146 |
modifications by one process are not seen by other processes. |
1147 |
|
1148 |
The "ithreads" work exactly like that: when creating a new ithreads |
1149 |
process, all state is copied (memory is copied physically, files and code |
1150 |
is copied logically). Afterwards, it isolates all modifications. On UNIX, |
1151 |
the same behaviour can be achieved by using operating system processes, |
1152 |
except that UNIX typically uses hardware built into the system to do this |
1153 |
efficiently, while the windows process emulation emulates this hardware in |
1154 |
software (rather efficiently, but of course it is still much slower than |
1155 |
dedicated hardware). |
1156 |
|
1157 |
As mentioned before, loading code, modifying code, modifying data |
1158 |
structures and so on is only visible in the ithreads process doing the |
1159 |
modification, not in other ithread processes within the same OS process. |
1160 |
|
1161 |
This is why "ithreads" do not implement threads for perl at all, only |
1162 |
processes. What makes it so bad is that on non-windows platforms, you can |
1163 |
actually take advantage of custom hardware for this purpose (as evidenced |
1164 |
by the forks module, which gives you the (i-) threads API, just much |
1165 |
faster). |
1166 |
|
1167 |
Sharing data is in the i-threads model is done by transfering data |
1168 |
structures between threads using copying semantics, which is very slow - |
1169 |
shared data simply does not exist. Benchmarks using i-threads which are |
1170 |
communication-intensive show extremely bad behaviour with i-threads (in |
1171 |
fact, so bad that Coro, which cannot take direct advantage of multiple |
1172 |
CPUs, is often orders of magnitude faster because it shares data using |
1173 |
real threads, refer to my talk for details). |
1174 |
|
1175 |
As summary, i-threads *use* threads to implement processes, while |
1176 |
the compatible forks module *uses* processes to emulate, uhm, |
1177 |
processes. I-threads slow down every perl program when enabled, and |
1178 |
outside of windows, serve no (or little) practical purpose, but |
1179 |
disadvantages every single-threaded Perl program. |
1180 |
|
1181 |
This is the reason that I try to avoid the name "ithreads", as it is |
1182 |
misleading as it implies that it implements some kind of thread model for |
1183 |
perl, and prefer the name "windows process emulation", which describes the |
1184 |
actual use and behaviour of it much better. |
1185 |
|
1186 |
=head1 SEE ALSO |
1187 |
|
1188 |
Event-Loop integration: L<Coro::AnyEvent>, L<Coro::EV>, L<Coro::Event>. |
1189 |
|
1190 |
Debugging: L<Coro::Debug>. |
1191 |
|
1192 |
Support/Utility: L<Coro::Specific>, L<Coro::Util>. |
1193 |
|
1194 |
Locking and IPC: L<Coro::Signal>, L<Coro::Channel>, L<Coro::Semaphore>, |
1195 |
L<Coro::SemaphoreSet>, L<Coro::RWLock>. |
1196 |
|
1197 |
I/O and Timers: L<Coro::Timer>, L<Coro::Handle>, L<Coro::Socket>, L<Coro::AIO>. |
1198 |
|
1199 |
Compatibility with other modules: L<Coro::LWP> (but see also L<AnyEvent::HTTP> for |
1200 |
a better-working alternative), L<Coro::BDB>, L<Coro::Storable>, |
1201 |
L<Coro::Select>. |
1202 |
|
1203 |
XS API: L<Coro::MakeMaker>. |
1204 |
|
1205 |
Low level Configuration, Thread Environment, Continuations: L<Coro::State>. |
1206 |
|
1207 |
=head1 AUTHOR |
1208 |
|
1209 |
Marc Lehmann <schmorp@schmorp.de> |
1210 |
http://home.schmorp.de/ |
1211 |
|
1212 |
=cut |
1213 |
|