cvsroot/Linux-Inotify2/Inotify2.pm

=head1 NAME

Linux::Inotify2 - scalable directory/file change notification

=head1 SYNOPSIS

=head2 Callback interface

 use Linux::Inotify2;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "Unable to create new inotify object: $!";
 
 # for Event:
 Event->io (fd =>$inotify->fileno, poll => 'r', cb => sub { $inotify->poll });
 # for Glib:
 add_watch Glib::IO $inotify->fileno, in => sub { $inotify->poll };
 # manually:
 1 while $inotify->poll;

 # add watchers
 $inotify->watch ("/etc/passwd", IN_ACCESS, sub {
    my $e = shift;
    my $name = $e->fullname;
    print "$name was accessed\n" if $e->IN_ACCESS;
    print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
    print "$name is gone\n" if $e->IN_IGNORED;
    print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
 
    # cancel this watcher: remove no further events
    $e->w->cancel;
 });

=head2 Streaming Interface

 use Linux::Inotify2 ;

 # create a new object
 my $inotify = new Linux::Inotify2
    or die "Unable to create new inotify object: $!" ;

 # create watch
 $inotify->watch ("/etc/passwd", IN_ACCESS)
    or die "watch creation failed" ;

 while () {
   my @events = $inotify->read;
   unless (@events > 0) {
     print "read error: $!";
     last ;
   }
   printf "mask\t%d\n", $_->mask foreach @events ; 
 }

=head1 DESCRIPTION

This module implements an interface to the Linux 2.6.13 and later Inotify
file/directory change notification sytem.

It has a number of advantages over the Linux::Inotify module:

   - it is portable (Linux::Inotify only works on x86)
   - the equivalent of fullname works correctly
   - it is better documented
   - it has callback-style interface, which is better suited for
     integration.

=head2 The Linux::Inotify2 Class

=over 4

=cut

package Linux::Inotify2;

use Carp ();
use Fcntl ();
use Scalar::Util ();

use base 'Exporter';

BEGIN {
   $VERSION = '1.01';

   @constants = qw(
      IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
      IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
      IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
      IN_ALL_EVENTS
      IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
      IN_CLOSE IN_MOVE
      IN_ISDIR IN_ONESHOT
   );

   @EXPORT = @constants;

   require XSLoader;
   XSLoader::load Linux::Inotify2, $VERSION;
}

=item my $inotify = new Linux::Inotify2

Create a new notify object and return it. A notify object is kind of a
container that stores watches on filesystem names and is responsible for
handling event data.

On error, C<undef> is returned and C<$!> will be set accordingly. The followign errors
are documented:

 ENFILE   The system limit on the total number of file descriptors has been reached.
 EMFILE   The user limit on the total number of inotify instances has been reached.
 ENOMEM   Insufficient kernel memory is available.

Example:

   my $inotify = new Linux::Inotify2
      or die "Unable to create new inotify object: $!";

=cut

sub new {
   my ($class) = @_;

   my $fd = inotify_init;

   return unless $fd >= 0;

   bless { fd => $fd }, $class
}

=item $watch = $inotify->watch ($name, $mask[, $cb])

Add a new watcher to the given notifier. The watcher will create events
on the pathname C<$name> as given in C<$mask>, which can be any of the
following constants (all exported by default) ORed together.

"file" refers to any filesystem object in the watch'ed object (always a
directory), that is files, directories, symlinks, device nodes etc., while
"object" refers to the object the watch has been set on itself:

 IN_ACCESS            object was accessed
 IN_MODIFY            object was modified
 IN_ATTRIB            object metadata changed
 IN_CLOSE_WRITE       writable fd to file / to object was closed
 IN_CLOSE_NOWRITE     readonly fd to file / to object closed
 IN_OPEN              object was opened
 IN_MOVED_FROM        file was moved from this object (directory)
 IN_MOVED_TO          file was moved to this object (directory)
 IN_CREATE            file was created in this object (directory)
 IN_DELETE            file was deleted from this object (directory)
 IN_DELETE_SELF       object itself was deleted
 IN_MOVE_SELF         object itself was moved
 IN_ALL_EVENTS        all of the above events

 IN_ONESHOT           only send event once

 IN_CLOSE             same as IN_CLOSE_WRITE | IN_CLOSE_NOWRITE
 IN_MOVE              same as IN_MOVED_FROM | IN_MOVED_TO

C<$cb> is a perl code reference that, if given, is called for each
event. It receives a C<Linux::Inotify2::Event> object.

The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.

On error, C<undef> is returned and C<$!> will be set accordingly. The
following errors are documented:

 EBADF    The given file descriptor is not valid.
 EINVAL   The given event mask contains no legal events.
 ENOMEM   Insufficient kernel memory was available.
 ENOSPC   The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
 EACCESS  Read access to the given file is not permitted.

Example, show when C</etc/passwd> gets accessed and/or modified once:

   $inotify->watch ("/etc/passwd", IN_ACCESS | IN_MODIFY, sub {
      my $e = shift;
      print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
      print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
      print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
      print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;

      $e->w->cancel;
   });

=cut

sub watch {
   my ($self, $name, $mask, $cb) = @_;

   my $wd = inotify_add_watch $self->{fd}, $name, $mask;

   return unless $wd >= 0;
   
   my $w = $self->{w}{$wd} = bless {
      inotify => $self,
      wd      => $wd,
      name    => $name,
      mask    => $mask,
      cb      => $cb,
   }, Linux::Inotify2::Watch::;

   Scalar::Util::weaken $w->{inotify};

   $w
}

=item $inotify->fileno

Returns the fileno for this notify object. You are responsible for calling
the C<poll> method when this fileno becomes ready for reading.

=cut

sub fileno {
   $_[0]{fd}
}

=item $inotify->blocking ($blocking)

Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.

=cut

sub blocking {
   my ($self, $blocking) = @_;

   inotify_blocking $self->{fd}, $blocking;
}

=item $count = $inotify->poll

Reads events from the kernel and handles them. If the notify fileno is
blocking (the default), then this method waits for at least one event
(and thus returns true unless an error occurs). Otherwise it returns
immediately when no pending events could be read.

Returns the count of events that have been handled.

=cut

sub poll {
   scalar &read
}

=item $count = $inotify->read

Reads events from the kernel. Blocks in blocking mode (default) until any
event arrives. Returns list of C<Linux::Inotify2::Event> objects or empty
list if none (non-blocking mode) or error occured ($! should be checked).

=cut

sub read {
   my ($self) = @_;

   my @ev = inotify_read $self->{fd};
   my @res;

   for (@ev) {
      my $w = $_->{w} = $self->{w}{$_->{wd}}
         or next; # no such watcher

      exists $self->{ignore}{$_->{wd}}
         and next; # watcher has been canceled

      bless $_, Linux::Inotify2::Event::;

      push @res, $_;

      $w->{cb}->($_) if $w->{cb};
      $w->cancel if $_->{mask} & (IN_IGNORED | IN_UNMOUNT | IN_ONESHOT);
   }

   delete $self->{ignore};

   @res
}

sub DESTROY {
   inotify_close $_[0]{fd}
}

=back

=head2 The Linux::Inotify2::Event Class

Objects of this class are handed as first argument to the watch
callback. It has the following members and methods:

=over 4

=item $event->w

=item $event->{w}

The watcher object for this event.

=item $event->name

=item $event->{name}

The path of the filesystem object, relative to the watch name.

=item $watch->fullname

Returns the "full" name of the relevant object, i.e. including the C<name>
member of the watcher (if the the watch is on a directory and a dir entry
is affected), or simply the C<name> member itself when the object is the
watch object itself.

=item $event->mask

=item $event->{mask}

The received event mask. In addition the the events described for
C<$inotify->watch>, the following flags (exported by default) can be set:

 IN_ISDIR             event object is a directory
 IN_Q_OVERFLOW        event queue overflowed

 # when any of the following flags are set,
 # then watchers for this event are automatically canceled
 IN_UNMOUNT           filesystem for watch'ed object was unmounted
 IN_IGNORED           file was ignored/is gone (no more events are delivered)
 IN_ONESHOT           only one event was generated

=item $event->IN_xxx

Returns a boolean that returns true if the event mask matches the
event. All of the C<IN_xxx> constants can be used as methods.

