package CFClient::MapWidget;

use strict;

use List::Util qw(min max);

use CFClient::OpenGL;

our @ISA = CFClient::UI::Base::;

sub new {
   my $class = shift;

   $class->SUPER::new (
      z         => -1,
      can_focus => 1,
      list      => glGenList,
      @_
   )
}

sub DESTROY {
   my $self = shift;

   glDeleteList $self->{list};

   $self->SUPER::DESTROY;
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;

   if ($ev->{button} == 2) {
      my ($ox, $oy) = ($ev->{x}, $ev->{y});
      my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->{x}, $ev->{y});

         $::CFG->{map_shift_x} = $bw + $x - $ox;
         $::CFG->{map_shift_y} = $bh + $y - $oy;

         $self->update;
      };
   }
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   $self->{motion}->($ev, $x, $y) if $self->{motion};
}

sub size_request {
   (
      1 + 32 * int $::WIDTH  / 32,
      1 + 32 * int $::HEIGHT / 32,
   )
}

sub update {
   my ($self) = @_;

   $self->{need_update} = 1;
   $self->SUPER::update;
}

sub draw {
   my ($self) = @_;

   if (delete $self->{need_update}) {
      glNewList $self->{list};

      if ($::MAP) {
         my $sw = int $::WIDTH  / (32 * $::CFG->{map_scale});
         my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale});

         glScale $::CFG->{map_scale}, $::CFG->{map_scale};

         my $sx = $::CFG->{map_shift_x} / $::CFG->{map_scale}; my $sx0 = $sx & 31; $sx = ($sx - $sx0) / 32;
         my $sy = $::CFG->{map_shift_y} / $::CFG->{map_scale}; my $sy0 = $sy & 31; $sy = ($sy - $sy0) / 32;

         glTranslate $sx0 - 32, $sy0 - 32, 0;

         my ($w, $h, $data) = $::MAP->draw ($sx, $sy, 0, 0, $sw + 1, $sh + 1);

         if ($::CFG->{fow_enable}) {
            if ($::CFG->{fow_smooth} && $CFClient::GL_VERSION >= 1.2) { # smooth fog of war
               glConvolutionParameter (GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER);
               glConvolutionFilter2D (
                  GL_CONVOLUTION_2D,
                  GL_ALPHA,
                  3, 3,
                  GL_ALPHA, GL_FLOAT,
                  pack "f*",
                     0.05, 0.13, 0.05,
                     0.13, 0.30, 0.13,
                     0.05, 0.13, 0.05,
               );
               glEnable GL_CONVOLUTION_2D;
            }

            $self->{fow_texture} = new CFClient::Texture
               w              => $w,
               h              => $h,
               data           => $data,
               internalformat => GL_ALPHA,
               format         => GL_ALPHA;

            glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth};

            glEnable GL_BLEND;
            glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
            glEnable GL_TEXTURE_2D;
            glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

            glColor +($::CFG->{fow_intensity}) x 3, 0.8;
            $self->{fow_texture}->draw_quad (0, 0, $w * 32, $h * 32);

            glDisable GL_TEXTURE_2D;
            glDisable GL_BLEND;
         }

         # HACK BEGIN
         {
           glTranslate -($sx0 - 32), -($sy0 - 32), 0;#remove

           glTranslate 0, 30;
           my ($w, $h) = (250, 250);

           my ($ox, $oy) = ($::MAP->ox, $::MAP->oy);

           glEnable GL_BLEND;
           glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
           glEnable GL_TEXTURE_2D;
           glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

           $self->{mapmap_texture} =
              new CFClient::Texture
                 w    => $w,
                 h    => $h,
                 data => $::MAP->mapmap (- $w * 0.5, - $h * 0.5, $w, $h),
                 type => $CFClient::GL_VERSION >= 1.2 ? GL_UNSIGNED_INT_8_8_8_8_REV : GL_UNSIGNED_BYTE;

           $self->{mapmap_texture}->draw_quad (0, 0);

           glDisable GL_TEXTURE_2D;

           glTranslate 0.375, 0.375;

           glColor 1, 1, 0, 1;
           glBegin GL_LINE_LOOP;
           glVertex $w * 0.5 - $sx      , $h * 0.5 - $sy      ;
           glVertex $w * 0.5 - $sx      , $h * 0.5 - $sy + $sh;
           glVertex $w * 0.5 - $sx + $sw, $h * 0.5 - $sy + $sh;
           glVertex $w * 0.5 - $sx + $sw, $h * 0.5 - $sy      ;
           glEnd;
           
           glDisable GL_BLEND;
         }
         # HACK END
      }

      glEndList;
   }

   glPushMatrix;
   glCallList $self->{list};
   glPopMatrix;

   if ($CFClient::UI::FOCUS != $self) {
      glColor 64/255, 64/255, 64/255;
      glLogicOp GL_AND;
      glEnable GL_COLOR_LOGIC_OP;
      glBegin GL_QUADS;
      glVertex 0, 0;
      glVertex 0, $::HEIGHT;
      glVertex $::WIDTH, $::HEIGHT;
      glVertex $::WIDTH, 0;
      glEnd;
      glDisable GL_COLOR_LOGIC_OP;
   }
}

