=head1 NAME

CFClient - undocumented utility garbage for our crossfire client

=head1 SYNOPSIS

 use CFClient;

=head1 DESCRIPTION

=over 4

=cut

package CFClient;

BEGIN {
   $VERSION = '0.1';

   use XSLoader;
   XSLoader::load "CFClient", $VERSION;
}

use Carp ();
use AnyEvent;
use BerkeleyDB;
use CFClient::OpenGL;

our %GL_EXT;
our $GL_VERSION;

our $GL_NPOT;

sub gl_init {
   $GL_VERSION = gl_version * 1;
   %GL_EXT = map +($_ => 1), split /\s+/, gl_extensions;

   $GL_NPOT = $GL_EXT{GL_ARB_texture_non_power_of_two} || $GL_VERSION >= 2;

   glEnable GL_TEXTURE_2D;
   glEnable GL_COLOR_MATERIAL;
   glShadeModel GL_FLAT;
   glDisable GL_DEPTH_TEST;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;

   glHint GL_PERSPECTIVE_CORRECTION_HINT, GL_FASTEST;

   CFClient::Texture::restore_state ();
}

sub find_rcfile($) {
   my $path;

   for (grep !ref, @INC) {
      $path = "$_/CFClient/resources/$_[0]";
      return $path if -r $path;
   }

   die "FATAL: can't find required file $_[0]\n";
}

sub read_cfg {
   my ($file) = @_;

   open CFG, $file
      or return;

   my $CFG;

   local $/;
   $CFG = eval <CFG>;

   $::CFG = $CFG;

   close CFG;
}

sub write_cfg {
   my ($file) = @_;

   open CFG, ">$file"
      or return;

   {
      require Data::Dumper;
      local $Data::Dumper::Purity = 1;
      $::CFG->{VERSION} = $::VERSION;
      print CFG Data::Dumper->Dump ([$::CFG], [qw/CFG/]);
   }

   close CFG;
}

mkdir "$Crossfire::VARDIR/pclient", 0777;

our $DB_ENV = new BerkeleyDB::Env
                 -Home => "$Crossfire::VARDIR/pclient",
                 -Cachesize => 1_000_000,
                 -ErrFile => "$Crossfire::VARDIR/pclient/errorlog.txt",
#                 -ErrPrefix => "DATABASE",
                 -Verbose => 1,
                 -Flags => DB_CREATE | DB_RECOVER_FATAL | DB_INIT_MPOOL | DB_INIT_LOCK | DB_INIT_TXN,
                    or die "unable to create/open database home $Crossfire::VARDIR/pclient: $BerkeleyDB::Error";

sub db_table($) {
   my ($table) = @_;

   $table =~ s/([^a-zA-Z0-9_\-])/sprintf "=%x=", ord $1/ge;
   
   new CFClient::Database
      -Env      => $DB_ENV,
      -Filename => $table,
#      -Filename => "database",
#      -Subname  => $table,
      -Flags    => DB_CREATE | DB_UPGRADE,
         or die "unable to create/open database table $_[0]: $BerkeleyDB::Error";
}

package CFClient::Database;

our @ISA = BerkeleyDB::Btree::;

sub get($$) {
   my $data;

   $_[0]->db_get ($_[1], $data) == 0
      ? $data
      : ()
}

my %DB_SYNC;

sub put($$$) {
   my ($db, $key, $data) = @_;

   $DB_SYNC{$db} = AnyEvent->timer (after => 5, cb => sub { $db->db_sync });

   $db->db_put ($key => $data)
}

package CFClient::Texture;

use strict;

use Scalar::Util;

use CFClient::OpenGL;

my %TEXTURES;

sub new {
   my ($class, %data) = @_;

   my $self = bless {
      internalformat => GL_RGBA,
      format         => GL_RGBA,
      type           => GL_UNSIGNED_BYTE,
      %data,
   }, $class;

   Scalar::Util::weaken ($TEXTURES{$self+0} = $self);

   $self->upload;

   $self
}

sub new_from_image {
   my ($class, $image, %arg) = @_;

   $class->new (image => $image, %arg)
}

