| 1 |
use Coro; |
| 2 |
use Coro::Semaphore; |
| 3 |
use Coro::EV; |
| 4 |
use Coro::Socket; |
| 5 |
use Coro::Signal; |
| 6 |
use Coro::AIO (); |
| 7 |
|
| 8 |
use HTTP::Date; |
| 9 |
use POSIX (); |
| 10 |
|
| 11 |
use Compress::Zlib (); |
| 12 |
|
| 13 |
no utf8; |
| 14 |
use bytes; |
| 15 |
|
| 16 |
# at least on my machine, this thingy serves files |
| 17 |
# quite a bit faster than apache, ;) |
| 18 |
# and quite a bit slower than thttpd :( |
| 19 |
|
| 20 |
$SIG{PIPE} = 'IGNORE'; |
| 21 |
|
| 22 |
our $accesslog; |
| 23 |
our $errorlog; |
| 24 |
|
| 25 |
our $NOW; |
| 26 |
our $HTTP_NOW; |
| 27 |
|
| 28 |
our $ERROR_LOG; |
| 29 |
our $ACCESS_LOG; |
| 30 |
|
| 31 |
our $update_time = EV::periodic 0, 1, undef, sub { |
| 32 |
$NOW = time; |
| 33 |
$HTTP_NOW = time2str $NOW; |
| 34 |
}; |
| 35 |
$update_time->invoke; |
| 36 |
|
| 37 |
if ($ERROR_LOG) { |
| 38 |
use IO::Handle; |
| 39 |
open $errorlog, ">>$ERROR_LOG" |
| 40 |
or die "$ERROR_LOG: $!"; |
| 41 |
$errorlog->autoflush(1); |
| 42 |
} |
| 43 |
|
| 44 |
if ($ACCESS_LOG) { |
| 45 |
use IO::Handle; |
| 46 |
open $accesslog, ">>$ACCESS_LOG" |
| 47 |
or die "$ACCESS_LOG: $!"; |
| 48 |
$accesslog->autoflush(1); |
| 49 |
} |
| 50 |
|
| 51 |
sub slog { |
| 52 |
my $level = shift; |
| 53 |
my $format = shift; |
| 54 |
my $NOW = (POSIX::strftime "%Y-%m-%d %H:%M:%S", gmtime $::NOW); |
| 55 |
printf "$NOW: $format\n", @_; |
| 56 |
printf $errorlog "$NOW: $format\n", @_ if $errorlog; |
| 57 |
} |
| 58 |
|
| 59 |
our $connections = new Coro::Semaphore $MAX_CONNECTS || 250; |
| 60 |
our $httpevent = new Coro::Signal; |
| 61 |
|
| 62 |
our $queue_file = new transferqueue $MAX_TRANSFERS; |
| 63 |
our $queue_index = new transferqueue 10; |
| 64 |
|
| 65 |
our $tbf_top = new tbf rate => $TBF_RATE || 100000; |
| 66 |
|
| 67 |
my $unused_bytes = 0; |
| 68 |
my $unused_last = time; |
| 69 |
|
| 70 |
sub unused_bandwidth { |
| 71 |
$unused_bytes += $_[0]; |
| 72 |
if ($unused_last < $NOW - 30 && $unused_bytes / ($NOW - $unused_last) > 50000) { |
| 73 |
$unused_last = $NOW; |
| 74 |
$unused_bytes = 0; |
| 75 |
$queue_file->force_wake_next; |
| 76 |
slog 1, "forced filetransfer due to unused bandwidth"; |
| 77 |
} |
| 78 |
} |
| 79 |
|
| 80 |
sub listen_on { |
| 81 |
my $listen = $_[0]; |
| 82 |
|
| 83 |
push @listen_sockets, $listen; |
| 84 |
|
| 85 |
# the "main thread" |
| 86 |
async { |
| 87 |
slog 1, "accepting connections"; |
| 88 |
while () { |
| 89 |
$connections->down; |
| 90 |
my @conn = $listen->accept; |
| 91 |
#slog 3, "accepted @$connections ".scalar(@pool); |
| 92 |
|
| 93 |
async_pool { |
| 94 |
eval { |
| 95 |
conn->new (@conn)->handle; |
| 96 |
}; |
| 97 |
slog 1, "$@" if $@ && !ref $@; |
| 98 |
|
| 99 |
$httpevent->broadcast; # only for testing, but doesn't matter much |
| 100 |
|
| 101 |
$connections->up; |
| 102 |
} |
| 103 |
} |
| 104 |
}; |
| 105 |
} |
| 106 |
|
| 107 |
my $http_port = new Coro::Socket |
| 108 |
LocalAddr => $SERVER_HOST, |
| 109 |
LocalPort => $SERVER_PORT, |
| 110 |
ReuseAddr => 1, |
| 111 |
Listen => 50, |
| 112 |
or die "unable to start server"; |
| 113 |
|
| 114 |
listen_on $http_port; |
| 115 |
|
| 116 |
if ($SERVER_PORT2) { |
| 117 |
my $http_port = new Coro::Socket |
| 118 |
LocalAddr => $SERVER_HOST, |
| 119 |
LocalPort => $SERVER_PORT2, |
| 120 |
ReuseAddr => 1, |
| 121 |
Listen => 50, |
| 122 |
or die "unable to start server"; |
| 123 |
|
| 124 |
listen_on $http_port; |
| 125 |
} |
| 126 |
|
| 127 |
package conn; |
| 128 |
|
| 129 |
use strict; |
| 130 |
use bytes; |
| 131 |
|
| 132 |
use Socket; |
| 133 |
use HTTP::Date; |
| 134 |
use Convert::Scalar 'weaken'; |
| 135 |
use IO::AIO; |
| 136 |
|
| 137 |
IO::AIO::min_parallel $::AIO_PARALLEL; |
| 138 |
|
| 139 |
our $AIO_WATCHER = EV::io IO::AIO::poll_fileno, EV::READ, \&IO::AIO::poll_cb; |
| 140 |
|
| 141 |
our %conn; # $conn{ip}{self} => connobj |
| 142 |
our %uri; # $uri{ip}{uri}{self} |
| 143 |
our %blocked; |
| 144 |
our %mimetype; |
| 145 |
|
| 146 |
sub read_mimetypes { |
| 147 |
if (open my $fh, "<mime_types") { |
| 148 |
while (<$fh>) { |
| 149 |
if (/^([^#]\S+)\t+(\S+)$/) { |
| 150 |
$mimetype{lc $1} = $2; |
| 151 |
} |
| 152 |
} |
| 153 |
} else { |
| 154 |
print "cannot open mime_types\n"; |
| 155 |
} |
| 156 |
} |
| 157 |
|
| 158 |
read_mimetypes; |
| 159 |
|
| 160 |
sub new { |
| 161 |
my $class = shift; |
| 162 |
my $fh = shift; |
| 163 |
my $peername = shift; |
| 164 |
my $self = bless { fh => $fh }, $class; |
| 165 |
my (undef, $iaddr) = unpack_sockaddr_in $peername |
| 166 |
or $self->err (500, "unable to decode peername"); |
| 167 |
|
| 168 |
$self->{remote_addr} = |
| 169 |
$self->{remote_id} = inet_ntoa $iaddr; |
| 170 |
|
| 171 |
$self->{time} = $::NOW; |
| 172 |
|
| 173 |
weaken ($Coro::current->{conn} = $self); |
| 174 |
|
| 175 |
++$::conns; |
| 176 |
$::maxconns = $::conns if $::conns > $::maxconns; |
| 177 |
|
| 178 |
$self |
| 179 |
} |
| 180 |
|
| 181 |
sub DESTROY { |
| 182 |
my $self = shift; |
| 183 |
|
| 184 |
--$::conns; |
| 185 |
} |
| 186 |
|
| 187 |
sub prune_cache { |
| 188 |
my $hash = $_[0]; |
| 189 |
|
| 190 |
for (keys %$hash) { |
| 191 |
if (ref $hash->{$_} eq HASH::) { |
| 192 |
prune_cache($hash->{$_}); |
| 193 |
unless (scalar keys %{$hash->{$_}}) { |
| 194 |
delete $hash->{$_}; |
| 195 |
} |
| 196 |
} |
| 197 |
} |
| 198 |
} |
| 199 |
|
| 200 |
sub prune_caches { |
| 201 |
prune_cache \%conn; |
| 202 |
prune_cache \%uri; |
| 203 |
|
| 204 |
for (keys %blocked) { |
| 205 |
delete $blocked{$_} unless $blocked{$_}[0] > $::NOW; |
| 206 |
} |
| 207 |
} |
| 208 |
|
| 209 |
our $PRUNE_WATCHER = EV::timer 60, 60, \&prune_caches; |
| 210 |
|
| 211 |
sub slog { |
| 212 |
my $self = shift; |
| 213 |
main::slog($_[0], "$self->{remote_id}> $_[1]"); |
| 214 |
} |
| 215 |
|
| 216 |
sub response { |
| 217 |
my ($self, $code, $msg, $hdr, $content) = @_; |
| 218 |
my $res = "HTTP/1.1 $code $msg\015\012"; |
| 219 |
my $GZ = ""; |
| 220 |
|
| 221 |
if (exists $hdr->{Connection}) { |
| 222 |
if ($hdr->{Connection} =~ /close/) { |
| 223 |
$self->{h}{connection} = "close" |
| 224 |
} |
| 225 |
} else { |
| 226 |
if ($self->{version} < 1.1) { |
| 227 |
if ($self->{h}{connection} =~ /keep-alive/i) { |
| 228 |
$hdr->{Connection} = "Keep-Alive"; |
| 229 |
} else { |
| 230 |
$self->{h}{connection} = "close" |
| 231 |
} |
| 232 |
} |
| 233 |
} |
| 234 |
|
| 235 |
if ($self->{method} ne "HEAD" |
| 236 |
&& $self->{h}{"accept-encoding"} =~ /\bgzip\b/ |
| 237 |
&& 400 < length $content |
| 238 |
&& $hdr->{"Content-Length"} == length $content |
| 239 |
&& !exists $hdr->{"Content-Encoding"} |
| 240 |
) { |
| 241 |
my $orig = length $content; |
| 242 |
$hdr->{"Content-Encoding"} = "gzip"; |
| 243 |
$content = Compress::Zlib::memGzip(\$content); |
| 244 |
$hdr->{"Content-Length"} = length $content; |
| 245 |
$GZ = sprintf "GZ%02d", 100 - 100*((length $content) / $orig); |
| 246 |
} |
| 247 |
|
| 248 |
$res .= "Date: $HTTP_NOW\015\012"; |
| 249 |
$res .= "Server: $::NAME\015\012"; |
| 250 |
|
| 251 |
while (my ($h, $v) = each %$hdr) { |
| 252 |
$res .= "$h: $v\015\012" |
| 253 |
} |
| 254 |
$res .= "\015\012"; |
| 255 |
|
| 256 |
$res .= $content if defined $content and $self->{method} ne "HEAD"; |
| 257 |
|
| 258 |
my $log = (POSIX::strftime "%Y-%m-%d %H:%M:%S", gmtime $::NOW). |
| 259 |
" $self->{remote_id} \"$self->{uri}\" $code ".$hdr->{"Content-Length"}.$GZ. |
| 260 |
" \"$self->{h}{referer}\"\n"; |
| 261 |
|
| 262 |
print $::accesslog $log if $::accesslog; |
| 263 |
print STDERR $log; |
| 264 |
|
| 265 |
$tbf_top->request(length $res, 1e6); |
| 266 |
$self->{written} += print {$self->{fh}} $res; |
| 267 |
} |
| 268 |
|
| 269 |
sub err { |
| 270 |
my $self = shift; |
| 271 |
my ($code, $msg, $hdr, $content) = @_; |
| 272 |
|
| 273 |
unless (defined $content) { |
| 274 |
$content = "$code $msg\n"; |
| 275 |
$hdr->{"Content-Type"} = "text/plain"; |
| 276 |
$hdr->{"Content-Length"} = length $content; |
| 277 |
} |
| 278 |
$hdr->{"Connection"} = "close"; |
| 279 |
|
| 280 |
$self->response ($code, $msg, $hdr, $content); |
| 281 |
|
| 282 |
die bless {}, err:: |
| 283 |
} |
| 284 |
|
| 285 |
sub handle { |
| 286 |
my $self = shift; |
| 287 |
my $fh = $self->{fh}; |
| 288 |
|
| 289 |
my $host; |
| 290 |
|
| 291 |
$fh->timeout($::REQ_TIMEOUT); |
| 292 |
while () { |
| 293 |
$self->{reqs}++; |
| 294 |
|
| 295 |
# read request and parse first line |
| 296 |
my $req = $fh->readline("\015\012\015\012"); |
| 297 |
|
| 298 |
unless (defined $req) { |
| 299 |
if (exists $self->{version}) { |
| 300 |
last; |
| 301 |
} else { |
| 302 |
$self->err(408, "request timeout"); |
| 303 |
} |
| 304 |
} |
| 305 |
|
| 306 |
$self->{h} = {}; |
| 307 |
|
| 308 |
$fh->timeout($::RES_TIMEOUT); |
| 309 |
|
| 310 |
$req =~ /^(?:\015\012)? |
| 311 |
(GET|HEAD) \040+ |
| 312 |
([^\040]+) \040+ |
| 313 |
HTTP\/([0-9]+\.[0-9]+) |
| 314 |
\015\012/gx |
| 315 |
or $self->err(405, "method not allowed", { Allow => "GET,HEAD" }); |
| 316 |
|
| 317 |
$self->{method} = $1; |
| 318 |
$self->{uri} = $2; |
| 319 |
$self->{version} = $3; |
| 320 |
|
| 321 |
$3 =~ /^1\./ |
| 322 |
or $self->err(506, "http protocol version $3 not supported"); |
| 323 |
|
| 324 |
# parse headers |
| 325 |
{ |
| 326 |
my (%hdr, $h, $v); |
| 327 |
|
| 328 |
$hdr{lc $1} .= ",$2" |
| 329 |
while $req =~ /\G |
| 330 |
([^:\000-\040]+): |
| 331 |
[\011\040]* |
| 332 |
((?: [^\015\012]+ | \015\012[\011\040] )*) |
| 333 |
\015\012 |
| 334 |
/gxc; |
| 335 |
|
| 336 |
$req =~ /\G\015\012$/ |
| 337 |
or $self->err(400, "bad request"); |
| 338 |
|
| 339 |
$self->{h}{$h} = substr $v, 1 |
| 340 |
while ($h, $v) = each %hdr; |
| 341 |
} |
| 342 |
|
| 343 |
# remote id should be unique per user |
| 344 |
my $id = $self->{remote_addr}; |
| 345 |
|
| 346 |
if (exists $self->{h}{"client-ip"}) { |
| 347 |
$id .= "[".$self->{h}{"client-ip"}."]"; |
| 348 |
} elsif (exists $self->{h}{"x-forwarded-for"}) { |
| 349 |
$id .= "[".$self->{h}{"x-forwarded-for"}."]"; |
| 350 |
} |
| 351 |
|
| 352 |
$self->{remote_id} = $id; |
| 353 |
|
| 354 |
weaken (local $conn{$id}{$self*1} = $self); |
| 355 |
|
| 356 |
if ($blocked{$id}) { |
| 357 |
$self->err_blocked |
| 358 |
if $blocked{$id}[0] > $::NOW; |
| 359 |
|
| 360 |
delete $blocked{$id}; |
| 361 |
} |
| 362 |
|
| 363 |
# find out server name and port |
| 364 |
if ($self->{uri} =~ s/^http:\/\/([^\/?#]*)//i) { |
| 365 |
$host = $1; |
| 366 |
} else { |
| 367 |
$host = $self->{h}{host}; |
| 368 |
} |
| 369 |
|
| 370 |
if (defined $host) { |
| 371 |
$self->{server_port} = $host =~ s/:([0-9]+)$// ? $1 : 80; |
| 372 |
} else { |
| 373 |
($self->{server_port}, $host) |
| 374 |
= unpack_sockaddr_in $self->{fh}->sockname |
| 375 |
or $self->err(500, "unable to get socket name"); |
| 376 |
$host = inet_ntoa $host; |
| 377 |
} |
| 378 |
|
| 379 |
$self->{server_name} = $host; |
| 380 |
|
| 381 |
weaken (local $uri{$id}{$self->{uri}}{$self*1} = $self); |
| 382 |
|
| 383 |
eval { |
| 384 |
$self->map_uri; |
| 385 |
$self->respond; |
| 386 |
}; |
| 387 |
|
| 388 |
die if $@ && !ref $@; |
| 389 |
|
| 390 |
last if $self->{h}{connection} =~ /close/i; |
| 391 |
|
| 392 |
$httpevent->broadcast; |
| 393 |
|
| 394 |
$fh->timeout($::PER_TIMEOUT); |
| 395 |
} |
| 396 |
} |
| 397 |
|
| 398 |
sub block { |
| 399 |
my $self = shift; |
| 400 |
|
| 401 |
$blocked{$self->{remote_id}} = [$::NOW + $_[0], $_[1]]; |
| 402 |
$self->slog(2, "blocked ip $self->{remote_id}"); |
| 403 |
$self->err_blocked; |
| 404 |
} |
| 405 |
|
| 406 |
# uri => path mapping |
| 407 |
sub map_uri { |
| 408 |
my $self = shift; |
| 409 |
my $host = $self->{server_name}; |
| 410 |
my $uri = $self->{uri}; |
| 411 |
|
| 412 |
$host =~ /[\/\\]/ |
| 413 |
and $self->err(400, "bad request"); |
| 414 |
|
| 415 |
# some massaging, also makes it more secure |
| 416 |
$uri =~ s/%([0-9a-fA-F][0-9a-fA-F])/chr hex $1/ge; |
| 417 |
$uri =~ s%//+%/%g; |
| 418 |
$uri =~ s%/\.(?=/|$)%%g; |
| 419 |
1 while $uri =~ s%/[^/]+/\.\.(?=/|$)%%; |
| 420 |
|
| 421 |
$uri =~ m%^/?\.\.(?=/|$)% |
| 422 |
and $self->err(400, "bad request"); |
| 423 |
|
| 424 |
$self->{name} = $uri; |
| 425 |
|
| 426 |
# now do the path mapping |
| 427 |
$self->{path} = "$::DOCROOT/$host$uri"; |
| 428 |
|
| 429 |
$self->access_check; |
| 430 |
} |
| 431 |
|
| 432 |
sub _cgi { |
| 433 |
my $self = shift; |
| 434 |
my $path = shift; |
| 435 |
my $fh; |
| 436 |
|
| 437 |
# no two-way xxx supported |
| 438 |
if (0 == fork) { |
| 439 |
open STDOUT, ">&".fileno($self->{fh}); |
| 440 |
if (chdir $::DOCROOT) { |
| 441 |
$ENV{SERVER_SOFTWARE} = "thttpd-myhttpd"; # we are thttpd-alike |
| 442 |
$ENV{HTTP_HOST} = $self->{server_name}; |
| 443 |
$ENV{HTTP_PORT} = $self->{server_port}; |
| 444 |
$ENV{SCRIPT_NAME} = $self->{name}; |
| 445 |
exec $path; |
| 446 |
} |
| 447 |
Coro::State::_exit(0); |
| 448 |
} else { |
| 449 |
die; |
| 450 |
} |
| 451 |
} |
| 452 |
|
| 453 |
sub server_hostport { |
| 454 |
$_[0]{server_port} == 80 |
| 455 |
? $_[0]{server_name} |
| 456 |
: "$_[0]{server_name}:$_[0]{server_port}"; |
| 457 |
} |
| 458 |
|
| 459 |
sub respond { |
| 460 |
my $self = shift; |
| 461 |
my $path = $self->{path}; |
| 462 |
|
| 463 |
if ($self->{name} =~ s%^/internal/([^/]+)%%) { |
| 464 |
if ($::internal{$1}) { |
| 465 |
$::internal{$1}->($self); |
| 466 |
} else { |
| 467 |
$self->err (404, "not found"); |
| 468 |
} |
| 469 |
} else { |
| 470 |
|
| 471 |
Coro::AIO::aio_stat $path |
| 472 |
and $self->err (404, "not found"); |
| 473 |
|
| 474 |
$self->{stat} = [stat _]; |
| 475 |
|
| 476 |
# idiotic netscape sends idiotic headers AGAIN |
| 477 |
my $ims = $self->{h}{"if-modified-since"} =~ /^([^;]+)/ |
| 478 |
? str2time $1 : 0; |
| 479 |
|
| 480 |
if (-d _ && -r _) { |
| 481 |
# directory |
| 482 |
if ($path !~ /\/$/) { |
| 483 |
# create a redirect to get the trailing "/" |
| 484 |
# we don't try to avoid the :80 |
| 485 |
$self->err (301, "moved permanently", { Location => "http://".$self->server_hostport."$self->{uri}/" }); |
| 486 |
} else { |
| 487 |
$ims < $self->{stat}[9] |
| 488 |
or $self->err (304, "not modified"); |
| 489 |
|
| 490 |
if (-r "$path/index.html") { |
| 491 |
# replace directory "size" by index.html filesize |
| 492 |
$self->{stat} = [stat ($self->{path} .= "/index.html")]; |
| 493 |
$self->handle_file ($queue_index, $tbf_top); |
| 494 |
} else { |
| 495 |
$self->handle_dir; |
| 496 |
} |
| 497 |
} |
| 498 |
} elsif (-f _ && -r _) { |
| 499 |
-x _ and $self->err (403, "forbidden"); |
| 500 |
|
| 501 |
if (keys %{$conn{$self->{remote_id}}} > $::MAX_TRANSFERS_IP) { |
| 502 |
my $timeout = $::NOW + 10; |
| 503 |
while (keys %{$conn{$self->{remote_id}}} > $::MAX_TRANSFERS_IP) { |
| 504 |
if ($timeout < $::NOW) { |
| 505 |
$self->block($::BLOCKTIME, "too many connections"); |
| 506 |
} else { |
| 507 |
$httpevent->wait; |
| 508 |
} |
| 509 |
} |
| 510 |
} |
| 511 |
|
| 512 |
$self->handle_file ($queue_file, $tbf_top); |
| 513 |
} else { |
| 514 |
$self->err (404, "not found"); |
| 515 |
} |
| 516 |
} |
| 517 |
} |
| 518 |
|
| 519 |
sub handle_dir { |
| 520 |
my $self = shift; |
| 521 |
my $idx = $self->diridx; |
| 522 |
|
| 523 |
$self->response (200, "ok", |
| 524 |
{ |
| 525 |
"Content-Type" => "text/html; charset=utf-8", |
| 526 |
"Content-Length" => length $idx, |
| 527 |
"Last-Modified" => time2str ($self->{stat}[9]), |
| 528 |
}, |
| 529 |
$idx); |
| 530 |
} |
| 531 |
|
| 532 |
sub handle_file { |
| 533 |
my ($self, $queue, $tbf) = @_; |
| 534 |
my $length = $self->{stat}[7]; |
| 535 |
my $hdr = { |
| 536 |
"Last-Modified" => time2str ((stat _)[9]), |
| 537 |
"Accept-Ranges" => "bytes", |
| 538 |
}; |
| 539 |
|
| 540 |
my @code = (200, "ok"); |
| 541 |
my ($l, $h); |
| 542 |
|
| 543 |
if ($self->{h}{range} =~ /^bytes=(.*)$/i) { |
| 544 |
for (split /,/, $1) { |
| 545 |
if (/^-(\d+)$/) { |
| 546 |
($l, $h) = ($length - $1, $length - 1); |
| 547 |
} elsif (/^(\d+)-(\d*)$/) { |
| 548 |
($l, $h) = ($1, ($2 ne "" || $2 >= $length) ? $2 : $length - 1); |
| 549 |
} else { |
| 550 |
($l, $h) = (0, $length - 1); |
| 551 |
goto ignore; |
| 552 |
} |
| 553 |
goto satisfiable if $l >= 0 && $l < $length && $h >= 0 && $h >= $l; |
| 554 |
} |
| 555 |
$hdr->{"Content-Range"} = "bytes */$length"; |
| 556 |
$hdr->{"Content-Length"} = $length; |
| 557 |
$self->err (416, "not satisfiable", $hdr, ""); |
| 558 |
|
| 559 |
satisfiable: |
| 560 |
# check for segmented downloads |
| 561 |
if ($l && $::NO_SEGMENTED) { |
| 562 |
my $timeout = $::NOW + 15; |
| 563 |
while (keys %{$uri{$self->{remote_id}}{$self->{uri}}} > 1) { |
| 564 |
if ($timeout <= $::NOW) { |
| 565 |
$self->block ($::BLOCKTIME, "segmented downloads are forbidden"); |
| 566 |
#$self->err_segmented_download; |
| 567 |
} else { |
| 568 |
$httpevent->wait; |
| 569 |
} |
| 570 |
} |
| 571 |
} |
| 572 |
|
| 573 |
$hdr->{"Content-Range"} = "bytes $l-$h/$length"; |
| 574 |
@code = (206, "partial content"); |
| 575 |
$length = $h - $l + 1; |
| 576 |
|
| 577 |
ignore: |
| 578 |
} else { |
| 579 |
($l, $h) = (0, $length - 1); |
| 580 |
} |
| 581 |
|
| 582 |
$self->{path} =~ /\.([^.]+)$/; |
| 583 |
$hdr->{"Content-Type"} = $mimetype{lc $1} || "application/octet-stream"; |
| 584 |
$hdr->{"Content-Length"} = $length; |
| 585 |
|
| 586 |
$self->response (@code, $hdr, ""); |
| 587 |
|
| 588 |
if ($self->{method} eq "GET") { |
| 589 |
$self->{time} = $::NOW; |
| 590 |
$self->{written} = 0; |
| 591 |
|
| 592 |
open my $fh, "<", $self->{path} |
| 593 |
or die "$self->{path}: late open failure ($!)"; |
| 594 |
|
| 595 |
$h -= $l - 1; |
| 596 |
|
| 597 |
my $transfer = $queue->start_transfer ($h); |
| 598 |
my $locked; |
| 599 |
my $bufsize = $::WAIT_BUFSIZE; # initial buffer size |
| 600 |
|
| 601 |
while ($h > 0) { |
| 602 |
unless ($locked) { |
| 603 |
if ($locked ||= $transfer->try ($::WAIT_INTERVAL)) { |
| 604 |
$bufsize = $::BUFSIZE; |
| 605 |
$self->{time} = $::NOW; |
| 606 |
$self->{written} = 0; |
| 607 |
} |
| 608 |
} |
| 609 |
|
| 610 |
if ($blocked{$self->{remote_id}}) { |
| 611 |
$self->{h}{connection} = "close"; |
| 612 |
die bless {}, err::; |
| 613 |
} |
| 614 |
|
| 615 |
Coro::AIO::aio_read $fh, $l, ($h > $bufsize ? $bufsize : $h), my $buf, 0 |
| 616 |
or last; |
| 617 |
|
| 618 |
$tbf->request (length $buf); |
| 619 |
my $w = $self->{fh}->syswrite ($buf) |
| 620 |
or last; |
| 621 |
$::written += $w; |
| 622 |
$self->{written} += $w; |
| 623 |
$l += $w; |
| 624 |
} |
| 625 |
|
| 626 |
close $fh; |
| 627 |
} |
| 628 |
} |
| 629 |
|
| 630 |
1 |
| 631 |
|