my %DIR = (
   CFClient::SDLK_KP8, [1, "north"],
   CFClient::SDLK_KP9, [2, "northeast"],
   CFClient::SDLK_KP6, [3, "east"],
   CFClient::SDLK_KP3, [4, "southeast"],
   CFClient::SDLK_KP2, [5, "south"],
   CFClient::SDLK_KP1, [6, "southwest"],
   CFClient::SDLK_KP4, [7, "west"],
   CFClient::SDLK_KP7, [8, "northwest"],

   CFClient::SDLK_UP,    [1, "north"],
   CFClient::SDLK_RIGHT, [3, "east"],
   CFClient::SDLK_DOWN,  [5, "south"],
   CFClient::SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};

   if ($sym == CFClient::SDLK_KP5) {
      $::CONN->user_send ("stay fire");
   } elsif ($sym == ord "a") {
      $::CONN->user_send ("apply");
   } elsif ($sym == ord "'") {
      $self->emit ('activate_console');
   } elsif ($sym == ord "/") {
      $self->emit (activate_console => '/');
   } elsif (exists $DIR{$sym}) {
      if ($mod & CFClient::KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->user_send ("fire $DIR{$sym}[0]");
      } elsif ($mod & CFClient::KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->user_send ("run $DIR{$sym}[0]");
      } else {
         $::CONN->user_send ("$DIR{$sym}[1]");
      }
   } elsif ($ev->{unicode}) {
      $self->{command_widget} ||=
         new CFClient::MapWidget::Command::
            command => $self->{command},
            can_focus       => 1,
            connect_execute => sub {
               $::CONN->user_send ($_[1]);
            },
            connect_close => sub {
               (delete $self->{command_widget})->hide;
               $self->focus_in;
            },
      ;
      $self->{command_widget}->key_down ($ev);
      $self->{command_widget}->show;
      $self->{command_widget}->focus_in;
   }
}

sub key_up {
   my ($self, $ev) = @_;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};

   if (!($mod & CFClient::KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->user_send ("fire_stop");
   }
   if (!($mod & CFClient::KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->user_send ("run_stop");
   }
}

sub add_command {
   my ($self, $command, $widget, $cb) = @_;

   (my $abbrev = $command) =~ s/(\S)[^[:space:]_]*[[:space:]_]+/$1/g;

   push @{$self->{command}}, [$abbrev, $command];
   #warn "$command|$abbrev|$widget\n";#d#
}

package CFClient::MapWidget::Command;

use strict;

use CFClient::OpenGL;

our @ISA = CFClient::UI::VBox::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      @_,
      children => [map
         CFClient::UI::Label->new (
            can_hover => 1,
            fontsize  => $_,
         ), 1, 1, 0.8, 0.8, 0.8, 0.8, 0.8
      ],
   );

   $self
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->move (($::WIDTH - $w) * 0.5, ($::HEIGHT - $h) * 0.6, 10);
}

sub update_labels {
   my ($self) = @_;

   my $command = $self->{command};
   my $search_abbrev = qr/^\Q$self->{search}/;
   my $search_full   = qr/\Q$self->{search}/;

   my @found;

   for (@$command) {
      if ($_->[0] =~ $search_abbrev) {
         push @found, [$_->[0], $_];
      } elsif ($_[1] =~ $search_full) {
         push @found, [$_->[1], $_];
      }
   }

   @found = sort { $a->[0] cmp $b->[0] } @found;

   $self->{children}[0]->set_text ("$self->{search}_");

   for (0..5) {
      $self->{children}[$_ + 1]->set_text ($found[$_] ? "$found[$_][0] ($found[$_][1][1])" : "");
   }

   $self->{select} = $found[0][1][1]
      if @found;

   if (@found > 6) {
      $self->{children}[6]->set_text ("...");
   }

   $self->check_size;
}

sub key_down {
   my ($self, $ev) = @_;

   if ($ev->{sym} == 8) {
      substr $self->{search}, -1, 1, "";
      $self->update_labels;
   } elsif ($ev->{sym} == 13) {
      if (exists $self->{select}) {
         $self->emit (execute => $self->{select});
         $self->emit ("close");
      }
   } elsif ($ev->{sym} == 27) {
      $self->emit ("close");
   } elsif ((chr $ev->{unicode}) =~ /^[[:alpha:]]$/) {
      $self->{search} .= chr $ev->{unicode};
      $self->update_labels;
   }

   length $self->{search}
      or $self->emit ("close");
}

1