1 |
=encoding utf8 |
2 |
|
3 |
=head1 NAME |
4 |
|
5 |
urxvtperl - rxvt-unicode's embedded perl interpreter |
6 |
|
7 |
=head1 SYNOPSIS |
8 |
|
9 |
# create a file grab_test in some directory: |
10 |
|
11 |
sub on_sel_grab { |
12 |
warn "you selected ", $_[0]->selection; |
13 |
() |
14 |
} |
15 |
|
16 |
# start a urxvt instance using it: |
17 |
|
18 |
urxvt --perl-lib path/to/somedirectory -pe grab_test |
19 |
|
20 |
=head1 DESCRIPTION |
21 |
|
22 |
Every time a terminal object gets created, extension scripts specified via |
23 |
the C<perl> resource are loaded and associated with it. |
24 |
|
25 |
Scripts are compiled in a 'use strict qw(vars subs)' and 'use utf8' |
26 |
environment, and thus must be encoded as UTF-8. |
27 |
|
28 |
Each script will only ever be loaded once, even in urxvtd, where |
29 |
scripts will be shared (but not enabled) for all terminals. |
30 |
|
31 |
You can disable the embedded perl interpreter by setting both "perl-ext" |
32 |
and "perl-ext-common" resources to the empty string. |
33 |
|
34 |
=head1 PREPACKAGED EXTENSIONS |
35 |
|
36 |
A number of extensions are delivered with this release. You can find them |
37 |
in F<< <libdir>/urxvt/perl/ >>, and the documentation can be viewed using |
38 |
F<< man urxvt-<EXTENSIONNAME> >>. |
39 |
|
40 |
You can activate them like this: |
41 |
|
42 |
urxvt -pe <extensionname> |
43 |
|
44 |
Or by adding them to the resource for extensions loaded by default: |
45 |
|
46 |
URxvt.perl-ext-common: default,selection-autotransform |
47 |
|
48 |
Extensions may add additional resources and C<actions>, i.e., methods |
49 |
which can be bound to a key and invoked by the user. An extension can |
50 |
define the resources it support using so called META comments, |
51 |
described below. Similarly to builtin resources, extension resources |
52 |
can also be specified on the command line as long options (with C<.> |
53 |
replaced by C<->), in which case the corresponding extension is loaded |
54 |
automatically. For this to work the extension B<must> define META |
55 |
comments for its resources. |
56 |
|
57 |
=head1 API DOCUMENTATION |
58 |
|
59 |
=head2 General API Considerations |
60 |
|
61 |
All objects (such as terminals, time watchers etc.) are typical |
62 |
reference-to-hash objects. The hash can be used to store anything you |
63 |
like. All members starting with an underscore (such as C<_ptr> or |
64 |
C<_hook>) are reserved for internal uses and B<MUST NOT> be accessed or |
65 |
modified). |
66 |
|
67 |
When objects are destroyed on the C++ side, the perl object hashes are |
68 |
emptied, so its best to store related objects such as time watchers and |
69 |
the like inside the terminal object so they get destroyed as soon as the |
70 |
terminal is destroyed. |
71 |
|
72 |
Argument names also often indicate the type of a parameter. Here are some |
73 |
hints on what they mean: |
74 |
|
75 |
=over |
76 |
|
77 |
=item $text |
78 |
|
79 |
Rxvt-unicode's special way of encoding text, where one "unicode" character |
80 |
always represents one screen cell. See L<ROW_t> for a discussion of this format. |
81 |
|
82 |
=item $string |
83 |
|
84 |
A perl text string, with an emphasis on I<text>. It can store all unicode |
85 |
characters and is to be distinguished with text encoded in a specific |
86 |
encoding (often locale-specific) and binary data. |
87 |
|
88 |
=item $octets |
89 |
|
90 |
Either binary data or - more common - a text string encoded in a |
91 |
locale-specific way. |
92 |
|
93 |
=item $keysym |
94 |
|
95 |
an integer that is a valid X11 keysym code. You can convert a string |
96 |
into a keysym and viceversa by using C<XStringToKeysym> and |
97 |
C<XKeysymToString>. |
98 |
|
99 |
=back |
100 |
|
101 |
=head2 Extension Objects |
102 |
|
103 |
Every perl extension is a perl class. A separate perl object is created |
104 |
for each terminal, and each terminal has its own set of extension objects, |
105 |
which are passed as the first parameter to hooks. So extensions can use |
106 |
their C<$self> object without having to think about clashes with other |
107 |
extensions or other terminals, with the exception of methods and members |
108 |
that begin with an underscore character C<_>: these are reserved for |
109 |
internal use. |
110 |
|
111 |
Although it isn't a C<urxvt::term> object, you can call all methods of the |
112 |
C<urxvt::term> class on this object. |
113 |
|
114 |
Additional methods only supported for extension objects are described in |
115 |
the C<urxvt::extension> section below. |
116 |
|
117 |
=head2 META comments |
118 |
|
119 |
Rxvt-unicode recognizes special meta comments in extensions that define |
120 |
different types of metadata. These comments are scanned whenever a |
121 |
terminal is created and are typically used to autoload extensions when |
122 |
their resources or command line parameters are used. |
123 |
|
124 |
Currently, it recognises these comments below. Individual components are |
125 |
separated by colons (C<:>), and should not contain colons themselves - |
126 |
there is also currently no escaping mechanism provided for this. |
127 |
|
128 |
=over |
129 |
|
130 |
=item #:META:RESOURCE:name:type:desc |
131 |
|
132 |
The RESOURCE comment defines a resource used by the extension, where |
133 |
C<name> is the resource name, C<type> is the resource type, C<boolean> |
134 |
or C<string>, and C<desc> is the resource description. |
135 |
|
136 |
The extension will be autoloaded when this resource is specified or used |
137 |
as a command line parameter. |
138 |
|
139 |
Example: matcher provides the C<matcher.launcher> resource by having this |
140 |
comment: |
141 |
|
142 |
#:META:RESOURCE:%.launcher:string:default launcher command |
143 |
|
144 |
Example: load this extension when the C<-tr> command line option or |
145 |
resource name is used. |
146 |
|
147 |
#:META:RESOURCE:tr:boolean:set root pixmap as background |
148 |
|
149 |
=item #:META:OSC:number:desc |
150 |
|
151 |
The OSC comment specifies an OSC sequence, where C<number> is the |
152 |
numerical OSC code and C<desc> is a short description that is currently |
153 |
unused. |
154 |
|
155 |
This will cause the extension to be autoloaded when the OSC sequence is |
156 |
used for the first time. |
157 |
|
158 |
Note that autoloading carries some extra responsibilities with it: |
159 |
although the terminal cannot really protect itself against malicious |
160 |
sources of command sequences, therefore relying on the programs running |
161 |
I<inside> to sanitize data that they output, it is very common for |
162 |
programs to emit command sequences from untrusted sources. |
163 |
|
164 |
While this means that extensions should, as a defense-in-depth mechanism, |
165 |
always consider whether OSC sequences are safe, autoloading automatically |
166 |
exposes any autoloaded extension in all terminal windows, so extra care |
167 |
should be taken. |
168 |
|
169 |
Example: the background extension registers OSC C<20> like this: |
170 |
|
171 |
#:META:OSC:20:change/query background image |
172 |
|
173 |
=item #:META:OSC_PERL:prefix:desc |
174 |
|
175 |
The same as the OSC comment, but for the Perl OSC sequence (C<777>). The |
176 |
C<prefix> should be unique among extensions, of course, which is most |
177 |
easily arranged by using the extension name, although this is not |
178 |
required. |
179 |
|
180 |
Example: the overlay-osc extension registers its Perl OSC like this: |
181 |
|
182 |
#:META:OSC_PERL:overlay:man overlay-osc |
183 |
|
184 |
=back |
185 |
|
186 |
=head2 Hooks |
187 |
|
188 |
The following subroutines can be declared in extension files, and will be |
189 |
called whenever the relevant event happens. |
190 |
|
191 |
The first argument passed to them is an extension object as described in |
192 |
the in the C<Extension Objects> section. |
193 |
|
194 |
B<All> of these hooks must return a boolean value. If any of the called |
195 |
hooks returns true, then the event counts as being I<consumed>, and the |
196 |
relevant action might not be carried out by the C++ code. |
197 |
|
198 |
I<< When in doubt, return a false value (preferably C<()>). >> |
199 |
|
200 |
=over |
201 |
|
202 |
=item on_attach $term |
203 |
|
204 |
Called when an extension package is attached to a running terminal |
205 |
instance. Must return true in all cases, and runs with the same |
206 |
limitations as C<on_init>. |
207 |
|
208 |
Unlike C<on_init> or C<on_start>, this is called when the extension is |
209 |
attached to a terminal, regardless of whether the extension is loaded |
210 |
before or after the terminal is started. Extensions that need to do |
211 |
something before they work can do it in this callback, as opposed to e.g. |
212 |
C<on_init>, which might not be called. |
213 |
|
214 |
=item on_init $term |
215 |
|
216 |
Called after a new terminal object has been initialized, but before |
217 |
windows are created or the command gets run. Most methods are unsafe to |
218 |
call or deliver senseless data, as terminal size and other characteristics |
219 |
have not yet been determined. You can safely query and change resources |
220 |
and options, though. For many purposes the C<on_start> hook is a better |
221 |
place. |
222 |
|
223 |
=item on_start $term |
224 |
|
225 |
Called at the very end of initialisation of a new terminal, just before |
226 |
trying to map (display) the toplevel and returning to the main loop. |
227 |
|
228 |
=item on_destroy $term |
229 |
|
230 |
Called whenever something tries to destroy terminal, when the terminal is |
231 |
still fully functional (not for long, though). |
232 |
|
233 |
=item on_reset $term |
234 |
|
235 |
Called after the screen is "reset" for any reason, such as resizing or |
236 |
control sequences. Here is where you can react on changes to size-related |
237 |
variables. |
238 |
|
239 |
=item on_child_start $term, $pid |
240 |
|
241 |
Called just after the child process has been C<fork>ed. |
242 |
|
243 |
=item on_child_exit $term, $status |
244 |
|
245 |
Called just after the child process has exited. C<$status> is the status |
246 |
from C<waitpid>. |
247 |
|
248 |
=item on_sel_make $term, $eventtime |
249 |
|
250 |
Called whenever a selection has been made by the user, but before the |
251 |
selection text is copied, so changes to the beginning, end or type of the |
252 |
selection will be honored. |
253 |
|
254 |
Returning a true value aborts selection making by urxvt, in which case you |
255 |
have to make a selection yourself by calling C<< $term->selection_grab >>. |
256 |
|
257 |
=item on_sel_grab $term, $eventtime |
258 |
|
259 |
Called whenever a selection has been copied, but before the selection is |
260 |
requested from the server. The selection text can be queried and changed |
261 |
by calling C<< $term->selection >>. |
262 |
|
263 |
Returning a true value aborts selection grabbing. It will still be highlighted. |
264 |
|
265 |
=item on_sel_extend $term |
266 |
|
267 |
Called whenever the user tries to extend the selection (e.g. with a double |
268 |
click) and is either supposed to return false (normal operation), or |
269 |
should extend the selection itself and return true to suppress the built-in |
270 |
processing. This can happen multiple times, as long as the callback |
271 |
returns true, it will be called on every further click by the user and is |
272 |
supposed to enlarge the selection more and more, if possible. |
273 |
|
274 |
See the F<selection> example extension. |
275 |
|
276 |
=item on_view_change $term, $offset |
277 |
|
278 |
Called whenever the view offset changes, i.e. the user or program |
279 |
scrolls. Offset C<0> means display the normal terminal, positive values |
280 |
show this many lines of scrollback. |
281 |
|
282 |
=item on_scroll_back $term, $lines, $saved |
283 |
|
284 |
Called whenever lines scroll out of the terminal area into the scrollback |
285 |
buffer. C<$lines> is the number of lines scrolled out and may be larger |
286 |
than the scroll back buffer or the terminal. |
287 |
|
288 |
It is called before lines are scrolled out (so rows 0 .. min ($lines - 1, |
289 |
$nrow - 1) represent the lines to be scrolled out). C<$saved> is the total |
290 |
number of lines that will be in the scrollback buffer. |
291 |
|
292 |
=item on_osc_seq $term, $op, $args, $resp |
293 |
|
294 |
Called on every OSC sequence and can be used to suppress it or modify its |
295 |
behaviour. The default should be to return an empty list. A true value |
296 |
suppresses execution of the request completely. Make sure you don't get |
297 |
confused by recursive invocations when you output an OSC sequence within |
298 |
this callback. |
299 |
|
300 |
C<on_osc_seq_perl> should be used for new behaviour. |
301 |
|
302 |
=item on_osc_seq_perl $term, $args, $resp |
303 |
|
304 |
Called whenever the B<ESC ] 777 ; prefix ; string ST> command sequence |
305 |
(OSC = operating system command) is processed. Cursor position and other |
306 |
state information is up-to-date when this happens. For interoperability, |
307 |
the argument should start with the extension name (sans -osc) or some |
308 |
other suitable prefix, and a semicolon, to distinguish it from commands |
309 |
for other extensions. |
310 |
|
311 |
For example, C<overlay-osc> uses this: |
312 |
|
313 |
sub on_osc_seq_perl { |
314 |
my ($self, $osc, $resp) = @_; |
315 |
|
316 |
return unless $osc =~ s/^overlay;//; |
317 |
|
318 |
... process remaining $osc string |
319 |
} |
320 |
|
321 |
Be careful not ever to trust (in a security sense) the data you receive, |
322 |
as its source can not easily be controlled (e-mail content, messages from |
323 |
other users on the same system etc.). |
324 |
|
325 |
For responses, C<$resp> contains the end-of-args separator used by the |
326 |
sender. |
327 |
|
328 |
=item on_add_lines $term, $string |
329 |
|
330 |
Called whenever text is about to be output, with the text as argument. You |
331 |
can filter/change and output the text yourself by returning a true value |
332 |
and calling C<< $term->scr_add_lines >> yourself. Please note that this |
333 |
might be very slow, however, as your hook is called for B<all> text being |
334 |
output. |
335 |
|
336 |
=item on_tt_write $term, $octets |
337 |
|
338 |
Called whenever some data is written to the tty/pty and can be used to |
339 |
suppress or filter tty input. |
340 |
|
341 |
=item on_tt_paste $term, $octets |
342 |
|
343 |
Called whenever text is about to be pasted, with the text as argument. You |
344 |
can filter/change and paste the text yourself by returning a true value |
345 |
and calling C<< $term->tt_paste >> yourself. C<$octets> is |
346 |
locale-encoded. |
347 |
|
348 |
=item on_line_update $term, $row |
349 |
|
350 |
Called whenever a line was updated or changed. Can be used to filter |
351 |
screen output (e.g. underline urls or other useless stuff). Only lines |
352 |
that are being shown will be filtered, and, due to performance reasons, |
353 |
not always immediately. |
354 |
|
355 |
The row number is always the topmost row of the line if the line spans |
356 |
multiple rows. |
357 |
|
358 |
Please note that, if you change the line, then the hook might get called |
359 |
later with the already-modified line (e.g. if unrelated parts change), so |
360 |
you cannot just toggle rendition bits, but only set them. |
361 |
|
362 |
=item on_refresh_begin $term |
363 |
|
364 |
Called just before the screen gets redrawn. Can be used for overlay or |
365 |
similar effects by modifying the terminal contents in refresh_begin, and |
366 |
restoring them in refresh_end. The built-in overlay and selection display |
367 |
code is run after this hook, and takes precedence. |
368 |
|
369 |
=item on_refresh_end $term |
370 |
|
371 |
Called just after the screen gets redrawn. See C<on_refresh_begin>. |
372 |
|
373 |
=item on_action $term, $string |
374 |
|
375 |
Called whenever an action is invoked for the corresponding extension |
376 |
(e.g. via a C<extension:string> builtin action bound to a key, see |
377 |
description of the B<keysym> resource in the urxvt(1) manpage). The |
378 |
event is simply the action string. Note that an action event is always |
379 |
associated to a single extension. |
380 |
|
381 |
=item on_user_command $term, $string *DEPRECATED* |
382 |
|
383 |
Called whenever a user-configured event is being activated (e.g. via |
384 |
a C<perl:string> action bound to a key, see description of the B<keysym> |
385 |
resource in the urxvt(1) manpage). |
386 |
|
387 |
The event is simply the action string. This interface is going away in |
388 |
preference to the C<on_action> hook. |
389 |
|
390 |
=item on_resize_all_windows $term, $new_width, $new_height |
391 |
|
392 |
Called just after the new window size has been calculated, but before |
393 |
windows are actually being resized or hints are being set. If this hook |
394 |
returns a true value, setting of the window hints is being skipped. |
395 |
|
396 |
=item on_x_event $term, $event |
397 |
|
398 |
Called on every X event received on the vt window (and possibly other |
399 |
windows). Should only be used as a last resort. Most event structure |
400 |
members are not passed. |
401 |
|
402 |
=item on_root_event $term, $event |
403 |
|
404 |
Like C<on_x_event>, but is called for events on the root window. |
405 |
|
406 |
=item on_focus_in $term |
407 |
|
408 |
Called whenever the window gets the keyboard focus, before rxvt-unicode |
409 |
does focus in processing. |
410 |
|
411 |
=item on_focus_out $term |
412 |
|
413 |
Called whenever the window loses keyboard focus, before rxvt-unicode does |
414 |
focus out processing. |
415 |
|
416 |
=item on_configure_notify $term, $event |
417 |
|
418 |
=item on_property_notify $term, $event |
419 |
|
420 |
=item on_key_press $term, $event, $keysym, $octets |
421 |
|
422 |
=item on_key_release $term, $event, $keysym |
423 |
|
424 |
=item on_button_press $term, $event |
425 |
|
426 |
=item on_button_release $term, $event |
427 |
|
428 |
=item on_motion_notify $term, $event |
429 |
|
430 |
=item on_map_notify $term, $event |
431 |
|
432 |
=item on_unmap_notify $term, $event |
433 |
|
434 |
Called whenever the corresponding X event is received for the terminal. If |
435 |
the hook returns true, then the event will be ignored by rxvt-unicode. |
436 |
|
437 |
The event is a hash with most values as named by Xlib (see the XEvent |
438 |
manpage), with the additional members C<row> and C<col>, which are the |
439 |
(real, not screen-based) row and column under the mouse cursor. |
440 |
|
441 |
C<on_key_press> additionally receives the string rxvt-unicode would |
442 |
output, if any, in locale-specific encoding. |
443 |
|
444 |
=item on_client_message $term, $event |
445 |
|
446 |
=item on_wm_protocols $term, $event |
447 |
|
448 |
=item on_wm_delete_window $term, $event |
449 |
|
450 |
Called when various types of ClientMessage events are received (all with |
451 |
format=32, WM_PROTOCOLS or WM_PROTOCOLS:WM_DELETE_WINDOW). |
452 |
|
453 |
=item on_bell $term |
454 |
|
455 |
Called on receipt of a bell character. |
456 |
|
457 |
=back |
458 |
|
459 |
=cut |
460 |
|
461 |
package urxvt; |
462 |
|
463 |
use utf8; |
464 |
use strict qw(vars subs); |
465 |
use Carp (); |
466 |
use Scalar::Util (); |
467 |
use List::Util (); |
468 |
|
469 |
our $VERSION = 1; |
470 |
our $TERM; |
471 |
our @TERM_INIT; # should go, prevents async I/O etc. |
472 |
our @TERM_EXT; # should go, prevents async I/O etc. |
473 |
our @HOOKNAME; |
474 |
our %HOOKTYPE = map +($HOOKNAME[$_] => $_), 0..$#HOOKNAME; |
475 |
our %OPTION; |
476 |
|
477 |
our $LIBDIR; |
478 |
our $RESNAME; |
479 |
our $RESCLASS; |
480 |
our $RXVTNAME; |
481 |
|
482 |
our $NOCHAR = chr 0xffff; |
483 |
|
484 |
=head2 Variables in the C<urxvt> Package |
485 |
|
486 |
=over |
487 |
|
488 |
=item $urxvt::LIBDIR |
489 |
|
490 |
The rxvt-unicode library directory, where, among other things, the perl |
491 |
modules and scripts are stored. |
492 |
|
493 |
=item $urxvt::RESCLASS, $urxvt::RESCLASS |
494 |
|
495 |
The resource class and name rxvt-unicode uses to look up X resources. |
496 |
|
497 |
=item $urxvt::RXVTNAME |
498 |
|
499 |
The basename of the installed binaries, usually C<urxvt>. |
500 |
|
501 |
=item $urxvt::TERM |
502 |
|
503 |
The current terminal. This variable stores the current C<urxvt::term> |
504 |
object, whenever a callback/hook is executing. |
505 |
|
506 |
=item @urxvt::TERM_INIT |
507 |
|
508 |
All code references in this array will be called as methods of the next newly |
509 |
created C<urxvt::term> object (during the C<on_init> phase). The array |
510 |
gets cleared before the code references that were in it are being executed, |
511 |
so references can push themselves onto it again if they so desire. |
512 |
|
513 |
This complements to the perl-eval command line option, but gets executed |
514 |
first. |
515 |
|
516 |
=item @urxvt::TERM_EXT |
517 |
|
518 |
Works similar to C<@TERM_INIT>, but contains perl package/class names, which |
519 |
get registered as normal extensions after calling the hooks in C<@TERM_INIT> |
520 |
but before other extensions. Gets cleared just like C<@TERM_INIT>. |
521 |
|
522 |
=back |
523 |
|
524 |
=head2 Functions in the C<urxvt> Package |
525 |
|
526 |
=over |
527 |
|
528 |
=item urxvt::fatal $errormessage |
529 |
|
530 |
Fatally aborts execution with the given error message (which should |
531 |
include a trailing newline). Avoid at all costs! The only time this |
532 |
is acceptable (and useful) is in the init hook, where it prevents the |
533 |
terminal from starting up. |
534 |
|
535 |
=item urxvt::warn $string |
536 |
|
537 |
Calls C<rxvt_warn> with the given string which should include a trailing |
538 |
newline. The module also overwrites the C<warn> builtin with a function |
539 |
that calls this function. |
540 |
|
541 |
Using this function has the advantage that its output ends up in the |
542 |
correct place, e.g. on stderr of the connecting urxvtc client. |
543 |
|
544 |
Messages have a size limit of 1023 bytes currently. |
545 |
|
546 |
=item @terms = urxvt::termlist |
547 |
|
548 |
Returns all urxvt::term objects that exist in this process, regardless of |
549 |
whether they are started, being destroyed etc., so be careful. Only term |
550 |
objects that have perl extensions attached will be returned (because there |
551 |
is no urxvt::term object associated with others). |
552 |
|
553 |
=item $time = urxvt::NOW |
554 |
|
555 |
Returns the "current time" (as per the event loop). |
556 |
|
557 |
=item urxvt::CurrentTime |
558 |
|
559 |
=item urxvt::ShiftMask, LockMask, ControlMask, Mod1Mask, Mod2Mask, |
560 |
Mod3Mask, Mod4Mask, Mod5Mask, Button1Mask, Button2Mask, Button3Mask, |
561 |
Button4Mask, Button5Mask, AnyModifier |
562 |
|
563 |
=item urxvt::NoEventMask, KeyPressMask, KeyReleaseMask, |
564 |
ButtonPressMask, ButtonReleaseMask, EnterWindowMask, LeaveWindowMask, |
565 |
PointerMotionMask, PointerMotionHintMask, Button1MotionMask, Button2MotionMask, |
566 |
Button3MotionMask, Button4MotionMask, Button5MotionMask, ButtonMotionMask, |
567 |
KeymapStateMask, ExposureMask, VisibilityChangeMask, StructureNotifyMask, |
568 |
ResizeRedirectMask, SubstructureNotifyMask, SubstructureRedirectMask, |
569 |
FocusChangeMask, PropertyChangeMask, ColormapChangeMask, OwnerGrabButtonMask |
570 |
|
571 |
=item urxvt::KeyPress, KeyRelease, ButtonPress, ButtonRelease, MotionNotify, |
572 |
EnterNotify, LeaveNotify, FocusIn, FocusOut, KeymapNotify, Expose, |
573 |
GraphicsExpose, NoExpose, VisibilityNotify, CreateNotify, DestroyNotify, |
574 |
UnmapNotify, MapNotify, MapRequest, ReparentNotify, ConfigureNotify, |
575 |
ConfigureRequest, GravityNotify, ResizeRequest, CirculateNotify, |
576 |
CirculateRequest, PropertyNotify, SelectionClear, SelectionRequest, |
577 |
SelectionNotify, ColormapNotify, ClientMessage, MappingNotify |
578 |
|
579 |
Various constants for use in X calls and event processing. |
580 |
|
581 |
=item urxvt::PrivMode_132, PrivMode_132OK, PrivMode_rVideo, PrivMode_relOrigin, |
582 |
PrivMode_Screen, PrivMode_Autowrap, PrivMode_aplCUR, PrivMode_aplKP, |
583 |
PrivMode_HaveBackSpace, PrivMode_BackSpace, PrivMode_ShiftKeys, |
584 |
PrivMode_VisibleCursor, PrivMode_MouseX10, PrivMode_MouseX11, |
585 |
PrivMode_scrollBar, PrivMode_TtyOutputInh, PrivMode_Keypress, |
586 |
PrivMode_smoothScroll, PrivMode_vt52, PrivMode_LFNL, PrivMode_MouseBtnEvent, |
587 |
PrivMode_MouseAnyEvent, PrivMode_BracketPaste, PrivMode_ExtMouseUTF8, |
588 |
PrivMode_ExtMouseUrxvt, PrivMode_BlinkingCursor, PrivMode_mouse_report, |
589 |
PrivMode_Default |
590 |
|
591 |
Constants for checking DEC private modes. |
592 |
|
593 |
=back |
594 |
|
595 |
=head2 RENDITION |
596 |
|
597 |
Rendition bitsets contain information about colour, font, font styles and |
598 |
similar information for each screen cell. |
599 |
|
600 |
The following "macros" deal with changes in rendition sets. You should |
601 |
never just create a bitset, you should always modify an existing one, |
602 |
as they contain important information required for correct operation of |
603 |
rxvt-unicode. |
604 |
|
605 |
=over |
606 |
|
607 |
=item $rend = urxvt::DEFAULT_RSTYLE |
608 |
|
609 |
Returns the default rendition, as used when the terminal is starting up or |
610 |
being reset. Useful as a base to start when creating renditions. |
611 |
|
612 |
=item $rend = urxvt::OVERLAY_RSTYLE |
613 |
|
614 |
Return the rendition mask used for overlays by default. |
615 |
|
616 |
=item $rendbit = urxvt::RS_Bold, urxvt::RS_Italic, urxvt::RS_Blink, |
617 |
urxvt::RS_RVid, urxvt::RS_Uline |
618 |
|
619 |
Return the bit that enabled bold, italic, blink, reverse-video and |
620 |
underline, respectively. To enable such a style, just logically OR it into |
621 |
the bitset. |
622 |
|
623 |
=item $foreground = urxvt::GET_BASEFG $rend |
624 |
|
625 |
=item $background = urxvt::GET_BASEBG $rend |
626 |
|
627 |
Return the foreground/background colour index, respectively. |
628 |
|
629 |
=item $rend = urxvt::SET_FGCOLOR $rend, $new_colour |
630 |
|
631 |
=item $rend = urxvt::SET_BGCOLOR $rend, $new_colour |
632 |
|
633 |
=item $rend = urxvt::SET_COLOR $rend, $new_fg, $new_bg |
634 |
|
635 |
Replace the foreground/background colour in the rendition mask with the |
636 |
specified one. |
637 |
|
638 |
=item $value = urxvt::GET_CUSTOM $rend |
639 |
|
640 |
Return the "custom" value: Every rendition has 5 bits for use by |
641 |
extensions. They can be set and changed as you like and are initially |
642 |
zero. |
643 |
|
644 |
=item $rend = urxvt::SET_CUSTOM $rend, $new_value |
645 |
|
646 |
Change the custom value. |
647 |
|
648 |
=back |
649 |
|
650 |
=cut |
651 |
|
652 |
BEGIN { |
653 |
# overwrite perl's warn |
654 |
*CORE::GLOBAL::warn = sub { |
655 |
my $msg = join "", @_; |
656 |
$msg .= "\n" |
657 |
unless $msg =~ /\n$/; |
658 |
urxvt::warn ($msg); |
659 |
}; |
660 |
} |
661 |
|
662 |
no warnings 'utf8'; |
663 |
|
664 |
sub parse_resource { |
665 |
my ($term, $name, $isarg, $longopt, $flag, $value) = @_; |
666 |
|
667 |
$term->scan_extensions; |
668 |
|
669 |
# iterating over all resources has quadratic time overhead |
670 |
# overall, maybe this could be optimised? |
671 |
my $r = $term->{meta}{resource}; |
672 |
keys %$r; # reset iterator |
673 |
while (my ($k, $v) = each %$r) { |
674 |
my $pattern = $k; |
675 |
$pattern =~ y/./-/ if $isarg; |
676 |
my $prefix = $name; |
677 |
my $suffix; |
678 |
if ($pattern =~ /\-$/) { |
679 |
$prefix = substr $name, 0, length $pattern; |
680 |
$suffix = substr $name, length $pattern; |
681 |
} |
682 |
if ($pattern eq $prefix) { |
683 |
$name = "$urxvt::RESCLASS.$k$suffix"; |
684 |
|
685 |
push @{ $term->{perl_ext_3} }, $v->[0]; |
686 |
|
687 |
return 1 unless $isarg; |
688 |
|
689 |
if ($v->[1] eq "boolean") { |
690 |
$term->put_option_db ($name, $flag ? "true" : "false"); |
691 |
return 1; |
692 |
} else { |
693 |
$term->put_option_db ($name, $value); |
694 |
return 1 + 2; |
695 |
} |
696 |
} |
697 |
} |
698 |
|
699 |
0 |
700 |
} |
701 |
|
702 |
sub usage { |
703 |
my ($term, $usage_type) = @_; |
704 |
|
705 |
$term->scan_extensions; |
706 |
|
707 |
my $r = $term->{meta}{resource}; |
708 |
|
709 |
for my $pattern (sort keys %$r) { |
710 |
my ($ext, $type, $desc) = @{ $r->{$pattern} }; |
711 |
|
712 |
$desc .= " (-pe $ext)"; |
713 |
|
714 |
if ($usage_type == 1) { |
715 |
$pattern =~ y/./-/; |
716 |
$pattern =~ s/-$/-.../g; |
717 |
|
718 |
if ($type eq "boolean") { |
719 |
urxvt::log sprintf " -%-30s %s\n", "/+$pattern", $desc; |
720 |
} else { |
721 |
urxvt::log sprintf " -%-30s %s\n", "$pattern $type", $desc; |
722 |
} |
723 |
} else { |
724 |
$pattern =~ s/\.$/.*/g; |
725 |
urxvt::log sprintf " %-31s %s\n", "$pattern:", $type; |
726 |
} |
727 |
} |
728 |
} |
729 |
|
730 |
my $verbosity = $ENV{URXVT_PERL_VERBOSITY} // 2; |
731 |
|
732 |
sub verbose { |
733 |
my ($level, $msg) = @_; |
734 |
warn "$msg\n" if $level <= $verbosity; |
735 |
} |
736 |
|
737 |
my %extension_pkg; |
738 |
|
739 |
# load a single script into its own package, once only |
740 |
sub extension_package($) { |
741 |
my ($path) = @_; |
742 |
|
743 |
$extension_pkg{$path} ||= do { |
744 |
$path =~ /([^\/\\]+)$/; |
745 |
my $pkg = $1; |
746 |
$pkg =~ s/[^[:word:]]/_/g; |
747 |
$pkg = "urxvt::ext::$pkg"; |
748 |
|
749 |
verbose 3, "loading extension '$path' into package '$pkg'"; |
750 |
|
751 |
(${"$pkg\::_NAME"} = $path) =~ s/^.*[\\\/]//; # hackish |
752 |
|
753 |
open my $fh, "<:raw", $path |
754 |
or die "$path: $!"; |
755 |
|
756 |
my $source = |
757 |
"package $pkg; use strict qw(vars subs); use utf8; no warnings 'utf8';\n" |
758 |
. "#line 1 \"$path\"\n{\n" |
759 |
. (do { local $/; <$fh> }) |
760 |
. "\n};\n1"; |
761 |
|
762 |
eval $source |
763 |
or die "$path: $@"; |
764 |
|
765 |
$pkg |
766 |
} |
767 |
} |
768 |
|
769 |
our $retval; # return value for urxvt |
770 |
|
771 |
# called by the rxvt core |
772 |
sub invoke { |
773 |
local $TERM = shift; |
774 |
my $htype = shift; |
775 |
|
776 |
if ($htype == HOOK_INIT) { |
777 |
$TERM->scan_extensions; |
778 |
|
779 |
my %ext_arg; |
780 |
|
781 |
{ |
782 |
my @init = @TERM_INIT; |
783 |
@TERM_INIT = (); |
784 |
$_->($TERM) for @init; |
785 |
my @pkg = @TERM_EXT; |
786 |
@TERM_EXT = (); |
787 |
$TERM->register_package ($_) for @pkg; |
788 |
} |
789 |
|
790 |
for ( |
791 |
@{ delete $TERM->{perl_ext_3} }, |
792 |
(grep $_, map { split /,/, $TERM->resource ("perl_ext_$_") } 1, 2), |
793 |
) { |
794 |
if ($_ eq "default") { |
795 |
|
796 |
$ext_arg{$_} = [] |
797 |
for qw(selection option-popup selection-popup readline searchable-scrollback confirm-paste); |
798 |
|
799 |
for ($TERM->_keysym_resources) { |
800 |
next if /^(?:string|command|builtin|builtin-string|perl)/; |
801 |
next unless /^([A-Za-z0-9_\-]+):/; |
802 |
|
803 |
my $ext = $1; |
804 |
|
805 |
$ext_arg{$ext} = []; |
806 |
} |
807 |
|
808 |
} elsif (/^-(.*)$/) { # remove from set |
809 |
delete $ext_arg{$1}; |
810 |
|
811 |
} elsif (/^\/(.*)$/) { # prohibit loading |
812 |
undef $TERM->{ext_prohibit}{$1}; |
813 |
|
814 |
} elsif (/^([^<]+)(?:<(.*)>)?$/) { # add to set, clear prohibit status |
815 |
delete $TERM->{ext_prohibit}{$1}; |
816 |
push @{ $ext_arg{$1} }, defined $2 ? $2 : (); |
817 |
|
818 |
} else { |
819 |
verbose 2, "cannot parse extension specification '$_', ignoring."; |
820 |
} |
821 |
} |
822 |
|
823 |
$TERM->set_should_invoke (HOOK_OSC_SEQ , +1) if $TERM->{meta}{autoload_osc}; |
824 |
$TERM->set_should_invoke (HOOK_OSC_SEQ_PERL, +1) if $TERM->{meta}{autoload_osc_perl}; |
825 |
|
826 |
for my $ext (sort keys %ext_arg) { |
827 |
my $path = $TERM->extension_path ($ext); |
828 |
|
829 |
if (defined $path) { |
830 |
$TERM->autoload_extension ($ext, $ext_arg{$ext}); |
831 |
} else { |
832 |
verbose 2, "perl extension '$ext' not found in perl library search path"; |
833 |
} |
834 |
} |
835 |
|
836 |
eval "#line 1 \"--perl-eval resource/argument\"\n" . $TERM->resource ("perl_eval"); |
837 |
warn $@ if $@; |
838 |
} |
839 |
|
840 |
if ($htype == HOOK_OSC_SEQ) { |
841 |
if (my $exts = delete $TERM->{meta}{autoload_osc}{$_[0]}) { |
842 |
$TERM->autoload_extension ($_->[0]) for @$exts; |
843 |
} |
844 |
} elsif ($htype == HOOK_OSC_SEQ_PERL) { |
845 |
if ($_[0] =~ /^([^;]+)/ and (my $exts = delete $TERM->{meta}{autoload_osc_perl}{$1})) { |
846 |
$TERM->autoload_extension ($_->[0]) for @$exts; |
847 |
} |
848 |
} |
849 |
|
850 |
$retval = undef; |
851 |
|
852 |
if (my $cb = $TERM->{_hook}[$htype]) { |
853 |
verbose 10, "$HOOKNAME[$htype] (" . (join ", ", $TERM, @_) . ")" |
854 |
if $verbosity >= 10; |
855 |
|
856 |
if ($htype == HOOK_ACTION) { |
857 |
# this hook is only sent to the extension with the name |
858 |
# matching the first arg |
859 |
my $pkg = shift; |
860 |
$pkg =~ y/-/_/; |
861 |
$pkg = "urxvt::ext::$pkg"; |
862 |
|
863 |
$cb = $cb->{$pkg} |
864 |
or return undef; #TODO: maybe warn user? |
865 |
|
866 |
$cb = { $pkg => $cb }; |
867 |
} |
868 |
|
869 |
for my $pkg (keys %$cb) { |
870 |
my $retval_ = eval { $cb->{$pkg}->($TERM->{_pkg}{$pkg} || $TERM, @_) }; |
871 |
$retval ||= $retval_; |
872 |
|
873 |
if ($@) { |
874 |
$TERM->ungrab; # better to lose the grab than the session |
875 |
warn $@; |
876 |
} |
877 |
} |
878 |
|
879 |
verbose 11, "$HOOKNAME[$htype] returning <$retval>" |
880 |
if $verbosity >= 11; |
881 |
} |
882 |
|
883 |
if ($htype == HOOK_DESTROY) { |
884 |
# clear package objects |
885 |
%$_ = () for values %{ $TERM->{_pkg} }; |
886 |
|
887 |
# clear package |
888 |
%$TERM = (); |
889 |
} |
890 |
|
891 |
$retval |
892 |
} |
893 |
|
894 |
sub SET_COLOR($$$) { |
895 |
SET_BGCOLOR (SET_FGCOLOR ($_[0], $_[1]), $_[2]) |
896 |
} |
897 |
|
898 |
sub rend2mask { |
899 |
no strict 'refs'; |
900 |
my ($str, $mask) = (@_, 0); |
901 |
my %color = ( fg => undef, bg => undef ); |
902 |
my @failed; |
903 |
for my $spec ( split /\s+/, $str ) { |
904 |
if ( $spec =~ /^([fb]g)[_:-]?(\d+)/i ) { |
905 |
$color{lc($1)} = $2; |
906 |
} else { |
907 |
my $neg = $spec =~ s/^[-^]//; |
908 |
unless ( exists &{"RS_$spec"} ) { |
909 |
push @failed, $spec; |
910 |
next; |
911 |
} |
912 |
my $cur = &{"RS_$spec"}; |
913 |
if ( $neg ) { |
914 |
$mask &= ~$cur; |
915 |
} else { |
916 |
$mask |= $cur; |
917 |
} |
918 |
} |
919 |
} |
920 |
($mask, @color{qw(fg bg)}, \@failed) |
921 |
} |
922 |
|
923 |
package urxvt::term::extension; |
924 |
|
925 |
=head2 The C<urxvt::term::extension> class |
926 |
|
927 |
Each extension attached to a terminal object is represented by |
928 |
a C<urxvt::term::extension> object. |
929 |
|
930 |
You can use these objects, which are passed to all callbacks to store any |
931 |
state related to the terminal and extension instance. |
932 |
|
933 |
The methods (And data members) documented below can be called on extension |
934 |
objects, in addition to call methods documented for the <urxvt::term> |
935 |
class. |
936 |
|
937 |
=over |
938 |
|
939 |
=item $urxvt_term = $self->{term} |
940 |
|
941 |
Returns the C<urxvt::term> object associated with this instance of the |
942 |
extension. This member I<must not> be changed in any way. |
943 |
|
944 |
=cut |
945 |
|
946 |
our $AUTOLOAD; |
947 |
|
948 |
sub AUTOLOAD { |
949 |
$AUTOLOAD =~ /:([^:]+)$/ |
950 |
or die "FATAL: \$AUTOLOAD '$AUTOLOAD' unparsable"; |
951 |
|
952 |
eval qq{ |
953 |
sub $AUTOLOAD { |
954 |
my \$proxy = shift; |
955 |
\$proxy->{term}->$1 (\@_) |
956 |
} |
957 |
1 |
958 |
} or die "FATAL: unable to compile method forwarder: $@"; |
959 |
|
960 |
goto &$AUTOLOAD; |
961 |
} |
962 |
|
963 |
sub DESTROY { |
964 |
# nop |
965 |
} |
966 |
|
967 |
# urxvt::destroy_hook (basically a cheap Guard:: implementation) |
968 |
|
969 |
sub urxvt::destroy_hook::DESTROY { |
970 |
${$_[0]}->(); |
971 |
} |
972 |
|
973 |
sub urxvt::destroy_hook(&) { |
974 |
bless \shift, urxvt::destroy_hook:: |
975 |
} |
976 |
|
977 |
=item $self->enable ($hook_name => $cb[, $hook_name => $cb..]) |
978 |
|
979 |
Dynamically enable the given hooks (named without the C<on_> prefix) for |
980 |
this extension, replacing any hook previously installed via C<enable> in |
981 |
this extension. |
982 |
|
983 |
This is useful when you want to overwrite time-critical hooks only |
984 |
temporarily. |
985 |
|
986 |
To install additional callbacks for the same hook, you can use the C<on> |
987 |
method of the C<urxvt::term> class. |
988 |
|
989 |
=item $self->disable ($hook_name[, $hook_name..]) |
990 |
|
991 |
Dynamically disable the given hooks. |
992 |
|
993 |
=cut |
994 |
|
995 |
sub enable { |
996 |
my ($self, %hook) = @_; |
997 |
my $pkg = $self->{_pkg}; |
998 |
|
999 |
while (my ($name, $cb) = each %hook) { |
1000 |
my $htype = $HOOKTYPE{uc $name}; |
1001 |
defined $htype |
1002 |
or Carp::croak "unsupported hook type '$name'"; |
1003 |
|
1004 |
$self->set_should_invoke ($htype, +1) |
1005 |
unless exists $self->{term}{_hook}[$htype]{$pkg}; |
1006 |
|
1007 |
$self->{term}{_hook}[$htype]{$pkg} = $cb; |
1008 |
} |
1009 |
} |
1010 |
|
1011 |
sub disable { |
1012 |
my ($self, @hook) = @_; |
1013 |
my $pkg = $self->{_pkg}; |
1014 |
|
1015 |
for my $name (@hook) { |
1016 |
my $htype = $HOOKTYPE{uc $name}; |
1017 |
defined $htype |
1018 |
or Carp::croak "unsupported hook type '$name'"; |
1019 |
|
1020 |
$self->set_should_invoke ($htype, -1) |
1021 |
if delete $self->{term}{_hook}[$htype]{$pkg}; |
1022 |
} |
1023 |
} |
1024 |
|
1025 |
=item $guard = $self->on ($hook_name => $cb[, $hook_name => $cb..]) |
1026 |
|
1027 |
Similar to the C<enable> enable, but installs additional callbacks for |
1028 |
the given hook(s) (that is, it doesn't replace existing callbacks), and |
1029 |
returns a guard object. When the guard object is destroyed the callbacks |
1030 |
are disabled again. |
1031 |
|
1032 |
=cut |
1033 |
|
1034 |
sub urxvt::extension::on_disable::DESTROY { |
1035 |
my $disable = shift; |
1036 |
|
1037 |
my $term = delete $disable->{""}; |
1038 |
|
1039 |
while (my ($htype, $id) = each %$disable) { |
1040 |
delete $term->{_hook}[$htype]{$id}; |
1041 |
$term->set_should_invoke ($htype, -1); |
1042 |
} |
1043 |
} |
1044 |
|
1045 |
sub on { |
1046 |
my ($self, %hook) = @_; |
1047 |
|
1048 |
my $term = $self->{term}; |
1049 |
|
1050 |
my %disable = ( "" => $term ); |
1051 |
|
1052 |
while (my ($name, $cb) = each %hook) { |
1053 |
my $htype = $HOOKTYPE{uc $name}; |
1054 |
defined $htype |
1055 |
or Carp::croak "unsupported hook type '$name'"; |
1056 |
|
1057 |
$term->set_should_invoke ($htype, +1); |
1058 |
$term->{_hook}[$htype]{ $disable{$htype} = $cb+0 } |
1059 |
= sub { shift; $cb->($self, @_) }; # very ugly indeed |
1060 |
} |
1061 |
|
1062 |
bless \%disable, "urxvt::extension::on_disable" |
1063 |
} |
1064 |
|
1065 |
=item $self->bind_action ($hotkey, $action) |
1066 |
|
1067 |
=item $self->x_resource ($pattern) |
1068 |
|
1069 |
=item $self->x_resource_boolean ($pattern) |
1070 |
|
1071 |
These methods support an additional C<%> prefix for C<$action> or |
1072 |
C<$pattern> when called on an extension object, compared to the |
1073 |
C<urxvt::term> methods of the same name - see the description of these |
1074 |
methods in the C<urxvt::term> class for details. |
1075 |
|
1076 |
=cut |
1077 |
|
1078 |
sub bind_action { |
1079 |
my ($self, $hotkey, $action) = @_; |
1080 |
$action =~ s/^%:/$_[0]{_name}:/; |
1081 |
$self->{term}->bind_action ($hotkey, $action) |
1082 |
} |
1083 |
|
1084 |
sub x_resource { |
1085 |
my ($self, $name) = @_; |
1086 |
$name =~ s/^%(\.|$)/$_[0]{_name}$1/; |
1087 |
$self->{term}->x_resource ($name) |
1088 |
} |
1089 |
|
1090 |
sub x_resource_boolean { |
1091 |
my ($self, $name) = @_; |
1092 |
$name =~ s/^%(\.|$)/$_[0]{_name}$1/; |
1093 |
$self->{term}->x_resource_boolean ($name) |
1094 |
} |
1095 |
|
1096 |
=back |
1097 |
|
1098 |
=cut |
1099 |
|
1100 |
package urxvt::anyevent; |
1101 |
|
1102 |
=head2 The C<urxvt::anyevent> Class |
1103 |
|
1104 |
The sole purpose of this class is to deliver an interface to the |
1105 |
C<AnyEvent> module - any module using it will work inside urxvt without |
1106 |
further programming. The only exception is that you cannot wait on |
1107 |
condition variables, but non-blocking condvar use is ok. |
1108 |
|
1109 |
In practical terms this means is that you cannot use blocking APIs, but |
1110 |
the non-blocking variant should work. |
1111 |
|
1112 |
=cut |
1113 |
|
1114 |
our $VERSION = '5.23'; |
1115 |
|
1116 |
$INC{"urxvt/anyevent.pm"} = 1; # mark us as there |
1117 |
push @AnyEvent::REGISTRY, [urxvt => urxvt::anyevent::]; |
1118 |
|
1119 |
sub timer { |
1120 |
my ($class, %arg) = @_; |
1121 |
|
1122 |
my $cb = $arg{cb}; |
1123 |
|
1124 |
urxvt::timer |
1125 |
->new |
1126 |
->after ($arg{after}, $arg{interval}) |
1127 |
->cb ($arg{interval} ? $cb : sub { |
1128 |
$_[0]->stop; # need to cancel manually |
1129 |
$cb->(); |
1130 |
}) |
1131 |
} |
1132 |
|
1133 |
sub io { |
1134 |
my ($class, %arg) = @_; |
1135 |
|
1136 |
my $cb = $arg{cb}; |
1137 |
my $fd = fileno $arg{fh}; |
1138 |
defined $fd or $fd = $arg{fh}; |
1139 |
|
1140 |
bless [$arg{fh}, urxvt::iow |
1141 |
->new |
1142 |
->fd ($fd) |
1143 |
->events (($arg{poll} =~ /r/ ? 1 : 0) |
1144 |
| ($arg{poll} =~ /w/ ? 2 : 0)) |
1145 |
->start |
1146 |
->cb ($cb) |
1147 |
], urxvt::anyevent:: |
1148 |
} |
1149 |
|
1150 |
sub idle { |
1151 |
my ($class, %arg) = @_; |
1152 |
|
1153 |
my $cb = $arg{cb}; |
1154 |
|
1155 |
urxvt::iw |
1156 |
->new |
1157 |
->start |
1158 |
->cb ($cb) |
1159 |
} |
1160 |
|
1161 |
sub child { |
1162 |
my ($class, %arg) = @_; |
1163 |
|
1164 |
my $cb = $arg{cb}; |
1165 |
|
1166 |
urxvt::pw |
1167 |
->new |
1168 |
->start ($arg{pid}) |
1169 |
->cb (sub { |
1170 |
$_[0]->stop; # need to cancel manually |
1171 |
$cb->($_[0]->rpid, $_[0]->rstatus); |
1172 |
}) |
1173 |
} |
1174 |
|
1175 |
sub DESTROY { |
1176 |
$_[0][1]->stop; |
1177 |
} |
1178 |
|
1179 |
# only needed for AnyEvent < 6 compatibility |
1180 |
sub one_event { |
1181 |
Carp::croak "AnyEvent->one_event blocking wait unsupported in urxvt, use a non-blocking API"; |
1182 |
} |
1183 |
|
1184 |
package urxvt::term; |
1185 |
|
1186 |
=head2 The C<urxvt::term> Class |
1187 |
|
1188 |
=over |
1189 |
|
1190 |
=cut |
1191 |
|
1192 |
# find on_xxx subs in the package and register them |
1193 |
# as hooks |
1194 |
sub register_package { |
1195 |
my ($self, $pkg, $argv) = @_; |
1196 |
|
1197 |
return if $self->{_pkg}{$pkg}; |
1198 |
|
1199 |
no strict 'refs'; |
1200 |
|
1201 |
urxvt::verbose 6, "register package $pkg to $self"; |
1202 |
|
1203 |
@{"$pkg\::ISA"} = urxvt::term::extension::; |
1204 |
|
1205 |
my $proxy = bless { |
1206 |
_pkg => $pkg, |
1207 |
_name => ${"$pkg\::_NAME"}, # hackish |
1208 |
argv => $argv, |
1209 |
}, $pkg; |
1210 |
Scalar::Util::weaken ($proxy->{term} = $self); |
1211 |
|
1212 |
$self->{_pkg}{$pkg} = $proxy; |
1213 |
|
1214 |
for my $name (@HOOKNAME) { |
1215 |
if (my $ref = $pkg->can ("on_" . lc $name)) { |
1216 |
$proxy->enable ($name => $ref); |
1217 |
} |
1218 |
} |
1219 |
|
1220 |
if (my $attach_hook = $pkg->can ("on_attach")) { |
1221 |
$attach_hook->($proxy) |
1222 |
or urxvt::verbose 1, "$pkg->on_attach returned false, extension failed to attach"; |
1223 |
} |
1224 |
} |
1225 |
|
1226 |
# map extension name to filesystem path |
1227 |
sub extension_path { |
1228 |
(grep -f $_, map "$_/$_[1]", $_[0]->perl_libdirs)[0] |
1229 |
} |
1230 |
|
1231 |
# load an extension by name |
1232 |
sub load_extension_file { |
1233 |
my ($self, $path, $argv) = @_; |
1234 |
|
1235 |
$self->register_package (urxvt::extension_package $path, $argv); |
1236 |
} |
1237 |
|
1238 |
# autoload an extension unless loading it is prohibited |
1239 |
sub autoload_extension { |
1240 |
my ($self, $name, $argv) = @_; |
1241 |
|
1242 |
return if exists $self->{ext_prohibit}{$name}; |
1243 |
|
1244 |
my $path = $self->extension_path ($name) |
1245 |
// return urxvt::verbose 2, "perl extension '$name' not found in perl library search path (during autoload)"; |
1246 |
|
1247 |
$self->load_extension_file ($path, $argv); |
1248 |
} |
1249 |
|
1250 |
sub perl_libdirs { |
1251 |
map { split /:/ } |
1252 |
$_[0]->resource ("perl_lib"), |
1253 |
$ENV{URXVT_PERL_LIB}, |
1254 |
"$ENV{HOME}/.urxvt/ext", |
1255 |
"$LIBDIR/perl" |
1256 |
} |
1257 |
|
1258 |
# scan for available extensions and collect their metadata |
1259 |
sub scan_extensions { |
1260 |
my ($self) = @_; |
1261 |
|
1262 |
return if exists $self->{meta}; |
1263 |
|
1264 |
my @urxvtdirs = perl_libdirs $self; |
1265 |
# my @cpandirs = grep -d, map "$_/URxvt/Ext", @INC; |
1266 |
|
1267 |
$self->{meta} = \my %allmeta; |
1268 |
|
1269 |
# first gather extensions |
1270 |
|
1271 |
my $gather = sub { |
1272 |
my ($dir, $core) = @_; |
1273 |
|
1274 |
opendir my $fh, $dir |
1275 |
or return; |
1276 |
|
1277 |
for my $ext (readdir $fh) { |
1278 |
$ext !~ /^\./ |
1279 |
or next; |
1280 |
|
1281 |
open my $fh, "<", "$dir/$ext" |
1282 |
or next; |
1283 |
|
1284 |
-f $fh |
1285 |
or next; |
1286 |
|
1287 |
$ext =~ s/\.uext$// or $core |
1288 |
or next; |
1289 |
|
1290 |
my %meta = (dir => $dir); |
1291 |
|
1292 |
while (<$fh>) { |
1293 |
if (/^#:META:(?:X_)?RESOURCE:(.*)/) { |
1294 |
my ($pattern, $type, $desc) = split /:/, $1; |
1295 |
$pattern =~ s/^%(\.|$)/$ext$1/g; # % in pattern == extension name |
1296 |
if ($pattern =~ /[^a-zA-Z0-9\-\.]/) { |
1297 |
warn "$dir/$ext: meta resource '$pattern' contains illegal characters (not alphanumeric nor . nor *)\n"; |
1298 |
} else { |
1299 |
$meta{resource}{$pattern} = [$ext, $type, $desc]; |
1300 |
} |
1301 |
|
1302 |
} elsif (/^#:META:OSC:([0-9]+):(.*)/) { |
1303 |
push @{$allmeta{autoload_osc}{$1}}, [$ext, $2]; |
1304 |
|
1305 |
} elsif (/^#:META:OSC_PERL:([^:]+):(.*)/) { |
1306 |
push @{$allmeta{autoload_osc_perl}{$1}}, [$ext, $2]; |
1307 |
|
1308 |
} elsif (/^\s*(?:#|$)/) { |
1309 |
# skip other comments and empty lines |
1310 |
|
1311 |
} else { |
1312 |
last; # stop parsing on first non-empty non-comment line |
1313 |
} |
1314 |
} |
1315 |
|
1316 |
$allmeta{ext}{$ext} = \%meta; |
1317 |
} |
1318 |
}; |
1319 |
|
1320 |
# $gather->($_, 0) for @cpandirs; |
1321 |
$gather->($_, 1) for @urxvtdirs; |
1322 |
|
1323 |
# and now merge resources |
1324 |
|
1325 |
$allmeta{resource} = \my %resource; |
1326 |
|
1327 |
while (my ($k, $v) = each %{ $allmeta{ext} }) { |
1328 |
#TODO: should check for extensions overriding each other |
1329 |
%resource = (%resource, %{ $v->{resource} }); |
1330 |
} |
1331 |
} |
1332 |
|
1333 |
=item $term = new urxvt::term $envhashref, $rxvtname, [arg...] |
1334 |
|
1335 |
Creates a new terminal, very similar as if you had started it with system |
1336 |
C<$rxvtname, arg...>. C<$envhashref> must be a reference to a C<%ENV>-like |
1337 |
hash which defines the environment of the new terminal. |
1338 |
|
1339 |
Croaks (and probably outputs an error message) if the new instance |
1340 |
couldn't be created. Returns C<undef> if the new instance didn't |
1341 |
initialise perl, and the terminal object otherwise. The C<init> and |
1342 |
C<start> hooks will be called before this call returns, and are free to |
1343 |
refer to global data (which is race free). |
1344 |
|
1345 |
=cut |
1346 |
|
1347 |
sub new { |
1348 |
my ($class, $env, @args) = @_; |
1349 |
|
1350 |
$env or Carp::croak "environment hash missing in call to urxvt::term->new"; |
1351 |
@args or Carp::croak "name argument missing in call to urxvt::term->new"; |
1352 |
|
1353 |
_new ([ map "$_=$env->{$_}", keys %$env ], \@args); |
1354 |
} |
1355 |
|
1356 |
=item $term->destroy |
1357 |
|
1358 |
Destroy the terminal object (close the window, free resources |
1359 |
etc.). Please note that urxvt will not exit as long as any event |
1360 |
watchers (timers, io watchers) are still active. |
1361 |
|
1362 |
=item $term->exec_async ($cmd[, @args]) |
1363 |
|
1364 |
Works like the combination of the C<fork>/C<exec> builtins, which executes |
1365 |
("starts") programs in the background. This function takes care of setting |
1366 |
the user environment before exec'ing the command (e.g. C<PATH>) and should |
1367 |
be preferred over explicit calls to C<exec> or C<system>. |
1368 |
|
1369 |
It also sets the C<URXVT_EXT_WINDOWID> environment variable to the window |
1370 |
ID of the terminal (C<< $self->parent >>), similar to the C<WINDOWID> |
1371 |
variable set for the process spawned inside the terminal. |
1372 |
|
1373 |
Returns the pid of the subprocess or C<undef> on error. |
1374 |
|
1375 |
=cut |
1376 |
|
1377 |
sub exec_async { |
1378 |
my $self = shift; |
1379 |
|
1380 |
my $pid = fork; |
1381 |
|
1382 |
return $pid |
1383 |
if !defined $pid or $pid; |
1384 |
|
1385 |
%ENV = ( |
1386 |
%{ $self->env }, |
1387 |
URXVT_EXT_WINDOWID => $self->parent, |
1388 |
); |
1389 |
|
1390 |
exec @_; |
1391 |
urxvt::_exit 255; |
1392 |
} |
1393 |
|
1394 |
=item $isset = $term->option ($optval[, $set]) |
1395 |
|
1396 |
Returns true if the option specified by C<$optval> is enabled, and |
1397 |
optionally change it. All option values are stored by name in the hash |
1398 |
C<%urxvt::OPTION>. Options not enabled in this binary are not in the hash. |
1399 |
|
1400 |
Here is a likely non-exhaustive list of option names, please see the |
1401 |
source file F</src/optinc.h> to see the actual list: |
1402 |
|
1403 |
borderLess buffered console cursorBlink cursorUnderline hold iconic |
1404 |
insecure intensityStyles iso14755 iso14755_52 jumpScroll loginShell |
1405 |
mapAlert meta8 mouseWheelScrollPage override_redirect pastableTabs |
1406 |
pointerBlank reverseVideo scrollBar scrollBar_floating scrollBar_right |
1407 |
scrollTtyKeypress scrollTtyOutput scrollWithBuffer secondaryScreen |
1408 |
secondaryScroll skipBuiltinGlyphs skipScroll transparent tripleclickwords |
1409 |
urgentOnBell utmpInhibit visualBell disablePasteBrackets |
1410 |
|
1411 |
=item $value = $term->resource ($name[, $newval]) |
1412 |
|
1413 |
Returns the current resource value associated with a given name and |
1414 |
optionally sets a new value. Setting values is most useful in the C<init> |
1415 |
hook. Unset resources are returned and accepted as C<undef>. |
1416 |
|
1417 |
The new value must be properly encoded to a suitable character encoding |
1418 |
before passing it to this method. Similarly, the returned value may need |
1419 |
to be converted from the used encoding to text. |
1420 |
|
1421 |
Resource names are as defined in F<src/rsinc.h>. Colours can be specified |
1422 |
as resource names of the form C<< color+<index> >>, e.g. C<color+5>. (will |
1423 |
likely change). |
1424 |
|
1425 |
Please note that resource strings will currently only be freed when the |
1426 |
terminal is destroyed, so changing options frequently will eat memory. |
1427 |
|
1428 |
Here is a likely non-exhaustive list of resource names, not all of which |
1429 |
are supported in every build, please see the source file F</src/rsinc.h> |
1430 |
to see the actual list: |
1431 |
|
1432 |
answerbackstring backgroundPixmap backspace_key blurradius |
1433 |
boldFont boldItalicFont borderLess buffered chdir color cursorBlink |
1434 |
cursorUnderline cutchars delete_key depth display_name embed ext_bwidth |
1435 |
fade font geometry hold iconName iconfile imFont imLocale inputMethod |
1436 |
insecure int_bwidth intensityStyles iso14755 iso14755_52 italicFont |
1437 |
jumpScroll letterSpace lineSpace loginShell mapAlert meta8 modifier |
1438 |
mouseWheelScrollPage name override_redirect pastableTabs path perl_eval |
1439 |
perl_ext_1 perl_ext_2 perl_lib pointerBlank pointerBlankDelay |
1440 |
preeditType print_pipe pty_fd reverseVideo saveLines scrollBar |
1441 |
scrollBar_align scrollBar_floating scrollBar_right scrollBar_thickness |
1442 |
scrollTtyKeypress scrollTtyOutput scrollWithBuffer scrollstyle |
1443 |
secondaryScreen secondaryScroll shade skipBuiltinGlyphs skipScroll |
1444 |
term_name title transient_for transparent tripleclickwords urgentOnBell |
1445 |
utmpInhibit visualBell rewrapMode disablePasteBrackets |
1446 |
|
1447 |
=cut |
1448 |
|
1449 |
sub resource($$;$) { |
1450 |
my ($self, $name) = (shift, shift); |
1451 |
unshift @_, $self, $name, ($name =~ s/\s*\+\s*(\d+)$// ? $1 : 0); |
1452 |
goto &urxvt::term::_resource |
1453 |
} |
1454 |
|
1455 |
=item $value = $term->x_resource ($pattern) |
1456 |
|
1457 |
Returns the X-Resource for the given pattern, excluding the program or |
1458 |
class name, i.e. C<< $term->x_resource ("boldFont") >> should return the |
1459 |
same value as used by this instance of rxvt-unicode. Returns C<undef> if no |
1460 |
resource with that pattern exists. |
1461 |
|
1462 |
Extensions that define extra resources also need to call this method |
1463 |
to access their values. |
1464 |
|
1465 |
If the method is called on an extension object (basically, from an |
1466 |
extension), then the special prefix C<%.> will be replaced by the name of |
1467 |
the extension and a dot, and the lone string C<%> will be replaced by the |
1468 |
extension name itself. This makes it possible to code extensions so you |
1469 |
can rename them and get a new set of resources without having to change |
1470 |
the actual code. |
1471 |
|
1472 |
This method should only be called during the C<on_start> hook, as there is |
1473 |
only one resource database per display, and later invocations might return |
1474 |
the wrong resources. |
1475 |
|
1476 |
=item $value = $term->x_resource_boolean ($pattern) |
1477 |
|
1478 |
Like C<x_resource>, above, but interprets the string value as a boolean |
1479 |
and returns C<1> for true values, C<0> for false values and C<undef> if |
1480 |
the resource or option isn't specified. |
1481 |
|
1482 |
You should always use this method to parse boolean resources. |
1483 |
|
1484 |
=cut |
1485 |
|
1486 |
sub x_resource_boolean { |
1487 |
my $res = &x_resource; |
1488 |
|
1489 |
$res =~ /^\s*(?:true|yes|on|1)\s*$/i ? 1 : defined $res && 0 |
1490 |
} |
1491 |
|
1492 |
=item $action = $term->lookup_keysym ($keysym, $state) |
1493 |
|
1494 |
Returns the action bound to key combination C<($keysym, $state)>, |
1495 |
if a binding for it exists, and C<undef> otherwise. |
1496 |
|
1497 |
=item $success = $term->bind_action ($key, $action) |
1498 |
|
1499 |
Adds a key binding exactly as specified via a C<keysym> resource. See the |
1500 |
C<keysym> resource in the urxvt(1) manpage. |
1501 |
|
1502 |
To add default bindings for actions, an extension should call C<< |
1503 |
->bind_action >> in its C<init> hook for every such binding. Doing it |
1504 |
in the C<init> hook allows users to override or remove the binding |
1505 |
again. |
1506 |
|
1507 |
Example: the C<searchable-scrollback> by default binds itself |
1508 |
on C<Meta-s>, using C<< $self->bind_action >>, which calls C<< |
1509 |
$term->bind_action >>. |
1510 |
|
1511 |
sub init { |
1512 |
my ($self) = @_; |
1513 |
|
1514 |
$self->bind_action ("M-s" => "%:start"); |
1515 |
} |
1516 |
|
1517 |
=item $rend = $term->rstyle ([$new_rstyle]) |
1518 |
|
1519 |
Return and optionally change the current rendition. Text that is output by |
1520 |
the terminal application will use this style. |
1521 |
|
1522 |
=item ($row, $col) = $term->screen_cur ([$row, $col]) |
1523 |
|
1524 |
Return the current coordinates of the text cursor position and optionally |
1525 |
set it (which is usually bad as applications don't expect that). |
1526 |
|
1527 |
=item ($row, $col) = $term->selection_mark ([$row, $col]) |
1528 |
|
1529 |
=item ($row, $col) = $term->selection_beg ([$row, $col]) |
1530 |
|
1531 |
=item ($row, $col) = $term->selection_end ([$row, $col]) |
1532 |
|
1533 |
Return the current values of the selection mark, begin or end positions. |
1534 |
|
1535 |
When arguments are given, then the selection coordinates are set to |
1536 |
C<$row> and C<$col>, and the selection screen is set to the current |
1537 |
screen. |
1538 |
|
1539 |
=item $screen = $term->selection_screen ([$screen]) |
1540 |
|
1541 |
Returns the current selection screen, and then optionally sets it. |
1542 |
|
1543 |
=item $term->selection_make ($eventtime[, $rectangular]) |
1544 |
|
1545 |
Tries to make a selection as set by C<selection_beg> and |
1546 |
C<selection_end>. If C<$rectangular> is true (default: false), a |
1547 |
rectangular selection will be made. This is the preferred function to make |
1548 |
a selection. |
1549 |
|
1550 |
=item $success = $term->selection_grab ($eventtime[, $clipboard]) |
1551 |
|
1552 |
Try to acquire ownership of the primary (clipboard if C<$clipboard> is |
1553 |
true) selection from the server. The corresponding text can be set |
1554 |
with the next method. No visual feedback will be given. This function |
1555 |
is mostly useful from within C<on_sel_grab> hooks. |
1556 |
|
1557 |
=item $oldtext = $term->selection ([$newtext, $clipboard]) |
1558 |
|
1559 |
Return the current selection (clipboard if C<$clipboard> is true) text |
1560 |
and optionally replace it by C<$newtext>. |
1561 |
|
1562 |
=item $term->selection_clear ([$clipboard]) |
1563 |
|
1564 |
Revoke ownership of the primary (clipboard if C<$clipboard> is true) selection. |
1565 |
|
1566 |
=item $term->overlay_simple ($x, $y, $text) |
1567 |
|
1568 |
Create a simple multi-line overlay box. See the next method for details. |
1569 |
|
1570 |
=cut |
1571 |
|
1572 |
sub overlay_simple { |
1573 |
my ($self, $x, $y, $text) = @_; |
1574 |
|
1575 |
my @lines = split /\n/, $text; |
1576 |
|
1577 |
my $w = List::Util::max map $self->strwidth ($_), @lines; |
1578 |
|
1579 |
my $overlay = $self->overlay ($x, $y, $w, scalar @lines); |
1580 |
$overlay->set (0, $_, $lines[$_]) for 0.. $#lines; |
1581 |
|
1582 |
$overlay |
1583 |
} |
1584 |
|
1585 |
=item $term->overlay ($x, $y, $width, $height[, $rstyle[, $border]]) |
1586 |
|
1587 |
Create a new (empty) overlay at the given position with the given |
1588 |
width/height. C<$rstyle> defines the initial rendition style |
1589 |
(default: C<OVERLAY_RSTYLE>). |
1590 |
|
1591 |
If C<$border> is C<2> (default), then a decorative border will be put |
1592 |
around the box. |
1593 |
|
1594 |
If either C<$x> or C<$y> is negative, then this is counted from the |
1595 |
right/bottom side, respectively. |
1596 |
|
1597 |
This method returns an urxvt::overlay object. The overlay will be visible |
1598 |
as long as the perl object is referenced. |
1599 |
|
1600 |
The methods currently supported on C<urxvt::overlay> objects are: |
1601 |
|
1602 |
=over |
1603 |
|
1604 |
=item $overlay->set ($x, $y, $text[, $rend]) |
1605 |
|
1606 |
Similar to C<< $term->ROW_t >> and C<< $term->ROW_r >> in that it puts |
1607 |
text in rxvt-unicode's special encoding and an array of rendition values |
1608 |
at a specific position inside the overlay. |
1609 |
|
1610 |
If C<$rend> is missing, then the rendition will not be changed. |
1611 |
|
1612 |
=item $overlay->hide |
1613 |
|
1614 |
If visible, hide the overlay, but do not destroy it. |
1615 |
|
1616 |
=item $overlay->show |
1617 |
|
1618 |
If hidden, display the overlay again. |
1619 |
|
1620 |
=back |
1621 |
|
1622 |
=item $popup = $term->popup ($event) |
1623 |
|
1624 |
Creates a new C<urxvt::popup> object that implements a popup menu. The |
1625 |
C<$event> I<must> be the event causing the menu to pop up (a button event, |
1626 |
currently). |
1627 |
|
1628 |
=cut |
1629 |
|
1630 |
sub popup { |
1631 |
my ($self, $event) = @_; |
1632 |
|
1633 |
$self->grab ($event->{time}, 1) |
1634 |
or return; |
1635 |
|
1636 |
my $popup = bless { |
1637 |
term => $self, |
1638 |
event => $event, |
1639 |
}, urxvt::popup::; |
1640 |
|
1641 |
Scalar::Util::weaken $popup->{term}; |
1642 |
|
1643 |
$self->{_destroy}{$popup} = urxvt::destroy_hook { $popup->{popup}->destroy }; |
1644 |
Scalar::Util::weaken $self->{_destroy}{$popup}; |
1645 |
|
1646 |
$popup |
1647 |
} |
1648 |
|
1649 |
=item $cellwidth = $term->strwidth ($string) |
1650 |
|
1651 |
Returns the number of screen-cells this string would need. Correctly |
1652 |
accounts for wide and combining characters. |
1653 |
|
1654 |
=item $octets = $term->locale_encode ($string) |
1655 |
|
1656 |
Convert the given text string into the corresponding locale |
1657 |
encoding. Returns C<undef> if C<$string> is C<undef>. |
1658 |
|
1659 |
=item $string = $term->locale_decode ($octets) |
1660 |
|
1661 |
Convert the given locale-encoded octets into a perl string. Returns |
1662 |
C<undef> if C<$octets> is C<undef>. |
1663 |
|
1664 |
=item $term->scr_xor_span ($beg_row, $beg_col, $end_row, $end_col[, $rstyle]) |
1665 |
|
1666 |
XORs the rendition values in the given span with the provided value |
1667 |
(default: C<RS_RVid>), which I<MUST NOT> contain font styles. Useful in |
1668 |
refresh hooks to provide effects similar to the selection. |
1669 |
|
1670 |
=item $term->scr_xor_rect ($beg_row, $beg_col, $end_row, $end_col[, $rstyle1[, $rstyle2]]) |
1671 |
|
1672 |
Similar to C<scr_xor_span>, but xors a rectangle instead. Trailing |
1673 |
whitespace will additionally be xored with the C<$rstyle2>, which defaults |
1674 |
to C<RS_RVid | RS_Uline>, which removes reverse video again and underlines |
1675 |
it instead. Both styles I<MUST NOT> contain font styles. |
1676 |
|
1677 |
=item $term->scr_bell |
1678 |
|
1679 |
Ring the bell! |
1680 |
|
1681 |
=item $term->scr_add_lines ($string) |
1682 |
|
1683 |
Write the given text string to the screen, as if output by the application |
1684 |
running inside the terminal. It may not contain command sequences (escape |
1685 |
codes - see C<cmd_parse> for that), but is free to use line feeds, |
1686 |
carriage returns and tabs. The string is a normal text string, not in |
1687 |
locale-dependent encoding. |
1688 |
|
1689 |
Normally its not a good idea to use this function, as programs might be |
1690 |
confused by changes in cursor position or scrolling. Its useful inside a |
1691 |
C<on_add_lines> hook, though. |
1692 |
|
1693 |
=item $term->scr_change_screen ($screen) |
1694 |
|
1695 |
Switch to given screen - 0 primary, 1 secondary. |
1696 |
|
1697 |
=item $term->cmd_parse ($octets) |
1698 |
|
1699 |
Similar to C<scr_add_lines>, but the argument must be in the |
1700 |
locale-specific encoding of the terminal and can contain command sequences |
1701 |
(escape codes) that will be interpreted. |
1702 |
|
1703 |
=item $term->tt_write ($octets) |
1704 |
|
1705 |
Write the octets given in C<$octets> to the tty (i.e. as user input |
1706 |
to the program, see C<cmd_parse> for the opposite direction). To pass |
1707 |
characters instead of octets, you should convert your strings first to the |
1708 |
locale-specific encoding using C<< $term->locale_encode >>. |
1709 |
|
1710 |
=item $term->tt_write_user_input ($octets) |
1711 |
|
1712 |
Like C<tt_write>, but should be used when writing strings in response to |
1713 |
the user pressing a key, to invoke the additional actions requested by |
1714 |
the user for that case (C<tt_write> doesn't do that). |
1715 |
|
1716 |
The typical use case would be inside C<on_action> hooks. |
1717 |
|
1718 |
=item $term->tt_paste ($octets) |
1719 |
|
1720 |
Write the octets given in C<$octets> to the tty as a paste, converting NL to |
1721 |
CR and bracketing the data with control sequences if bracketed paste mode |
1722 |
is set. |
1723 |
|
1724 |
=item $old_events = $term->pty_ev_events ([$new_events]) |
1725 |
|
1726 |
Replaces the event mask of the pty watcher by the given event mask. Can |
1727 |
be used to suppress input and output handling to the pty/tty. See the |
1728 |
description of C<< urxvt::timer->events >>. Make sure to always restore |
1729 |
the previous value. |
1730 |
|
1731 |
=item $fd = $term->pty_fd |
1732 |
|
1733 |
Returns the master file descriptor for the pty in use, or C<-1> if no pty |
1734 |
is used. |
1735 |
|
1736 |
=item $windowid = $term->parent |
1737 |
|
1738 |
Return the window id of the toplevel window. |
1739 |
|
1740 |
=item $windowid = $term->vt |
1741 |
|
1742 |
Return the window id of the terminal window. |
1743 |
|
1744 |
=item $term->vt_emask_add ($x_event_mask) |
1745 |
|
1746 |
Adds the specified events to the vt event mask. Useful e.g. when you want |
1747 |
to receive pointer events all the times: |
1748 |
|
1749 |
$term->vt_emask_add (urxvt::PointerMotionMask); |
1750 |
|
1751 |
=item $term->set_urgency ($set) |
1752 |
|
1753 |
Enable/disable the urgency hint on the toplevel window. |
1754 |
|
1755 |
=item $term->focus_in |
1756 |
|
1757 |
=item $term->focus_out |
1758 |
|
1759 |
=item $term->key_press ($state, $keycode[, $time]) |
1760 |
|
1761 |
=item $term->key_release ($state, $keycode[, $time]) |
1762 |
|
1763 |
Deliver various fake events to to terminal. |
1764 |
|
1765 |
=item $window_width = $term->width ([$new_value]) |
1766 |
|
1767 |
=item $window_height = $term->height ([$new_value]) |
1768 |
|
1769 |
=item $font_width = $term->fwidth ([$new_value]) |
1770 |
|
1771 |
=item $font_height = $term->fheight ([$new_value]) |
1772 |
|
1773 |
=item $font_ascent = $term->fbase ([$new_value]) |
1774 |
|
1775 |
=item $terminal_rows = $term->nrow ([$new_value]) |
1776 |
|
1777 |
=item $terminal_columns = $term->ncol ([$new_value]) |
1778 |
|
1779 |
=item $has_focus = $term->focus ([$new_value]) |
1780 |
|
1781 |
=item $is_mapped = $term->mapped ([$new_value]) |
1782 |
|
1783 |
=item $max_scrollback = $term->saveLines ([$new_value]) |
1784 |
|
1785 |
=item $nrow_plus_saveLines = $term->total_rows ([$new_value]) |
1786 |
|
1787 |
=item $topmost_scrollback_row = $term->top_row ([$new_value]) |
1788 |
|
1789 |
Return various integers describing terminal characteristics. If an |
1790 |
argument is given, changes the value and returns the previous one. |
1791 |
|
1792 |
=item $x_display = $term->display_id |
1793 |
|
1794 |
Return the DISPLAY used by rxvt-unicode. |
1795 |
|
1796 |
=item $lc_ctype = $term->locale |
1797 |
|
1798 |
Returns the LC_CTYPE category string used by this rxvt-unicode. |
1799 |
|
1800 |
=item $env = $term->env |
1801 |
|
1802 |
Returns a copy of the environment in effect for the terminal as a hashref |
1803 |
similar to C<\%ENV>. |
1804 |
|
1805 |
=item @envv = $term->envv |
1806 |
|
1807 |
Returns the environment as array of strings of the form C<VAR=VALUE>. |
1808 |
|
1809 |
=item @argv = $term->argv |
1810 |
|
1811 |
Return the argument vector as this terminal, similar to @ARGV, but |
1812 |
includes the program name as first element. |
1813 |
|
1814 |
=cut |
1815 |
|
1816 |
sub env { |
1817 |
+{ map /^([^=]+)(?:=(.*))?$/s && ($1 => $2), $_[0]->envv } |
1818 |
} |
1819 |
|
1820 |
=item $modifiermask = $term->ModLevel3Mask |
1821 |
|
1822 |
=item $modifiermask = $term->ModMetaMask |
1823 |
|
1824 |
=item $modifiermask = $term->ModNumLockMask |
1825 |
|
1826 |
Return the modifier masks corresponding to the "ISO Level 3 Shift" (often |
1827 |
AltGr), the meta key (often Alt) and the num lock key, if applicable. |
1828 |
|
1829 |
=item $screen = $term->current_screen |
1830 |
|
1831 |
Returns the currently displayed screen (0 primary, 1 secondary). |
1832 |
|
1833 |
=item $cursor_is_hidden = $term->hidden_cursor |
1834 |
|
1835 |
Returns whether the cursor is currently hidden or not. |
1836 |
|
1837 |
=item $priv_modes = $term->priv_modes |
1838 |
|
1839 |
Returns a bitset with the state of DEC private modes. |
1840 |
|
1841 |
Example: |
1842 |
|
1843 |
if ($term->priv_modes & urxvt::PrivMode_mouse_report) { |
1844 |
# mouse reporting is turned on |
1845 |
} |
1846 |
|
1847 |
=item $view_start = $term->view_start ([$newvalue]) |
1848 |
|
1849 |
Returns the row number of the topmost displayed line and changes it, |
1850 |
if an argument is given. Values greater than or equal to C<0> display |
1851 |
the terminal contents. Lower values scroll this many lines into the |
1852 |
scrollback buffer. |
1853 |
|
1854 |
=item $term->want_refresh |
1855 |
|
1856 |
Requests a screen refresh. At the next opportunity, rxvt-unicode will |
1857 |
compare the on-screen display with its stored representation. If they |
1858 |
differ, it redraws the differences. |
1859 |
|
1860 |
Used after changing terminal contents to display them. |
1861 |
|
1862 |
=item $term->refresh_check |
1863 |
|
1864 |
Checks if a refresh has been requested and, if so, schedules one. |
1865 |
|
1866 |
=item $text = $term->ROW_t ($row_number[, $new_text[, $start_col]]) |
1867 |
|
1868 |
Returns the text of the entire row with number C<$row_number>. Row C<< $term->top_row >> |
1869 |
is the topmost terminal line, row C<< $term->nrow-1 >> is the bottommost |
1870 |
terminal line. Nothing will be returned if a nonexistent line |
1871 |
is requested. |
1872 |
|
1873 |
If C<$new_text> is specified, it will replace characters in the current |
1874 |
line, starting at column C<$start_col> (default C<0>), which is useful |
1875 |
to replace only parts of a line. The font index in the rendition will |
1876 |
automatically be updated. |
1877 |
|
1878 |
C<$text> is in a special encoding: tabs and wide characters that use more |
1879 |
than one cell when displayed are padded with C<$urxvt::NOCHAR> (chr 65535) |
1880 |
characters. Characters with combining characters and other characters that |
1881 |
do not fit into the normal text encoding will be replaced with characters |
1882 |
in the private use area. |
1883 |
|
1884 |
You have to obey this encoding when changing text. The advantage is |
1885 |
that C<substr> and similar functions work on screen cells and not on |
1886 |
characters. |
1887 |
|
1888 |
The methods C<< $term->special_encode >> and C<< $term->special_decode >> |
1889 |
can be used to convert normal strings into this encoding and vice versa. |
1890 |
|
1891 |
=item $rend = $term->ROW_r ($row_number[, $new_rend[, $start_col]]) |
1892 |
|
1893 |
Like C<< $term->ROW_t >>, but returns an arrayref with rendition |
1894 |
bitsets. Rendition bitsets contain information about colour, font, font |
1895 |
styles and similar information. See also C<< $term->ROW_t >>. |
1896 |
|
1897 |
When setting rendition, the font mask will be ignored. |
1898 |
|
1899 |
See the section on RENDITION, above. |
1900 |
|
1901 |
=item $length = $term->ROW_l ($row_number[, $new_length]) |
1902 |
|
1903 |
Returns the number of screen cells that are in use ("the line |
1904 |
length"). Unlike the urxvt core, this returns C<< $term->ncol >> if the |
1905 |
line is joined with the following one. |
1906 |
|
1907 |
=item $bool = $term->is_longer ($row_number) |
1908 |
|
1909 |
Returns true if the row is part of a multiple-row logical "line" (i.e. |
1910 |
joined with the following row), which means all characters are in use |
1911 |
and it is continued on the next row (and possibly a continuation of the |
1912 |
previous row(s)). |
1913 |
|
1914 |
=item $line = $term->line ($row_number) |
1915 |
|
1916 |
Create and return a new C<urxvt::line> object that stores information |
1917 |
about the logical line that row C<$row_number> is part of. It supports the |
1918 |
following methods: |
1919 |
|
1920 |
=over |
1921 |
|
1922 |
=item $text = $line->t ([$new_text]) |
1923 |
|
1924 |
Returns or replaces the full text of the line, similar to C<ROW_t> |
1925 |
|
1926 |
=item $rend = $line->r ([$new_rend]) |
1927 |
|
1928 |
Returns or replaces the full rendition array of the line, similar to C<ROW_r> |
1929 |
|
1930 |
=item $length = $line->l |
1931 |
|
1932 |
Returns the length of the line in cells, similar to C<ROW_l>. |
1933 |
|
1934 |
=item $rownum = $line->beg |
1935 |
|
1936 |
=item $rownum = $line->end |
1937 |
|
1938 |
Return the row number of the first/last row of the line, respectively. |
1939 |
|
1940 |
=item $offset = $line->offset_of ($row, $col) |
1941 |
|
1942 |
Returns the character offset of the given row|col pair within the logical |
1943 |
line. Works for rows outside the line, too, and returns corresponding |
1944 |
offsets outside the string. |
1945 |
|
1946 |
=item ($row, $col) = $line->coord_of ($offset) |
1947 |
|
1948 |
Translates a string offset into terminal coordinates again. |
1949 |
|
1950 |
=back |
1951 |
|
1952 |
=cut |
1953 |
|
1954 |
sub line { |
1955 |
my ($self, $row) = @_; |
1956 |
|
1957 |
my $maxrow = $self->nrow - 1; |
1958 |
|
1959 |
my ($beg, $end) = ($row, $row); |
1960 |
|
1961 |
--$beg while $self->ROW_is_longer ($beg - 1); |
1962 |
++$end while $self->ROW_is_longer ($end) && $end < $maxrow; |
1963 |
|
1964 |
bless { |
1965 |
term => $self, |
1966 |
beg => $beg, |
1967 |
end => $end, |
1968 |
ncol => $self->ncol, |
1969 |
len => ($end - $beg) * $self->ncol + $self->ROW_l ($end), |
1970 |
}, urxvt::line:: |
1971 |
} |
1972 |
|
1973 |
sub urxvt::line::t { |
1974 |
my ($self) = @_; |
1975 |
|
1976 |
if (@_ > 1) { |
1977 |
$self->{term}->ROW_t ($_, $_[1], 0, ($_ - $self->{beg}) * $self->{ncol}, $self->{ncol}) |
1978 |
for $self->{beg} .. $self->{end}; |
1979 |
} |
1980 |
|
1981 |
defined wantarray && |
1982 |
substr +(join "", map $self->{term}->ROW_t ($_), $self->{beg} .. $self->{end}), |
1983 |
0, $self->{len} |
1984 |
} |
1985 |
|
1986 |
sub urxvt::line::r { |
1987 |
my ($self) = @_; |
1988 |
|
1989 |
if (@_ > 1) { |
1990 |
$self->{term}->ROW_r ($_, $_[1], 0, ($_ - $self->{beg}) * $self->{ncol}, $self->{ncol}) |
1991 |
for $self->{beg} .. $self->{end}; |
1992 |
} |
1993 |
|
1994 |
if (defined wantarray) { |
1995 |
my $rend = [ |
1996 |
map @{ $self->{term}->ROW_r ($_) }, $self->{beg} .. $self->{end} |
1997 |
]; |
1998 |
$#$rend = $self->{len} - 1; |
1999 |
return $rend; |
2000 |
} |
2001 |
|
2002 |
() |
2003 |
} |
2004 |
|
2005 |
sub urxvt::line::beg { $_[0]{beg} } |
2006 |
sub urxvt::line::end { $_[0]{end} } |
2007 |
sub urxvt::line::l { $_[0]{len} } |
2008 |
|
2009 |
sub urxvt::line::offset_of { |
2010 |
my ($self, $row, $col) = @_; |
2011 |
|
2012 |
($row - $self->{beg}) * $self->{ncol} + $col |
2013 |
} |
2014 |
|
2015 |
sub urxvt::line::coord_of { |
2016 |
my ($self, $offset) = @_; |
2017 |
|
2018 |
use integer; |
2019 |
|
2020 |
( |
2021 |
$offset / $self->{ncol} + $self->{beg}, |
2022 |
$offset % $self->{ncol} |
2023 |
) |
2024 |
} |
2025 |
|
2026 |
=item $text = $term->special_encode ($string) |
2027 |
|
2028 |
Converts a perl string into the special encoding used by rxvt-unicode, |
2029 |
where one character corresponds to one screen cell. See |
2030 |
C<< $term->ROW_t >> for details. |
2031 |
|
2032 |
=item $string = $term->special_decode ($text) |
2033 |
|
2034 |
Converts rxvt-unicode's text representation into a perl string. See |
2035 |
C<< $term->ROW_t >> for details. |
2036 |
|
2037 |
=item $success = $term->grab_button ($button, $modifiermask[, $window = $term->vt]) |
2038 |
|
2039 |
=item $term->ungrab_button ($button, $modifiermask[, $window = $term->vt]) |
2040 |
|
2041 |
Register/unregister a synchronous button grab. See the XGrabButton |
2042 |
manpage. |
2043 |
|
2044 |
=item $success = $term->grab ($eventtime[, $sync]) |
2045 |
|
2046 |
Calls XGrabPointer and XGrabKeyboard in asynchronous (default) or |
2047 |
synchronous (C<$sync> is true). Also remembers the grab timestamp. |
2048 |
|
2049 |
=item $term->allow_events_async |
2050 |
|
2051 |
Calls XAllowEvents with AsyncBoth for the most recent grab. |
2052 |
|
2053 |
=item $term->allow_events_sync |
2054 |
|
2055 |
Calls XAllowEvents with SyncBoth for the most recent grab. |
2056 |
|
2057 |
=item $term->allow_events_replay |
2058 |
|
2059 |
Calls XAllowEvents with both ReplayPointer and ReplayKeyboard for the most |
2060 |
recent grab. |
2061 |
|
2062 |
=item $term->ungrab |
2063 |
|
2064 |
Calls XUngrabPointer and XUngrabKeyboard for the most recent grab. Is called automatically on |
2065 |
evaluation errors, as it is better to lose the grab in the error case as |
2066 |
the session. |
2067 |
|
2068 |
=item $atom = $term->XInternAtom ($atom_name[, $only_if_exists]) |
2069 |
|
2070 |
=item $atom_name = $term->XGetAtomName ($atom) |
2071 |
|
2072 |
=item @atoms = $term->XListProperties ($window) |
2073 |
|
2074 |
=item ($type,$format,$octets) = $term->XGetWindowProperty ($window, $property) |
2075 |
|
2076 |
=item $term->XChangeProperty ($window, $property, $type, $format, $octets) |
2077 |
|
2078 |
=item $term->XDeleteProperty ($window, $property) |
2079 |
|
2080 |
=item $window = $term->DefaultRootWindow |
2081 |
|
2082 |
=item $term->XReparentWindow ($window, $parent, [$x, $y]) |
2083 |
|
2084 |
=item $term->XMapWindow ($window) |
2085 |
|
2086 |
=item $term->XUnmapWindow ($window) |
2087 |
|
2088 |
=item $term->XMoveResizeWindow ($window, $x, $y, $width, $height) |
2089 |
|
2090 |
=item ($x, $y, $child_window) = $term->XTranslateCoordinates ($src, $dst, $x, $y) |
2091 |
|
2092 |
=item $term->XChangeInput ($window, $add_events[, $del_events]) |
2093 |
|
2094 |
=item $keysym = $term->XStringToKeysym ($string) |
2095 |
|
2096 |
=item $string = $term->XKeysymToString ($keysym) |
2097 |
|
2098 |
Various X or X-related functions. The C<$term> object only serves as |
2099 |
the source of the display, otherwise those functions map more-or-less |
2100 |
directly onto the X functions of the same name. |
2101 |
|
2102 |
=back |
2103 |
|
2104 |
=cut |
2105 |
|
2106 |
package urxvt::popup; |
2107 |
|
2108 |
=head2 The C<urxvt::popup> Class |
2109 |
|
2110 |
=over |
2111 |
|
2112 |
=cut |
2113 |
|
2114 |
sub add_item { |
2115 |
my ($self, $item) = @_; |
2116 |
|
2117 |
$item->{rend}{normal} = "\x1b[0;30;47m" unless exists $item->{rend}{normal}; |
2118 |
$item->{rend}{hover} = "\x1b[0;30;46m" unless exists $item->{rend}{hover}; |
2119 |
$item->{rend}{active} = "\x1b[m" unless exists $item->{rend}{active}; |
2120 |
|
2121 |
$item->{render} ||= sub { $_[0]{text} }; |
2122 |
|
2123 |
push @{ $self->{item} }, $item; |
2124 |
} |
2125 |
|
2126 |
=item $popup->add_title ($title) |
2127 |
|
2128 |
Adds a non-clickable title to the popup. |
2129 |
|
2130 |
=cut |
2131 |
|
2132 |
sub add_title { |
2133 |
my ($self, $title) = @_; |
2134 |
|
2135 |
$self->add_item ({ |
2136 |
rend => { normal => "\x1b[38;5;11;44m", hover => "\x1b[38;5;11;44m", active => "\x1b[38;5;11;44m" }, |
2137 |
text => $title, |
2138 |
activate => sub { }, |
2139 |
}); |
2140 |
} |
2141 |
|
2142 |
=item $popup->add_separator ([$sepchr]) |
2143 |
|
2144 |
Creates a separator, optionally using the character given as C<$sepchr>. |
2145 |
|
2146 |
=cut |
2147 |
|
2148 |
sub add_separator { |
2149 |
my ($self, $sep) = @_; |
2150 |
|
2151 |
$sep ||= "="; |
2152 |
|
2153 |
$self->add_item ({ |
2154 |
rend => { normal => "\x1b[0;30;47m", hover => "\x1b[0;30;47m", active => "\x1b[0;30;47m" }, |
2155 |
text => "", |
2156 |
render => sub { $sep x $self->{term}->ncol }, |
2157 |
activate => sub { }, |
2158 |
}); |
2159 |
} |
2160 |
|
2161 |
=item $popup->add_button ($text, $cb) |
2162 |
|
2163 |
Adds a clickable button to the popup. C<$cb> is called whenever it is |
2164 |
selected. |
2165 |
|
2166 |
=cut |
2167 |
|
2168 |
sub add_button { |
2169 |
my ($self, $text, $cb) = @_; |
2170 |
|
2171 |
$self->add_item ({ type => "button", text => $text, activate => $cb}); |
2172 |
} |
2173 |
|
2174 |
=item $popup->add_toggle ($text, $initial_value, $cb) |
2175 |
|
2176 |
Adds a toggle/checkbox item to the popup. The callback gets called |
2177 |
whenever it gets toggled, with a boolean indicating its new value as its |
2178 |
first argument. |
2179 |
|
2180 |
=cut |
2181 |
|
2182 |
sub add_toggle { |
2183 |
my ($self, $text, $value, $cb) = @_; |
2184 |
|
2185 |
my $item; $item = { |
2186 |
type => "button", |
2187 |
text => " $text", |
2188 |
value => $value, |
2189 |
render => sub { ($_[0]{value} ? "* " : " ") . $text }, |
2190 |
activate => sub { $cb->($_[1]{value} = !$_[1]{value}); }, |
2191 |
}; |
2192 |
|
2193 |
$self->add_item ($item); |
2194 |
} |
2195 |
|
2196 |
=item $popup->show |
2197 |
|
2198 |
Displays the popup (which is initially hidden). |
2199 |
|
2200 |
=cut |
2201 |
|
2202 |
sub show { |
2203 |
my ($self) = @_; |
2204 |
|
2205 |
local $urxvt::popup::self = $self; |
2206 |
|
2207 |
my $env = $self->{term}->env; |
2208 |
# we can't hope to reproduce the locale algorithm, so nuke LC_ALL and set LC_CTYPE. |
2209 |
delete $env->{LC_ALL}; |
2210 |
$env->{LC_CTYPE} = $self->{term}->locale; |
2211 |
|
2212 |
my $term = urxvt::term->new ( |
2213 |
$env, "popup", |
2214 |
"--perl-lib" => "", "--perl-ext-common" => "", |
2215 |
"-pty-fd" => -1, "-sl" => 0, |
2216 |
"-b" => 1, "-bd" => "grey80", "-bl", "-override-redirect", |
2217 |
"--transient-for" => $self->{term}->parent, |
2218 |
"-display" => $self->{term}->display_id, |
2219 |
"-pe" => "urxvt-popup", |
2220 |
) or die "unable to create popup window\n"; |
2221 |
|
2222 |
unless (delete $term->{urxvt_popup_init_done}) { |
2223 |
$term->ungrab; |
2224 |
$term->destroy; |
2225 |
die "unable to initialise popup window\n"; |
2226 |
} |
2227 |
} |
2228 |
|
2229 |
sub DESTROY { |
2230 |
my ($self) = @_; |
2231 |
|
2232 |
delete $self->{term}{_destroy}{$self}; |
2233 |
$self->{term}->ungrab; |
2234 |
} |
2235 |
|
2236 |
=back |
2237 |
|
2238 |
=cut |
2239 |
|
2240 |
package urxvt::watcher; |
2241 |
|
2242 |
=head2 The C<urxvt::timer> Class |
2243 |
|
2244 |
This class implements timer watchers/events. Time is represented as a |
2245 |
fractional number of seconds since the epoch. Example: |
2246 |
|
2247 |
$term->{overlay} = $term->overlay (-1, 0, 8, 1, urxvt::OVERLAY_RSTYLE, 0); |
2248 |
$term->{timer} = urxvt::timer |
2249 |
->new |
2250 |
->interval (1) |
2251 |
->cb (sub { |
2252 |
$term->{overlay}->set (0, 0, |
2253 |
sprintf "%2d:%02d:%02d", (localtime urxvt::NOW)[2,1,0]); |
2254 |
}); |
2255 |
|
2256 |
=over |
2257 |
|
2258 |
=item $timer = new urxvt::timer |
2259 |
|
2260 |
Create a new timer object in started state. It is scheduled to fire |
2261 |
immediately. |
2262 |
|
2263 |
=item $timer = $timer->cb (sub { my ($timer) = @_; ... }) |
2264 |
|
2265 |
Set the callback to be called when the timer triggers. |
2266 |
|
2267 |
=item $timer = $timer->set ($tstamp[, $interval]) |
2268 |
|
2269 |
Set the time the event is generated to $tstamp (and optionally specifies a |
2270 |
new $interval). |
2271 |
|
2272 |
=item $timer = $timer->interval ($interval) |
2273 |
|
2274 |
By default (and when C<$interval> is C<0>), the timer will automatically |
2275 |
stop after it has fired once. If C<$interval> is non-zero, then the timer |
2276 |
is automatically rescheduled at the given intervals. |
2277 |
|
2278 |
=item $timer = $timer->start |
2279 |
|
2280 |
Start the timer. |
2281 |
|
2282 |
=item $timer = $timer->start ($tstamp[, $interval]) |
2283 |
|
2284 |
Set the event trigger time to C<$tstamp> and start the timer. Optionally |
2285 |
also replaces the interval. |
2286 |
|
2287 |
=item $timer = $timer->after ($delay[, $interval]) |
2288 |
|
2289 |
Like C<start>, but sets the expiry timer to c<urxvt::NOW + $delay>. |
2290 |
|
2291 |
=item $timer = $timer->stop |
2292 |
|
2293 |
Stop the timer. |
2294 |
|
2295 |
=back |
2296 |
|
2297 |
=head2 The C<urxvt::iow> Class |
2298 |
|
2299 |
This class implements io watchers/events. Example: |
2300 |
|
2301 |
$term->{socket} = ... |
2302 |
$term->{iow} = urxvt::iow |
2303 |
->new |
2304 |
->fd (fileno $term->{socket}) |
2305 |
->events (urxvt::EV_READ) |
2306 |
->start |
2307 |
->cb (sub { |
2308 |
my ($iow, $revents) = @_; |
2309 |
# $revents must be 1 here, no need to check |
2310 |
sysread $term->{socket}, my $buf, 8192 |
2311 |
or end-of-file; |
2312 |
}); |
2313 |
|
2314 |
|
2315 |
=over |
2316 |
|
2317 |
=item $iow = new urxvt::iow |
2318 |
|
2319 |
Create a new io watcher object in stopped state. |
2320 |
|
2321 |
=item $iow = $iow->cb (sub { my ($iow, $reventmask) = @_; ... }) |
2322 |
|
2323 |
Set the callback to be called when io events are triggered. C<$reventmask> |
2324 |
is a bitset as described in the C<events> method. |
2325 |
|
2326 |
=item $iow = $iow->fd ($fd) |
2327 |
|
2328 |
Set the file descriptor (not handle) to watch. |
2329 |
|
2330 |
=item $iow = $iow->events ($eventmask) |
2331 |
|
2332 |
Set the event mask to watch. The only allowed values are |
2333 |
C<urxvt::EV_READ> and C<urxvt::EV_WRITE>, which might be ORed |
2334 |
together, or C<urxvt::EV_NONE>. |
2335 |
|
2336 |
=item $iow = $iow->start |
2337 |
|
2338 |
Start watching for requested events on the given handle. |
2339 |
|
2340 |
=item $iow = $iow->stop |
2341 |
|
2342 |
Stop watching for events on the given file handle. |
2343 |
|
2344 |
=back |
2345 |
|
2346 |
=head2 The C<urxvt::iw> Class |
2347 |
|
2348 |
This class implements idle watchers, that get called automatically when |
2349 |
the process is idle. They should return as fast as possible, after doing |
2350 |
some useful work. |
2351 |
|
2352 |
=over |
2353 |
|
2354 |
=item $iw = new urxvt::iw |
2355 |
|
2356 |
Create a new idle watcher object in stopped state. |
2357 |
|
2358 |
=item $iw = $iw->cb (sub { my ($iw) = @_; ... }) |
2359 |
|
2360 |
Set the callback to be called when the watcher triggers. |
2361 |
|
2362 |
=item $timer = $timer->start |
2363 |
|
2364 |
Start the watcher. |
2365 |
|
2366 |
=item $timer = $timer->stop |
2367 |
|
2368 |
Stop the watcher. |
2369 |
|
2370 |
=back |
2371 |
|
2372 |
=head2 The C<urxvt::pw> Class |
2373 |
|
2374 |
This class implements process watchers. They create an event whenever a |
2375 |
process exits, after which they stop automatically. |
2376 |
|
2377 |
my $pid = fork; |
2378 |
... |
2379 |
$term->{pw} = urxvt::pw |
2380 |
->new |
2381 |
->start ($pid) |
2382 |
->cb (sub { |
2383 |
my ($pw, $exit_status) = @_; |
2384 |
... |
2385 |
}); |
2386 |
|
2387 |
=over |
2388 |
|
2389 |
=item $pw = new urxvt::pw |
2390 |
|
2391 |
Create a new process watcher in stopped state. |
2392 |
|
2393 |
=item $pw = $pw->cb (sub { my ($pw, $exit_status) = @_; ... }) |
2394 |
|
2395 |
Set the callback to be called when the timer triggers. |
2396 |
|
2397 |
=item $pw = $timer->start ($pid) |
2398 |
|
2399 |
Tells the watcher to start watching for process C<$pid>. |
2400 |
|
2401 |
=item $pw = $pw->stop |
2402 |
|
2403 |
Stop the watcher. |
2404 |
|
2405 |
=back |
2406 |
|
2407 |
=head1 ENVIRONMENT |
2408 |
|
2409 |
=head2 URXVT_PERL_VERBOSITY |
2410 |
|
2411 |
This variable controls the verbosity level of the perl extension. Higher |
2412 |
numbers indicate more verbose output. |
2413 |
|
2414 |
=over |
2415 |
|
2416 |
=item == 0 - fatal messages only |
2417 |
|
2418 |
=item >= 2 - general warnings (default level) |
2419 |
|
2420 |
=item >= 3 - script loading and management |
2421 |
|
2422 |
=item >=10 - all called hooks |
2423 |
|
2424 |
=item >=11 - hook return values |
2425 |
|
2426 |
=back |
2427 |
|
2428 |
=head1 AUTHOR |
2429 |
|
2430 |
Marc Lehmann <schmorp@schmorp.de> |
2431 |
http://software.schmorp.de/pkg/rxvt-unicode |
2432 |
|
2433 |
=cut |
2434 |
|
2435 |
1 |
2436 |
|
2437 |
# vim: sw=3: |