Deliantra-Client/DC/DB.pm

=head1 NAME

CFPlus::DB - async. database and filesystem access for cfplus

=head1 SYNOPSIS

 use CFPlus::DB;

=head1 DESCRIPTION

=over 4

=cut

package CFPlus::DB;

use strict;
use utf8;

use Carp ();
use Storable ();
use Config;
use Event ();

use CFPlus;

our $DB_HOME = "$Crossfire::VARDIR/cfplus-$BerkeleyDB::db_version-$Config{archname}";

sub path_of_res($) {
   utf8::downgrade $_[0]; # bug in unpack "H*"
   "$DB_HOME/res-data-" . unpack "H*", $_[0]
}

sub sync {
   # for debugging
   #CFPlus::DB::Server::req (sync => sub { });
   CFPlus::DB::Server::sync ();
}

sub exists($$$) {
   CFPlus::DB::Server::req (exists => @_);
}

sub get($$$) {
   CFPlus::DB::Server::req (get => @_);
}

sub put($$$$) {
   CFPlus::DB::Server::req (put => @_);
}

sub unlink($$) {
   CFPlus::DB::Server::req (unlink => @_);
}

sub write_file($$$) {
   CFPlus::DB::Server::req (write_file => @_);
}

sub prefetch_file($$$) {
   CFPlus::DB::Server::req (prefetch_file => @_);
}

sub logprint($$$) {
   CFPlus::DB::Server::req (logprint => @_);
}

our $tilemap;

sub get_tile_id_sync($) {
   my ($hash) = @_;

   # fetch the full face table first
   unless ($tilemap) {
      CFPlus::DB::Server::req (table => facemap => sub { $tilemap = $_[0] });
      sync;
   }

   $tilemap->{$hash} ||= do {
      my $id;
      CFPlus::DB::Server::req (get_tile_id => $hash, sub { $id = $_[0] });
      sync;
      $id
   }
}

package CFPlus::DB::Server;

use strict;

use Fcntl;
use BerkeleyDB;

our $DB_ENV;
our $DB_STATE;
our %DB_TABLE;

sub open_db {
   mkdir $DB_HOME, 0777;
   my $recover = $BerkeleyDB::db_version >= 4.4 
                 ? eval "DB_REGISTER | DB_RECOVER"
                 : 0;

   $DB_ENV = new BerkeleyDB::Env
                    -Home => $DB_HOME,
                    -Cachesize => 8_000_000,
                    -ErrFile => "$DB_HOME/errorlog.txt",
#                 -ErrPrefix => "DATABASE",
                    -Verbose => 1,
                    -Flags => DB_CREATE | DB_RECOVER | DB_INIT_MPOOL | DB_INIT_LOCK | DB_INIT_TXN | $recover,
                    -SetFlags => DB_AUTO_COMMIT | DB_LOG_AUTOREMOVE,
                       or die "unable to create/open database home $DB_HOME: $BerkeleyDB::Error";

   1
}

sub table($) {
   $DB_TABLE{$_[0]} ||= do {
      my ($table) = @_;

      $table =~ s/([^a-zA-Z0-9_\-])/sprintf "=%x=", ord $1/ge;

      new BerkeleyDB::Btree
         -Env      => $DB_ENV,
         -Filename => $table,
#      -Filename => "database",
#      -Subname  => $table,
         -Property => DB_CHKSUM,
         -Flags    => DB_CREATE | DB_UPGRADE,
            or die "unable to create/open database table $_[0]: $BerkeleyDB::Error"
   }
}

our %CB;
our $FH;
our $ID = "aaa0";
our ($fh_r_watcher, $fh_w_watcher);
our $sync_timer;
our $write_buf;
our $read_buf;

our $SYNC = Event->idle (min => 5, max => 60, parked => 1, cb => sub {
   CFPlus::DB::Server::req (sync => sub { });
   $_[0]->w->stop;
});

sub fh_write {
   my $len = syswrite $FH, $write_buf;

   substr $write_buf, 0, $len, "";

   $fh_w_watcher->stop
      unless length $write_buf;
}

sub fh_read {
   my $status = sysread $FH, $read_buf, 16384, length $read_buf;

   die "FATAL: database process died\n"
      if $status == 0 && defined $status;

   while () {
      return if 4 > length $read_buf;
      my $len = unpack "N", $read_buf;

      return if $len + 4 > length $read_buf;

      substr $read_buf, 0, 4, "";
      my $res = Storable::thaw substr $read_buf, 0, $len, "";

      my ($id, @args) = @$res;
      (delete $CB{$id})->(@args);
   }
}

