| 1 |
package CFClient::MapWidget; |
| 2 |
|
| 3 |
use strict; |
| 4 |
use utf8; |
| 5 |
|
| 6 |
use List::Util qw(min max); |
| 7 |
|
| 8 |
use CFClient::OpenGL; |
| 9 |
|
| 10 |
our @ISA = CFClient::UI::Base::; |
| 11 |
|
| 12 |
my $magicmap_tex = |
| 13 |
new_from_file CFClient::Texture CFClient::find_rcfile "magicmap.png", |
| 14 |
mipmap => 1, wrap => 0, internalformat => GL_ALPHA; |
| 15 |
|
| 16 |
sub new { |
| 17 |
my $class = shift; |
| 18 |
|
| 19 |
my $self = $class->SUPER::new ( |
| 20 |
z => -1, |
| 21 |
can_focus => 1, |
| 22 |
list => glGenList, |
| 23 |
|
| 24 |
smooth_matrix => [ |
| 25 |
0.05, 0.13, 0.05, |
| 26 |
0.13, 0.30, 0.13, |
| 27 |
0.05, 0.13, 0.05, |
| 28 |
], |
| 29 |
|
| 30 |
@_ |
| 31 |
); |
| 32 |
|
| 33 |
$self->{completer} = new CFClient::MapWidget::Command:: |
| 34 |
command => $self->{command}, |
| 35 |
can_focus => 1, |
| 36 |
tooltip => "<b>The Command Completer</b>\n\n" |
| 37 |
. "This is your central interface to send text commands to the server. " |
| 38 |
. "To enter a verbatim command to send to the server, just type the command, " |
| 39 |
. "followed by a space, and press return. " |
| 40 |
. "Typing the initial letters of words (or just any letters) displays guesses " |
| 41 |
. "for commands you might want to use.\n" |
| 42 |
. "You can use the cursor-up and cursor-down keys to select between those guesses.\n" |
| 43 |
. "<b>Right-Click</b> opens a menu where you cna select further options, sich as redefining key bindings.", |
| 44 |
; |
| 45 |
|
| 46 |
$self |
| 47 |
} |
| 48 |
|
| 49 |
sub add_command { |
| 50 |
my ($self, $command, $tooltip, $widget, $cb) = @_; |
| 51 |
|
| 52 |
(my $data = $command) =~ s/\\//g; |
| 53 |
|
| 54 |
$tooltip =~ s/^\s+//; |
| 55 |
$tooltip = "<big>$data</big>\n\n$tooltip"; |
| 56 |
$tooltip =~ s/\s+$//; |
| 57 |
|
| 58 |
$self->{completer}{command}{$command} = [$data, $tooltip, $widget, $cb, ++$self->{command_id}]; |
| 59 |
} |
| 60 |
|
| 61 |
sub clr_commands { |
| 62 |
my ($self) = @_; |
| 63 |
|
| 64 |
%{$self->{completer}{command}} = (); |
| 65 |
} |
| 66 |
|
| 67 |
sub invoke_button_down { |
| 68 |
my ($self, $ev, $x, $y) = @_; |
| 69 |
|
| 70 |
if ($ev->{button} == 1) { |
| 71 |
$self->grab_focus; |
| 72 |
return unless $::CONN; |
| 73 |
|
| 74 |
my $x = 1 + CFClient::floor +($ev->{x} - $self->{sx0}) / $self->{tilesize} - $self->{sx}; |
| 75 |
my $y = 1 + CFClient::floor +($ev->{y} - $self->{sy0}) / $self->{tilesize} - $self->{sy}; |
| 76 |
|
| 77 |
$x -= int 0.5 * $self->{sw}; |
| 78 |
$y -= int 0.5 * $self->{sh}; |
| 79 |
|
| 80 |
$::CONN->lookat ($x, $y) |
| 81 |
if $::CONN; |
| 82 |
|
| 83 |
} elsif ($ev->{button} == 2) { |
| 84 |
$self->grab_focus; |
| 85 |
return unless $::CONN; |
| 86 |
|
| 87 |
my ($ox, $oy) = ($ev->{x}, $ev->{y}); |
| 88 |
my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y}); |
| 89 |
|
| 90 |
$self->{motion} = sub { |
| 91 |
my ($ev, $x, $y) = @_; |
| 92 |
|
| 93 |
($x, $y) = ($ev->{x}, $ev->{y}); |
| 94 |
|
| 95 |
$::CFG->{map_shift_x} = $bw + $x - $ox; |
| 96 |
$::CFG->{map_shift_y} = $bh + $y - $oy; |
| 97 |
|
| 98 |
$self->update; |
| 99 |
}; |
| 100 |
} elsif ($ev->{button} == 3) { |
| 101 |
(new CFClient::UI::Menu |
| 102 |
items => [ |
| 103 |
["Help Browser…\tF1", sub { $::HELP_WINDOW->toggle_visibility }], |
| 104 |
["Statistics\tF2", sub { ::toggle_player_page ($::STATS_PAGE) }], |
| 105 |
["Skills\tF3", sub { ::toggle_player_page ($::SKILL_PAGE) }], |
| 106 |
["Spells…\tF4", sub { ::toggle_player_page ($::SPELL_PAGE) }], |
| 107 |
["Inventory…\tF5", sub { ::toggle_player_page ($::INVENTORY_PAGE) }], |
| 108 |
["Setup… \tF9", sub { $::SETUP_DIALOG->toggle_visibility }], |
| 109 |
["Server Messages…", sub { $::MESSAGE_WINDOW->toggle_visibility }], |
| 110 |
[ |
| 111 |
$::PICKUP_ENABLE->{state} |
| 112 |
? "Disable automatic pickup" |
| 113 |
: "Enable automatic pickup", |
| 114 |
sub { $::PICKUP_ENABLE->toggle } |
| 115 |
], |
| 116 |
], |
| 117 |
)->popup ($ev); |
| 118 |
} |
| 119 |
|
| 120 |
1 |
| 121 |
} |
| 122 |
|
| 123 |
sub invoke_button_up { |
| 124 |
my ($self, $ev, $x, $y) = @_; |
| 125 |
|
| 126 |
delete $self->{motion}; |
| 127 |
|
| 128 |
1 |
| 129 |
} |
| 130 |
|
| 131 |
sub invoke_mouse_motion { |
| 132 |
my ($self, $ev, $x, $y) = @_; |
| 133 |
|
| 134 |
if ($self->{motion}) { |
| 135 |
$self->{motion}->($ev, $x, $y); |
| 136 |
} else { |
| 137 |
return 0; |
| 138 |
} |
| 139 |
|
| 140 |
1 |
| 141 |
} |
| 142 |
|
| 143 |
sub size_request { |
| 144 |
( |
| 145 |
32 * CFClient::ceil $::WIDTH / 32, |
| 146 |
32 * CFClient::ceil $::HEIGHT / 32, |
| 147 |
) |
| 148 |
} |
| 149 |
|
| 150 |
sub update { |
| 151 |
my ($self) = @_; |
| 152 |
|
| 153 |
$self->{need_update} = 1; |
| 154 |
$self->SUPER::update; |
| 155 |
} |
| 156 |
|
| 157 |
my %DIR = ( |
| 158 |
CFClient::SDLK_KP8, [1, "north"], |
| 159 |
CFClient::SDLK_KP9, [2, "northeast"], |
| 160 |
CFClient::SDLK_KP6, [3, "east"], |
| 161 |
CFClient::SDLK_KP3, [4, "southeast"], |
| 162 |
CFClient::SDLK_KP2, [5, "south"], |
| 163 |
CFClient::SDLK_KP1, [6, "southwest"], |
| 164 |
CFClient::SDLK_KP4, [7, "west"], |
| 165 |
CFClient::SDLK_KP7, [8, "northwest"], |
| 166 |
|
| 167 |
CFClient::SDLK_UP, [1, "north"], |
| 168 |
CFClient::SDLK_RIGHT, [3, "east"], |
| 169 |
CFClient::SDLK_DOWN, [5, "south"], |
| 170 |
CFClient::SDLK_LEFT, [7, "west"], |
| 171 |
); |
| 172 |
|
| 173 |
sub invoke_key_down { |
| 174 |
my ($self, $ev) = @_; |
| 175 |
|
| 176 |
my $mod = $ev->{mod}; |
| 177 |
my $sym = $ev->{sym}; |
| 178 |
my $uni = $ev->{unicode}; |
| 179 |
|
| 180 |
$mod &= CFClient::KMOD_CTRL | CFClient::KMOD_ALT | CFClient::KMOD_SHIFT; |
| 181 |
|
| 182 |
if ($uni == ord "\t") { |
| 183 |
$::PL_WINDOW->toggle_visibility; |
| 184 |
} elsif ($sym == CFClient::SDLK_F1 && !$mod) { |
| 185 |
$::HELP_WINDOW->toggle_visibility; |
| 186 |
} elsif ($sym == CFClient::SDLK_F2 && !$mod) { |
| 187 |
::toggle_player_page ($::STATS_PAGE); |
| 188 |
} elsif ($sym == CFClient::SDLK_F3 && !$mod) { |
| 189 |
::toggle_player_page ($::SKILL_PAGE); |
| 190 |
} elsif ($sym == CFClient::SDLK_F4 && !$mod) { |
| 191 |
::toggle_player_page ($::SPELL_PAGE); |
| 192 |
} elsif ($sym == CFClient::SDLK_F5 && !$mod) { |
| 193 |
::toggle_player_page ($::INVENTORY_PAGE); |
| 194 |
} elsif ($sym == CFClient::SDLK_F9 && !$mod) { |
| 195 |
$::SETUP_DIALOG->toggle_visibility; |
| 196 |
} elsif ($sym == CFClient::SDLK_INSERT && $mod & CFClient::KMOD_CTRL) { |
| 197 |
$::BIND_EDITOR->set_binding (undef, undef, [], |
| 198 |
sub { |
| 199 |
my ($mod, $sym, $cmds) = @_; |
| 200 |
$::BIND_EDITOR->cfg_bind ($mod, $sym, $cmds); |
| 201 |
}); |
| 202 |
$::BIND_EDITOR->start; |
| 203 |
$::BIND_EDITOR->show; |
| 204 |
} elsif ($sym == CFClient::SDLK_INSERT && not ($mod & CFClient::KMOD_CTRL)) { |
| 205 |
$::BIND_EDITOR->stop; |
| 206 |
$::BIND_EDITOR->ask_for_bind_and_commit; |
| 207 |
$::BIND_EDITOR->hide; |
| 208 |
} elsif (!$::CONN) { |
| 209 |
return 0; # bindings further down need a valid connection |
| 210 |
|
| 211 |
} elsif ($sym == CFClient::SDLK_KP5 && !$mod) { |
| 212 |
$::CONN->user_send ("stay fire"); |
| 213 |
} elsif ($uni == ord ",") { |
| 214 |
$::CONN->user_send ("take"); |
| 215 |
} elsif ($uni == ord " ") { |
| 216 |
$::CONN->user_send ("apply"); |
| 217 |
} elsif ($uni == ord ".") { |
| 218 |
$::CONN->user_send ($self->{completer}{last_command}) |
| 219 |
if exists $self->{completer}{last_command}; |
| 220 |
} elsif (my $bind_cmd = $::CFG->{profile}{default}{bindings}{$mod}{$sym}) { |
| 221 |
$::CONN->user_send ($_) for @$bind_cmd; |
| 222 |
} elsif (($sym == CFClient::SDLK_KP_PLUS && !$mod) || $uni == ord "+") { |
| 223 |
$::CONN->user_send ("rotateshoottype +"); |
| 224 |
} elsif (($sym == CFClient::SDLK_KP_MINUS && !$mod) || $uni == ord "-") { |
| 225 |
$::CONN->user_send ("rotateshoottype -"); |
| 226 |
} elsif ($uni == ord '"') { |
| 227 |
$self->{completer}->set_prefix ("$::CFG->{say_command} "); |
| 228 |
$self->{completer}->show; |
| 229 |
} elsif ($uni == ord "'") { |
| 230 |
$self->{completer}->set_prefix (""); |
| 231 |
$self->{completer}->show; |
| 232 |
} elsif (exists $DIR{$sym}) { |
| 233 |
if ($mod & CFClient::KMOD_SHIFT) { |
| 234 |
$self->{shft}++; |
| 235 |
if ($DIR{$sym}[0] != $self->{fire_dir}) { |
| 236 |
$::CONN->user_send ("fire $DIR{$sym}[0]"); |
| 237 |
} |
| 238 |
$self->{fire_dir} = $DIR{$sym}[0]; |
| 239 |
} elsif ($mod & CFClient::KMOD_CTRL) { |
| 240 |
$self->{ctrl}++; |
| 241 |
$::CONN->user_send ("run $DIR{$sym}[0]"); |
| 242 |
} else { |
| 243 |
$::CONN->user_send ("$DIR{$sym}[1]"); |
| 244 |
} |
| 245 |
} elsif ((ord 'a') <= $uni && $uni <= (ord 'z')) { |
| 246 |
$self->{completer}->invoke_key_down ($ev); |
| 247 |
$self->{completer}->show; |
| 248 |
} else { |
| 249 |
return 0; |
| 250 |
} |
| 251 |
|
| 252 |
1 |
| 253 |
} |
| 254 |
|
| 255 |
sub invoke_key_up { |
| 256 |
my ($self, $ev) = @_; |
| 257 |
|
| 258 |
my $res = 0; |
| 259 |
my $mod = $ev->{mod}; |
| 260 |
my $sym = $ev->{sym}; |
| 261 |
|
| 262 |
if ($::CFG->{shift_fire_stop}) { |
| 263 |
if (!($mod & CFClient::KMOD_SHIFT) && delete $self->{shft}) { |
| 264 |
$::CONN->user_send ("fire_stop"); |
| 265 |
delete $self->{fire_dir}; |
| 266 |
$res = 1; |
| 267 |
} |
| 268 |
} else { |
| 269 |
if (exists $DIR{$sym} && delete $self->{shft}) { |
| 270 |
$::CONN->user_send ("fire_stop"); |
| 271 |
delete $self->{fire_dir}; |
| 272 |
$res = 1; |
| 273 |
} elsif (($sym == CFClient::SDLK_LSHIFT || $sym == CFClient::SDLK_RSHIFT) && delete $self->{shft}) { # XXX: is RSHIFT ok? |
| 274 |
$::CONN->user_send ("fire_stop"); |
| 275 |
delete $self->{fire_dir}; |
| 276 |
$res = 1; |
| 277 |
} |
| 278 |
} |
| 279 |
|
| 280 |
if (!($mod & CFClient::KMOD_CTRL ) && delete $self->{ctrl}) { |
| 281 |
$::CONN->user_send ("run_stop"); |
| 282 |
$res = 1; |
| 283 |
} |
| 284 |
|
| 285 |
$res |
| 286 |
} |
| 287 |
|
| 288 |
sub set_magicmap { |
| 289 |
my ($self, $w, $h, $x, $y, $data) = @_; |
| 290 |
|
| 291 |
$x -= $::MAP->ox + int 0.5 * $::MAP->w; |
| 292 |
$y -= $::MAP->oy + int 0.5 * $::MAP->h; |
| 293 |
|
| 294 |
$self->{magicmap} = [$x, $y, $w, $h, $data]; |
| 295 |
|
| 296 |
$self->update; |
| 297 |
} |
| 298 |
|
| 299 |
sub draw { |
| 300 |
my ($self) = @_; |
| 301 |
|
| 302 |
return unless $::MAP; |
| 303 |
|
| 304 |
my $focused = $CFClient::UI::FOCUS == $self |
| 305 |
|| $CFClient::UI::FOCUS == $self->{completer}{entry}; |
| 306 |
|
| 307 |
return |
| 308 |
unless $focused || !$::FAST; |
| 309 |
|
| 310 |
if (delete $self->{need_update}) { |
| 311 |
my $tilesize = $self->{tilesize} = int 32 * $::CFG->{map_scale}; |
| 312 |
|
| 313 |
my $sx = $self->{sx} = CFClient::ceil $::CFG->{map_shift_x} / $tilesize; |
| 314 |
my $sy = $self->{sy} = CFClient::ceil $::CFG->{map_shift_y} / $tilesize; |
| 315 |
|
| 316 |
my $sx0 = $self->{sx0} = $::CFG->{map_shift_x} - $sx * $tilesize; |
| 317 |
my $sy0 = $self->{sy0} = $::CFG->{map_shift_y} - $sy * $tilesize; |
| 318 |
|
| 319 |
my $sw = $self->{sw} = 1 + CFClient::ceil $self->{w} / $tilesize; |
| 320 |
my $sh = $self->{sh} = 1 + CFClient::ceil $self->{h} / $tilesize; |
| 321 |
|
| 322 |
if ($::CFG->{fow_enable}) { |
| 323 |
my ($w, $h, $data) = $::MAP->fow_texture ($sx, $sy, 0, 0, $sw, $sh); |
| 324 |
|
| 325 |
if ($::CFG->{fow_smooth} && $CFClient::OpenGL::GL_VERSION >= 1.2) { # smooth fog of war |
| 326 |
glConvolutionParameter (GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER); |
| 327 |
glConvolutionFilter2D ( |
| 328 |
GL_CONVOLUTION_2D, |
| 329 |
GL_ALPHA, |
| 330 |
3, 3, |
| 331 |
GL_ALPHA, GL_FLOAT, |
| 332 |
(pack "f*", @{ $self->{smooth_matrix} }), |
| 333 |
); |
| 334 |
glEnable GL_CONVOLUTION_2D; |
| 335 |
} |
| 336 |
|
| 337 |
$self->{fow_texture} = new CFClient::Texture |
| 338 |
w => $w, |
| 339 |
h => $h, |
| 340 |
data => $data, |
| 341 |
internalformat => GL_ALPHA, |
| 342 |
format => GL_ALPHA; |
| 343 |
|
| 344 |
glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth}; |
| 345 |
} else { |
| 346 |
delete $self->{fow_texture}; |
| 347 |
} |
| 348 |
|
| 349 |
glNewList $self->{list}; |
| 350 |
|
| 351 |
glPushMatrix; |
| 352 |
glTranslate $sx0, $sy0; |
| 353 |
glScale $::CFG->{map_scale}, $::CFG->{map_scale}; |
| 354 |
|
| 355 |
$::MAP->draw ($sx, $sy, 0, 0, $sw, $sh); |
| 356 |
|
| 357 |
glScale 32, 32; |
| 358 |
|
| 359 |
if (my $tex = $self->{fow_texture}) { |
| 360 |
glEnable GL_TEXTURE_2D; |
| 361 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE; |
| 362 |
|
| 363 |
glColor +($::CFG->{fow_intensity}) x 3, 0.9; |
| 364 |
$self->{fow_texture}->draw_quad_alpha (0, 0); |
| 365 |
|
| 366 |
glDisable GL_TEXTURE_2D; |
| 367 |
} |
| 368 |
|
| 369 |
if ($self->{magicmap}) { |
| 370 |
my ($x, $y, $w, $h, $data) = @{ $self->{magicmap} }; |
| 371 |
|
| 372 |
$x += $::MAP->ox - $sx + int 0.5 * ($::MAP->w - $sw + 1); |
| 373 |
$y += $::MAP->oy - $sy + int 0.5 * ($::MAP->h - $sh + 1); |
| 374 |
|
| 375 |
glTranslate - $x - 1, - $y - 1; |
| 376 |
glBindTexture GL_TEXTURE_2D, $magicmap_tex->{name}; |
| 377 |
$::MAP->draw_magicmap ($x, $y, $w, $h, $data); |
| 378 |
} |
| 379 |
|
| 380 |
glPopMatrix; |
| 381 |
glEndList; |
| 382 |
} |
| 383 |
|
| 384 |
glCallList $self->{list}; |
| 385 |
|
| 386 |
# TNT2 emulates logops in software (or worse :) |
| 387 |
unless ($focused) { |
| 388 |
glColor 0.4, 0.2, 0.2, 0.6; |
| 389 |
glEnable GL_BLEND; |
| 390 |
glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA; |
| 391 |
glBegin GL_QUADS; |
| 392 |
glVertex 0, 0; |
| 393 |
glVertex 0, $::HEIGHT; |
| 394 |
glVertex $::WIDTH, $::HEIGHT; |
| 395 |
glVertex $::WIDTH, 0; |
| 396 |
glEnd; |
| 397 |
glDisable GL_BLEND; |
| 398 |
} |
| 399 |
} |
| 400 |
|
| 401 |
sub DESTROY { |
| 402 |
my $self = shift; |
| 403 |
|
| 404 |
glDeleteList $self->{list}; |
| 405 |
|
| 406 |
$self->SUPER::DESTROY; |
| 407 |
} |
| 408 |
|
| 409 |
package CFClient::MapWidget::MapMap; |
| 410 |
|
| 411 |
our @ISA = CFClient::UI::Base::; |
| 412 |
|
| 413 |
use Time::HiRes qw(time); |
| 414 |
use CFClient::OpenGL; |
| 415 |
|
| 416 |
sub size_request { |
| 417 |
($::HEIGHT * 0.25, $::HEIGHT * 0.25) |
| 418 |
} |
| 419 |
|
| 420 |
sub invoke_size_allocate { |
| 421 |
my ($self, $w, $h) = @_; |
| 422 |
|
| 423 |
$self->update; |
| 424 |
|
| 425 |
1 |
| 426 |
} |
| 427 |
|
| 428 |
sub update { |
| 429 |
my ($self) = @_; |
| 430 |
|
| 431 |
delete $self->{texture_atime}; |
| 432 |
$self->SUPER::update; |
| 433 |
} |
| 434 |
|
| 435 |
sub _draw { |
| 436 |
my ($self) = @_; |
| 437 |
|
| 438 |
$::MAP or return; |
| 439 |
|
| 440 |
my ($w, $h) = @$self{qw(w h)}; |
| 441 |
|
| 442 |
my $sw = int $::WIDTH / (32 * $::CFG->{map_scale}) + 0.99; |
| 443 |
my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99; |
| 444 |
|
| 445 |
my $sx = int $::CFG->{map_shift_x} / 32; |
| 446 |
my $sy = int $::CFG->{map_shift_y} / 32; |
| 447 |
|
| 448 |
my $ox = 0.5 * ($w - $sw); |
| 449 |
my $oy = 0.5 * ($h - $sh); |
| 450 |
|
| 451 |
glEnable GL_BLEND; |
| 452 |
glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA; |
| 453 |
glEnable GL_TEXTURE_2D; |
| 454 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE; |
| 455 |
|
| 456 |
if ($self->{texture_atime} < time) { |
| 457 |
$self->{texture_atime} = time + 1/3; |
| 458 |
|
| 459 |
$self->{texture} = |
| 460 |
new CFClient::Texture |
| 461 |
w => $w, |
| 462 |
h => $h, |
| 463 |
data => $::MAP->mapmap (-$ox, -$oy, $w, $h), |
| 464 |
type => $CFClient::GL_VERSION >= 1.2 ? GL_UNSIGNED_INT_8_8_8_8_REV : GL_UNSIGNED_BYTE; |
| 465 |
} |
| 466 |
|
| 467 |
$self->{texture}->draw_quad (0, 0); |
| 468 |
|
| 469 |
glDisable GL_TEXTURE_2D; |
| 470 |
|
| 471 |
glTranslate 0.375, 0.375; |
| 472 |
|
| 473 |
#TODO: map scale is completely borked |
| 474 |
|
| 475 |
my $x0 = int $ox - $sx + 0.5; |
| 476 |
my $y0 = int $oy - $sy + 0.5; |
| 477 |
|
| 478 |
glColor 1, 1, 0, 1; |
| 479 |
glBegin GL_LINE_LOOP; |
| 480 |
glVertex $x0 , $y0 ; |
| 481 |
glVertex $x0 , $y0 + $sh; |
| 482 |
glVertex $x0 + $sw, $y0 + $sh; |
| 483 |
glVertex $x0 + $sw, $y0 ; |
| 484 |
glEnd; |
| 485 |
|
| 486 |
glDisable GL_BLEND; |
| 487 |
} |
| 488 |
|
| 489 |
package CFClient::MapWidget::Command; |
| 490 |
|
| 491 |
use strict; |
| 492 |
|
| 493 |
use CFClient::OpenGL; |
| 494 |
|
| 495 |
our @ISA = CFClient::UI::Frame::; |
| 496 |
|
| 497 |
sub new { |
| 498 |
my $class = shift; |
| 499 |
|
| 500 |
my $self = $class->SUPER::new ( |
| 501 |
bg => [0, 0, 0, 0.8], |
| 502 |
@_, |
| 503 |
); |
| 504 |
|
| 505 |
$self->add ($self->{vbox} = new CFClient::UI::VBox); |
| 506 |
|
| 507 |
$self->{label} = [ |
| 508 |
map |
| 509 |
CFClient::UI::Label->new ( |
| 510 |
can_hover => 1, |
| 511 |
can_events => 1, |
| 512 |
tooltip_width => 0.33, |
| 513 |
fontsize => $_, |
| 514 |
), (0.8) x 16 |
| 515 |
]; |
| 516 |
|
| 517 |
$self->{entry} = new CFClient::UI::Entry |
| 518 |
on_changed => sub { |
| 519 |
$self->update_labels; |
| 520 |
0 |
| 521 |
}, |
| 522 |
on_button_down => sub { |
| 523 |
my ($entry, $ev, $x, $y) = @_; |
| 524 |
|
| 525 |
if ($ev->{button} == 3) { |
| 526 |
(new CFClient::UI::Menu |
| 527 |
items => [ |
| 528 |
["bind <i>" . (CFClient::UI::Label::escape $self->{select}) . "</i> to a key" |
| 529 |
=> sub { $::BIND_EDITOR->do_quick_binding ([$self->{select}], sub { $entry->grab_focus }) }] |
| 530 |
], |
| 531 |
)->popup ($ev); |
| 532 |
return 1; |
| 533 |
} |
| 534 |
0 |
| 535 |
}, |
| 536 |
on_key_down => sub { |
| 537 |
my ($entry, $ev) = @_; |
| 538 |
|
| 539 |
my $self = $entry->{parent}{parent}; |
| 540 |
|
| 541 |
if ($ev->{sym} == 13) { |
| 542 |
if (exists $self->{select}) { |
| 543 |
$self->{last_command} = $self->{select}; |
| 544 |
$::CONN->user_send ($self->{select}); |
| 545 |
|
| 546 |
unshift @{$self->{history}}, $self->{entry}->get_text; |
| 547 |
$self->{hist_ptr} = 0; |
| 548 |
|
| 549 |
$self->hide; |
| 550 |
} |
| 551 |
} elsif ($ev->{sym} == 27) { |
| 552 |
$self->{hist_ptr} = 0; |
| 553 |
$self->hide; |
| 554 |
} elsif ($ev->{sym} == CFClient::SDLK_DOWN) { |
| 555 |
if ($self->{hist_ptr} > 1) { |
| 556 |
$self->{hist_ptr}--; |
| 557 |
$self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1]); |
| 558 |
} elsif ($self->{hist_ptr} > 0) { |
| 559 |
$self->{hist_ptr}--; |
| 560 |
$self->{entry}->set_text ($self->{hist_saveback}); |
| 561 |
} else { |
| 562 |
++$self->{select_offset} |
| 563 |
if $self->{select_offset} < $#{ $self->{last_match} || [] }; |
| 564 |
} |
| 565 |
$self->update_labels; |
| 566 |
} elsif ($ev->{sym} == CFClient::SDLK_UP) { |
| 567 |
if ($self->{select_offset}) { |
| 568 |
--$self->{select_offset} |
| 569 |
} else { |
| 570 |
unless ($self->{hist_ptr}) { |
| 571 |
$self->{hist_saveback} = $self->{entry}->get_text; |
| 572 |
} |
| 573 |
if ($self->{hist_ptr} <= $#{$self->{history}}) { |
| 574 |
$self->{hist_ptr}++; |
| 575 |
} |
| 576 |
$self->{entry}->set_text ($self->{history}->[$self->{hist_ptr} - 1]) |
| 577 |
if exists $self->{history}->[$self->{hist_ptr} - 1]; |
| 578 |
} |
| 579 |
$self->update_labels; |
| 580 |
} else { |
| 581 |
return 0; |
| 582 |
} |
| 583 |
|
| 584 |
1 |
| 585 |
} |
| 586 |
; |
| 587 |
|
| 588 |
$self->{vbox}->add ( |
| 589 |
$self->{entry}, |
| 590 |
@{$self->{label}}, |
| 591 |
); |
| 592 |
|
| 593 |
$self |
| 594 |
} |
| 595 |
|
| 596 |
sub set_prefix { |
| 597 |
my ($self, $prefix) = @_; |
| 598 |
|
| 599 |
$self->{entry}->set_text ($prefix); |
| 600 |
$self->show; |
| 601 |
} |
| 602 |
|
| 603 |
sub invoke_size_allocate { |
| 604 |
my ($self, $w, $h) = @_; |
| 605 |
|
| 606 |
$self->move_abs (($::WIDTH - $w) * 0.5, ($::HEIGHT - $h) * 0.6, 10); |
| 607 |
|
| 608 |
$self->SUPER::invoke_size_allocate ($w, $h) |
| 609 |
} |
| 610 |
|
| 611 |
sub show { |
| 612 |
my ($self) = @_; |
| 613 |
|
| 614 |
$self->SUPER::show; |
| 615 |
$self->{entry}->grab_focus; |
| 616 |
} |
| 617 |
|
| 618 |
sub hide { |
| 619 |
my ($self) = @_; |
| 620 |
|
| 621 |
$self->SUPER::hide; |
| 622 |
$self->{entry}->set_text (""); |
| 623 |
} |
| 624 |
|
| 625 |
sub invoke_key_down { |
| 626 |
my ($self, $ev) = @_; |
| 627 |
|
| 628 |
$self->{entry}->emit (key_down => $ev) |
| 629 |
} |
| 630 |
|
| 631 |
sub update_labels { |
| 632 |
my ($self) = @_; |
| 633 |
|
| 634 |
my $text = $self->{entry}->get_text; |
| 635 |
|
| 636 |
length $text |
| 637 |
or return $self->hide; |
| 638 |
|
| 639 |
my ($cmd, $arg) = $text =~ /^\s*([^[:space:]]*)(.*)$/; |
| 640 |
|
| 641 |
if ($text ne $self->{last_search}) { |
| 642 |
my @match; |
| 643 |
|
| 644 |
if ($text =~ /^(.*?)\s+$/) { |
| 645 |
@match = [$cmd, "(appended whitespace suppresses completion)"]; |
| 646 |
} else { |
| 647 |
my $regexp = do { |
| 648 |
my ($beg, @chr) = split //, lc $cmd; |
| 649 |
|
| 650 |
# the following regex is used to match our "completion entry" |
| 651 |
# to an actual command - the parentheses match kind of "overhead" |
| 652 |
# - the more characters the parentheses match, the less attractive |
| 653 |
# is the match. |
| 654 |
my $regexp = "^\Q$beg\E" |
| 655 |
. join "", map "(?:.*?[ \\\\]\Q$_\E|(.*?)\Q$_\E)", @chr; |
| 656 |
qr<$regexp> |
| 657 |
}; |
| 658 |
|
| 659 |
my @penalty; |
| 660 |
|
| 661 |
for (keys %{$self->{command}}) { |
| 662 |
if (@penalty = $_ =~ $regexp) { |
| 663 |
push @match, [$_, length join "", map "::$_", grep defined, @penalty]; |
| 664 |
} |
| 665 |
} |
| 666 |
|
| 667 |
@match = map $self->{command}{$_->[0]}, |
| 668 |
sort { |
| 669 |
$a->[1] <=> $b->[1] |
| 670 |
or $self->{command}{$a->[0]}[4] <=> $self->{command}{$b->[0]}[4] |
| 671 |
or (length $b->[0]) <=> (length $a->[0]) |
| 672 |
} @match; |
| 673 |
} |
| 674 |
|
| 675 |
$self->{last_search} = $text; |
| 676 |
$self->{last_match} = \@match; |
| 677 |
|
| 678 |
$self->{select_offset} = 0; |
| 679 |
} |
| 680 |
|
| 681 |
my @labels = @{ $self->{label} }; |
| 682 |
my @matches = @{ $self->{last_match} || [] }; |
| 683 |
|
| 684 |
if ($self->{select_offset}) { |
| 685 |
splice @matches, 0, $self->{select_offset}, (); |
| 686 |
|
| 687 |
my $label = shift @labels; |
| 688 |
$label->set_text ("..."); |
| 689 |
$label->set_tooltip ("Use Cursor-Up to view previous matches"); |
| 690 |
} |
| 691 |
|
| 692 |
for my $label (@labels) { |
| 693 |
$label->{fg} = [1, 1, 1, 1]; |
| 694 |
$label->{bg} = [0, 0, 0, 0]; |
| 695 |
} |
| 696 |
|
| 697 |
if (@matches) { |
| 698 |
$self->{select} = "$matches[0][0]$arg"; |
| 699 |
|
| 700 |
$labels[0]->{fg} = [0, 0, 0, 1]; |
| 701 |
$labels[0]->{bg} = [1, 1, 1, 0.8]; |
| 702 |
} else { |
| 703 |
$self->{select} = "$cmd$arg"; |
| 704 |
} |
| 705 |
|
| 706 |
for my $match (@matches) { |
| 707 |
my $label = shift @labels; |
| 708 |
|
| 709 |
if (@labels) { |
| 710 |
$label->set_text ("$match->[0]$arg"); |
| 711 |
$label->set_tooltip ($match->[1]); |
| 712 |
} else { |
| 713 |
$label->set_text ("..."); |
| 714 |
$label->set_tooltip ("Use Cursor-Down to view more matches"); |
| 715 |
last; |
| 716 |
} |
| 717 |
} |
| 718 |
|
| 719 |
for my $label (@labels) { |
| 720 |
$label->set_text (""); |
| 721 |
$label->set_tooltip (""); |
| 722 |
} |
| 723 |
|
| 724 |
$self->update; |
| 725 |
} |
| 726 |
|
| 727 |
sub _draw { |
| 728 |
my ($self) = @_; |
| 729 |
|
| 730 |
# hack |
| 731 |
local $CFClient::UI::FOCUS = $self->{entry}; |
| 732 |
|
| 733 |
$self->SUPER::_draw; |
| 734 |
} |
| 735 |
|
| 736 |
1 |
