--- deliantra/Deliantra-Client/DC.pm	2006/05/27 20:46:54	1.72
+++ deliantra/Deliantra-Client/DC.pm	2006/05/29 19:30:27	1.73
@@ -322,6 +322,217 @@
    );
 }
 
+package CFClient::Recorder;
+
+our $RECORD_WINDOW;
+
+my $CMDBOX;
+my $CURRENT_CMDS;
+my $REC_BTN;
+
+my @ALLOWED_MODIFIER_KEYS = (
+   (CFClient::SDLK_LSHIFT) => "LSHIFT",
+   (CFClient::SDLK_LCTRL ) => "LCTRL",
+   (CFClient::SDLK_LALT  ) => "LALT",
+   (CFClient::SDLK_LMETA ) => "LMETA",
+
+   (CFClient::SDLK_RSHIFT) => "RSHIFT",
+   (CFClient::SDLK_RCTRL ) => "RCTRL",
+   (CFClient::SDLK_RALT  ) => "RALT",
+   (CFClient::SDLK_RMETA ) => "RMETA",
+);
+
+my %ALLOWED_MODIFIERS = (
+   (CFClient::KMOD_LSHIFT) => "LSHIFT",
+   (CFClient::KMOD_LCTRL ) => "LCTRL",
+   (CFClient::KMOD_LALT  ) => "LALT",
+   (CFClient::KMOD_LMETA ) => "LMETA",
+
+   (CFClient::KMOD_RSHIFT) => "RSHIFT",
+   (CFClient::KMOD_RCTRL ) => "RCTRL",
+   (CFClient::KMOD_RALT  ) => "RALT",
+   (CFClient::KMOD_RMETA ) => "RMETA",
+);
+
+my %DIRECT_BIND_CHARS = map { $_ => 1 } qw/0 1 2 3 4 5 6 7 8 9/;
+my @DIRECT_BIND_KEYS = (
+   CFClient::SDLK_F1,
+   CFClient::SDLK_F2,
+   CFClient::SDLK_F3,
+   CFClient::SDLK_F4,
+   CFClient::SDLK_F5,
+   CFClient::SDLK_F6,
+   CFClient::SDLK_F7,
+   CFClient::SDLK_F8,
+   CFClient::SDLK_F9,
+   CFClient::SDLK_F10,
+   CFClient::SDLK_F11,
+   CFClient::SDLK_F12,
+   CFClient::SDLK_F13,
+   CFClient::SDLK_F14,
+   CFClient::SDLK_F15,
+);
+
+# this binding dialog asks for a key-combo to be pressed
+# and if successful it binds the modifier+symbol to the 
+# supplied actions in $cmd.
+# (Bindings are stored in $::CFG->{bindings}->{$mod}->{$sym})
+sub open_binding_dialog {
+   my ($cmd) = @_;
+
+   my $w = new CFClient::UI::FancyFrame
+      title => "Bind Action";
+
+   $w->add (my $vb = new CFClient::UI::VBox);
+   $vb->add (new CFClient::UI::Label
+      text => "Press a modifier (CTRL, ALT and/or SHIFT) and a key."
+             ."You can only bind 0-9 and F1-F15 without modifiers."
+   );
+   $vb->add (my $entry = new CFClient::UI::Entry
+      text => "",
+      on_key_down => sub {
+         my ($entry, $ev) = @_;
+
+         my $mod = $ev->{mod};
+         my $sym = $ev->{sym};
+
+         # XXX: This seems a little bit hackisch to me, but i have to ignore them
+         if (grep { $_ == $sym } @ALLOWED_MODIFIER_KEYS) {
+            return;
+         }
+
+         if ($mod == CFClient::KMOD_NONE
+             and not $DIRECT_BIND_CHARS{chr ($ev->{unicode})}
+             and not grep { $sym == $_ } @DIRECT_BIND_KEYS)
+         {
+            $::STATUSBOX->add (
+               "Can't bind key ".CFClient::SDL_GetKeyName ($sym)
+               ." directly without modifier! It would damage the completer handling."
+            );
+            return;
+         }
+
+         $entry->focus_out;
+
+         $::CFG->{bindings}->{$mod}->{$sym} = $cmd;
+         $::STATUSBOX->add ("Bound actions to '".keycombo_to_name ($mod, $sym)."'. Don't forget Save Layout!");
+
+         $w->destroy
+      });
+
+   $entry->focus_in;
+   $w->center;
+   $w->show;
+}
+
+sub keycombo_to_name {
+   my ($mod, $sym) = @_;
+
+   my $mods = join '+',
+                 map { $ALLOWED_MODIFIERS{$_} }
+                    grep { $_ & $mod }
+                       keys %ALLOWED_MODIFIERS;
+   $mods .= "+" if $mods ne '';
+
+   return $mods . CFClient::SDL_GetKeyName ($sym);
+}
+
+sub clear_command_list {
+   $CMDBOX->clear () if $CMDBOX;
+}
+
+sub set_command_list {
+   my ($list) = @_;
+
+   return unless $CMDBOX;
+
+   $CMDBOX->clear ();
+   $CURRENT_CMDS = $list;
+
+   my $idx = 0;
+
+   for (@$list) {
+      $CMDBOX->add (my $hb = new CFClient::UI::HBox);
+
+      my $i = $idx;
+      $hb->add (new CFClient::UI::Button
+         text => "del",
+         tooltip => "Deletes the action from the record",
+         on_activate => sub {
+            $CMDBOX->remove ($hb);
+            $list->[$i] = undef;
+         });
+
+      $hb->add (new CFClient::UI::Label text => $_);
+
+      $idx++
+   }
+}
+
+# if $show is 1 the recorder will be shown
+sub start {
+   my ($show) = @_;
+
+   $RECORD_WINDOW->show if $show;
+
+   $REC_BTN->set_text ("stop recording");
+   $REC_BTN->{recording} = 1;
+   clear_command_list;
+   $::CONN->start_record;
+}
+
+# if $autobind is 1 the recorder will be automatically
+# jump into the binding query and hide the recorder window
+sub stop {
+   my ($autobind) = @_;
+
+   $REC_BTN->set_text ("start recording");
+   $REC_BTN->{recording} = 0;
+
+   my $rec = $::CONN->stop_record;
+   return unless ref $rec eq 'ARRAY';
+   set_command_list ($rec);
+
+   if ($autobind) {
+      open_binding_dialog ([ grep { defined $_ } @$CURRENT_CMDS ]);
+      $RECORD_WINDOW->hide;
+   }
+}
+
+sub make_window {
+   $RECORD_WINDOW = new CFClient::UI::FancyFrame
+      req_y => 1,
+      req_x => -1,
+      title => "Action Recorder";
+
+   $RECORD_WINDOW->add (my $vb = new CFClient::UI::VBox);
+   $vb->add ($REC_BTN = new CFClient::UI::Button
+      text => "start recording",
+      tooltip => "Start/Stops recording of actions."
+                ."(CTRL+INS Starts the recorder, INS Stops recorder and binds automatically)"
+                ."All subsequent actions after the recording started will be captured."
+                ."The actions are displayed after the record was stopped."
+                ."To bind the action you have to click on the 'Bind' button",
+      on_activate => sub {
+         my ($btn) = @_;
+
+         unless ($btn->{recording}) {
+            start;
+         } else {
+            stop;
+         }
+      });
+   $vb->add ($CMDBOX = new CFClient::UI::VBox);
+   $vb->add (new CFClient::UI::Button
+      text => "bind",
+      tooltip => "This opens a query where you have to press the key combination to bind the recorded actions",
+      on_activate => sub {
+         open_binding_dialog ([ grep { defined $_ } @$CURRENT_CMDS ]);
+      });
+
+   $RECORD_WINDOW
+}
+
 1;
 
 =back