sub sync {
   # biggest mess evarr
   my $fds; (vec $fds, fileno $FH, 1) =  1;

   while (1 < scalar keys %CB) {
      my $r = $fds;
      my $w = length $write_buf ? $fds : undef;
      select $r, $w, undef, undef;

      fh_write if vec $w, fileno $FH, 1;
      fh_read  if vec $r, fileno $FH, 1;
   }
}

sub req {
   my ($type, @args) = @_;
   my $cb = pop @args;

   my $id = ++$ID;
   $write_buf .= pack "N/a*", Storable::freeze [$id, $type, @args];
   $CB{$id} = $cb;

   $fh_w_watcher->start;
   $SYNC->start;
}

sub do_sync {
   $DB_ENV->txn_checkpoint (0, 0, 0);
   ()
}

sub do_exists {
   my ($db, $key) = @_;

   utf8::downgrade $key;
   my $data;
   (table $db)->db_get ($key, $data) == 0
      ? length $data
      : ()
}

sub do_get {
   my ($db, $key) = @_;

   utf8::downgrade $key;
   my $data;
   (table $db)->db_get ($key, $data) == 0
      ? $data
      : ()
}

sub do_put {
   my ($db, $key, $data) = @_;

   utf8::downgrade $key;
   utf8::downgrade $data;
   (table $db)->db_put ($key => $data)
}

sub do_table {
   my ($db) = @_;

   $db = table $db;

   my $cursor = $db->db_cursor;
   my %kv;
   my ($k, $v);
   $kv{$k} = $v while $cursor->c_get ($k, $v, BerkeleyDB::DB_NEXT) == 0;

   \%kv
}

sub do_get_tile_id {
   my ($hash) = @_;

   my $id;
   my $table = table "facemap";

   return $id
      if $table->db_get ($hash, $id) == 0;

   for (1..100) {
      my $txn = $DB_ENV->txn_begin;
      my $status = $table->db_get (id => $id);
      if ($status == 0 || $status == BerkeleyDB::DB_NOTFOUND) {
         $id = ($id || 64) + 1;
         if ($table->db_put (id => $id) == 0
             && $table->db_put ($hash => $id) == 0) {
            $txn->txn_commit;

            return $id;
         }
      }
      $txn->txn_abort;
   }

   die "maximum number of transaction retries reached - database problems?";
}

sub do_unlink {
   unlink $_[0];
}

sub do_write_file {
   my ($file, $data) = @_;

   utf8::downgrade $file;
   utf8::downgrade $data;
   open my $fh, ">:raw", $file
      or return;
   print $fh $data;
   close $fh;

   1
}

sub do_prefetch_file {
   my ($file, $size) = @_;

   utf8::downgrade $file;
   open my $fh, "<:raw", $file
      or return;
   sysread $fh, my $buf, $size;

   1
}

our %LOG_FH;

sub do_logprint {
   my ($path, $line) = @_;

   $LOG_FH{$path} ||= do {
      open my $fh, ">>:utf8", $path
         or warn "Couldn't open logfile $path: $!";

      $fh->autoflush (1);

      $fh
   };

   my ($sec, $min, $hour, $mday, $mon, $year) = localtime time;

   my $ts = sprintf "%04d-%02d-%02d %02d:%02d:%02d",
               $year + 1900, $mon + 1, $mday, $hour, $min, $sec;

   print { $LOG_FH{$path} } "$ts $line\n"
}

sub run {
   ($FH, my $fh) = CFPlus::socketpipe;

   my $oldfh = select $FH; $| = 1; select $oldfh;
   my $oldfh = select $fh; $| = 1; select $oldfh;

   my $pid = fork;
   
   if (defined $pid && !$pid) {
      local $SIG{QUIT};
      local $SIG{__DIE__};
      local $SIG{__WARN__};
      eval {
         close $FH;

         unless (eval { open_db }) {
            eval { File::Path::rmtree $DB_HOME };
            open_db;
         }

         while () {
            4 == read $fh, my $len, 4
               or last;
            $len = unpack "N", $len;
            $len == read $fh, my $req, $len
               or die "unexpected eof while reading request";

            $req = Storable::thaw $req;

            my ($id, $type, @args) = @$req;
            my $cb = CFPlus::DB::Server->can ("do_$type")
               or die "$type: unknown database request type\n";
            my $res = pack "N/a*", Storable::freeze [$id, $cb->(@args)];
            (syswrite $fh, $res) == length $res
               or die;
         }
      };

      my $error = $@;

      eval {
         undef %DB_TABLE;
         undef $DB_ENV;

         Storable::store_fd [die => $error], $fh;
      };

      CFPlus::_exit 0;
   }

   close $fh;
   CFPlus::fh_nonblocking $FH, 1;

   $CB{die} = sub { die shift };

   $fh_r_watcher = Event->io (fd => $FH, poll => 'r', nice => 1, cb => \&fh_read);
   $fh_w_watcher = Event->io (fd => $FH, poll => 'w', nice => -1, parked => 1, cb => \&fh_write);
   $SYNC->start;
}