sub new_from_file {
   my ($class, $path, %arg) = @_;

   open my $fh, "<:raw", $path
      or die "$path: $!";

   local $/;
   $class->new_from_image (<$fh>, %arg)
}

#sub new_from_surface {
#   my ($class, $surface) = @_;
#
#   $surface->rgba;
#
#   $class->new (
#      data   => $surface->pixels,
#      w      => $surface->width,
#      h      => $surface->height,
#   )
#}

sub new_from_layout {
   my ($class, $layout, %arg) = @_;

   my ($w, $h, $data) = $layout->render;

   $class->new (
      w              => $w,
      h              => $h,
      data           => $data,
      format         => GL_ALPHA,
      internalformat => GL_ALPHA,
      type           => GL_UNSIGNED_BYTE,
      %arg,
   )
}

sub new_from_opengl {
   my ($class, $w, $h, $cb) = @_;

   $class->new (w => $w, h => $h, render_cb => $cb)
}

sub topot {
   (grep $_ >= $_[0], 1, 2, 4, 8, 16, 32, 64, 128, 256, 512, 1024, 2048, 4096, 8192, 16384, 32768)[0]
}

sub upload {
   my ($self) = @_;

   return unless $GL_VERSION;

   my $data;

   if (exists $self->{data}) {
      $data = $self->{data};

   } elsif (exists $self->{render_cb}) {
      glViewport 0, 0, $self->{w}, $self->{h};
      glMatrixMode GL_PROJECTION;
      glLoadIdentity;
      glOrtho 0, $self->{w}, 0, $self->{h}, -10000, 10000;
      glMatrixMode GL_MODELVIEW;
      glLoadIdentity;
      $self->{render_cb}->($self, $self->{w}, $self->{h});

   } else {
      ($self->{w}, $self->{h}, $data, $self->{internalformat}, $self->{format}, $self->{type})
         = CFClient::load_image_inline $self->{image};
   }

   my ($tw, $th) = @$self{qw(w h)};

   unless ($tw > 0 && $th > 0) {
      $tw = $th = 1;
      $data = "\x00" x 64;
   }

   $self->{minified} = [CFClient::average $tw, $th, $data]
      if $self->{minify};

   unless ($GL_NPOT) {
      # TODO: does not work for zero-sized textures
      $tw = topot $tw;
      $th = topot $th;

      if (($tw != $self->{w} || $th != $self->{h}) && defined $data) {
         my $bpp = (length $data) / ($self->{w} * $self->{h});
         $data = pack "(a" . ($tw * $bpp) . ")*",
                    unpack "(a" . ($self->{w} * $bpp) . ")*", $data;
         $data .= ("\x00" x ($tw * $bpp)) x ($th - $self->{h});
      }
   }

   $self->{s} = $self->{w} / $tw;
   $self->{t} = $self->{h} / $th;

   $self->{name} ||= glGenTexture;

   glBindTexture GL_TEXTURE_2D, $self->{name};

   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_CLAMP;
   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_CLAMP;

   if ($::FAST) {
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST;
   } elsif ($self->{mipmap} && $GL_VERSION >= 1.4) {
      # alternatively check for 0x8191
      glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, 1;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR;
   } else {
      glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, $self->{mipmap};
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR;
   }
   
   glGetError;

   if (defined $data) {
      glTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   $tw, $th, # need to pad texture first
                   0,
                   $self->{format},
                   $self->{type},
                   $data;
      if (my $error = glGetError) {
         Carp::cluck sprintf "texture upload error: %x %dx%d i=%x f=%x t=%x",
                      $error, $tw, $th, $self->{internalformat},  $self->{format}, $self->{type};
      }
   } else {
      glCopyTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   0, 0,
                   $tw, $th,
                   0;
      if (my $error = glGetError) {
         Carp::cluck sprintf "texture upload error: %x %dx%d i=%x",
                      $error, $tw, $th, $self->{internalformat};
      }
   }
}

sub DESTROY {
   my ($self) = @_;

   delete $TEXTURES{$self+0};

   glDeleteTexture delete $self->{name}
      if $self->{name};
}

sub restore_state{
   $_->upload
      for values %TEXTURES;
};

1;

=back

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut