package CFClient::MapWidget;

use strict;
use utf8;

use List::Util qw(min max);

use CFClient::OpenGL;

our @ISA = CFClient::UI::Base::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      z         => -1,
      can_focus => 1,
      list      => glGenList,
      @_
   );

   $self
}

sub DESTROY {
   my $self = shift;

   glDeleteList $self->{list};

   $self->SUPER::DESTROY;
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;

   if ($ev->{button} == 2) {
      my ($ox, $oy) = ($ev->{x}, $ev->{y});
      my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->{x}, $ev->{y});

         $::CFG->{map_shift_x} = $bw + $x - $ox;
         $::CFG->{map_shift_y} = $bh + $y - $oy;

         $self->update;
      };
   }
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   $self->{motion}->($ev, $x, $y) if $self->{motion};
}

sub size_request {
   (
      1 + 32 * int $::WIDTH  / 32,
      1 + 32 * int $::HEIGHT / 32,
   )
}

sub update {
   my ($self) = @_;

   $self->{need_update} = 1;
   $self->SUPER::update;
}

sub draw {
   my ($self) = @_;

   return
      unless $CFClient::UI::FOCUS == $self || !$::FAST;

   if (delete $self->{need_update}) {
      glNewList $self->{list};

      if ($::MAP) {
         my $sw = int $::WIDTH  / (32 * $::CFG->{map_scale}) + 0.99;
         my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;

         my $sx = $::CFG->{map_shift_x} / $::CFG->{map_scale}; my $sx0 = $sx & 31; $sx = ($sx - $sx0) / 32;
         my $sy = $::CFG->{map_shift_y} / $::CFG->{map_scale}; my $sy0 = $sy & 31; $sy = ($sy - $sy0) / 32;

         glPushMatrix;
         glScale $::CFG->{map_scale}, $::CFG->{map_scale};

         glTranslate $sx0 - 32, $sy0 - 32, 0;

         my ($w, $h, $data) = $::MAP->draw ($sx, $sy, 0, 0, $sw + 1, $sh + 1);

         if ($::CFG->{fow_enable}) {
            if ($::CFG->{fow_smooth} && $CFClient::GL_VERSION >= 1.2) { # smooth fog of war
               glConvolutionParameter (GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER);
               glConvolutionFilter2D (
                  GL_CONVOLUTION_2D,
                  GL_ALPHA,
                  3, 3,
                  GL_ALPHA, GL_FLOAT,
                  pack "f*",
                     0.05, 0.13, 0.05,
                     0.13, 0.30, 0.13,
                     0.05, 0.13, 0.05,
               );
               glEnable GL_CONVOLUTION_2D;
            }

            $self->{fow_texture_name} ||= glGenTexture;
            # try to re-use the texture name: TODO improve texture class instead

            $self->{fow_texture} = new CFClient::Texture
               w              => $w,
               h              => $h,
               data           => $data,
               name           => $self->{fow_texture_name},
               internalformat => GL_ALPHA,
               format         => GL_ALPHA;

            glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth};

            glEnable GL_TEXTURE_2D;
            glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

            glColor +($::CFG->{fow_intensity}) x 3, 0.8;
            $self->{fow_texture}->draw_quad_alpha (0, 0, $w * 32, $h * 32);

            glDisable GL_TEXTURE_2D;
         }

         glPopMatrix;
      }

      glEndList;
   }

   glPushMatrix;
   glCallList $self->{list};
   glPopMatrix;

   # TNT2 emulates logops in software (or worse :)
   if ($CFClient::UI::FOCUS == $self) {
      (delete $self->{out_of_focus})->destroy
         if $self->{out_of_focus};
   } else {
      glColor 0.4, 0.2, 0.2, 0.6;
      glEnable GL_BLEND;
      glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
      glBegin GL_QUADS;
      glVertex 0, 0;
      glVertex 0, $::HEIGHT;
      glVertex $::WIDTH, $::HEIGHT;
      glVertex $::WIDTH, 0;
      glEnd;
      glDisable GL_BLEND;

      $self->{out_of_focus} ||= do {
         my $label = new CFClient::UI::Label
            x         => 0,
            y         => 0,
            z         => 1,
            ellipsise => 0,
            text      => "map out of focus (click map to play)";

         $label->show;
         $label->update;

         $CFClient::UI::ROOT->on_post_alloc ("$self$label" => sub {
            $label->move (
               ($::WIDTH  - $label->{w}) * 0.5,
               ($::HEIGHT - $label->{h}) * 0.5,
            );
         });

         $label
      };
   }
}

my %DIR = (
   CFClient::SDLK_KP8, [1, "north"],
   CFClient::SDLK_KP9, [2, "northeast"],
   CFClient::SDLK_KP6, [3, "east"],
   CFClient::SDLK_KP3, [4, "southeast"],
   CFClient::SDLK_KP2, [5, "south"],
   CFClient::SDLK_KP1, [6, "southwest"],
   CFClient::SDLK_KP4, [7, "west"],
   CFClient::SDLK_KP7, [8, "northwest"],

   CFClient::SDLK_UP,    [1, "north"],
   CFClient::SDLK_RIGHT, [3, "east"],
   CFClient::SDLK_DOWN,  [5, "south"],
   CFClient::SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   return unless $::CONN;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};
   my $uni = $ev->{unicode};

   if ($sym == CFClient::SDLK_KP5) {
      $::CONN->user_send ("stay fire");
   } elsif ($uni == ord ",") {
      $::CONN->user_send ("take");
   } elsif ($uni == ord "\t" or $uni == ord " ") {
      $::CONN->user_send ("apply");
   } elsif ($sym == CFClient::SDLK_KP_PLUS  || $uni == ord "+") {
      $::CONN->user_send ("rotateshoottype +");
   } elsif ($sym == CFClient::SDLK_KP_MINUS || $uni == ord "-") {
      $::CONN->user_send ("rotateshoottype -");
   } elsif ($uni == ord "'") {
      $self->emit ('activate_console');
   } elsif ($uni == ord "/") {
      $self->emit (activate_console => '/');
   } elsif (exists $DIR{$sym}) {
      if ($mod & CFClient::KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->user_send ("fire $DIR{$sym}[0]");
      } elsif ($mod & CFClient::KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->user_send ("run $DIR{$sym}[0]");
      } else {
         $::CONN->user_send ("$DIR{$sym}[1]");
      }
   } elsif ($ev->{unicode}) {
      $self->{command_widget} ||=
         new CFClient::MapWidget::Command::
            command => $self->{command},
            can_focus       => 1,
            connect_execute => sub {
               # todo: support callback instead of user_send
               $::CONN->user_send ($_[1]);
            },
            connect_close => sub {
               (delete $self->{command_widget})->hide;
               $self->focus_in;
            },
      ;
      $self->{command_widget}->key_down ($ev)
         unless $ev->{unicode} == 20;
      return unless $self->{command_widget};
      $self->{command_widget}->show;
      $self->{command_widget}->focus_in;
   }
}

sub key_up {
   my ($self, $ev) = @_;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};

   if (!($mod & CFClient::KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->user_send ("fire_stop");
   }
   if (!($mod & CFClient::KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->user_send ("run_stop");
   }
}

sub add_command {
   my ($self, $command, $tooltip, $widget, $cb) = @_;

   (my $data = $command) =~ s/\\//g;

   $tooltip =~ s/^\s+//;

   $tooltip = "<big>$data</big>\n\n$tooltip";

   $tooltip =~ s/\s+$//;

   $self->{command}{$command} = [$data, $tooltip, $widget, $cb, ++$self->{command_id}];
}

sub clr_commands {
   my ($self) = @_;

   %{$self->{command}} = ();
}

package CFClient::MapWidget::MapMap;

our @ISA = CFClient::UI::Base::;

use Time::HiRes qw(time);
use CFClient::OpenGL;

sub size_request {
   ($::HEIGHT * 0.25, $::HEIGHT * 0.25)
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->update;
}

sub update {
   my ($self) = @_;

   delete $self->{texture_atime};
   $self->SUPER::update;
}

sub _draw {
   my ($self) = @_;

   $::MAP or return;

   my ($w, $h) = @$self{qw(w h)};

   my $sw = int $::WIDTH  / (32 * $::CFG->{map_scale}) + 0.99;
   my $sh = int $::HEIGHT / (32 * $::CFG->{map_scale}) + 0.99;

   my $sx = int $::CFG->{map_shift_x} / 32;
   my $sy = int $::CFG->{map_shift_y} / 32;

   my $ox = 0.5 * ($w - $sw);
   my $oy = 0.5 * ($h - $sh);

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   if ($self->{texture_atime} < time) {
      $self->{texture_atime} = time + 1/3;

      $self->{texture} =
         new CFClient::Texture
            w    => $w,
            h    => $h,
            data => $::MAP->mapmap (-$ox, -$oy, $w, $h),
            type => $CFClient::GL_VERSION >= 1.2 ? GL_UNSIGNED_INT_8_8_8_8_REV : GL_UNSIGNED_BYTE;
   }

   $self->{texture}->draw_quad (0, 0);

   glDisable GL_TEXTURE_2D;

   glTranslate 0.375, 0.375;

   #TODO: map scale is completely borked

   my $x0 = int $ox - $sx + 0.5;
   my $y0 = int $oy - $sy + 0.5;

   glColor 1, 1, 0, 1;
   glBegin GL_LINE_LOOP;
   glVertex $x0      , $y0      ;
   glVertex $x0      , $y0 + $sh;
   glVertex $x0 + $sw, $y0 + $sh;
   glVertex $x0 + $sw, $y0      ;
   glEnd;
   
   glDisable GL_BLEND;
}

package CFClient::MapWidget::Command;

use strict;

use CFClient::OpenGL;

our @ISA = CFClient::UI::Frame::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      bg => [0, 0, 0, 0.8],
      @_,
   );

   $self->add ($self->{vbox} = new CFClient::UI::VBox);

   $self->{label} = [
      map
         CFClient::UI::Label->new (
            can_hover     => 1,
            can_events    => 1,
            tooltip_width => 0.33,
            fontsize      => $_,
         ), (0.8) x 16
   ];

   $self->{entry} = new CFClient::UI::Entry
      connect_changed => sub {
         $self->update_labels;
      };

   $self->{vbox}->add (
      $self->{entry},
      @{$self->{label}},
   );

   $self
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->move (($::WIDTH - $w) * 0.5, ($::HEIGHT - $h) * 0.6, 10);
}

sub key_down {
   my ($self, $ev) = @_;

   if ($ev->{sym} == 13) {
      if (exists $self->{select}) {
         $self->emit (execute => $self->{select});
         $self->emit ("close");
      }
   } elsif ($ev->{sym} == 27) {
      $self->{entry}->set_text ("");
      $self->emit ("close");
      return;
   } elsif ($ev->{sym} == CFClient::SDLK_DOWN) {
      ++$self->{select_offset}
         if $self->{select_offset} < $#{ $self->{last_match} || [] };
      $self->update_labels;
   } elsif ($ev->{sym} == CFClient::SDLK_UP) {
      --$self->{select_offset}
         if $self->{select_offset};
      $self->update_labels;
   } else {
      #$self->{entry}{force_alloc} = 1;
      $self->{entry}->key_down ($ev);
   }
}

sub update_labels {
   my ($self) = @_;

   my $text = $self->{entry}->get_text;

   length $text
      or return $self->emit ("close");

   my ($cmd, $arg) = $text =~ /^\s*([^[:space:]]*)(.*)$/;

   if ($cmd ne $self->{last_search}) {
      my $regexp = do {
         my ($beg, @chr) = split //, lc $cmd;

         # the following regex is used to match our "completion entry"
         # to an actual command - the parentheses match kind of "overhead"
         # - the more characters the parentheses match, the less attractive
         # is the match.
         my $regexp = "^\Q$beg\E"
                    . join "", map "(?:.*?[ \\\\]\Q$_\E|(.*?)\Q$_\E)", @chr;
         qr<$regexp>
      };

      my @match;
      my @penalty;

      for (keys %{$self->{command}}) {
         if (@penalty = $_ =~ $regexp) {
            push @match, [$_, length join "", map "::$_", grep defined, @penalty];
         }
      }

      @match = map $self->{command}{$_->[0]},
                  sort {
                     $a->[1] <=> $b->[1]
                        or $self->{command}{$a->[0]}[4] <=> $self->{command}{$b->[0]}[4]
                        or (length $a->[0]) <=> (length $b->[0])
                  } @match;

      $self->{last_search} = $cmd;
      $self->{last_match} = \@match;

      $self->{select_offset} = 0;
   }

   my @labels = @{ $self->{label} };
   my @matches = @{ $self->{last_match} || [] };

   if ($self->{select_offset}) {
      splice @matches, 0, $self->{select_offset}, ();

      my $label = shift @labels;
      $label->set_text ("...");
      $label->set_tooltip ("Use Cursor-Up to view previous matches");
   }

   for my $label (@labels) {
      $label->{fg} = [1, 1, 1, 1];
      $label->{bg} = [0, 0, 0, 0];
   }

   if (@matches) {
      $self->{select} = "$matches[0][0]$arg";

      $labels[0]->{fg} = [0, 0, 0, 1];
      $labels[0]->{bg} = [1, 1, 1, 0.8];
   } else {
      $self->{select} = "$cmd$arg";
   }

   for my $match (@matches) {
      my $label = shift @labels;

      if (@labels) {
         $label->set_text ("$match->[0]$arg");
         $label->set_tooltip ($match->[1]);
      } else {
         $label->set_text ("...");
         $label->set_tooltip ("Use Cursor-Down to view more matches");
         last;
      }
   }

   for my $label (@labels) {
      $label->set_text ("");
      $label->set_tooltip ("");
   }

   $self->update;
   ###
}

sub _draw {
   my ($self) = @_;

   # hack
   local $CFClient::UI::FOCUS = $self->{entry};

   $self->SUPER::_draw;
}

1