=item $event->cookie

=item $event->{cookie}

The event cookie to "synchronize two events". Normally zero, this value is
set when two events relating to the same file are generated. As far as I
know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
identify the old and new name of a file.

=back

=cut

package Linux::Inotify2::Event;

sub w       { $_[0]{w}      }
sub name    { $_[0]{name}   }
sub mask    { $_[0]{mask}   }
sub cookie  { $_[0]{cookie} }

sub fullname {
   length $_[0]{name}
      ? "$_[0]{w}{name}/$_[0]{name}"
      : $_[0]{w}{name};
}

for my $name (@Linux::Inotify2::constants) {
   my $mask = &{"Linux::Inotify2::$name"};

   *$name = sub { ($_[0]{mask} & $mask) == $mask };
}

=head2 The Linux::Inotify2::Watch Class

Watch objects are created by calling the C<watch> method of a notifier.

It has the following members and methods:

=item $watch->name

=item $watch->{name}

The name as specified in the C<watch> call. For the object itself, this is
the empty string.  For directory watches, this is the name of the entry
without leading path elements.

=item $watch->mask

=item $watch->{mask}

The mask as specified in the C<watch> call.

=item $watch->cb ([new callback])

=item $watch->{cb}

The callback as specified in the C<watch> call. Can optionally be changed.

=item $watch->cancel

Cancels/removes this watch. Future events, even if already queued queued,
will not be handled and resources will be freed.

=cut

package Linux::Inotify2::Watch;

sub name    { $_[0]{name} }
sub mask    { $_[0]{mask} }

sub cb {
   $_[0]{cb} = $_[1] if @_ > 1;
   $_[0]{cb}
}