sub stop {
   close $FH;
}

1;

=back

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.15
Committed:	Mon Aug 6 02:11:45 2007 UTC (16 years, 10 months ago) by root
Branch:	MAIN
Changes since 1.14:	+28 -0 lines
Log Message:	remove (the last\|a) chokepoint in cfplus, logprint caused hangs on heavy disk i/o, e.g. when syncing the database data to disk
#	User	Rev	Content
1	root	1.1	=head1 NAME
2
3	root	1.9	CFPlus::DB - async. database and filesystem access for cfplus
4	root	1.1
5			=head1 SYNOPSIS
6
7			use CFPlus::DB;
8
9			=head1 DESCRIPTION
10
11			=over 4
12
13			=cut
14
15			package CFPlus::DB;
16
17			use strict;
18			use utf8;
19
20			use Carp ();
21	root	1.5	use Storable ();
22	root	1.9	use Config;
23	root	1.14	use Event ();
24	root	1.1
25	root	1.3	use CFPlus;
26
27	root	1.9	our $DB_HOME = "$Crossfire::VARDIR/cfplus-$BerkeleyDB::db_version-$Config{archname}";
28
29	root	1.11	sub path_of_res($) {
30	root	1.12	utf8::downgrade $_[0]; # bug in unpack "H*"
31			"$DB_HOME/res-data-" . unpack "H*", $_[0]
32	root	1.9	}
33
34	root	1.1	sub sync {
35			# for debugging
36			#CFPlus::DB::Server::req (sync => sub { });
37			CFPlus::DB::Server::sync ();
38			}
39
40	root	1.9	sub exists($$$) {
41			CFPlus::DB::Server::req (exists => @_);
42			}
43
44	root	1.1	sub get($$$) {
45			CFPlus::DB::Server::req (get => @_);
46			}
47
48			sub put($$$$) {
49			CFPlus::DB::Server::req (put => @_);
50			}
51
52	root	1.9	sub unlink($$) {
53			CFPlus::DB::Server::req (unlink => @_);
54			}
55
56			sub write_file($$$) {
57			CFPlus::DB::Server::req (write_file => @_);
58			}
59
60	root	1.11	sub prefetch_file($$$) {
61			CFPlus::DB::Server::req (prefetch_file => @_);
62			}
63
64	root	1.15	sub logprint($$$) {
65			CFPlus::DB::Server::req (logprint => @_);
66			}
67
68	root	1.1	our $tilemap;
69
70			sub get_tile_id_sync($) {
71			my ($hash) = @_;
72
73			# fetch the full face table first
74			unless ($tilemap) {
75			CFPlus::DB::Server::req (table => facemap => sub { $tilemap = $_[0] });
76			sync;
77			}
78
79			$tilemap->{$hash} \|\|= do {
80			my $id;
81			CFPlus::DB::Server::req (get_tile_id => $hash, sub { $id = $_[0] });
82			sync;
83			$id
84			}
85			}
86
87			package CFPlus::DB::Server;
88
89			use strict;
90
91			use Fcntl;
92			use BerkeleyDB;
93
94			our $DB_ENV;
95			our $DB_STATE;
96			our %DB_TABLE;
97
98			sub open_db {
99			mkdir $DB_HOME, 0777;
100			my $recover = $BerkeleyDB::db_version >= 4.4
101			? eval "DB_REGISTER \| DB_RECOVER"
102			: 0;
103
104			$DB_ENV = new BerkeleyDB::Env
105			-Home => $DB_HOME,
106			-Cachesize => 8_000_000,
107			-ErrFile => "$DB_HOME/errorlog.txt",
108			# -ErrPrefix => "DATABASE",
109			-Verbose => 1,
110			-Flags => DB_CREATE \| DB_RECOVER \| DB_INIT_MPOOL \| DB_INIT_LOCK \| DB_INIT_TXN \| $recover,
111			-SetFlags => DB_AUTO_COMMIT \| DB_LOG_AUTOREMOVE,
112			or die "unable to create/open database home $DB_HOME: $BerkeleyDB::Error";
113
114			1
115			}
116
117			sub table($) {
118			$DB_TABLE{$_[0]} \|\|= do {
119			my ($table) = @_;
120
121			$table =~ s/([^a-zA-Z0-9_\-])/sprintf "=%x=", ord $1/ge;
122
123			new BerkeleyDB::Btree
124			-Env => $DB_ENV,
125			-Filename => $table,
126			# -Filename => "database",
127			# -Subname => $table,
128			-Property => DB_CHKSUM,
129			-Flags => DB_CREATE \| DB_UPGRADE,
130			or die "unable to create/open database table $_[0]: $BerkeleyDB::Error"
131			}
132			}
133
134			our %CB;
135			our $FH;
136			our $ID = "aaa0";
137			our ($fh_r_watcher, $fh_w_watcher);
138			our $sync_timer;
139			our $write_buf;
140			our $read_buf;
141
142	root	1.14	our $SYNC = Event->idle (min => 5, max => 60, parked => 1, cb => sub {
143			CFPlus::DB::Server::req (sync => sub { });
144			$_[0]->w->stop;
145			});
146
147	root	1.1	sub fh_write {
148			my $len = syswrite $FH, $write_buf;
149
150			substr $write_buf, 0, $len, "";
151
152	root	1.14	$fh_w_watcher->stop
153	root	1.1	unless length $write_buf;
154			}
155
156			sub fh_read {
157			my $status = sysread $FH, $read_buf, 16384, length $read_buf;
158
159			die "FATAL: database process died\n"
160			if $status == 0 && defined $status;
161
162			while () {
163			return if 4 > length $read_buf;
164			my $len = unpack "N", $read_buf;
165
166			return if $len + 4 > length $read_buf;
167
168			substr $read_buf, 0, 4, "";
169			my $res = Storable::thaw substr $read_buf, 0, $len, "";
170
171			my ($id, @args) = @$res;
172			(delete $CB{$id})->(@args);
173			}
174			}
175
176			sub sync {
177			# biggest mess evarr
178			my $fds; (vec $fds, fileno $FH, 1) = 1;
179
180			while (1 < scalar keys %CB) {
181			my $r = $fds;
182			my $w = length $write_buf ? $fds : undef;
183			select $r, $w, undef, undef;
184
185			fh_write if vec $w, fileno $FH, 1;
186			fh_read if vec $r, fileno $FH, 1;
187			}
188			}
189
190			sub req {
191			my ($type, @args) = @_;
192			my $cb = pop @args;
193
194			my $id = ++$ID;
195			$write_buf .= pack "N/a*", Storable::freeze [$id, $type, @args];
196			$CB{$id} = $cb;
197
198	root	1.14	$fh_w_watcher->start;
199			$SYNC->start;
200	root	1.1	}
201
202			sub do_sync {
203			$DB_ENV->txn_checkpoint (0, 0, 0);
204			()
205			}
206
207	root	1.9	sub do_exists {
208			my ($db, $key) = @_;
209
210			utf8::downgrade $key;
211			my $data;
212			(table $db)->db_get ($key, $data) == 0
213			? length $data
214			: ()
215			}
216
217	root	1.1	sub do_get {
218			my ($db, $key) = @_;
219
220	root	1.5	utf8::downgrade $key;
221	root	1.1	my $data;
222			(table $db)->db_get ($key, $data) == 0
223			? $data
224			: ()
225			}
226
227			sub do_put {
228			my ($db, $key, $data) = @_;
229
230	root	1.5	utf8::downgrade $key;
231			utf8::downgrade $data;
232	root	1.1	(table $db)->db_put ($key => $data)
233			}
234
235			sub do_table {
236			my ($db) = @_;
237
238			$db = table $db;
239
240			my $cursor = $db->db_cursor;
241			my %kv;
242			my ($k, $v);
243			$kv{$k} = $v while $cursor->c_get ($k, $v, BerkeleyDB::DB_NEXT) == 0;
244
245			\%kv
246			}
247
248			sub do_get_tile_id {
249			my ($hash) = @_;
250
251			my $id;
252			my $table = table "facemap";
253
254			return $id
255			if $table->db_get ($hash, $id) == 0;
256
257			for (1..100) {
258			my $txn = $DB_ENV->txn_begin;
259			my $status = $table->db_get (id => $id);
260			if ($status == 0 \|\| $status == BerkeleyDB::DB_NOTFOUND) {
261			$id = ($id \|\| 64) + 1;
262			if ($table->db_put (id => $id) == 0
263			&& $table->db_put ($hash => $id) == 0) {
264			$txn->txn_commit;
265
266			return $id;
267			}
268			}
269			$txn->txn_abort;
270			}
271
272			die "maximum number of transaction retries reached - database problems?";
273			}
274
275	root	1.9	sub do_unlink {
276			unlink $_[0];
277			}
278
279			sub do_write_file {
280			my ($file, $data) = @_;
281
282			utf8::downgrade $file;
283			utf8::downgrade $data;
284	root	1.11	open my $fh, ">:raw", $file
285	root	1.9	or return;
286			print $fh $data;
287			close $fh;
288
289			1
290			}
291
292	root	1.11	sub do_prefetch_file {
293			my ($file, $size) = @_;
294
295			utf8::downgrade $file;
296			open my $fh, "<:raw", $file
297			or return;
298			sysread $fh, my $buf, $size;
299
300			1
301			}
302
303	root	1.15	our %LOG_FH;
304
305			sub do_logprint {
306			my ($path, $line) = @_;
307
308			$LOG_FH{$path} \|\|= do {
309			open my $fh, ">>:utf8", $path
310			or warn "Couldn't open logfile $path: $!";
311
312			$fh->autoflush (1);
313
314			$fh
315			};
316
317			my ($sec, $min, $hour, $mday, $mon, $year) = localtime time;
318
319			my $ts = sprintf "%04d-%02d-%02d %02d:%02d:%02d",
320			$year + 1900, $mon + 1, $mday, $hour, $min, $sec;
321
322			print { $LOG_FH{$path} } "$ts $line\n"
323			}
324
325	root	1.1	sub run {
326			($FH, my $fh) = CFPlus::socketpipe;
327
328			my $oldfh = select $FH; $\| = 1; select $oldfh;
329			my $oldfh = select $fh; $\| = 1; select $oldfh;
330
331			my $pid = fork;
332
333			if (defined $pid && !$pid) {
334	root	1.15	local $SIG{QUIT};
335	root	1.1	local $SIG{__DIE__};
336	root	1.15	local $SIG{__WARN__};
337	root	1.1	eval {
338			close $FH;
339
340			unless (eval { open_db }) {
341	root	1.6	eval { File::Path::rmtree $DB_HOME };
342	root	1.1	open_db;
343			}
344
345			while () {
346			4 == read $fh, my $len, 4
347			or last;
348			$len = unpack "N", $len;
349			$len == read $fh, my $req, $len
350			or die "unexpected eof while reading request";
351
352			$req = Storable::thaw $req;
353
354			my ($id, $type, @args) = @$req;
355			my $cb = CFPlus::DB::Server->can ("do_$type")
356			or die "$type: unknown database request type\n";
357			my $res = pack "N/a*", Storable::freeze [$id, $cb->(@args)];
358			(syswrite $fh, $res) == length $res
359			or die;
360			}
361			};
362
363			my $error = $@;
364
365			eval {
366			undef %DB_TABLE;
367			undef $DB_ENV;
368
369			Storable::store_fd [die => $error], $fh;
370			};
371
372			CFPlus::_exit 0;
373			}
374
375			close $fh;
376	root	1.3	CFPlus::fh_nonblocking $FH, 1;
377	root	1.1
378	root	1.2	$CB{die} = sub { die shift };
379	root	1.1
380	root	1.14	$fh_r_watcher = Event->io (fd => $FH, poll => 'r', nice => 1, cb => \&fh_read);
381			$fh_w_watcher = Event->io (fd => $FH, poll => 'w', nice => -1, parked => 1, cb => \&fh_write);
382			$SYNC->start;
383	root	1.1	}
384
385	root	1.6	sub stop {
386			close $FH;
387			}
388
389	root	1.1	1;
390
391			=back
392
393			=head1 AUTHOR
394
395			Marc Lehmann <schmorp@schmorp.de>
396			http://home.schmorp.de/
397
398			=cut
399