| 1 |
use Coro; |
| 2 |
use Coro::Semaphore; |
| 3 |
use Coro::Event; |
| 4 |
use Coro::Socket; |
| 5 |
use Coro::Signal; |
| 6 |
|
| 7 |
use HTTP::Date; |
| 8 |
use POSIX (); |
| 9 |
|
| 10 |
no utf8; |
| 11 |
use bytes; |
| 12 |
|
| 13 |
# at least on my machine, this thingy serves files |
| 14 |
# quite a bit faster than apache, ;) |
| 15 |
# and quite a bit slower than thttpd :( |
| 16 |
|
| 17 |
$SIG{PIPE} = 'IGNORE'; |
| 18 |
|
| 19 |
our $accesslog; |
| 20 |
|
| 21 |
if ($ACCESS_LOG) { |
| 22 |
use IO::Handle; |
| 23 |
open $accesslog, ">>$ACCESS_LOG" |
| 24 |
or die "$ACCESS_LOG: $!"; |
| 25 |
$accesslog->autoflush(1); |
| 26 |
} |
| 27 |
|
| 28 |
sub slog { |
| 29 |
my $level = shift; |
| 30 |
my $format = shift; |
| 31 |
printf "---: $format\n", @_; |
| 32 |
} |
| 33 |
|
| 34 |
our $connections = new Coro::Semaphore $MAX_CONNECTS || 250; |
| 35 |
our $httpevent = new Coro::Signal; |
| 36 |
|
| 37 |
our $wait_factor = 0.95; |
| 38 |
|
| 39 |
our @transfers = ( |
| 40 |
(new Coro::Semaphore $MAX_TRANSFERS_SMALL), |
| 41 |
(new Coro::Semaphore $MAX_TRANSFERS_LARGE), |
| 42 |
); |
| 43 |
|
| 44 |
my @newcons; |
| 45 |
my @pool; |
| 46 |
|
| 47 |
# one "execution thread" |
| 48 |
sub handler { |
| 49 |
while () { |
| 50 |
if (@newcons) { |
| 51 |
eval { |
| 52 |
conn->new(@{pop @newcons})->handle; |
| 53 |
}; |
| 54 |
slog 1, "$@" if $@ && !ref $@; |
| 55 |
$connections->up; |
| 56 |
} else { |
| 57 |
last if @pool >= $MAX_POOL; |
| 58 |
push @pool, $Coro::current; |
| 59 |
schedule; |
| 60 |
} |
| 61 |
} |
| 62 |
} |
| 63 |
|
| 64 |
sub listen_on { |
| 65 |
my $listen = $_[0]; |
| 66 |
|
| 67 |
push @listen_sockets, $listen; |
| 68 |
|
| 69 |
# the "main thread" |
| 70 |
async { |
| 71 |
slog 1, "accepting connections"; |
| 72 |
while () { |
| 73 |
$connections->down; |
| 74 |
push @newcons, [$listen->accept]; |
| 75 |
#slog 3, "accepted @$connections ".scalar(@pool); |
| 76 |
if (@pool) { |
| 77 |
(pop @pool)->ready; |
| 78 |
} else { |
| 79 |
async \&handler; |
| 80 |
} |
| 81 |
|
| 82 |
} |
| 83 |
}; |
| 84 |
} |
| 85 |
|
| 86 |
my $http_port = new Coro::Socket |
| 87 |
LocalAddr => $SERVER_HOST, |
| 88 |
LocalPort => $SERVER_PORT, |
| 89 |
ReuseAddr => 1, |
| 90 |
Listen => 50, |
| 91 |
or die "unable to start server"; |
| 92 |
|
| 93 |
listen_on $http_port; |
| 94 |
|
| 95 |
if ($SERVER_PORT2) { |
| 96 |
my $http_port = new Coro::Socket |
| 97 |
LocalAddr => $SERVER_HOST, |
| 98 |
LocalPort => $SERVER_PORT2, |
| 99 |
ReuseAddr => 1, |
| 100 |
Listen => 50, |
| 101 |
or die "unable to start server"; |
| 102 |
|
| 103 |
listen_on $http_port; |
| 104 |
} |
| 105 |
|
| 106 |
our $NOW; |
| 107 |
our $HTTP_NOW; |
| 108 |
|
| 109 |
Event->timer(interval => 1, hard => 1, cb => sub { |
| 110 |
$NOW = time; |
| 111 |
$HTTP_NOW = time2str $NOW; |
| 112 |
})->now; |
| 113 |
|
| 114 |
package conn; |
| 115 |
|
| 116 |
use Socket; |
| 117 |
use HTTP::Date; |
| 118 |
use Convert::Scalar 'weaken'; |
| 119 |
use Linux::AIO; |
| 120 |
|
| 121 |
Linux::AIO::min_parallel $::AIO_PARALLEL; |
| 122 |
|
| 123 |
Event->io(fd => Linux::AIO::poll_fileno, |
| 124 |
poll => 'r', async => 1, |
| 125 |
cb => \&Linux::AIO::poll_cb); |
| 126 |
|
| 127 |
our %conn; # $conn{ip}{self} => connobj |
| 128 |
our %uri; # $uri{ip}{uri}{self} |
| 129 |
our %blocked; |
| 130 |
our %mimetype; |
| 131 |
|
| 132 |
sub read_mimetypes { |
| 133 |
local *M; |
| 134 |
if (open M, "<mime_types") { |
| 135 |
while (<M>) { |
| 136 |
if (/^([^#]\S+)\t+(\S+)$/) { |
| 137 |
$mimetype{lc $1} = $2; |
| 138 |
} |
| 139 |
} |
| 140 |
} else { |
| 141 |
print "cannot open mime_types\n"; |
| 142 |
} |
| 143 |
} |
| 144 |
|
| 145 |
read_mimetypes; |
| 146 |
|
| 147 |
sub new { |
| 148 |
my $class = shift; |
| 149 |
my $fh = shift; |
| 150 |
my $peername = shift; |
| 151 |
my $self = bless { fh => $fh }, $class; |
| 152 |
my (undef, $iaddr) = unpack_sockaddr_in $peername |
| 153 |
or $self->err(500, "unable to decode peername"); |
| 154 |
|
| 155 |
$self->{remote_addr} = |
| 156 |
$self->{remote_id} = inet_ntoa $iaddr; |
| 157 |
$self->{time} = $::NOW; |
| 158 |
|
| 159 |
weaken ($Coro::current->{conn} = $self); |
| 160 |
|
| 161 |
$::conns++; |
| 162 |
|
| 163 |
$self; |
| 164 |
} |
| 165 |
|
| 166 |
sub DESTROY { |
| 167 |
my $self = shift; |
| 168 |
$::conns--; |
| 169 |
$self->eoconn; |
| 170 |
} |
| 171 |
|
| 172 |
# end of connection |
| 173 |
sub eoconn { |
| 174 |
my $self = shift; |
| 175 |
|
| 176 |
# clean up hints |
| 177 |
delete $conn{$self->{remote_id}}{$self*1}; |
| 178 |
delete $uri{$self->{remote_id}}{$self->{uri}}{$self*1}; |
| 179 |
|
| 180 |
$httpevent->broadcast; |
| 181 |
} |
| 182 |
|
| 183 |
sub slog { |
| 184 |
my $self = shift; |
| 185 |
main::slog($_[0], "$self->{remote_id}> $_[1]"); |
| 186 |
} |
| 187 |
|
| 188 |
sub response { |
| 189 |
my ($self, $code, $msg, $hdr, $content) = @_; |
| 190 |
my $res = "HTTP/1.1 $code $msg\015\012"; |
| 191 |
|
| 192 |
if (exists $hdr->{Connection}) { |
| 193 |
if ($hdr->{Connection} =~ /close/) { |
| 194 |
$self->{h}{connection} = "close" |
| 195 |
} |
| 196 |
} else { |
| 197 |
if ($self->{version} < 1.1) { |
| 198 |
if ($self->{h}{connection} =~ /keep-alive/i) { |
| 199 |
$hdr->{Connection} = "Keep-Alive"; |
| 200 |
} else { |
| 201 |
$self->{h}{connection} = "close" |
| 202 |
} |
| 203 |
} |
| 204 |
} |
| 205 |
|
| 206 |
$res .= "Date: $HTTP_NOW\015\012"; |
| 207 |
|
| 208 |
while (my ($h, $v) = each %$hdr) { |
| 209 |
$res .= "$h: $v\015\012" |
| 210 |
} |
| 211 |
$res .= "\015\012"; |
| 212 |
|
| 213 |
$res .= $content if defined $content and $self->{method} ne "HEAD"; |
| 214 |
|
| 215 |
my $log = (POSIX::strftime "%Y-%m-%d %H:%M:%S", gmtime $NOW). |
| 216 |
" $self->{remote_id} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}. |
| 217 |
" \"$self->{h}{referer}\"\n"; |
| 218 |
|
| 219 |
print $accesslog $log if $accesslog; |
| 220 |
print STDERR $log; |
| 221 |
|
| 222 |
$self->{written} += |
| 223 |
print {$self->{fh}} $res; |
| 224 |
} |
| 225 |
|
| 226 |
sub err { |
| 227 |
my $self = shift; |
| 228 |
my ($code, $msg, $hdr, $content) = @_; |
| 229 |
|
| 230 |
unless (defined $content) { |
| 231 |
$content = "$code $msg\n"; |
| 232 |
$hdr->{"Content-Type"} = "text/plain"; |
| 233 |
$hdr->{"Content-Length"} = length $content; |
| 234 |
} |
| 235 |
$hdr->{"Connection"} = "close"; |
| 236 |
|
| 237 |
$self->response($code, $msg, $hdr, $content); |
| 238 |
|
| 239 |
die bless {}, err::; |
| 240 |
} |
| 241 |
|
| 242 |
sub handle { |
| 243 |
my $self = shift; |
| 244 |
my $fh = $self->{fh}; |
| 245 |
|
| 246 |
my $host; |
| 247 |
|
| 248 |
$fh->timeout($::REQ_TIMEOUT); |
| 249 |
while() { |
| 250 |
$self->{reqs}++; |
| 251 |
|
| 252 |
# read request and parse first line |
| 253 |
my $req = $fh->readline("\015\012\015\012"); |
| 254 |
|
| 255 |
unless (defined $req) { |
| 256 |
if (exists $self->{version}) { |
| 257 |
last; |
| 258 |
} else { |
| 259 |
$self->err(408, "request timeout"); |
| 260 |
} |
| 261 |
} |
| 262 |
|
| 263 |
$self->{h} = {}; |
| 264 |
|
| 265 |
$fh->timeout($::RES_TIMEOUT); |
| 266 |
|
| 267 |
$req =~ /^(?:\015\012)? |
| 268 |
(GET|HEAD) \040+ |
| 269 |
([^\040]+) \040+ |
| 270 |
HTTP\/([0-9]+\.[0-9]+) |
| 271 |
\015\012/gx |
| 272 |
or $self->err(405, "method not allowed", { Allow => "GET,HEAD" }); |
| 273 |
|
| 274 |
$self->{method} = $1; |
| 275 |
$self->{uri} = $2; |
| 276 |
$self->{version} = $3; |
| 277 |
|
| 278 |
$3 =~ /^1\./ |
| 279 |
or $self->err(506, "http protocol version $3 not supported"); |
| 280 |
|
| 281 |
# parse headers |
| 282 |
{ |
| 283 |
my (%hdr, $h, $v); |
| 284 |
|
| 285 |
$hdr{lc $1} .= ",$2" |
| 286 |
while $req =~ /\G |
| 287 |
([^:\000-\040]+): |
| 288 |
[\008\040]* |
| 289 |
((?: [^\015\012]+ | \015\012[\008\040] )*) |
| 290 |
\015\012 |
| 291 |
/gxc; |
| 292 |
|
| 293 |
$req =~ /\G\015\012$/ |
| 294 |
or $self->err(400, "bad request"); |
| 295 |
|
| 296 |
$self->{h}{$h} = substr $v, 1 |
| 297 |
while ($h, $v) = each %hdr; |
| 298 |
} |
| 299 |
|
| 300 |
# remote id should be unique per user |
| 301 |
my $id = $self->{remote_addr}; |
| 302 |
|
| 303 |
if (exists $self->{h}{"client-ip"}) { |
| 304 |
$id .= "[".$self->{h}{"client-ip"}."]"; |
| 305 |
} elsif (exists $self->{h}{"x-forwarded-for"}) { |
| 306 |
$id .= "[".$self->{h}{"x-forwarded-for"}."]"; |
| 307 |
} |
| 308 |
|
| 309 |
$self->{remote_id} = $id; |
| 310 |
|
| 311 |
if ($blocked{$id}) { |
| 312 |
$self->err_blocked($blocked{$id}) |
| 313 |
if $blocked{$id} > $::NOW; |
| 314 |
|
| 315 |
delete $blocked{$id}; |
| 316 |
} |
| 317 |
|
| 318 |
if (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 319 |
my $delay = $::PER_TIMEOUT + $::NOW + 15; |
| 320 |
while (%{$conn{$id}} >= $::MAX_CONN_IP) { |
| 321 |
if ($delay < $::NOW) { |
| 322 |
$self->slog(2, "blocked ip $id"); |
| 323 |
$self->err_blocked; |
| 324 |
} else { |
| 325 |
$httpevent->wait; |
| 326 |
} |
| 327 |
} |
| 328 |
} |
| 329 |
|
| 330 |
# find out server name and port |
| 331 |
if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) { |
| 332 |
$host = $1; |
| 333 |
} else { |
| 334 |
$host = $self->{h}{host}; |
| 335 |
} |
| 336 |
|
| 337 |
if (defined $host) { |
| 338 |
$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80; |
| 339 |
} else { |
| 340 |
($self->{server_port}, $host) |
| 341 |
= unpack_sockaddr_in $self->{fh}->sockname |
| 342 |
or $self->err(500, "unable to get socket name"); |
| 343 |
$host = inet_ntoa $host; |
| 344 |
} |
| 345 |
|
| 346 |
$self->{server_name} = $host; |
| 347 |
|
| 348 |
# enter ourselves into various lists |
| 349 |
weaken ($conn{$id}{$self*1} = $self); |
| 350 |
weaken ($uri{$id}{$self->{uri}}{$self*1} = $self); |
| 351 |
|
| 352 |
eval { |
| 353 |
$self->map_uri; |
| 354 |
$self->respond; |
| 355 |
}; |
| 356 |
|
| 357 |
$self->eoconn; |
| 358 |
|
| 359 |
die if $@ && !ref $@; |
| 360 |
|
| 361 |
last if $self->{h}{connection} =~ /close/; |
| 362 |
|
| 363 |
$httpevent->broadcast; |
| 364 |
|
| 365 |
$fh->timeout($::PER_TIMEOUT); |
| 366 |
} |
| 367 |
} |
| 368 |
|
| 369 |
# uri => path mapping |
| 370 |
sub map_uri { |
| 371 |
my $self = shift; |
| 372 |
my $host = $self->{server_name}; |
| 373 |
my $uri = $self->{uri}; |
| 374 |
|
| 375 |
# some massaging, also makes it more secure |
| 376 |
$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge; |
| 377 |
$uri =~ s%//+%/%g; |
| 378 |
$uri =~ s%/\.(?=/|$)%%g; |
| 379 |
1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%; |
| 380 |
|
| 381 |
$uri =~ m%^/?\.\.(?=/|$)% |
| 382 |
and $self->err(400, "bad request"); |
| 383 |
|
| 384 |
$self->{name} = $uri; |
| 385 |
|
| 386 |
# now do the path mapping |
| 387 |
$self->{path} = "$::DOCROOT/$host$uri"; |
| 388 |
|
| 389 |
$self->access_check; |
| 390 |
} |
| 391 |
|
| 392 |
sub _cgi { |
| 393 |
my $self = shift; |
| 394 |
my $path = shift; |
| 395 |
my $fh; |
| 396 |
|
| 397 |
# no two-way xxx supported |
| 398 |
if (0 == fork) { |
| 399 |
open STDOUT, ">&".fileno($self->{fh}); |
| 400 |
if (chdir $::DOCROOT) { |
| 401 |
$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike |
| 402 |
$ENV{HTTP_HOST} = $self->{server_name}; |
| 403 |
$ENV{HTTP_PORT} = $self->{server_port}; |
| 404 |
$ENV{SCRIPT_NAME} = $self->{name}; |
| 405 |
exec $path; |
| 406 |
} |
| 407 |
Coro::State::_exit(0); |
| 408 |
} else { |
| 409 |
die; |
| 410 |
} |
| 411 |
} |
| 412 |
|
| 413 |
sub server_hostport { |
| 414 |
$_[0]{server_port} == 80 |
| 415 |
? $_[0]{server_name} |
| 416 |
: "$_[0]{server_name}:$_[0]{server_port}"; |
| 417 |
} |
| 418 |
|
| 419 |
sub respond { |
| 420 |
my $self = shift; |
| 421 |
my $path = $self->{path}; |
| 422 |
|
| 423 |
if ($self->{name} =~ s%^/internal/([^/]+)%%) { |
| 424 |
if ($::internal{$1}) { |
| 425 |
$::internal{$1}->($self); |
| 426 |
} else { |
| 427 |
$self->err(404, "not found"); |
| 428 |
} |
| 429 |
} else { |
| 430 |
|
| 431 |
stat $path |
| 432 |
or $self->err(404, "not found"); |
| 433 |
|
| 434 |
$self->{stat} = [stat _]; |
| 435 |
|
| 436 |
# idiotic netscape sends idiotic headers AGAIN |
| 437 |
my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/ |
| 438 |
? str2time $1 : 0; |
| 439 |
|
| 440 |
if (-d _ && -r _) { |
| 441 |
# directory |
| 442 |
if ($path !~ /\/$/) { |
| 443 |
# create a redirect to get the trailing "/" |
| 444 |
# we don't try to avoid the :80 |
| 445 |
$self->err(301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" }); |
| 446 |
} else { |
| 447 |
$ims < $self->{stat}[9] |
| 448 |
or $self->err(304, "not modified"); |
| 449 |
|
| 450 |
if (-r "$path/index.html") { |
| 451 |
# replace directory "size" by index.html filesize |
| 452 |
$self->{stat}[7] = (stat ($self->{path} .= "/index.html"))[7]; |
| 453 |
$self->handle_file; |
| 454 |
} else { |
| 455 |
$self->handle_dir; |
| 456 |
} |
| 457 |
} |
| 458 |
} elsif (-f _ && -r _) { |
| 459 |
-x _ and $self->err(403, "forbidden"); |
| 460 |
$self->handle_file; |
| 461 |
} else { |
| 462 |
$self->err(404, "not found"); |
| 463 |
} |
| 464 |
} |
| 465 |
} |
| 466 |
|
| 467 |
sub handle_dir { |
| 468 |
my $self = shift; |
| 469 |
my $idx = $self->diridx; |
| 470 |
|
| 471 |
$self->response(200, "ok", |
| 472 |
{ |
| 473 |
"Content-Type" => "text/html", |
| 474 |
"Content-Length" => length $idx, |
| 475 |
#d# directories change all the time, so X- |
| 476 |
"X-Last-Modified" => time2str ((stat _)[9]), |
| 477 |
}, |
| 478 |
$idx); |
| 479 |
} |
| 480 |
|
| 481 |
sub handle_file { |
| 482 |
my $self = shift; |
| 483 |
my $length = $self->{stat}[7]; |
| 484 |
my $queue = $::transfers[$length >= $::TRANSFER_SMALL]; |
| 485 |
my $hdr = { |
| 486 |
"Last-Modified" => time2str ((stat _)[9]), |
| 487 |
}; |
| 488 |
|
| 489 |
my @code = (200, "ok"); |
| 490 |
my ($l, $h); |
| 491 |
|
| 492 |
if ($self->{h}{range} =~ /^bytes=(.*)$/) { |
| 493 |
for (split /,/, $1) { |
| 494 |
if (/^-(\d+)$/) { |
| 495 |
($l, $h) = ($length - $1, $length - 1); |
| 496 |
} elsif (/^(\d+)-(\d*)$/) { |
| 497 |
($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1); |
| 498 |
} else { |
| 499 |
($l, $h) = (0, $length - 1); |
| 500 |
goto ignore; |
| 501 |
} |
| 502 |
goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l; |
| 503 |
} |
| 504 |
$hdr->{"Content-Range"} = "bytes */$length"; |
| 505 |
$hdr->{"Content-Length"} = $length; |
| 506 |
$self->err(416, "not satisfiable", $hdr, ""); |
| 507 |
|
| 508 |
satisfiable: |
| 509 |
# check for segmented downloads |
| 510 |
if ($l && $::NO_SEGMENTED) { |
| 511 |
my $delay = $::NOW + $::PER_TIMEOUT + 15; |
| 512 |
while (%{$uri{$self->{remote_id}}{$self->{uri}}} > 1) { |
| 513 |
if ($delay <= $::NOW) { |
| 514 |
$self->err_segmented_download; |
| 515 |
} else { |
| 516 |
$httpevent->wait; |
| 517 |
} |
| 518 |
} |
| 519 |
} |
| 520 |
|
| 521 |
$hdr->{"Content-Range"} = "bytes $l-$h/$length"; |
| 522 |
@code = (206, "partial content"); |
| 523 |
$length = $h - $l + 1; |
| 524 |
|
| 525 |
ignore: |
| 526 |
} else { |
| 527 |
($l, $h) = (0, $length - 1); |
| 528 |
} |
| 529 |
|
| 530 |
$self->{path} =~ /\.([^.]+)$/; |
| 531 |
$hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream"; |
| 532 |
$hdr->{"Content-Length"} = $length; |
| 533 |
|
| 534 |
$self->response(@code, $hdr, ""); |
| 535 |
|
| 536 |
if ($self->{method} eq "GET") { |
| 537 |
$self->{time} = $::NOW; |
| 538 |
|
| 539 |
my $current = $Coro::current; |
| 540 |
|
| 541 |
my ($fh, $buf, $r); |
| 542 |
|
| 543 |
open $fh, "<", $self->{path} |
| 544 |
or die "$self->{path}: late open failure ($!)"; |
| 545 |
|
| 546 |
$h -= $l - 1; |
| 547 |
|
| 548 |
if (0) { # !AIO |
| 549 |
if ($l) { |
| 550 |
sysseek $fh, $l, 0; |
| 551 |
} |
| 552 |
} |
| 553 |
|
| 554 |
my $transfer; # transfer guard |
| 555 |
my $bufsize = $::WAIT_BUFSIZE; # initial buffer size |
| 556 |
|
| 557 |
$self->{time} = $::NOW; |
| 558 |
|
| 559 |
while ($h > 0) { |
| 560 |
unless ($transfer) { |
| 561 |
if ($transfer ||= $queue->timed_guard($::WAIT_INTERVAL)) { |
| 562 |
$bufsize = $::BUFSIZE; |
| 563 |
$self->{time} = $::NOW; |
| 564 |
} |
| 565 |
} |
| 566 |
|
| 567 |
if (0) { # !AIO |
| 568 |
sysread $fh, $buf, $h > $bufsize ? $bufsize : $h |
| 569 |
or last; |
| 570 |
} else { |
| 571 |
aio_read($fh, $l, ($h > $bufsize ? $bufsize : $h), |
| 572 |
$buf, 0, sub { |
| 573 |
$r = $_[0]; |
| 574 |
Coro::ready($current); |
| 575 |
}); |
| 576 |
&Coro::schedule; |
| 577 |
last unless $r; |
| 578 |
} |
| 579 |
my $w = syswrite $self->{fh}, $buf |
| 580 |
or last; |
| 581 |
$::written += $w; |
| 582 |
$self->{written} += $w; |
| 583 |
$l += $r; |
| 584 |
} |
| 585 |
|
| 586 |
close $fh; |
| 587 |
} |
| 588 |
} |
| 589 |
|
| 590 |
1; |