sub cancel {
   my ($self) = @_;

   my $inotify = delete $self->{inotify}
      or return 1; # already canceled

   delete $inotify->{w}{$self->{wd}}; # we are no longer there
   $inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll

   (Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
      ? 1 : undef
}

=head1 SEE ALSO

L<Linux::Inotify>.

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

1
Revision:	1.12
Committed:	Tue Dec 20 11:32:05 2005 UTC (18 years, 6 months ago) by root
Branch:	MAIN
Changes since 1.11:	+5 -4 lines
Log Message:	* empty log message *
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3			Linux::Inotify2 - scalable directory/file change notification
4
5			=head1 SYNOPSIS
6
7	root	1.11	=head2 Callback interface
8
9	root	1.1	use Linux::Inotify2;
10
11	root	1.4	# create a new object
12			my $inotify = new Linux::Inotify2
13			or die "Unable to create new inotify object: $!";
14
15			# for Event:
16			Event->io (fd =>$inotify->fileno, poll => 'r', cb => sub { $inotify->poll });
17			# for Glib:
18			add_watch Glib::IO $inotify->fileno, in => sub { $inotify->poll };
19			# manually:
20			1 while $inotify->poll;
21
22			# add watchers
23			$inotify->watch ("/etc/passwd", IN_ACCESS, sub {
24			my $e = shift;
25			my $name = $e->fullname;
26			print "$name was accessed\n" if $e->IN_ACCESS;
27			print "$name is no longer mounted\n" if $e->IN_UNMOUNT;
28			print "$name is gone\n" if $e->IN_IGNORED;
29			print "events for $name have been lost\n" if $e->IN_Q_OVERFLOW;
30
31	root	1.11	# cancel this watcher: remove no further events
32	root	1.4	$e->w->cancel;
33			});
34
35	root	1.11	=head2 Streaming Interface
36
37			use Linux::Inotify2 ;
38
39			# create a new object
40			my $inotify = new Linux::Inotify2
41			or die "Unable to create new inotify object: $!" ;
42
43			# create watch
44			$inotify->watch ("/etc/passwd", IN_ACCESS)
45			or die "watch creation failed" ;
46
47			while () {
48			my @events = $inotify->read;
49			unless (@events > 0) {
50			print "read error: $!";
51			last ;
52			}
53			printf "mask\t%d\n", $_->mask foreach @events ;
54			}
55
56	root	1.1	=head1 DESCRIPTION
57
58	root	1.3	This module implements an interface to the Linux 2.6.13 and later Inotify
59			file/directory change notification sytem.
60	root	1.2
61	root	1.3	It has a number of advantages over the Linux::Inotify module:
62	root	1.2
63			- it is portable (Linux::Inotify only works on x86)
64			- the equivalent of fullname works correctly
65			- it is better documented
66			- it has callback-style interface, which is better suited for
67			integration.
68
69	root	1.6	=head2 The Linux::Inotify2 Class
70
71	root	1.1	=over 4
72
73			=cut
74
75			package Linux::Inotify2;
76
77			use Carp ();
78	root	1.11	use Fcntl ();
79	root	1.1	use Scalar::Util ();
80
81			use base 'Exporter';
82
83			BEGIN {
84	root	1.12	$VERSION = '1.01';
85	root	1.1
86			@constants = qw(
87			IN_ACCESS IN_MODIFY IN_ATTRIB IN_CLOSE_WRITE
88			IN_CLOSE_NOWRITE IN_OPEN IN_MOVED_FROM IN_MOVED_TO
89	root	1.9	IN_CREATE IN_DELETE IN_DELETE_SELF IN_MOVE_SELF
90	root	1.1	IN_ALL_EVENTS
91			IN_UNMOUNT IN_Q_OVERFLOW IN_IGNORED
92			IN_CLOSE IN_MOVE
93			IN_ISDIR IN_ONESHOT
94			);
95
96			@EXPORT = @constants;
97
98			require XSLoader;
99			XSLoader::load Linux::Inotify2, $VERSION;
100			}
101
102			=item my $inotify = new Linux::Inotify2
103
104			Create a new notify object and return it. A notify object is kind of a
105			container that stores watches on filesystem names and is responsible for
106			handling event data.
107
108			On error, C<undef> is returned and C<$!> will be set accordingly. The followign errors
109			are documented:
110
111			ENFILE The system limit on the total number of file descriptors has been reached.
112			EMFILE The user limit on the total number of inotify instances has been reached.
113			ENOMEM Insufficient kernel memory is available.
114
115	root	1.4	Example:
116
117			my $inotify = new Linux::Inotify2
118			or die "Unable to create new inotify object: $!";
119
120	root	1.1	=cut
121
122			sub new {
123			my ($class) = @_;
124
125			my $fd = inotify_init;
126
127			return unless $fd >= 0;
128
129			bless { fd => $fd }, $class
130			}
131
132	root	1.11	=item $watch = $inotify->watch ($name, $mask[, $cb])
133	root	1.1
134			Add a new watcher to the given notifier. The watcher will create events
135			on the pathname C<$name> as given in C<$mask>, which can be any of the
136	root	1.4	following constants (all exported by default) ORed together.
137
138			"file" refers to any filesystem object in the watch'ed object (always a
139			directory), that is files, directories, symlinks, device nodes etc., while
140			"object" refers to the object the watch has been set on itself:
141
142			IN_ACCESS object was accessed
143			IN_MODIFY object was modified
144			IN_ATTRIB object metadata changed
145			IN_CLOSE_WRITE writable fd to file / to object was closed
146			IN_CLOSE_NOWRITE readonly fd to file / to object closed
147			IN_OPEN object was opened
148			IN_MOVED_FROM file was moved from this object (directory)
149			IN_MOVED_TO file was moved to this object (directory)
150			IN_CREATE file was created in this object (directory)
151			IN_DELETE file was deleted from this object (directory)
152			IN_DELETE_SELF object itself was deleted
153	root	1.9	IN_MOVE_SELF object itself was moved
154	root	1.4	IN_ALL_EVENTS all of the above events
155	root	1.1
156			IN_ONESHOT only send event once
157
158	root	1.4	IN_CLOSE same as IN_CLOSE_WRITE \| IN_CLOSE_NOWRITE
159			IN_MOVE same as IN_MOVED_FROM \| IN_MOVED_TO
160	root	1.1
161	root	1.11	C<$cb> is a perl code reference that, if given, is called for each
162			event. It receives a C<Linux::Inotify2::Event> object.
163	root	1.1
164			The returned C<$watch> object is of class C<Linux::Inotify2::Watch>.
165
166			On error, C<undef> is returned and C<$!> will be set accordingly. The
167			following errors are documented:
168
169			EBADF The given file descriptor is not valid.
170			EINVAL The given event mask contains no legal events.
171			ENOMEM Insufficient kernel memory was available.
172			ENOSPC The user limit on the total number of inotify watches was reached or the kernel failed to allocate a needed resource.
173			EACCESS Read access to the given file is not permitted.
174
175			Example, show when C</etc/passwd> gets accessed and/or modified once:
176
177			$inotify->watch ("/etc/passwd", IN_ACCESS \| IN_MODIFY, sub {
178			my $e = shift;
179			print "$e->{w}{name} was accessed\n" if $e->IN_ACCESS;
180			print "$e->{w}{name} was modified\n" if $e->IN_MODIFY;
181			print "$e->{w}{name} is no longer mounted\n" if $e->IN_UNMOUNT;
182			print "events for $e->{w}{name} have been lost\n" if $e->IN_Q_OVERFLOW;
183
184			$e->w->cancel;
185			});
186
187			=cut
188
189			sub watch {
190			my ($self, $name, $mask, $cb) = @_;
191
192			my $wd = inotify_add_watch $self->{fd}, $name, $mask;
193
194			return unless $wd >= 0;
195
196			my $w = $self->{w}{$wd} = bless {
197			inotify => $self,
198			wd => $wd,
199			name => $name,
200			mask => $mask,
201			cb => $cb,
202	root	1.12	}, Linux::Inotify2::Watch::;
203	root	1.1
204			Scalar::Util::weaken $w->{inotify};
205
206			$w
207			}
208
209	root	1.4	=item $inotify->fileno
210	root	1.1
211			Returns the fileno for this notify object. You are responsible for calling
212			the C<poll> method when this fileno becomes ready for reading.
213
214			=cut
215
216			sub fileno {
217			$_[0]{fd}
218			}
219
220	root	1.11	=item $inotify->blocking ($blocking)
221
222			Clears ($blocking true) or sets ($blocking false) the C<O_NONBLOCK> flag on the file descriptor.
223
224			=cut
225
226			sub blocking {
227			my ($self, $blocking) = @_;
228
229			inotify_blocking $self->{fd}, $blocking;
230			}
231
232	root	1.4	=item $count = $inotify->poll
233	root	1.1
234	root	1.4	Reads events from the kernel and handles them. If the notify fileno is
235			blocking (the default), then this method waits for at least one event
236			(and thus returns true unless an error occurs). Otherwise it returns
237			immediately when no pending events could be read.
238	root	1.1
239			Returns the count of events that have been handled.
240
241			=cut
242
243			sub poll {
244	root	1.11	scalar &read
245			}
246
247			=item $count = $inotify->read
248
249			Reads events from the kernel. Blocks in blocking mode (default) until any
250			event arrives. Returns list of C<Linux::Inotify2::Event> objects or empty
251			list if none (non-blocking mode) or error occured ($! should be checked).
252
253			=cut
254
255			sub read {
256	root	1.1	my ($self) = @_;
257
258	root	1.4	my @ev = inotify_read $self->{fd};
259	root	1.11	my @res;
260	root	1.4
261			for (@ev) {
262			my $w = $_->{w} = $self->{w}{$_->{wd}}
263	root	1.1	or next; # no such watcher
264	root	1.4
265			exists $self->{ignore}{$_->{wd}}
266			and next; # watcher has been canceled
267
268	root	1.12	bless $_, Linux::Inotify2::Event::;
269
270	root	1.11	push @res, $_;
271
272	root	1.12	$w->{cb}->($_) if $w->{cb};
273	root	1.10	$w->cancel if $_->{mask} & (IN_IGNORED \| IN_UNMOUNT \| IN_ONESHOT);
274	root	1.1	}
275	root	1.4
276			delete $self->{ignore};
277
278	root	1.11	@res
279	root	1.1	}
280
281			sub DESTROY {
282			inotify_close $_[0]{fd}
283			}
284
285			=back
286
287			=head2 The Linux::Inotify2::Event Class
288
289			Objects of this class are handed as first argument to the watch
290			callback. It has the following members and methods:
291
292			=over 4
293
294			=item $event->w
295
296			=item $event->{w}
297
298			The watcher object for this event.
299
300			=item $event->name
301
302			=item $event->{name}
303
304			The path of the filesystem object, relative to the watch name.
305
306			=item $watch->fullname
307
308			Returns the "full" name of the relevant object, i.e. including the C<name>
309	root	1.7	member of the watcher (if the the watch is on a directory and a dir entry
310			is affected), or simply the C<name> member itself when the object is the
311			watch object itself.
312	root	1.1
313			=item $event->mask
314
315			=item $event->{mask}
316
317			The received event mask. In addition the the events described for
318			C<$inotify->watch>, the following flags (exported by default) can be set:
319
320	root	1.4	IN_ISDIR event object is a directory
321			IN_Q_OVERFLOW event queue overflowed
322
323	root	1.10	# when any of the following flags are set,
324			# then watchers for this event are automatically canceled
325	root	1.4	IN_UNMOUNT filesystem for watch'ed object was unmounted
326			IN_IGNORED file was ignored/is gone (no more events are delivered)
327	root	1.10	IN_ONESHOT only one event was generated
328	root	1.1
329			=item $event->IN_xxx
330
331			Returns a boolean that returns true if the event mask matches the
332			event. All of the C<IN_xxx> constants can be used as methods.
333
334			=item $event->cookie
335
336			=item $event->{cookie}
337
338	root	1.10	The event cookie to "synchronize two events". Normally zero, this value is
339			set when two events relating to the same file are generated. As far as I
340			know, this only happens for C<IN_MOVED_FROM> and C<IN_MOVED_TO> events, to
341			identify the old and new name of a file.
342	root	1.1
343			=back
344
345			=cut
346
347			package Linux::Inotify2::Event;
348
349			sub w { $_[0]{w} }
350			sub name { $_[0]{name} }
351			sub mask { $_[0]{mask} }
352			sub cookie { $_[0]{cookie} }
353
354			sub fullname {
355			length $_[0]{name}
356			? "$_[0]{w}{name}/$_[0]{name}"
357			: $_[0]{w}{name};
358			}
359
360			for my $name (@Linux::Inotify2::constants) {
361			my $mask = &{"Linux::Inotify2::$name"};
362
363			*$name = sub { ($_[0]{mask} & $mask) == $mask };
364			}
365
366			=head2 The Linux::Inotify2::Watch Class
367
368			Watch objects are created by calling the C<watch> method of a notifier.
369
370			It has the following members and methods:
371
372			=item $watch->name
373
374			=item $watch->{name}
375
376			The name as specified in the C<watch> call. For the object itself, this is
377			the empty string. For directory watches, this is the name of the entry
378			without leading path elements.
379
380			=item $watch->mask
381
382			=item $watch->{mask}
383
384			The mask as specified in the C<watch> call.
385
386			=item $watch->cb ([new callback])
387
388			=item $watch->{cb}
389
390			The callback as specified in the C<watch> call. Can optionally be changed.
391
392			=item $watch->cancel
393
394			Cancels/removes this watch. Future events, even if already queued queued,
395			will not be handled and resources will be freed.
396
397			=cut
398
399			package Linux::Inotify2::Watch;
400
401			sub name { $_[0]{name} }
402			sub mask { $_[0]{mask} }
403
404			sub cb {
405			$_[0]{cb} = $_[1] if @_ > 1;
406			$_[0]{cb}
407			}
408
409			sub cancel {
410			my ($self) = @_;
411
412	root	1.4	my $inotify = delete $self->{inotify}
413			or return 1; # already canceled
414
415			delete $inotify->{w}{$self->{wd}}; # we are no longer there
416			$inotify->{ignore}{$self->{wd}} = 1; # ignore further events for one poll
417
418			(Linux::Inotify2::inotify_rm_watch $inotify->{fd}, $self->{wd})
419	root	1.1	? 1 : undef
420			}
421
422			=head1 SEE ALSO
423
424			L<Linux::Inotify>.
425
426			=head1 AUTHOR
427
428			Marc Lehmann <schmorp@schmorp.de>
429			http://home.schmorp.de/
430
431			=cut
432
433			1