=head1 NAME

Crossfire::Client - undocumented utility garbage for our crossfire client

=head1 SYNOPSIS

 use Crossfire::Client;

=head1 DESCRIPTION

=over 4

=cut

package Crossfire::Client;

BEGIN {
   $VERSION = '0.1';

   use XSLoader;
   XSLoader::load "Crossfire::Client", $VERSION;
}

sub find_rcfile($) {
   my $path;

   for (@INC) {
      $path = "$_/Crossfire/resources/$_[0]";
      return $path if -r $path;
   }

   die "FATAL: can't find required file $_[0]\n";
}

sub read_cfg {
   my ($file) = @_;

   open CFG, $file
      or return;

   my $CFG;

   local $/;
   $CFG = eval <CFG>;

   $::CFG = $CFG;

   close CFG;
}

sub write_cfg {
   my ($file) = @_;

   open CFG, ">$file"
      or return;

   {
      require Data::Dumper;
      local $Data::Dumper::Purity = 1;
      $::CFG->{VERSION} = $::VERSION;
      print CFG Data::Dumper->Dump ([$::CFG], [qw/CFG/]);
   }

   close CFG;
}

package Crossfire::Client::Texture;

use Scalar::Util;

use SDL::OpenGL;

my @textures;

sub new {
   my ($class, %data) = @_;

   my $self = bless {
      internalformat => GL_RGBA,
      format         => GL_RGBA,
      %data,
   }, $class;

   push @textures, $self;
   Scalar::Util::weaken $textures[-1];

   $self->upload;

   $self
}

sub new_from_image {
   my ($class, $image) = @_;

   $class->new (image => $image)
}

sub new_from_file {
   my ($class, $path) = @_;

   open my $fh, "<:raw", $path
      or die "$path: $!";

   local $/;
   $class->new_from_image (<$fh>)
}

#sub new_from_surface {
#   my ($class, $surface) = @_;
#
#   $surface->rgba;
#
#   $class->new (
#      data   => $surface->pixels,
#      width  => $surface->width,
#      height => $surface->height,
#   )
#}

sub new_from_text {
   my ($class, $text, $height) = @_;

   my ($w, $h, $data) = Crossfire::Client::font_render $text, $height;

   $class->new (
      width          => $w,
      height         => $h,
      data           => $data,
      internalformat => GL_ALPHA4,
      format         => GL_ALPHA,
   )
}

sub new_from_opengl {
   my ($class, $w, $h, $cb) = @_;

   $class->new (width => $w, height => $h, rendercb => $cb)
}

sub upload {
   my ($self) = @_;

   return unless $SDL::App::USING_OPENGL;

   my $data;

   if (exists $self->{data}) {
      $data = $self->{data};
   } elsif (exists $self->{rendercb}) {
      glViewport 0, 0, $self->{width}, $self->{height};
      glMatrixMode GL_PROJECTION;
      glLoadIdentity;
      glOrtho 0, $self->{width}, 0, $self->{height}, -100, 100;
      glMatrixMode GL_MODELVIEW;
      glPushmatrix;
      glLoadIdentity;
      glClear GL_COLOR_BUFFER_BIT;

      $self->{rendercb}->($self, $self->{width}, $self->{height});
   } else {
      my $pb = new Gtk2::Gdk::PixbufLoader;
      $pb->write ($self->{image});
      $pb->close;

      $pb = $pb->get_pixbuf;
      $pb = $pb->add_alpha (0, 0, 0, 0);

      $self->{width}  = $pb->get_width;
      $self->{height} = $pb->get_height;

      $data = $pb->get_pixels;
   }

   ($self->{name}) = @{glGenTextures 1};

   glBindTexture GL_TEXTURE_2D, $self->{name};

   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST;
   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST;#_MIPMAP_LINEAR;
   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP;
   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP;
   
   glGetError;
   if (defined $data) {
      glTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   $self->{width}, $self->{height},
                   0,
                   $self->{format},
                   GL_UNSIGNED_BYTE,
                   $data;
      glGetError and die;
   } else {
      glCopyTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   0, 0,
                   $self->{width}, $self->{height},
                   0;
      glPopmatrix;
   }
}

sub DESTROY {
   my ($self) = @_;

   return unless exists $self->{name};

   glDeleteTextures delete $self->{name};
}

push @::GL_INIT, sub {
   $_->upload
      for grep $_, @textures;
};

1;

=back

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut