1 |
package CFPlus::Protocol; |
2 |
|
3 |
use utf8; |
4 |
use strict; |
5 |
|
6 |
use Crossfire::Protocol::Constants; |
7 |
|
8 |
use CFPlus; |
9 |
use CFPlus::DB; |
10 |
use CFPlus::UI; |
11 |
use CFPlus::Pod; |
12 |
use CFPlus::Macro; |
13 |
use CFPlus::Item; |
14 |
|
15 |
use Crossfire::Protocol::Base 0.95; |
16 |
|
17 |
use base 'Crossfire::Protocol::Base'; |
18 |
|
19 |
sub new { |
20 |
my ($class, %arg) = @_; |
21 |
|
22 |
my $self = $class->SUPER::new (%arg, |
23 |
setup_req => { |
24 |
extmap => 1, |
25 |
excmd => 1, |
26 |
ywidget => 1, |
27 |
%{$arg{setup_req} || {}}, |
28 |
}, |
29 |
); |
30 |
|
31 |
$self->{map_widget}->clr_commands; |
32 |
|
33 |
my @cmd_help = map { |
34 |
$_->{kw}[0] =~ /^(\S+) (?:\s+ \( ([^\)]*) \) )?/x |
35 |
or die "unparseable command help: $_->{kw}[0]"; |
36 |
|
37 |
my $cmd = $1; |
38 |
my @args = split /\|/, $2; |
39 |
@args = (".*") unless @args; |
40 |
|
41 |
my (undef, @par) = CFPlus::Pod::section_of $_; |
42 |
my $text = CFPlus::Pod::as_label @par; |
43 |
|
44 |
$_ = $_ eq ".*" ? "" : " $_" |
45 |
for @args; |
46 |
|
47 |
map ["$cmd$_", $text], |
48 |
sort { (length $a) <=> (length $b) } |
49 |
@args |
50 |
} sort { $a->{par} <=> $b->{par} } |
51 |
CFPlus::Pod::find command => "*"; |
52 |
|
53 |
$self->connect_ext (event_music => sub { |
54 |
my ($ev) = @_; |
55 |
|
56 |
return unless $::CFG->{bgm_enable}; |
57 |
|
58 |
my $faces = $ev->{faces}; |
59 |
my @songs; |
60 |
|
61 |
# request music from server if appropriate |
62 |
if (my $faces = $ev->{faces}) { |
63 |
for (@$faces) { |
64 |
my ($face, $pri, $chksum) = @$_; |
65 |
utf8::downgrade $chksum; |
66 |
|
67 |
$chksum = unpack "H*", $chksum; |
68 |
$self->{music_map}{$face} = $chksum; |
69 |
|
70 |
# check if already cached |
71 |
CFPlus::DB::get "res-metadata" => $chksum, sub { |
72 |
my ($meta_json) = @_; |
73 |
my $path = CFPlus::DB::path_of_res $chksum; |
74 |
|
75 |
if (defined $meta_json) { |
76 |
my $meta = $self->{json_coder}->decode ($meta_json); |
77 |
$meta->{path} = $path; |
78 |
$self->{music_meta}{$chksum} = $meta; |
79 |
&::audio_music_set ($self->{songs}); |
80 |
} else { |
81 |
::message ({ markup => "starting to download song #$face/$pri, check your output-rate setting if your connection gets laggy." }); |
82 |
$self->ask_face ($face, -100 - $pri, undef, sub { |
83 |
my $len = length $_[1]; |
84 |
my ($meta_json, $data) = unpack "(w/a*)*", $_[1]; |
85 |
|
86 |
CFPlus::DB::write_file $path, $data, sub { |
87 |
CFPlus::DB::put "res-metadata" => $chksum => $meta_json, sub { |
88 |
my $meta = $self->{json_coder}->decode ($meta_json); |
89 |
$meta->{path} = $path; |
90 |
$self->{music_meta}{$chksum} = $meta; |
91 |
|
92 |
::message ({ markup => "downloaded song #$face, size $len octets" }); |
93 |
&::audio_music_set ($self->{songs}); |
94 |
}; |
95 |
}; |
96 |
}); |
97 |
} |
98 |
} |
99 |
} |
100 |
} |
101 |
|
102 |
if (my $play = $ev->{play}) { |
103 |
&::audio_music_set ($self->{songs} = [map $self->{music_map}{$_}, @$play]); |
104 |
} |
105 |
}); |
106 |
|
107 |
$self->connect_ext (event_capabilities => sub { |
108 |
my ($cap) = @_; |
109 |
|
110 |
if (my $ts = $cap->{tileset}) { |
111 |
if (my ($default) = grep $_->[2] & 1, @$ts) { |
112 |
$self->{tileset} = $default; |
113 |
$self->{tilesize} = $default->[3]; |
114 |
$self->setup_req (tileset => $default->[0]); |
115 |
|
116 |
my $w = int $self->{mapw} * 32 / $self->{tilesize}; |
117 |
my $h = int $self->{maph} * 32 / $self->{tilesize}; |
118 |
|
119 |
$self->setup_req (mapsize => "${w}x${h}"); |
120 |
} |
121 |
} |
122 |
}); |
123 |
|
124 |
$self->{json_coder} |
125 |
->convert_blessed |
126 |
->filter_json_single_key_object (__widget_ref__ => sub { |
127 |
$self->{widget}{$_[0]} |
128 |
}); |
129 |
|
130 |
# widgetset new |
131 |
$self->connect_ext (ws_n => sub { |
132 |
my ($arg) = @_; |
133 |
|
134 |
$self->{widgetset}{$arg{id}} = { |
135 |
w => {}, |
136 |
}; |
137 |
}); |
138 |
|
139 |
# widgetset destroy |
140 |
$self->connect_ext (ws_d => sub { |
141 |
my ($arg) = @_; |
142 |
|
143 |
my $ws = delete $self->{widgetset}{$arg{id}} |
144 |
or return; |
145 |
|
146 |
$_->destroy |
147 |
for values %{$ws->{w}}; |
148 |
}); |
149 |
|
150 |
# widgetset destroy |
151 |
$self->connect_ext (ws_c => sub { |
152 |
my ($arg) = @_; |
153 |
|
154 |
my $args = $arg->{args} || {}; |
155 |
|
156 |
for my $ev (grep /^on_/, keys %$args) { |
157 |
$args->{$ev} = sub { |
158 |
my $id = shift->{s_id}; |
159 |
$self->send_exti_msg (w_e => id => $id, name => $ev, args => \@_); |
160 |
|
161 |
1 |
162 |
}; |
163 |
} |
164 |
|
165 |
if (my $widget = eval { |
166 |
local $SIG{__DIE__}; |
167 |
"CFPlus::UI::$arg->{class}"->new ( |
168 |
%$args, |
169 |
s_ws => $arg->{ws}, |
170 |
s_id => $arg->{id}, |
171 |
) |
172 |
} |
173 |
) { |
174 |
$self->{widget}{$arg->{id}} |
175 |
= $self->{widgetset}{$arg->{ws}}{w}{$arg->{id}} |
176 |
= $widget; |
177 |
|
178 |
$widget->connect (on_destroy => sub { |
179 |
my ($widget) = @_; |
180 |
|
181 |
delete $self->{widget}{$widget->{s_id}}; |
182 |
delete $self->{widgetset}{$widget->{s_ws}}{$widget->{s_id}}; |
183 |
}); |
184 |
} else { |
185 |
warn "server failed creating client-side widget " . (CFPlus::to_json $arg) . ": $@\n"; |
186 |
$self->send_exti_msg (w_e => id => $arg->{id}, name => "destroy"); |
187 |
} |
188 |
}); |
189 |
|
190 |
# widget call |
191 |
$self->connect_ext (w_c => sub { |
192 |
my ($arg) = @_; |
193 |
|
194 |
my $w = $self->{widget}{$arg->{id}} |
195 |
or return; |
196 |
my $m = $arg->{name}; |
197 |
|
198 |
my $a = $arg->{args} || []; |
199 |
|
200 |
if (exists $arg->{rid}) { |
201 |
$self->send_exti_msg (w_r => rid => $arg->{rid}, res => [$w->$m (@$a)]); |
202 |
} else { |
203 |
$w->$m (@$a); |
204 |
} |
205 |
}); |
206 |
|
207 |
# widget set |
208 |
$self->connect_ext (w_s => sub { |
209 |
my ($arg) = @_; |
210 |
|
211 |
my $w = $self->{widget}{$arg->{id}} |
212 |
or return; |
213 |
|
214 |
my $attr = $arg->{attr}; |
215 |
|
216 |
for (my $i = 0; $i < $#$attr; $i += 2) { |
217 |
my ($member, $value) = @$attr[$i, $i+1]; |
218 |
if (defined $value) { |
219 |
$w->{$member} = $value; |
220 |
} else { |
221 |
delete $w->{$member}; |
222 |
} |
223 |
$w->{parent}->realloc if $member =~ /^c_/ && $w->{visible}; |
224 |
} |
225 |
}); |
226 |
|
227 |
# widget get |
228 |
$self->connect_ext (w_g => sub { |
229 |
my ($arg) = @_; |
230 |
|
231 |
my $w = $self->{widget}{$arg->{id}} |
232 |
or return; |
233 |
|
234 |
$self->send_exti_msg (w_r => rid => $arg->{rid}, res => [map $w->{$_}, @{$arg->{attr}}]); |
235 |
}); |
236 |
|
237 |
# destroy widgets on logout |
238 |
$self->{on_stop_game_guard} = $self->{map_widget}{root}->connect (stop_game => sub { |
239 |
for my $ws (values %{delete $self->{widgetset} || {}}) { |
240 |
$_->destroy |
241 |
for values %{delete $ws->{w} || {}}; |
242 |
} |
243 |
}); |
244 |
|
245 |
$self->{map_widget}->add_command (@$_) |
246 |
for @cmd_help; |
247 |
|
248 |
{ |
249 |
$self->{dialogue} = my $tex = new_from_file CFPlus::Texture |
250 |
CFPlus::find_rcfile "dialogue.png", minify => 1, mipmap => 1; |
251 |
$self->{map}->set_texture (1, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
252 |
} |
253 |
|
254 |
{ |
255 |
$self->{noface} = my $tex = new_from_file CFPlus::Texture |
256 |
CFPlus::find_rcfile "noface.png", minify => 1, mipmap => 1; |
257 |
$self->{map}->set_texture (2, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
258 |
} |
259 |
|
260 |
$self->{open_container} = 0; |
261 |
|
262 |
# per server |
263 |
$self->{mapcache} = "mapcache_$self->{host}_$self->{port}"; |
264 |
|
265 |
$self |
266 |
} |
267 |
|
268 |
sub logprint { |
269 |
my ($self, @a) = @_; |
270 |
|
271 |
$self->{log_fh} ||= do { |
272 |
my $path = "$Crossfire::VARDIR/log.$self->{host}"; |
273 |
|
274 |
open my $fh, ">>:utf8", $path |
275 |
or die "Couldn't open logfile $path: $!"; |
276 |
|
277 |
$fh->autoflush (1); |
278 |
|
279 |
$fh; |
280 |
}; |
281 |
|
282 |
my ($sec, $min, $hour, $mday, $mon, $year) = localtime time; |
283 |
|
284 |
my $ts = sprintf "%04d-%02d-%02d %02d:%02d:%02d", |
285 |
$year + 1900, $mon + 1, $mday, $hour, $min, $sec; |
286 |
|
287 |
print {$self->{log_fh}} "$ts ", @a, "\n"; |
288 |
} |
289 |
|
290 |
sub _stat_numdiff { |
291 |
my ($self, $name, $old, $new) = @_; |
292 |
|
293 |
my $diff = $new - $old; |
294 |
|
295 |
$diff = 0.01 * int $diff * 100; |
296 |
|
297 |
0.1 >= abs $diff ? () |
298 |
: $diff < 0 ? "$name$diff" : "$name+$diff" |
299 |
} |
300 |
|
301 |
sub _stat_skillmaskdiff { |
302 |
my ($self, $name, $old, $new) = @_; |
303 |
|
304 |
my $diff = $old ^ $new |
305 |
or return; |
306 |
|
307 |
my @diff = map |
308 |
{ |
309 |
$diff & $_ |
310 |
? (($new & $_ ? "+" : "-") . $self->{spell_paths}{$_}) |
311 |
: () |
312 |
} |
313 |
sort { $a <=> $b } keys %{$self->{spell_paths}}; |
314 |
|
315 |
join "", @diff |
316 |
} |
317 |
|
318 |
# all stats that are chacked against changes |
319 |
my @statchange = ( |
320 |
[&CS_STAT_STR => \&_stat_numdiff, "Str"], |
321 |
[&CS_STAT_INT => \&_stat_numdiff, "Int"], |
322 |
[&CS_STAT_WIS => \&_stat_numdiff, "Wis"], |
323 |
[&CS_STAT_DEX => \&_stat_numdiff, "Dex"], |
324 |
[&CS_STAT_CON => \&_stat_numdiff, "Con"], |
325 |
[&CS_STAT_CHA => \&_stat_numdiff, "Cha"], |
326 |
[&CS_STAT_POW => \&_stat_numdiff, "Pow"], |
327 |
[&CS_STAT_WC => \&_stat_numdiff, "Wc"], |
328 |
[&CS_STAT_AC => \&_stat_numdiff, "Ac"], |
329 |
[&CS_STAT_DAM => \&_stat_numdiff, "Dam"], |
330 |
[&CS_STAT_SPEED => \&_stat_numdiff, "Speed"], |
331 |
[&CS_STAT_WEAP_SP => \&_stat_numdiff, "WSp"], |
332 |
[&CS_STAT_MAXHP => \&_stat_numdiff, "HP"], |
333 |
[&CS_STAT_MAXSP => \&_stat_numdiff, "Mana"], |
334 |
[&CS_STAT_MAXGRACE => \&_stat_numdiff, "Grace"], |
335 |
[&CS_STAT_WEIGHT_LIM => \&_stat_numdiff, "Weight"], |
336 |
[&CS_STAT_SPELL_ATTUNE => \&_stat_skillmaskdiff, "attuned"], |
337 |
[&CS_STAT_SPELL_REPEL => \&_stat_skillmaskdiff, "repelled"], |
338 |
[&CS_STAT_SPELL_DENY => \&_stat_skillmaskdiff, "denied"], |
339 |
[&CS_STAT_RES_PHYS => \&_stat_numdiff, "phys"], |
340 |
[&CS_STAT_RES_MAG => \&_stat_numdiff, "magic"], |
341 |
[&CS_STAT_RES_FIRE => \&_stat_numdiff, "fire"], |
342 |
[&CS_STAT_RES_ELEC => \&_stat_numdiff, "electricity"], |
343 |
[&CS_STAT_RES_COLD => \&_stat_numdiff, "cold"], |
344 |
[&CS_STAT_RES_CONF => \&_stat_numdiff, "confusion"], |
345 |
[&CS_STAT_RES_ACID => \&_stat_numdiff, "acid"], |
346 |
[&CS_STAT_RES_DRAIN => \&_stat_numdiff, "drain"], |
347 |
[&CS_STAT_RES_GHOSTHIT => \&_stat_numdiff, "ghosthit"], |
348 |
[&CS_STAT_RES_POISON => \&_stat_numdiff, "poison"], |
349 |
[&CS_STAT_RES_SLOW => \&_stat_numdiff, "slow"], |
350 |
[&CS_STAT_RES_PARA => \&_stat_numdiff, "paralyse"], |
351 |
[&CS_STAT_TURN_UNDEAD => \&_stat_numdiff, "turnundead"], |
352 |
[&CS_STAT_RES_FEAR => \&_stat_numdiff, "fear"], |
353 |
[&CS_STAT_RES_DEPLETE => \&_stat_numdiff, "depletion"], |
354 |
[&CS_STAT_RES_DEATH => \&_stat_numdiff, "death"], |
355 |
[&CS_STAT_RES_HOLYWORD => \&_stat_numdiff, "godpower"], |
356 |
[&CS_STAT_RES_BLIND => \&_stat_numdiff, "blind"], |
357 |
); |
358 |
|
359 |
sub stats_update { |
360 |
my ($self, $stats) = @_; |
361 |
|
362 |
my $prev = $self->{prev_stats} || { }; |
363 |
|
364 |
if (my @diffs = |
365 |
( |
366 |
($stats->{+CS_STAT_EXP64} > $prev->{+CS_STAT_EXP64} ? ($stats->{+CS_STAT_EXP64} - $prev->{+CS_STAT_EXP64}) . " experience gained" : ()), |
367 |
map { |
368 |
$stats->{$_} && $prev->{$_} |
369 |
&& $stats->{$_}[1] > $prev->{$_}[1] ? "($self->{skill_info}{$_}+" . ($stats->{$_}[1] - $prev->{$_}[1]) . ")" : () |
370 |
} sort { $a <=> $b } keys %{$self->{skill_info}} |
371 |
) |
372 |
) { |
373 |
my $msg = join " ", @diffs; |
374 |
$self->{statusbox}->add ($msg, group => "experience $msg", fg => [0.5, 1, 0.5, 0.8], timeout => 5); |
375 |
} |
376 |
|
377 |
if ( |
378 |
my @diffs = map $_->[1]->($self, $_->[2], $prev->{$_->[0]}, $stats->{$_->[0]}), @statchange |
379 |
) { |
380 |
my $msg = "<b>stat change</b>: " . (join " ", @diffs); |
381 |
$self->{statusbox}->add ($msg, group => "stat $msg", fg => [0.8, 1, 0.2, 1], timeout => 10); |
382 |
} |
383 |
|
384 |
$self->update_stats_window ($stats, $prev); |
385 |
|
386 |
$self->{prev_stats} = { %$stats }; |
387 |
} |
388 |
|
389 |
my %RES_TBL = ( |
390 |
phys => CS_STAT_RES_PHYS, |
391 |
magic => CS_STAT_RES_MAG, |
392 |
fire => CS_STAT_RES_FIRE, |
393 |
elec => CS_STAT_RES_ELEC, |
394 |
cold => CS_STAT_RES_COLD, |
395 |
conf => CS_STAT_RES_CONF, |
396 |
acid => CS_STAT_RES_ACID, |
397 |
drain => CS_STAT_RES_DRAIN, |
398 |
ghit => CS_STAT_RES_GHOSTHIT, |
399 |
pois => CS_STAT_RES_POISON, |
400 |
slow => CS_STAT_RES_SLOW, |
401 |
para => CS_STAT_RES_PARA, |
402 |
tund => CS_STAT_TURN_UNDEAD, |
403 |
fear => CS_STAT_RES_FEAR, |
404 |
depl => CS_STAT_RES_DEPLETE, |
405 |
deat => CS_STAT_RES_DEATH, |
406 |
holyw => CS_STAT_RES_HOLYWORD, |
407 |
blind => CS_STAT_RES_BLIND, |
408 |
); |
409 |
|
410 |
sub update_stats_window { |
411 |
my ($self, $stats, $prev) = @_; |
412 |
|
413 |
# I love text protocols... |
414 |
|
415 |
my $hp = $stats->{+CS_STAT_HP} * 1; |
416 |
my $hp_m = $stats->{+CS_STAT_MAXHP} * 1; |
417 |
my $sp = $stats->{+CS_STAT_SP} * 1; |
418 |
my $sp_m = $stats->{+CS_STAT_MAXSP} * 1; |
419 |
my $fo = $stats->{+CS_STAT_FOOD} * 1; |
420 |
my $fo_m = 999; |
421 |
my $gr = $stats->{+CS_STAT_GRACE} * 1; |
422 |
my $gr_m = $stats->{+CS_STAT_MAXGRACE} * 1; |
423 |
|
424 |
$::GAUGES->{hp} ->set_value ($hp, $hp_m); |
425 |
$::GAUGES->{mana} ->set_value ($sp, $sp_m); |
426 |
$::GAUGES->{food} ->set_value ($fo, $fo_m); |
427 |
$::GAUGES->{grace} ->set_value ($gr, $gr_m); |
428 |
$::GAUGES->{exp} ->set_text ("Exp: " . (::formsep ($stats->{+CS_STAT_EXP64})) |
429 |
. " (lvl " . ($stats->{+CS_STAT_LEVEL} * 1) . ")"); |
430 |
$::GAUGES->{range} ->set_text ($stats->{+CS_STAT_RANGE}); |
431 |
my $title = $stats->{+CS_STAT_TITLE}; |
432 |
$title =~ s/^Player: //; |
433 |
$::STATWIDS->{title} ->set_text ("Title: " . $title); |
434 |
|
435 |
$::STATWIDS->{st_str} ->set_text (sprintf "%d" , $stats->{+CS_STAT_STR}); |
436 |
$::STATWIDS->{st_dex} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DEX}); |
437 |
$::STATWIDS->{st_con} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CON}); |
438 |
$::STATWIDS->{st_int} ->set_text (sprintf "%d" , $stats->{+CS_STAT_INT}); |
439 |
$::STATWIDS->{st_wis} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WIS}); |
440 |
$::STATWIDS->{st_pow} ->set_text (sprintf "%d" , $stats->{+CS_STAT_POW}); |
441 |
$::STATWIDS->{st_cha} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CHA}); |
442 |
$::STATWIDS->{st_wc} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WC}); |
443 |
$::STATWIDS->{st_ac} ->set_text (sprintf "%d" , $stats->{+CS_STAT_AC}); |
444 |
$::STATWIDS->{st_dam} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DAM}); |
445 |
$::STATWIDS->{st_arm} ->set_text (sprintf "%d" , $stats->{+CS_STAT_RES_PHYS}); |
446 |
$::STATWIDS->{st_spd} ->set_text (sprintf "%.1f", $stats->{+CS_STAT_SPEED}); |
447 |
$::STATWIDS->{st_wspd}->set_text (sprintf "%.1f", $stats->{+CS_STAT_WEAP_SP}); |
448 |
|
449 |
$self->update_weight; |
450 |
|
451 |
$::STATWIDS->{"res_$_"}->set_text (sprintf "%d%", $stats->{$RES_TBL{$_}}) |
452 |
for keys %RES_TBL; |
453 |
|
454 |
my $sktbl = $::STATWIDS->{skill_tbl}; |
455 |
my @skills = keys %{ $self->{skill_info} }; |
456 |
|
457 |
if (grep +(exists $stats->{$_}) != (exists $prev->{$_}), @skills) { |
458 |
$sktbl->clear; |
459 |
|
460 |
my @add; |
461 |
|
462 |
push @add, |
463 |
0, 0, (new CFPlus::UI::Label text => "Experience", align => 1), |
464 |
1, 0, (new CFPlus::UI::Label text => "Lvl.", align => 1), |
465 |
2, 0, (new CFPlus::UI::Label text => "Skill", expand => 1), |
466 |
3, 0, (new CFPlus::UI::Label text => "Experience", align => 1), |
467 |
4, 0, (new CFPlus::UI::Label text => "Lvl.", align => 1), |
468 |
5, 0, (new CFPlus::UI::Label text => "Skill", expand => 1), |
469 |
; |
470 |
|
471 |
my $TOOLTIP_ALL = "\n\n<small>Left click - ready skill\nMiddle click - use spell\nRight click - further options</small>"; |
472 |
|
473 |
my @TOOLTIP_LVL = (tooltip => "<b>Level</b>. The level of the skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
474 |
my @TOOLTIP_EXP = (tooltip => "<b>Experience</b>. The experience points you have in this skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
475 |
|
476 |
my ($x, $y) = (0, 1); |
477 |
for ( |
478 |
sort { $stats->{$b->[0]}[1] <=> $stats->{$a->[0]}[1] or $a->[1] cmp $b->[1] } |
479 |
map [$_, $self->{skill_info}{$_}], |
480 |
grep exists $stats->{$_}, |
481 |
@skills |
482 |
) { |
483 |
my ($idx, $name) = @$_; |
484 |
|
485 |
my $spell_cb = sub { |
486 |
my ($widget, $ev) = @_; |
487 |
|
488 |
if ($ev->{button} == 1) { |
489 |
$::CONN->user_send ("ready_skill $name"); |
490 |
} elsif ($ev->{button} == 2) { |
491 |
$::CONN->user_send ("use_skill $name"); |
492 |
} elsif ($ev->{button} == 3) { |
493 |
my $shortname = CFPlus::shorten $name, 14; |
494 |
(new CFPlus::UI::Menu |
495 |
items => [ |
496 |
["bind <i>ready_skill $shortname</i> to a key" => sub { CFPlus::Macro::quick_macro ["ready_skill $name"] }], |
497 |
["bind <i>use_skill $shortname</i> to a key" => sub { CFPlus::Macro::quick_macro ["use_skill $name"] }], |
498 |
], |
499 |
)->popup ($ev); |
500 |
} else { |
501 |
return 0; |
502 |
} |
503 |
|
504 |
1 |
505 |
}; |
506 |
|
507 |
push @add, |
508 |
$x * 3 + 0, $y, ($self->{stat_widget_exp}{$idx} = new CFPlus::UI::Label |
509 |
align => 1, font => $::FONT_FIXED, fg => [1, 1, 0], on_button_down => $spell_cb, @TOOLTIP_EXP), |
510 |
$x * 3 + 1, $y, ($self->{stat_widget_lvl}{$idx} = new CFPlus::UI::Label |
511 |
text => "0", align => 1, font => $::FONT_FIXED, fg => [0, 1, 0], padding_x => 4, on_button_down => $spell_cb, @TOOLTIP_LVL), |
512 |
$x * 3 + 2, $y, (new CFPlus::UI::Label text => $name, on_button_down => $spell_cb, |
513 |
can_events => 1, can_hover => 1, tooltip => (CFPlus::Pod::section_label skill_description => $name) . $TOOLTIP_ALL), |
514 |
; |
515 |
|
516 |
$x++ and ($x, $y) = (0, $y + 1); |
517 |
} |
518 |
|
519 |
$sktbl->add_at (@add); |
520 |
} |
521 |
|
522 |
for (grep exists $stats->{$_}, @skills) { |
523 |
$self->{stat_widget_exp}{$_}->set_text (::formsep ($stats->{$_}[1])); |
524 |
$self->{stat_widget_lvl}{$_}->set_text ($stats->{$_}[0] * 1); |
525 |
} |
526 |
} |
527 |
|
528 |
sub macro_send { |
529 |
my ($self, $macro) = @_; |
530 |
|
531 |
for my $cmd (@{ $macro->{action} }) { |
532 |
$self->send_command ($cmd); |
533 |
} |
534 |
} |
535 |
|
536 |
sub user_send { |
537 |
my ($self, $command) = @_; |
538 |
|
539 |
$self->{record}->($command) |
540 |
if $self->{record}; |
541 |
|
542 |
$self->logprint ("send: ", $command); |
543 |
$self->send_command ($command); |
544 |
::status ($command); |
545 |
} |
546 |
|
547 |
sub record { |
548 |
my ($self, $cb) = @_; |
549 |
|
550 |
$self->{record} = $cb; |
551 |
} |
552 |
|
553 |
sub map_scroll { |
554 |
my ($self, $dx, $dy) = @_; |
555 |
|
556 |
$self->{map}->scroll ($dx, $dy); |
557 |
} |
558 |
|
559 |
sub feed_map1a { |
560 |
my ($self, $data) = @_; |
561 |
|
562 |
$self->{map}->map1a_update ($data, $self->{setup}{extmap}); |
563 |
$self->{map_widget}->update; |
564 |
} |
565 |
|
566 |
sub magicmap { |
567 |
my ($self, $w, $h, $x, $y, $data) = @_; |
568 |
|
569 |
$self->{map_widget}->set_magicmap ($w, $h, $x, $y, $data); |
570 |
} |
571 |
|
572 |
sub flush_map { |
573 |
my ($self) = @_; |
574 |
|
575 |
my $map_info = delete $self->{map_info} |
576 |
or return; |
577 |
|
578 |
my ($hash, $x, $y, $w, $h) = @$map_info; |
579 |
|
580 |
my $data = $self->{map}->get_rect ($x, $y, $w, $h); |
581 |
CFPlus::DB::put $self->{mapcache} => $hash => Compress::LZF::compress $data, sub { }; |
582 |
#warn sprintf "SAVEmap[%s] length %d\n", $hash, length $data;#d# |
583 |
} |
584 |
|
585 |
sub map_clear { |
586 |
my ($self) = @_; |
587 |
|
588 |
$self->flush_map; |
589 |
delete $self->{neigh_map}; |
590 |
|
591 |
$self->{map}->clear; |
592 |
delete $self->{map_widget}{magicmap}; |
593 |
} |
594 |
|
595 |
sub bg_fetch { |
596 |
my ($self) = @_; |
597 |
|
598 |
my $id; |
599 |
|
600 |
do { |
601 |
$id = pop @{$self->{bg_fetch}} |
602 |
or return; |
603 |
} while $self->{texture}[$id]; |
604 |
|
605 |
CFPlus::DB::get tilecache => $id, sub { |
606 |
my ($data) = @_; |
607 |
|
608 |
return unless $self->{map}; # stop when destroyed |
609 |
|
610 |
$self->set_texture ($id => $data) |
611 |
if defined $data; |
612 |
|
613 |
$self->bg_fetch; |
614 |
}; |
615 |
} |
616 |
|
617 |
sub load_map($$$) { |
618 |
my ($self, $hash, $x, $y) = @_; |
619 |
|
620 |
my $gen = $self->{map_change_gen}; |
621 |
|
622 |
CFPlus::DB::get $self->{mapcache} => $hash, sub { |
623 |
return unless $gen == $self->{map_change_gen}; |
624 |
|
625 |
my ($data) = @_; |
626 |
|
627 |
if (defined $data) { |
628 |
$data = Compress::LZF::decompress $data; |
629 |
#warn sprintf "LOADmap[%s,%d,%d] length %d\n", $hash, $x, $y, length $data;#d# |
630 |
|
631 |
my $inprogress = @{ $self->{bg_fetch} || [] }; |
632 |
unshift @{ $self->{bg_fetch} }, $self->{map}->set_rect ($x, $y, $data); |
633 |
$self->bg_fetch unless $inprogress; |
634 |
} |
635 |
}; |
636 |
} |
637 |
|
638 |
# hardcode /world/world_xxx_xxx map names, the savings are enourmous, |
639 |
# (server resource,s latency, bandwidth), so this hack is warranted. |
640 |
# the right fix is to make real tiled maps with an overview file |
641 |
sub send_mapinfo { |
642 |
my ($self, $data, $cb) = @_; |
643 |
|
644 |
if ($self->{map_info}[0] =~ m%^/world/world_(\d\d\d)_(\d\d\d)$%) { |
645 |
my ($wx, $wy) = ($1, $2); |
646 |
|
647 |
if ($data =~ /^spatial ([1-4]+)$/) { |
648 |
my @dx = (0, 0, 1, 0, -1); |
649 |
my @dy = (0, -1, 0, 1, 0); |
650 |
my ($dx, $dy); |
651 |
|
652 |
for (split //, $1) { |
653 |
$dx += $dx[$_]; |
654 |
$dy += $dy[$_]; |
655 |
} |
656 |
|
657 |
$cb->(spatial => 15, |
658 |
$self->{map_info}[1] - $self->{map}->ox + $dx * 50, |
659 |
$self->{map_info}[2] - $self->{map}->oy + $dy * 50, |
660 |
50, 50, |
661 |
sprintf "/world/world_%03d_%03d", $wx + $dx, $wy + $dy |
662 |
); |
663 |
|
664 |
return; |
665 |
} |
666 |
} |
667 |
|
668 |
$self->SUPER::send_mapinfo ($data, $cb); |
669 |
} |
670 |
|
671 |
# this method does a "flood fill" into every tile direction |
672 |
# it assumes that tiles are arranged in a rectangular grid, |
673 |
# i.e. a map is the same as the left of the right map etc. |
674 |
# failure to comply are harmless and result in display errors |
675 |
# at worst. |
676 |
sub flood_fill { |
677 |
my ($self, $block, $gx, $gy, $path, $hash, $flags) = @_; |
678 |
|
679 |
# the server does not allow map paths > 6 |
680 |
return if 7 <= length $path; |
681 |
|
682 |
my ($x0, $y0, $x1, $y1) = @{$self->{neigh_rect}}; |
683 |
|
684 |
for ( |
685 |
[1, 3, 0, -1], |
686 |
[2, 4, 1, 0], |
687 |
[3, 1, 0, 1], |
688 |
[4, 2, -1, 0], |
689 |
) { |
690 |
my ($tile, $tile2, $dx, $dy) = @$_; |
691 |
|
692 |
next if $block & (1 << $tile); |
693 |
my $block = $block | (1 << $tile2); |
694 |
|
695 |
my $gx = $gx + $dx; |
696 |
my $gy = $gy + $dy; |
697 |
|
698 |
next unless $flags & (1 << ($tile - 1)); |
699 |
next if $self->{neigh_grid}{$gx, $gy}++; |
700 |
|
701 |
my $neigh = $self->{neigh_map}{$hash} ||= []; |
702 |
if (my $info = $neigh->[$tile]) { |
703 |
my ($flags, $x, $y, $w, $h, $hash) = @$info; |
704 |
|
705 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
706 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
707 |
|
708 |
} else { |
709 |
my $gen = $self->{map_change_gen}; |
710 |
$self->send_mapinfo ("spatial $path$tile", sub { |
711 |
return unless $gen == $self->{map_change_gen}; |
712 |
|
713 |
my ($mode, $flags, $x, $y, $w, $h, $hash) = @_; |
714 |
|
715 |
return if $mode ne "spatial"; |
716 |
|
717 |
$x += $self->{map}->ox; |
718 |
$y += $self->{map}->oy; |
719 |
|
720 |
$self->load_map ($hash, $x, $y) |
721 |
unless $self->{neigh_map}{$hash}[5]++;#d# |
722 |
|
723 |
$neigh->[$tile] = [$flags, $x, $y, $w, $h, $hash]; |
724 |
|
725 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
726 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
727 |
}); |
728 |
} |
729 |
} |
730 |
} |
731 |
|
732 |
sub map_change { |
733 |
my ($self, $mode, $flags, $x, $y, $w, $h, $hash) = @_; |
734 |
|
735 |
$self->flush_map; |
736 |
|
737 |
++$self->{map_change_gen}; |
738 |
|
739 |
my ($ox, $oy) = ($::MAP->ox, $::MAP->oy); |
740 |
|
741 |
my $mapmapw = $self->{mapmap}->{w}; |
742 |
my $mapmaph = $self->{mapmap}->{h}; |
743 |
|
744 |
$self->{neigh_rect} = [ |
745 |
$ox - $mapmapw * 0.5, $oy - $mapmapw * 0.5, |
746 |
$ox + $mapmapw * 0.5 + $w, $oy + $mapmapw * 0.5 + $h, |
747 |
]; |
748 |
|
749 |
delete $self->{neigh_grid}; |
750 |
|
751 |
$x += $ox; |
752 |
$y += $oy; |
753 |
|
754 |
$self->{map_info} = [$hash, $x, $y, $w, $h]; |
755 |
|
756 |
(my $map = $hash) =~ s/^.*?\/([^\/]+)$/\1/; |
757 |
$::STATWIDS->{map}->set_text ("Map: " . $map); |
758 |
|
759 |
$self->load_map ($hash, $x, $y); |
760 |
$self->flood_fill (0, 0, 0, "", $hash, $flags); |
761 |
} |
762 |
|
763 |
sub face_find { |
764 |
my ($self, $facenum, $face, $cb) = @_; |
765 |
|
766 |
my $hash = "$face->{chksum},$face->{name}"; |
767 |
|
768 |
my $id = CFPlus::DB::get_tile_id_sync $hash; |
769 |
|
770 |
$face->{id} = $id; |
771 |
$self->{faceid}[$facenum] = $id; |
772 |
|
773 |
$self->{map}->set_tileid ($facenum => $id); |
774 |
|
775 |
CFPlus::DB::get tilecache => $id, $cb; |
776 |
} |
777 |
|
778 |
sub face_update { |
779 |
my ($self, $facenum, $face, $changed) = @_; |
780 |
|
781 |
CFPlus::DB::put tilecache => $face->{id} => $face->{image}, sub { } |
782 |
if $changed; |
783 |
|
784 |
$self->set_texture ($face->{id} => delete $face->{image}); |
785 |
} |
786 |
|
787 |
sub smooth_update { |
788 |
my ($self, $facenum, $face) = @_; |
789 |
|
790 |
$self->{map}->set_smooth ($facenum, $face->{smoothface}, $face->{smoothlevel}); |
791 |
} |
792 |
|
793 |
sub set_texture { |
794 |
my ($self, $id, $data) = @_; |
795 |
|
796 |
return unless $self->{map}; |
797 |
|
798 |
$self->{texture}[$id] = my $tex = |
799 |
new_from_image CFPlus::Texture |
800 |
$data, minify => 1, mipmap => 1; |
801 |
|
802 |
$self->{map}->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
803 |
$self->{map_widget}->update; |
804 |
|
805 |
$_->() for @{(delete $self->{face_cb}{$id}) || []}; |
806 |
} |
807 |
|
808 |
sub connect_face_update { |
809 |
my ($self, $id, $cb) = @_; |
810 |
|
811 |
push @{$self->{face_cb}{$id}}, $cb; |
812 |
|
813 |
CFPlus::guard { |
814 |
@{$self->{face_cb}{$id}} |
815 |
= grep $_ != $cb, |
816 |
@{$self->{face_cb}{$id}}; |
817 |
} |
818 |
} |
819 |
|
820 |
sub sound_play { |
821 |
my ($self, $x, $y, $soundnum, $type) = @_; |
822 |
|
823 |
$self->{sound_play}->($x, $y, $soundnum, $type); |
824 |
} |
825 |
|
826 |
my $LAST_QUERY; # server is stupid, stupid, stupid |
827 |
|
828 |
sub query { |
829 |
my ($self, $flags, $prompt) = @_; |
830 |
|
831 |
$prompt = $LAST_QUERY unless length $prompt; |
832 |
$LAST_QUERY = $prompt; |
833 |
|
834 |
$self->{query}-> ($self, $flags, $prompt); |
835 |
} |
836 |
|
837 |
sub sanitise_xml($) { |
838 |
local $_ = shift; |
839 |
|
840 |
# we now weed out all tags we do not support |
841 |
s%<(?!/?i>|/?u>|/?b>|fg |/fg>)%<%g; |
842 |
# now all entities |
843 |
s/&(?!amp;|lt;|gt;|apos;|quot;|#[0-9]+;|#x[0-9a-fA-F]+;)/&/g; |
844 |
|
845 |
# handle some elements |
846 |
s/<fg name='([^']*)'>(.*?)<\/fg>/<span foreground='$1'>$2<\/span>/gs; |
847 |
s/<fg name="([^"]*)">(.*?)<\/fg>/<span foreground="$1">$2<\/span>/gs; |
848 |
|
849 |
$_ |
850 |
} |
851 |
|
852 |
our %NAME_TO_COLOR = ( |
853 |
black => 0, |
854 |
white => 1, |
855 |
darkblue => 2, |
856 |
red => 3, |
857 |
orange => 4, |
858 |
lightblue => 5, |
859 |
darkorange => 6, |
860 |
green => 7, |
861 |
darkgreen => 8, |
862 |
grey => 9, |
863 |
brown => 10, |
864 |
yellow => 11, |
865 |
tan => 12, |
866 |
); |
867 |
|
868 |
our @CF_COLOR = ( |
869 |
[1.00, 1.00, 1.00], #[0.00, 0.00, 0.00], |
870 |
[1.00, 1.00, 1.00], |
871 |
[0.50, 0.50, 1.00], #[0.00, 0.00, 0.55] |
872 |
[1.00, 0.00, 0.00], |
873 |
[1.00, 0.54, 0.00], |
874 |
[0.11, 0.56, 1.00], |
875 |
[0.93, 0.46, 0.00], |
876 |
[0.18, 0.54, 0.34], |
877 |
[0.56, 0.73, 0.56], |
878 |
[0.80, 0.80, 0.80], |
879 |
[0.75, 0.61, 0.20], |
880 |
[0.99, 0.77, 0.26], |
881 |
[0.74, 0.65, 0.41], |
882 |
); |
883 |
|
884 |
sub msg { |
885 |
my ($self, $color, $type, $text, @extra) = @_; |
886 |
|
887 |
$text = sanitise_xml $text; |
888 |
|
889 |
if (my $cb = $self->{cb_msg}{$type}) { |
890 |
$_->($self, $color, $type, $text, @extra) for values %$cb; |
891 |
} elsif ($type =~ /^(?:chargen-race-title|chargen-race-description)$/) { |
892 |
$type =~ s/-/_/g; |
893 |
$self->{$type} = $text; |
894 |
} else { |
895 |
$self->logprint ("msg: ", $text); |
896 |
return if $color < 0; # negative color == ignore if not understood |
897 |
|
898 |
my $fg = $CF_COLOR[$color % @CF_COLOR]; |
899 |
|
900 |
## try to create single paragraphs of multiple lines sent by the server |
901 |
# no longer neecssary with TRT servers |
902 |
#$text =~ s/(?<=\S)\n(?=\w)/ /g; |
903 |
|
904 |
::message ({ fg => $fg, markup => $_ }) |
905 |
for split /\n/, $text; |
906 |
|
907 |
$self->{statusbox}->add ($text, |
908 |
group => $text, |
909 |
fg => $fg, |
910 |
timeout => $color >= 2 ? 180 : 10, |
911 |
tooltip_font => $::FONT_FIXED, |
912 |
); |
913 |
} |
914 |
} |
915 |
|
916 |
sub spell_add { |
917 |
my ($self, $spell) = @_; |
918 |
|
919 |
# try to create single paragraphs out of the multiple lines sent by the server |
920 |
$spell->{message} =~ s/(?<=\S)\n(?=\w)/ /g; |
921 |
$spell->{message} =~ s/\n+$//; |
922 |
$spell->{message} ||= "Server did not provide a description for this spell."; |
923 |
|
924 |
$::SPELL_LIST->add_spell ($spell); |
925 |
|
926 |
$self->{map_widget}->add_command ("invoke $spell->{name}", CFPlus::asxml $spell->{message}); |
927 |
$self->{map_widget}->add_command ("cast $spell->{name}", CFPlus::asxml $spell->{message}); |
928 |
} |
929 |
|
930 |
sub spell_delete { |
931 |
my ($self, $spell) = @_; |
932 |
|
933 |
$::SPELL_LIST->remove_spell ($spell); |
934 |
} |
935 |
|
936 |
sub setup { |
937 |
my ($self, $setup) = @_; |
938 |
|
939 |
$self->{map_widget}->set_tilesize ($self->{tilesize}); |
940 |
$::MAP->resize ($self->{mapw}, $self->{maph}); |
941 |
} |
942 |
|
943 |
sub addme_success { |
944 |
my ($self) = @_; |
945 |
|
946 |
my %skill_help; |
947 |
|
948 |
for my $node (CFPlus::Pod::find skill_description => "*") { |
949 |
my (undef, @par) = CFPlus::Pod::section_of $node; |
950 |
$skill_help{$node->{kw}[0]} = CFPlus::Pod::as_label @par; |
951 |
}; |
952 |
|
953 |
for my $skill (values %{$self->{skill_info}}) { |
954 |
$self->{map_widget}->add_command ("ready_skill $skill", |
955 |
(CFPlus::asxml "Ready the skill '$skill'\n\n") |
956 |
. $skill_help{$skill}); |
957 |
$self->{map_widget}->add_command ("use_skill $skill", |
958 |
(CFPlus::asxml "Immediately use the skill '$skill'\n\n") |
959 |
. $skill_help{$skill}); |
960 |
} |
961 |
} |
962 |
|
963 |
sub eof { |
964 |
my ($self) = @_; |
965 |
|
966 |
$self->{map_widget}->clr_commands; |
967 |
|
968 |
::stop_game (); |
969 |
} |
970 |
|
971 |
sub image_info { |
972 |
my ($self, $numfaces) = @_; |
973 |
|
974 |
$self->{num_faces} = $numfaces; |
975 |
$self->{face_prefetch} = [1 .. $numfaces]; |
976 |
$self->face_prefetch; |
977 |
} |
978 |
|
979 |
sub face_prefetch { |
980 |
my ($self) = @_; |
981 |
|
982 |
return unless $::CFG->{face_prefetch}; |
983 |
|
984 |
if ($self->{num_faces}) { |
985 |
return if @{ $self->{send_queue} || [] }; |
986 |
my $todo = @{ $self->{face_prefetch} } |
987 |
or return; |
988 |
|
989 |
my ($face) = splice @{ $self->{face_prefetch} }, + rand @{ $self->{face_prefetch} }, 1, (); |
990 |
|
991 |
$self->send ("requestinfo image_sums $face $face"); |
992 |
|
993 |
$self->{statusbox}->add (CFPlus::asxml "prefetching $todo", |
994 |
group => "prefetch", timeout => 3, fg => [1, 1, 0, 0.5]); |
995 |
} elsif (!exists $self->{num_faces}) { |
996 |
$self->send ("requestinfo image_info"); |
997 |
|
998 |
$self->{num_faces} = 0; |
999 |
|
1000 |
$self->{statusbox}->add (CFPlus::asxml "starting to prefetch", |
1001 |
group => "prefetch", timeout => 3, fg => [1, 1, 0, 0.5]); |
1002 |
} |
1003 |
} |
1004 |
|
1005 |
sub update_floorbox { |
1006 |
$CFPlus::UI::ROOT->on_refresh ($::FLOORBOX => sub { |
1007 |
return unless $::CONN; |
1008 |
|
1009 |
$::FLOORBOX->clear; |
1010 |
|
1011 |
my @add; |
1012 |
|
1013 |
my $row; |
1014 |
for (sort { $a->{count} <=> $b->{count} } values %{ $::CONN->{container}{$::CONN->{open_container} || 0} }) { |
1015 |
if ($row < 6) { |
1016 |
local $_->{face_widget}; # hack to force recreation of widget |
1017 |
local $_->{desc_widget}; # hack to force recreation of widget |
1018 |
CFPlus::Item::update_widgets $_; |
1019 |
|
1020 |
push @add, |
1021 |
0, $row, $_->{face_widget}, |
1022 |
1, $row, $_->{desc_widget}; |
1023 |
|
1024 |
$row++; |
1025 |
} else { |
1026 |
push @add, 1, $row, new CFPlus::UI::Button |
1027 |
text => "More...", |
1028 |
on_activate => sub { ::toggle_player_page ($::INVENTORY_PAGE); 0 }, |
1029 |
; |
1030 |
last; |
1031 |
} |
1032 |
} |
1033 |
if ($::CONN->{open_container}) { |
1034 |
push @add, 1, $row++, new CFPlus::UI::Button |
1035 |
text => "Close container", |
1036 |
on_activate => sub { $::CONN->send ("apply $::CONN->{open_container}") } |
1037 |
; |
1038 |
} |
1039 |
|
1040 |
$::FLOORBOX->add_at (@add); |
1041 |
}); |
1042 |
|
1043 |
$::WANT_REFRESH++; |
1044 |
} |
1045 |
|
1046 |
sub set_opencont { |
1047 |
my ($conn, $tag, $name) = @_; |
1048 |
$conn->{open_container} = $tag; |
1049 |
update_floorbox; |
1050 |
|
1051 |
$::INV_RIGHT_HB->clear (); |
1052 |
$::INV_RIGHT_HB->add (new CFPlus::UI::Label align => 0, expand => 1, text => $name); |
1053 |
|
1054 |
if ($tag != 0) { # Floor isn't closable, is it? |
1055 |
$::INV_RIGHT_HB->add (new CFPlus::UI::Button |
1056 |
text => "Close container", |
1057 |
tooltip => "Close the currently open container (if one is open)", |
1058 |
on_activate => sub { |
1059 |
$::CONN->send ("apply $tag") # $::CONN->{open_container}") |
1060 |
if $tag != 0; |
1061 |
#if $CONN->{open_container} != 0; |
1062 |
0 |
1063 |
}, |
1064 |
); |
1065 |
} |
1066 |
|
1067 |
$::INVR->set_items ($conn->{container}{$tag}); |
1068 |
} |
1069 |
|
1070 |
sub update_containers { |
1071 |
my ($self) = @_; |
1072 |
|
1073 |
$CFPlus::UI::ROOT->on_refresh ("update_containers_$self" => sub { |
1074 |
my $todo = delete $self->{update_container} |
1075 |
or return; |
1076 |
|
1077 |
for my $tag (keys %$todo) { |
1078 |
update_floorbox if $tag == 0 or $tag == $self->{open_container}; |
1079 |
if ($tag == 0) { |
1080 |
$::INVR->set_items ($self->{container}{0}) |
1081 |
if $tag == $self->{open_container}; |
1082 |
} elsif ($tag == $self->{player}{tag}) { |
1083 |
$::INV->set_items ($self->{container}{$tag}) |
1084 |
} else { |
1085 |
$::INVR->set_items ($self->{container}{$tag}) |
1086 |
if $tag == $self->{open_container}; |
1087 |
} |
1088 |
} |
1089 |
}); |
1090 |
} |
1091 |
|
1092 |
sub container_add { |
1093 |
my ($self, $tag, $items) = @_; |
1094 |
|
1095 |
$self->{update_container}{$tag}++; |
1096 |
$self->update_containers; |
1097 |
} |
1098 |
|
1099 |
sub container_clear { |
1100 |
my ($self, $tag) = @_; |
1101 |
|
1102 |
$self->{update_container}{$tag}++; |
1103 |
$self->update_containers; |
1104 |
} |
1105 |
|
1106 |
sub item_delete { |
1107 |
my ($self, @items) = @_; |
1108 |
|
1109 |
$self->{update_container}{$_->{container}}++ |
1110 |
for @items; |
1111 |
|
1112 |
$self->update_containers; |
1113 |
} |
1114 |
|
1115 |
sub item_update { |
1116 |
my ($self, $item) = @_; |
1117 |
|
1118 |
#d# print "item_update: $item->{tag} in $item->{container} ($self->{player}{tag}) ($::CONN->{open_container})\n"; |
1119 |
|
1120 |
CFPlus::Item::update_widgets $item; |
1121 |
|
1122 |
if ($item->{tag} == $::CONN->{open_container} && not ($item->{flags} & F_OPEN)) { |
1123 |
set_opencont ($::CONN, 0, "Floor"); |
1124 |
|
1125 |
} elsif ($item->{flags} & F_OPEN) { |
1126 |
set_opencont ($::CONN, $item->{tag}, CFPlus::Item::desc_string $item); |
1127 |
|
1128 |
} else { |
1129 |
$self->{update_container}{$item->{container}}++; |
1130 |
$self->update_containers; |
1131 |
} |
1132 |
} |
1133 |
|
1134 |
sub player_update { |
1135 |
my ($self, $player) = @_; |
1136 |
|
1137 |
$self->update_weight; |
1138 |
} |
1139 |
|
1140 |
sub update_weight { |
1141 |
my ($self) = @_; |
1142 |
|
1143 |
my $weight = .001 * $self->{player}{weight}; |
1144 |
my $limit = .001 * $self->{stat}{+CS_STAT_WEIGHT_LIM}; |
1145 |
|
1146 |
$::STATWIDS->{weight}->set_text (sprintf "Weight: %.1fkg", $weight); |
1147 |
$::STATWIDS->{m_weight}->set_text (sprintf "%.1fkg", $limit); |
1148 |
$::STATWIDS->{i_weight}->set_text (sprintf "%.1f/%.1fkg", $weight, $limit); |
1149 |
} |
1150 |
|
1151 |
sub update_server_info { |
1152 |
my ($self) = @_; |
1153 |
|
1154 |
my @yesno = ("<span foreground='red'>no</span>", "<span foreground='green'>yes</span>"); |
1155 |
|
1156 |
$::SERVER_INFO->set_markup ( |
1157 |
"server <tt>$self->{host}:$self->{port}</tt>\n" |
1158 |
. "protocol version <tt>$self->{version}</tt>\n" |
1159 |
. "minimap support $yesno[$self->{setup}{mapinfocmd} > 0]\n" |
1160 |
. "extended command support $yesno[$self->{setup}{extcmd} > 0]\n" |
1161 |
. "examine command support $yesno[$self->{setup}{excmd} > 0]\n" |
1162 |
. "editing support $yesno[!!$self->{editor_support}]\n" |
1163 |
. "map attributes $yesno[$self->{setup}{extmap} > 0]\n" |
1164 |
. "big image protocol support $yesno[$self->{setup}{fxix} > 0]\n" |
1165 |
. "cfplus support $yesno[$self->{cfplus_ext} > 0]" |
1166 |
. ($self->{cfplus_ext} > 0 ? ", version $self->{cfplus_ext}" : "") ."\n" |
1167 |
. "map size $self->{mapw}×$self->{maph}\n" |
1168 |
); |
1169 |
|
1170 |
::setup_build_button ($self->{editor_support}->{builder_ui}); |
1171 |
} |
1172 |
|
1173 |
sub logged_in { |
1174 |
my ($self) = @_; |
1175 |
|
1176 |
$self->send_ext_req (cfplus_support => version => 1, sub { |
1177 |
$self->{cfplus_ext} = $_[0]{version}; |
1178 |
$self->update_server_info; |
1179 |
|
1180 |
if ($self->{cfplus_ext} >= 2) { |
1181 |
$self->send_ext_req ("editor_support", sub { |
1182 |
$self->{editor_support} = $_[0]; |
1183 |
$self->update_server_info; |
1184 |
|
1185 |
0 |
1186 |
}); |
1187 |
} |
1188 |
|
1189 |
0 |
1190 |
}); |
1191 |
|
1192 |
$self->update_server_info; |
1193 |
|
1194 |
$self->send_command ("output-sync $::CFG->{output_sync}"); |
1195 |
$self->send_command ("output-count $::CFG->{output_count}"); |
1196 |
$self->send_command ("output-rate $::CFG->{output_rate}") if $::CFG->{output_rate} > 0; |
1197 |
$self->send_command ("pickup $::CFG->{pickup}"); |
1198 |
} |
1199 |
|
1200 |
sub buildat { |
1201 |
my ($self, $builditem, $x, $y) = @_; |
1202 |
|
1203 |
if ($self->{cfplus_ext}) { |
1204 |
$self->send_ext_msg (builder_build => dx => $x, dy => $y, (ref ($builditem) eq 'HASH') ? %$builditem : (item => $builditem)); |
1205 |
} |
1206 |
} |
1207 |
|
1208 |
sub lookat { |
1209 |
my ($self, $x, $y) = @_; |
1210 |
|
1211 |
if ($self->{cfplus_ext}) { |
1212 |
$self->send_ext_req (lookat => dx => $x, dy => $y, sub { |
1213 |
my ($msg) = @_; |
1214 |
|
1215 |
if (exists $msg->{npc_dialog}) { |
1216 |
# start npc chat dialog |
1217 |
$self->{npc_dialog} = new CFPlus::NPCDialog:: |
1218 |
dx => $x, |
1219 |
dy => $y, |
1220 |
title => "$msg->{npc_dialog} (NPC)", |
1221 |
conn => $self, |
1222 |
; |
1223 |
} |
1224 |
}); |
1225 |
} |
1226 |
|
1227 |
$self->send ("lookat $x $y"); |
1228 |
} |
1229 |
|
1230 |
sub destroy { |
1231 |
my ($self) = @_; |
1232 |
|
1233 |
(delete $self->{npc_dialog})->destroy |
1234 |
if $self->{npc_dialog}; |
1235 |
|
1236 |
$self->SUPER::destroy; |
1237 |
|
1238 |
%$self = (); |
1239 |
} |
1240 |
|
1241 |
package CFPlus::NPCDialog; |
1242 |
|
1243 |
our @ISA = 'CFPlus::UI::Toplevel'; |
1244 |
|
1245 |
sub new { |
1246 |
my $class = shift; |
1247 |
|
1248 |
my $self = $class->SUPER::new ( |
1249 |
x => 'center', |
1250 |
y => 'center', |
1251 |
name => "npc_dialog", |
1252 |
force_w => $::WIDTH * 0.7, |
1253 |
force_h => $::HEIGHT * 0.7, |
1254 |
title => "NPC Dialog", |
1255 |
kw => { hi => 0, yes => 0, no => 0 }, |
1256 |
has_close_button => 1, |
1257 |
@_, |
1258 |
); |
1259 |
|
1260 |
CFPlus::weaken (my $this = $self); |
1261 |
|
1262 |
$self->connect (delete => sub { $this->destroy; 1 }); |
1263 |
|
1264 |
# better use a pane... |
1265 |
$self->add (my $hbox = new CFPlus::UI::HBox); |
1266 |
$hbox->add ($self->{textview} = new CFPlus::UI::TextScroller expand => 1); |
1267 |
|
1268 |
$hbox->add (my $vbox = new CFPlus::UI::VBox); |
1269 |
|
1270 |
$vbox->add (new CFPlus::UI::Label text => "Message Entry:"); |
1271 |
$vbox->add ($self->{entry} = new CFPlus::UI::Entry |
1272 |
tooltip => "#npc_message_entry", |
1273 |
on_activate => sub { |
1274 |
my ($entry, $text) = @_; |
1275 |
|
1276 |
return unless $text =~ /\S/; |
1277 |
|
1278 |
$entry->set_text (""); |
1279 |
$this->send ($text); |
1280 |
|
1281 |
0 |
1282 |
}, |
1283 |
); |
1284 |
|
1285 |
$vbox->add ($self->{options} = new CFPlus::UI::VBox); |
1286 |
|
1287 |
$self->{bye_button} = new CFPlus::UI::Button |
1288 |
text => "Bye (close)", |
1289 |
tooltip => "Use this button to end talking to the NPC. This also closes the dialog window.", |
1290 |
on_activate => sub { $this->destroy; 1 }, |
1291 |
; |
1292 |
|
1293 |
$self->update_options; |
1294 |
|
1295 |
$self->{id} = $self->{conn}->send_ext_req ( |
1296 |
npc_dialog_begin => dx => $self->{dx}, dy => $self->{dy}, |
1297 |
sub { $this && $this->feed (@_) } |
1298 |
); |
1299 |
|
1300 |
$self->{entry}->grab_focus; |
1301 |
|
1302 |
$self->{textview}->add_paragraph ({ |
1303 |
fg => [1, 1, 0, 1], |
1304 |
markup => "<small>[starting conversation with <b>$self->{title}</b>]</small>\n\n", |
1305 |
}); |
1306 |
|
1307 |
$self->show; |
1308 |
$self |
1309 |
}; |
1310 |
|
1311 |
sub update_options { |
1312 |
my ($self) = @_; |
1313 |
|
1314 |
CFPlus::weaken $self; |
1315 |
|
1316 |
$self->{options}->clear; |
1317 |
$self->{options}->add ($self->{bye_button}); |
1318 |
|
1319 |
for my $kw (sort keys %{ $self->{kw} }) { |
1320 |
$self->{options}->add (new CFPlus::UI::Button |
1321 |
text => $kw, |
1322 |
on_activate => sub { |
1323 |
$self->send ($kw); |
1324 |
0 |
1325 |
}, |
1326 |
); |
1327 |
} |
1328 |
} |
1329 |
|
1330 |
sub feed { |
1331 |
my ($self, $msg) = @_; |
1332 |
|
1333 |
CFPlus::weaken $self; |
1334 |
|
1335 |
if ($msg->{msgtype} eq "reply") { |
1336 |
$self->{kw}{$_} = 1 for @{$msg->{add_topics} || []}; |
1337 |
$self->{kw}{$_} = 0 for @{$msg->{del_topics} || []}; |
1338 |
|
1339 |
my $text = "\n" . CFPlus::Protocol::sanitise_xml $msg->{msg}; |
1340 |
my $match = join "|", map "\\b\Q$_\E\\b", sort { (length $b) <=> (length $a) } keys %{ $self->{kw} }; |
1341 |
my @link; |
1342 |
$text =~ s{ |
1343 |
($match) |
1344 |
}{ |
1345 |
my $kw = $1; |
1346 |
|
1347 |
push @link, new CFPlus::UI::Label |
1348 |
markup => "<span foreground='#c0c0ff' underline='single'>$kw</span>", |
1349 |
can_hover => 1, |
1350 |
can_events => 1, |
1351 |
padding_x => 0, |
1352 |
padding_y => 0, |
1353 |
on_button_up => sub { |
1354 |
$self->send ($kw); |
1355 |
}; |
1356 |
|
1357 |
"\x{fffc}" |
1358 |
}giex; |
1359 |
|
1360 |
$self->{textview}->add_paragraph ({ markup => $text, widget => \@link }); |
1361 |
$self->{textview}->scroll_to_bottom; |
1362 |
$self->update_options; |
1363 |
} else { |
1364 |
$self->destroy; |
1365 |
} |
1366 |
|
1367 |
1 |
1368 |
} |
1369 |
|
1370 |
sub send { |
1371 |
my ($self, $msg) = @_; |
1372 |
|
1373 |
$self->{textview}->add_paragraph ({ markup => "\n" . CFPlus::asxml $msg }); |
1374 |
$self->{textview}->scroll_to_bottom; |
1375 |
|
1376 |
$self->{conn}->send_ext_msg (npc_dialog_tell => msgid => $self->{id}, msg => $msg); |
1377 |
} |
1378 |
|
1379 |
sub destroy { |
1380 |
my ($self) = @_; |
1381 |
|
1382 |
#Carp::cluck "debug\n";#d# #todo# enable: destroy gets called twice because scalar keys {} is 1 |
1383 |
|
1384 |
if ($self->{conn}) { |
1385 |
$self->{conn}->send_ext_msg (npc_dialog_end => msgid => $self->{id}) if $self->{id}; |
1386 |
delete $self->{conn}{npc_dialog}; |
1387 |
$self->{conn}->disconnect_ext ($self->{id}); |
1388 |
} |
1389 |
|
1390 |
$self->SUPER::destroy; |
1391 |
} |
1392 |
|
1393 |
1 |
1394 |
|