1 |
package DC::Protocol; |
2 |
|
3 |
use common::sense; |
4 |
|
5 |
use Guard (); |
6 |
|
7 |
use Deliantra::Protocol::Constants; |
8 |
|
9 |
use DC; |
10 |
use DC::DB; |
11 |
use DC::UI; |
12 |
use DC::Macro; |
13 |
use DC::Item; |
14 |
|
15 |
use base 'Deliantra::Protocol::Base'; |
16 |
|
17 |
our $TEX_DIALOGUE = new_from_resource DC::Texture |
18 |
"dialogue.png", minify => 1, mipmap => 1; |
19 |
|
20 |
our $TEX_NOFACE = new_from_resource DC::Texture |
21 |
"noface.png", minify => 1, mipmap => 1, wrap => 1; |
22 |
|
23 |
sub MIN_TEXTURE_UNUSED() { 1 }#d# |
24 |
|
25 |
sub new { |
26 |
my ($class, %arg) = @_; |
27 |
|
28 |
my $self = $class->SUPER::new (%arg, |
29 |
setup_req => { |
30 |
extmap => 1, |
31 |
widget => 2, |
32 |
%{$arg{setup_req} || {}}, |
33 |
}, |
34 |
); |
35 |
|
36 |
$self->update_fx_want; |
37 |
|
38 |
my $exp_guard = $self->addme_guard; |
39 |
my $skl_guard = $self->addme_guard; |
40 |
my $spl_guard = $self->addme_guard; |
41 |
$self->send_exti_req (resource => qw(exp_table skill_info spell_paths), sub { |
42 |
my ($exp, $skl, $spl) = @_; |
43 |
|
44 |
$self->register_face_handler ($exp, sub { |
45 |
my ($face) = @_; |
46 |
|
47 |
undef $exp_guard; |
48 |
$self->{exp_table} = $self->{json_coder}->decode (delete $face->{data}); |
49 |
$_->() for values %{ $self->{on_exp_update} }; |
50 |
}); |
51 |
|
52 |
$self->register_face_handler ($skl, sub { |
53 |
my ($face) = @_; |
54 |
|
55 |
undef $skl_guard; |
56 |
my $info = $self->{json_coder}->decode (delete $face->{data}); |
57 |
$self->{skill_info} = { map { CS_STAT_SKILLINFO + $_ => $info->[$_][0] } 0 .. $#$info }; |
58 |
}); |
59 |
|
60 |
$self->register_face_handler ($spl, sub { |
61 |
my ($face) = @_; |
62 |
|
63 |
undef $spl_guard; |
64 |
my $info = $self->{json_coder}->decode (delete $face->{data}); |
65 |
$self->{spell_paths} = { map { (1 << $_) => $info->[$_][0] } 0 .. $#$info }; |
66 |
}); |
67 |
|
68 |
() |
69 |
}); |
70 |
|
71 |
$::COMPLETER->reset; |
72 |
|
73 |
$self->{json_coder} |
74 |
->convert_blessed |
75 |
->filter_json_single_key_object ("\fw" => sub { |
76 |
$self->{widget}{$_[0]} |
77 |
}) |
78 |
->filter_json_single_key_object ("\fc" => sub { |
79 |
my ($id) = @_; |
80 |
sub { |
81 |
$self->send_exti_msg (w_e => $id, @_); |
82 |
} |
83 |
}); |
84 |
|
85 |
# destroy widgets on logout |
86 |
$self->{on_stop_game_guard} = $self->{map_widget}{root}->connect (stop_game => sub { |
87 |
for my $ws (values %{delete $self->{widgetset} || {}}) { |
88 |
$_->destroy |
89 |
for values %{delete $ws->{w} || {}}; |
90 |
} |
91 |
|
92 |
delete $self->{items}; |
93 |
$::INV->clear; |
94 |
$::INVR->clear; |
95 |
$::INVR_HB->clear; |
96 |
$::FLOORBOX->clear; |
97 |
}); |
98 |
|
99 |
{ |
100 |
$self->{dialogue} = my $tex = $TEX_DIALOGUE; |
101 |
$self->{map}->set_texture (1, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
102 |
} |
103 |
|
104 |
{ |
105 |
$self->{noface} = my $tex = $TEX_NOFACE; |
106 |
$self->{map}->set_texture (2, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
107 |
} |
108 |
|
109 |
# $self->{expire_count} = DC::DB::FIRST_TILE_ID; # minimum non-fixed tile id |
110 |
# $self->{expire_w} = AE::timer 1, 1, sub { |
111 |
# my $count = (int @{ $self->{texture} } / MIN_TEXTURE_UNUSED) || 1; |
112 |
# |
113 |
# for ($self->{map}->expire_textures ($self->{expire_count}, $count)) { |
114 |
# warn DC::SvREFCNT $self->{texture}[$_]; |
115 |
# $self->{texture}[$_]->unload; |
116 |
# warn "expire texture $_\n";#d# |
117 |
# } |
118 |
# |
119 |
# ($self->{expire_count} += $count) < @{ $self->{texture} } |
120 |
# or $self->{expire_count} = DC::DB::FIRST_TILE_ID; |
121 |
# warn "count is $count\n";#d# |
122 |
# }; |
123 |
|
124 |
$self->{open_container} = 0; |
125 |
|
126 |
# per server |
127 |
$self->{mapcache} = "mapcache_$self->{host}_$self->{port}"; |
128 |
|
129 |
$self |
130 |
} |
131 |
|
132 |
#$self->send_exti_req (nickmon => 1, sub { use Data::Dump; ddx \@_ });#d# |
133 |
#sub ext_nicklist { shift; use Data::Dump; ddx \@_; } #d# |
134 |
|
135 |
sub update_fx_want { |
136 |
my ($self) = @_; |
137 |
|
138 |
$self->send_exti_msg (fx_want => { |
139 |
3 => !!$::CFG->{bgm_enable}, # FT_MUSIC |
140 |
5 => !!$::CFG->{audio_enable}, # FT_SOUND |
141 |
6 => 1, # FT_RSRC |
142 |
}); |
143 |
} |
144 |
|
145 |
sub ext_capabilities { |
146 |
my ($self, %cap) = @_; |
147 |
|
148 |
if (my $ts = $cap{tileset}) { |
149 |
if (my ($default) = grep $_->[2] & 1, @$ts) { |
150 |
$self->{tileset} = $default; |
151 |
$self->{tilesize} = $default->[3]; |
152 |
$self->setup_req (tileset => $default->[0]); |
153 |
|
154 |
my $w = int $self->{mapw} * 32 / $self->{tilesize}; |
155 |
my $h = int $self->{maph} * 32 / $self->{tilesize}; |
156 |
|
157 |
$self->setup_req (mapsize => "${w}x${h}"); |
158 |
} |
159 |
} |
160 |
} |
161 |
|
162 |
sub ext_ambient_music { |
163 |
my ($self, $songs) = @_; |
164 |
&::audio_music_set_ambient ($songs); |
165 |
} |
166 |
|
167 |
sub ext_command_list { |
168 |
my ($self, @faces) = @_; |
169 |
|
170 |
my $handler = $self->{command_facehandler} = {}; |
171 |
my $commands = $::COMPLETER->{command_list} = {}; |
172 |
|
173 |
$::COMPLETER->{command_lists} = \@faces; |
174 |
|
175 |
for my $idx (@faces) { |
176 |
$handler->{$idx} = $self->register_face_handler ($idx, sub { |
177 |
my ($face) = @_; |
178 |
|
179 |
$commands->{$idx} = |
180 |
$face->{cache} ||= $self->{json_coder}->decode ($face->{data}); |
181 |
}); |
182 |
} |
183 |
} |
184 |
|
185 |
############################################################################# |
186 |
|
187 |
sub widget_associate { |
188 |
my ($self, $ws, $id, $widget) = @_; |
189 |
|
190 |
$widget ||= new DC::UI::Bin; |
191 |
|
192 |
$widget->{s_id} = $id; |
193 |
$self->{widget}{$id} = $widget; |
194 |
|
195 |
if ($ws) { |
196 |
$widget->{s_ws} = $ws; |
197 |
$self->{widgetset}{$ws}{w}{$id} = $widget; |
198 |
} |
199 |
|
200 |
$widget->connect (on_destroy => sub { |
201 |
my ($widget) = @_; |
202 |
|
203 |
delete $self->{widget}{$widget->{s_id}}; |
204 |
delete $self->{widgetset}{$widget->{s_ws}}{$widget->{s_id}} |
205 |
if exists $widget->{s_ws}; |
206 |
}); |
207 |
} |
208 |
|
209 |
# widgetset new |
210 |
sub ext_ws_n { |
211 |
my ($self, $id) = @_; |
212 |
|
213 |
$self->{widgetset}{$id} = { |
214 |
w => {}, |
215 |
}; |
216 |
} |
217 |
|
218 |
# widgetset destroy |
219 |
sub ext_ws_d { |
220 |
my ($self, $id) = @_; |
221 |
|
222 |
my $ws = delete $self->{widgetset}{$id} |
223 |
or return; |
224 |
|
225 |
$_->destroy |
226 |
for values %{$ws->{w}}; |
227 |
} |
228 |
|
229 |
# widgetset create |
230 |
sub ext_ws_c { |
231 |
my ($self, $ws, $id, $class, $args) = @_; |
232 |
|
233 |
$self->widget_associate ( |
234 |
$ws, $id => scalar eval { |
235 |
local $SIG{__DIE__}; |
236 |
"DC::UI::$class"->new (%$args) |
237 |
} |
238 |
); |
239 |
} |
240 |
|
241 |
# widgetset create template |
242 |
sub ext_ws_ct { |
243 |
my ($self, $ws, $type, $template, $done_cb, $cfg) = @_; |
244 |
|
245 |
$done_cb ||= sub { }; |
246 |
|
247 |
my $parse_list; $parse_list = sub { |
248 |
my ($list) = @_; |
249 |
my @w; |
250 |
|
251 |
while (@$list) { |
252 |
my ($class, $args) = splice @$list, 0, 2; |
253 |
my $name = delete $args->{s_id}; |
254 |
my $cl = delete $args->{s_cl}; |
255 |
my $cfg = delete $cfg->{$name}; |
256 |
my $id = delete $cfg->{id}; |
257 |
my $w = eval { "DC::UI::$class"->new (%$args, %{ $cfg || {} }) } |
258 |
or next; |
259 |
|
260 |
$self->widget_associate ($ws, $id, $w) |
261 |
if $id; |
262 |
|
263 |
$w->add ($parse_list->($cl)) |
264 |
if $cl; |
265 |
|
266 |
push @w, $w; |
267 |
} |
268 |
|
269 |
@w |
270 |
}; |
271 |
|
272 |
# either array reference, or face # |
273 |
if ($type eq "inline") { |
274 |
$done_cb->(); |
275 |
$parse_list->($template); |
276 |
} elsif ($type eq "face") { |
277 |
my $handler; $handler = $self->register_face_handler ($template, sub { |
278 |
my ($face) = @_; |
279 |
|
280 |
undef $handler; |
281 |
$done_cb->(); |
282 |
$parse_list->($self->{json_coder}->decode ($face->{data})); |
283 |
}); |
284 |
} else { |
285 |
$done_cb->(0); |
286 |
} |
287 |
} |
288 |
|
289 |
# widgetset associate |
290 |
sub ext_ws_a { |
291 |
my ($self, %ass) = @_; |
292 |
|
293 |
# everything that has a name, wether conceivably useful or not |
294 |
my %wkw = ( |
295 |
root => $DC::UI::ROOT, |
296 |
tooltip => $DC::UI::TOOLTIP, |
297 |
|
298 |
mapwidget => $::MAPWIDGET, |
299 |
menubar => $::MENUBAR, |
300 |
menupopup => $::MENUPOPUP, |
301 |
pickup_enable => $::PICKUP_ENABLE, |
302 |
buttonbar => $::BUTTONBAR, |
303 |
metaserver => $::METASERVER, |
304 |
buttonbar => $::BUTTONBAR, |
305 |
login_button => $::LOGIN_BUTTON, |
306 |
quit_dialog => $::QUIT_DIALOG, |
307 |
host_entry => $::HOST_ENTRY, |
308 |
metaserver => $::METASERVER, |
309 |
server_info => $::SERVER_INFO, |
310 |
|
311 |
setup_dialog => $::SETUP_DIALOG, |
312 |
setup_notebook => $::SETUP_NOTEBOOK, |
313 |
setup_server => $::SETUP_SERVER, |
314 |
setup_keyboard => $::SETUP_KEYBOARD, |
315 |
|
316 |
pl_notebook => $::PL_NOTEBOOK, |
317 |
pl_window => $::PL_WINDOW, |
318 |
inventory_page => $::INVENTORY_PAGE, |
319 |
stats_page => $::STATS_PAGE, |
320 |
skill_page => $::SKILL_PAGE, |
321 |
spell_page => $::SPELL_PAGE, |
322 |
spell_list => $::SPELL_LIST, |
323 |
|
324 |
floorbox => $::FLOORBOX, |
325 |
help_window => $::HELP_WINDOW, |
326 |
message_window => $::MESSAGE_WINDOW, |
327 |
message_dist => $::MESSAGE_DIST, |
328 |
statusbox => $::STATUSBOX, |
329 |
|
330 |
inv => $::INV, |
331 |
invr => $::INVR, |
332 |
invr_hb => $::INVR_HB, |
333 |
); |
334 |
|
335 |
while (my ($id, $name) = each %ass) { |
336 |
$self->widget_associate (undef, $id => $wkw{$name}); |
337 |
} |
338 |
} |
339 |
|
340 |
# widget call |
341 |
sub ext_w_c { |
342 |
my ($self, $id, $rcb, $method, @args) = @_; |
343 |
|
344 |
my $w = $self->{widget}{$id} |
345 |
or return; |
346 |
|
347 |
if ($rcb) { |
348 |
$rcb->($w->$method (@args)); |
349 |
} else { |
350 |
$w->$method (@args); |
351 |
} |
352 |
} |
353 |
|
354 |
# widget set |
355 |
sub ext_w_s { |
356 |
my ($self, $id, $attr) = @_; |
357 |
|
358 |
my $w = $self->{widget}{$id} |
359 |
or return; |
360 |
|
361 |
for (my $i = 0; $i < $#$attr; $i += 2) { |
362 |
my ($member, $value) = @$attr[$i, $i+1]; |
363 |
if (defined $value) { |
364 |
$w->{$member} = $value; |
365 |
} else { |
366 |
delete $w->{$member}; |
367 |
} |
368 |
$w->{parent}->realloc if $member =~ /^c_/ && $w->{visible}; |
369 |
} |
370 |
} |
371 |
|
372 |
# widget get |
373 |
sub ext_w_g { |
374 |
my ($self, $id, $rid, @attr) = @_; |
375 |
|
376 |
my $w = $self->{widget}{$id} |
377 |
or return; |
378 |
|
379 |
$self->send_exti_msg (w_e => $rid, map $w->{$_}, @attr); |
380 |
} |
381 |
|
382 |
# message window |
383 |
sub ext_channel_info { |
384 |
my ($self, $info) = @_; |
385 |
$self->{channels}->{$info->{id}} = $info; |
386 |
$::MESSAGE_DIST->add_channel ($info); |
387 |
} |
388 |
|
389 |
############################################################################# |
390 |
|
391 |
sub logprint { |
392 |
my ($self, @a) = @_; |
393 |
|
394 |
DC::DB::logprint "$Deliantra::VARDIR/log.$self->{host}" => (join "", @a), sub { }; |
395 |
} |
396 |
|
397 |
sub _stat_numdiff { |
398 |
my ($self, $name, $old, $new) = @_; |
399 |
|
400 |
my $diff = $new - $old; |
401 |
|
402 |
$diff = 0.01 * int $diff * 100; |
403 |
|
404 |
0.1 >= abs $diff ? () |
405 |
: $diff < 0 ? "$name$diff" : "$name+$diff" |
406 |
} |
407 |
|
408 |
sub _stat_skillmaskdiff { |
409 |
my ($self, $name, $old, $new) = @_; |
410 |
|
411 |
my $diff = $old ^ $new |
412 |
or return; |
413 |
|
414 |
my @diff = map |
415 |
{ |
416 |
$diff & $_ |
417 |
? (($new & $_ ? "+" : "-") . $self->{spell_paths}{$_}) |
418 |
: () |
419 |
} |
420 |
sort { $a <=> $b } keys %{$self->{spell_paths}}; |
421 |
|
422 |
"\u$name: " . (join ", ", @diff) |
423 |
} |
424 |
|
425 |
# all stats that are chacked against changes |
426 |
my @statchange = ( |
427 |
[&CS_STAT_STR => \&_stat_numdiff, "Str"], |
428 |
[&CS_STAT_INT => \&_stat_numdiff, "Int"], |
429 |
[&CS_STAT_WIS => \&_stat_numdiff, "Wis"], |
430 |
[&CS_STAT_DEX => \&_stat_numdiff, "Dex"], |
431 |
[&CS_STAT_CON => \&_stat_numdiff, "Con"], |
432 |
[&CS_STAT_CHA => \&_stat_numdiff, "Cha"], |
433 |
[&CS_STAT_POW => \&_stat_numdiff, "Pow"], |
434 |
[&CS_STAT_WC => \&_stat_numdiff, "Wc"], |
435 |
[&CS_STAT_AC => \&_stat_numdiff, "Ac"], |
436 |
[&CS_STAT_DAM => \&_stat_numdiff, "Dam"], |
437 |
[&CS_STAT_SPEED => \&_stat_numdiff, "Speed"], |
438 |
[&CS_STAT_WEAP_SP => \&_stat_numdiff, "WSp"], |
439 |
[&CS_STAT_MAXHP => \&_stat_numdiff, "HP"], |
440 |
[&CS_STAT_MAXSP => \&_stat_numdiff, "Mana"], |
441 |
[&CS_STAT_MAXGRACE => \&_stat_numdiff, "Grace"], |
442 |
[&CS_STAT_WEIGHT_LIM => \&_stat_numdiff, "Weight"], |
443 |
[&CS_STAT_SPELL_ATTUNE => \&_stat_skillmaskdiff, "attuned"], |
444 |
[&CS_STAT_SPELL_REPEL => \&_stat_skillmaskdiff, "repelled"], |
445 |
[&CS_STAT_SPELL_DENY => \&_stat_skillmaskdiff, "denied"], |
446 |
[&CS_STAT_RES_PHYS => \&_stat_numdiff, "phys"], |
447 |
[&CS_STAT_RES_MAG => \&_stat_numdiff, "magic"], |
448 |
[&CS_STAT_RES_FIRE => \&_stat_numdiff, "fire"], |
449 |
[&CS_STAT_RES_ELEC => \&_stat_numdiff, "electricity"], |
450 |
[&CS_STAT_RES_COLD => \&_stat_numdiff, "cold"], |
451 |
[&CS_STAT_RES_CONF => \&_stat_numdiff, "confusion"], |
452 |
[&CS_STAT_RES_ACID => \&_stat_numdiff, "acid"], |
453 |
[&CS_STAT_RES_DRAIN => \&_stat_numdiff, "drain"], |
454 |
[&CS_STAT_RES_GHOSTHIT => \&_stat_numdiff, "ghosthit"], |
455 |
[&CS_STAT_RES_POISON => \&_stat_numdiff, "poison"], |
456 |
[&CS_STAT_RES_SLOW => \&_stat_numdiff, "slow"], |
457 |
[&CS_STAT_RES_PARA => \&_stat_numdiff, "paralyse"], |
458 |
[&CS_STAT_TURN_UNDEAD => \&_stat_numdiff, "turnundead"], |
459 |
[&CS_STAT_RES_FEAR => \&_stat_numdiff, "fear"], |
460 |
[&CS_STAT_RES_DEPLETE => \&_stat_numdiff, "depletion"], |
461 |
[&CS_STAT_RES_DEATH => \&_stat_numdiff, "death"], |
462 |
[&CS_STAT_RES_HOLYWORD => \&_stat_numdiff, "godpower"], |
463 |
[&CS_STAT_RES_BLIND => \&_stat_numdiff, "blind"], |
464 |
); |
465 |
|
466 |
sub stats_update { |
467 |
my ($self, $stats) = @_; |
468 |
|
469 |
my $prev = $self->{prev_stats} || { }; |
470 |
|
471 |
if (my @diffs = |
472 |
( |
473 |
($stats->{+CS_STAT_EXP64} > $prev->{+CS_STAT_EXP64} ? ($stats->{+CS_STAT_EXP64} - $prev->{+CS_STAT_EXP64}) . " experience gained" : ()), |
474 |
map { |
475 |
$stats->{$_} && $prev->{$_} |
476 |
&& $stats->{$_}[1] > $prev->{$_}[1] ? "($self->{skill_info}{$_}+" . ($stats->{$_}[1] - $prev->{$_}[1]) . ")" : () |
477 |
} sort { $a <=> $b } keys %{$self->{skill_info}} |
478 |
) |
479 |
) { |
480 |
my $msg = join " ", @diffs; |
481 |
$self->{statusbox}->add ($msg, group => "experience $msg", fg => [0.5, 1, 0.5, 0.8], timeout => 5); |
482 |
} |
483 |
|
484 |
if ( |
485 |
my @diffs = map $_->[1]->($self, $_->[2], $prev->{$_->[0]}, $stats->{$_->[0]}), @statchange |
486 |
) { |
487 |
my $msg = "<b>stat change</b>: " . (join " ", map "($_)", @diffs); |
488 |
$self->{statusbox}->add ($msg, group => "stat $msg", fg => [0.8, 1, 0.2, 1], timeout => 20); |
489 |
} |
490 |
|
491 |
$self->update_stats_window ($stats, $prev); |
492 |
|
493 |
$self->{prev_stats} = { %$stats }; |
494 |
} |
495 |
|
496 |
my %RES_TBL = ( |
497 |
phys => CS_STAT_RES_PHYS, |
498 |
magic => CS_STAT_RES_MAG, |
499 |
fire => CS_STAT_RES_FIRE, |
500 |
elec => CS_STAT_RES_ELEC, |
501 |
cold => CS_STAT_RES_COLD, |
502 |
conf => CS_STAT_RES_CONF, |
503 |
acid => CS_STAT_RES_ACID, |
504 |
drain => CS_STAT_RES_DRAIN, |
505 |
ghit => CS_STAT_RES_GHOSTHIT, |
506 |
pois => CS_STAT_RES_POISON, |
507 |
slow => CS_STAT_RES_SLOW, |
508 |
para => CS_STAT_RES_PARA, |
509 |
tund => CS_STAT_TURN_UNDEAD, |
510 |
fear => CS_STAT_RES_FEAR, |
511 |
depl => CS_STAT_RES_DEPLETE, |
512 |
deat => CS_STAT_RES_DEATH, |
513 |
holyw => CS_STAT_RES_HOLYWORD, |
514 |
blind => CS_STAT_RES_BLIND, |
515 |
); |
516 |
|
517 |
sub update_stats_window { |
518 |
my ($self, $stats, $prev) = @_; |
519 |
|
520 |
# I love text protocols... |
521 |
|
522 |
my $hp = $stats->{+CS_STAT_HP} * 1; |
523 |
my $hp_m = $stats->{+CS_STAT_MAXHP} * 1; |
524 |
my $sp = $stats->{+CS_STAT_SP} * 1; |
525 |
my $sp_m = $stats->{+CS_STAT_MAXSP} * 1; |
526 |
my $fo = $stats->{+CS_STAT_FOOD} * 1; |
527 |
my $fo_m = 999; |
528 |
my $gr = $stats->{+CS_STAT_GRACE} * 1; |
529 |
my $gr_m = $stats->{+CS_STAT_MAXGRACE} * 1; |
530 |
|
531 |
$::GAUGES->{hp} ->set_value ($hp, $hp_m); |
532 |
$::GAUGES->{mana} ->set_value ($sp, $sp_m); |
533 |
$::GAUGES->{food} ->set_value ($fo, $fo_m); |
534 |
$::GAUGES->{grace} ->set_value ($gr, $gr_m); |
535 |
$::GAUGES->{exp} ->set_label ("Exp: " . (::formsep ($stats->{+CS_STAT_EXP64}))#d# |
536 |
. " (lvl " . ($stats->{+CS_STAT_LEVEL} * 1) . ")"); |
537 |
$::GAUGES->{exp} ->set_value ($stats->{+CS_STAT_LEVEL}, $stats->{+CS_STAT_EXP64}); |
538 |
$::GAUGES->{range} ->set_text ($stats->{+CS_STAT_RANGE}); |
539 |
my $title = $stats->{+CS_STAT_TITLE}; |
540 |
$title =~ s/^Player: //; |
541 |
$::STATWIDS->{title} ->set_text ("Title: " . $title); |
542 |
|
543 |
$::STATWIDS->{st_str} ->set_text (sprintf "%d" , $stats->{+CS_STAT_STR}); |
544 |
$::STATWIDS->{st_dex} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DEX}); |
545 |
$::STATWIDS->{st_con} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CON}); |
546 |
$::STATWIDS->{st_int} ->set_text (sprintf "%d" , $stats->{+CS_STAT_INT}); |
547 |
$::STATWIDS->{st_wis} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WIS}); |
548 |
$::STATWIDS->{st_pow} ->set_text (sprintf "%d" , $stats->{+CS_STAT_POW}); |
549 |
$::STATWIDS->{st_cha} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CHA}); |
550 |
$::STATWIDS->{st_wc} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WC}); |
551 |
$::STATWIDS->{st_ac} ->set_text (sprintf "%d" , $stats->{+CS_STAT_AC}); |
552 |
$::STATWIDS->{st_dam} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DAM}); |
553 |
$::STATWIDS->{st_arm} ->set_text (sprintf "%d" , $stats->{+CS_STAT_RES_PHYS}); |
554 |
$::STATWIDS->{st_spd} ->set_text (sprintf "%.1f", $stats->{+CS_STAT_SPEED}); |
555 |
$::STATWIDS->{st_wspd}->set_text (sprintf "%.1f", $stats->{+CS_STAT_WEAP_SP}); |
556 |
|
557 |
$self->update_weight; |
558 |
|
559 |
$::STATWIDS->{"res_$_"}->set_text (sprintf "%d%%", $stats->{$RES_TBL{$_}}) |
560 |
for keys %RES_TBL; |
561 |
|
562 |
my $sktbl = $::STATWIDS->{skill_tbl}; |
563 |
my @skills = keys %{ $self->{skill_info} }; |
564 |
|
565 |
my @order = sort { $stats->{$b->[0]}[1] <=> $stats->{$a->[0]}[1] or $a->[1] cmp $b->[1] } |
566 |
map [$_, $self->{skill_info}{$_}], |
567 |
grep exists $stats->{$_}, |
568 |
@skills; |
569 |
|
570 |
if ($self->{stat_order} ne join ",", map $_->[0], @order) { |
571 |
$self->{stat_order} = join ",", map $_->[0], @order; |
572 |
|
573 |
$sktbl->clear; |
574 |
|
575 |
my $sw = $self->{skillwid}{""} ||= [ |
576 |
0, 0, (new DC::UI::Label text => "Experience", align => 1), |
577 |
1, 0, (new DC::UI::Label text => "Lvl.", align => 1), |
578 |
2, 0, (new DC::UI::Label text => "Progress"), |
579 |
3, 0, (new DC::UI::Label text => "Skill", expand => 1, align => 0), |
580 |
4, 0, (new DC::UI::Label text => "Experience", align => 1), |
581 |
5, 0, (new DC::UI::Label text => "Lvl.", align => 1), |
582 |
6, 0, (new DC::UI::Label text => "Progress"), |
583 |
7, 0, (new DC::UI::Label text => "Skill", expand => 1, align => 0), |
584 |
]; |
585 |
|
586 |
my @add = @$sw; |
587 |
|
588 |
my $TOOLTIP_ALL = "\n\n<small>Left click - ready skill\nMiddle click - use skill\nRight click - further options</small>"; |
589 |
|
590 |
my @TOOLTIP_LVL = (tooltip => "<b>Level</b>. The level of the skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
591 |
my @TOOLTIP_EXP = (tooltip => "<b>Experience</b>. The experience points you have in this skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
592 |
|
593 |
my ($x, $y) = (0, 1); |
594 |
for (@order) { |
595 |
my ($idx, $name) = @$_; |
596 |
|
597 |
my $spell_cb = sub { |
598 |
my ($widget, $ev) = @_; |
599 |
|
600 |
if ($ev->{button} == 1) { |
601 |
$::CONN->user_send ("ready_skill $name"); |
602 |
} elsif ($ev->{button} == 2) { |
603 |
$::CONN->user_send ("use_skill $name"); |
604 |
} elsif ($ev->{button} == 3) { |
605 |
my $shortname = DC::shorten $name, 14; |
606 |
(new DC::UI::Menu |
607 |
items => [ |
608 |
["bind <i>ready_skill $shortname</i> to a key" => sub { DC::Macro::quick_macro ["ready_skill $name"] }], |
609 |
["bind <i>use_skill $shortname</i> to a key" => sub { DC::Macro::quick_macro ["use_skill $name"] }], |
610 |
], |
611 |
)->popup ($ev); |
612 |
} else { |
613 |
return 0; |
614 |
} |
615 |
|
616 |
1 |
617 |
}; |
618 |
|
619 |
my $sw = $self->{skillwid}{$idx} ||= [ |
620 |
# exp |
621 |
(new DC::UI::Label |
622 |
align => 1, font => $::FONT_FIXED, fg => [1, 1, 0], on_button_down => $spell_cb, @TOOLTIP_EXP), |
623 |
|
624 |
# level |
625 |
(new DC::UI::Label |
626 |
text => "0", align => 1, font => $::FONT_FIXED, fg => [0, 1, 0], padding_x => 4, on_button_down => $spell_cb, @TOOLTIP_LVL), |
627 |
|
628 |
# progress |
629 |
(new DC::UI::ExperienceProgress), |
630 |
|
631 |
# label |
632 |
(new DC::UI::Label text => $name, on_button_down => $spell_cb, align => 0, |
633 |
can_events => 1, can_hover => 1, tooltip => "#(skill/$name)$TOOLTIP_ALL"), |
634 |
]; |
635 |
|
636 |
push @add, |
637 |
$x * 4 + 0, $y, $sw->[0], |
638 |
$x * 4 + 1, $y, $sw->[1], |
639 |
$x * 4 + 2, $y, $sw->[2], |
640 |
$x * 4 + 3, $y, $sw->[3], |
641 |
; |
642 |
|
643 |
$x++ and ($x, $y) = (0, $y + 1); |
644 |
} |
645 |
|
646 |
$sktbl->add_at (@add); |
647 |
} |
648 |
|
649 |
for (@order) { |
650 |
my ($idx, $name) = @$_; |
651 |
my $val = $stats->{$idx}; |
652 |
|
653 |
next if $prev->{$idx}[1] eq $val->[1]; |
654 |
|
655 |
my $sw = $self->{skillwid}{$idx}; |
656 |
$sw->[0]->set_text (::formsep ($val->[1])); |
657 |
$sw->[1]->set_text ($val->[0] * 1); |
658 |
$sw->[2]->set_value (@$val); |
659 |
|
660 |
$::GAUGES->{skillexp}->set_label ("$name %d%%"); |
661 |
$::GAUGES->{skillexp}->set_value (@$val); |
662 |
} |
663 |
} |
664 |
|
665 |
sub user_send { |
666 |
my ($self, $command) = @_; |
667 |
|
668 |
$self->{record}->($command) |
669 |
if $self->{record}; |
670 |
|
671 |
$self->logprint ("send: ", $command); |
672 |
$self->send_command ($command); |
673 |
} |
674 |
|
675 |
sub record { |
676 |
my ($self, $cb) = @_; |
677 |
|
678 |
$self->{record} = $cb; |
679 |
} |
680 |
|
681 |
sub map_scroll { |
682 |
my ($self, $dx, $dy) = @_; |
683 |
|
684 |
$self->{map_widget}->scroll ($dx, $dy); |
685 |
} |
686 |
|
687 |
sub feed_map1a { |
688 |
my ($self, $data) = @_; |
689 |
|
690 |
my $missing = $self->{map}->map1a_update ($data); |
691 |
my $delay; |
692 |
|
693 |
for my $tile (@$missing) { |
694 |
next if $self->{delay}{$tile}; |
695 |
|
696 |
$delay = 1; |
697 |
|
698 |
if (my $tex = $self->{texture}[$tile]) { |
699 |
$tex->upload; |
700 |
} else { |
701 |
$self->{delay}{$tile} = 1; |
702 |
|
703 |
# we assume the face is in-flight and will eventually arrive |
704 |
push @{$self->{tile_cb}{$tile}}, sub { |
705 |
delete $self->{delay}{$tile}; |
706 |
$_[0]->upload; |
707 |
}; |
708 |
} |
709 |
} |
710 |
|
711 |
if ($delay) { |
712 |
# delay the map drawing a tiny bit in the hope of getting the missing tiles fetched |
713 |
EV::once undef, 0, 0.03, sub { |
714 |
$self->{map_widget}->update |
715 |
if $self->{map_widget}; |
716 |
}; |
717 |
} else { |
718 |
$self->{map_widget}->update; |
719 |
} |
720 |
} |
721 |
|
722 |
sub magicmap { |
723 |
my ($self, $w, $h, $x, $y, $data) = @_; |
724 |
|
725 |
$self->{map_widget}->set_magicmap ($w, $h, $x, $y, $data); |
726 |
} |
727 |
|
728 |
sub flush_map { |
729 |
my ($self) = @_; |
730 |
|
731 |
return unless $self->{map_info}; |
732 |
|
733 |
for my $map_info (values %{ $self->{map_cache} || {} }) { |
734 |
my ($hash, $rdata, $x, $y, $w, $h) = @$map_info; |
735 |
|
736 |
my $data = $self->{map}->get_rect ($x, $y, $w, $h); |
737 |
|
738 |
if ($data ne $$rdata) { |
739 |
$map_info->[1] = \$data; |
740 |
my $cdata = Compress::LZF::compress $data; |
741 |
DC::DB::put $self->{mapcache} => $hash => $cdata, sub { }; |
742 |
} |
743 |
} |
744 |
} |
745 |
|
746 |
sub map_clear { |
747 |
my ($self) = @_; |
748 |
|
749 |
$self->flush_map; |
750 |
delete $self->{map_info}; |
751 |
delete $self->{neigh_map}; |
752 |
|
753 |
$self->{map}->clear; |
754 |
delete $self->{map_widget}{magicmap}; |
755 |
} |
756 |
|
757 |
sub bg_fetch { |
758 |
my ($self) = @_; |
759 |
|
760 |
my $tile; |
761 |
|
762 |
do { |
763 |
$tile = pop @{$self->{bg_fetch}} |
764 |
or return; |
765 |
} while $self->{texture}[$tile]; |
766 |
|
767 |
DC::DB::get tilecache => $tile, sub { |
768 |
my ($data) = @_; |
769 |
|
770 |
return unless $self->{map}; # stop when destroyed |
771 |
|
772 |
if (defined $data) { |
773 |
$self->have_tile ($tile, $data); |
774 |
$self->{texture}[$tile]->upload; |
775 |
} |
776 |
|
777 |
$self->bg_fetch; |
778 |
}; |
779 |
} |
780 |
|
781 |
sub load_map($$$$$$) { |
782 |
my ($self, $hash, $x, $y, $w, $h) = @_; |
783 |
|
784 |
my $map_info = $self->{map_cache}{$hash} = [$hash, \"", $x, $y, $w, $h]; |
785 |
|
786 |
my $cb = sub { |
787 |
$map_info->[1] = \$_[0]; |
788 |
|
789 |
my $inprogress = @{ $self->{bg_fetch} || [] }; |
790 |
unshift @{ $self->{bg_fetch} }, $self->{map}->set_rect ($x, $y, $_[0]); |
791 |
$self->bg_fetch unless $inprogress; |
792 |
}; |
793 |
|
794 |
if (my $map_info = $self->{map_cache_old}{$hash}) { |
795 |
$cb->(${ $map_info->[1] }); |
796 |
} else { |
797 |
my $gen = $self->{map_change_gen}; |
798 |
|
799 |
DC::DB::get $self->{mapcache} => $hash, sub { |
800 |
return unless $gen == $self->{map_change_gen}; |
801 |
return unless defined $_[0]; |
802 |
$cb->(Compress::LZF::decompress $_[0]); |
803 |
}; |
804 |
} |
805 |
} |
806 |
|
807 |
# hardcode /world/world_xxx_xxx map names, the savings are enourmous, |
808 |
# (server resources, latency, bandwidth), so this hack is warranted. |
809 |
# the right fix is to make real tiled maps with an overview file |
810 |
sub send_mapinfo { |
811 |
my ($self, $data, $cb) = @_; |
812 |
|
813 |
if ($self->{map_info}[0] =~ m%^/world/world_(\d\d\d)_(\d\d\d)$%) { |
814 |
my ($wx, $wy) = ($1, $2); |
815 |
|
816 |
if ($data =~ /^spatial ([1-4]+)$/) { |
817 |
my @dx = (0, 0, 1, 0, -1); |
818 |
my @dy = (0, -1, 0, 1, 0); |
819 |
my ($dx, $dy); |
820 |
|
821 |
for (split //, $1) { |
822 |
$dx += $dx[$_]; |
823 |
$dy += $dy[$_]; |
824 |
} |
825 |
|
826 |
$cb->(spatial => 15, |
827 |
$self->{map_info}[1] - $self->{map}->ox + $dx * 50, |
828 |
$self->{map_info}[2] - $self->{map}->oy + $dy * 50, |
829 |
50, 50, |
830 |
sprintf "/world/world_%03d_%03d", $wx + $dx, $wy + $dy |
831 |
); |
832 |
|
833 |
return; |
834 |
} |
835 |
} |
836 |
|
837 |
$self->SUPER::send_mapinfo ($data, $cb); |
838 |
} |
839 |
|
840 |
# this method does a "flood fill" into every tile direction |
841 |
# it assumes that tiles are arranged in a rectangular grid, |
842 |
# i.e. a map is the same as the left of the right map etc. |
843 |
# failure to comply is harmless and results in display errors |
844 |
# at worst. |
845 |
sub flood_fill { |
846 |
my ($self, $block, $gx, $gy, $path, $hash, $flags) = @_; |
847 |
|
848 |
# the server does not allow map paths > 6 |
849 |
return if 7 <= length $path; |
850 |
|
851 |
my ($x0, $y0, $x1, $y1) = @{$self->{neigh_rect}}; |
852 |
|
853 |
for ( |
854 |
[1, 3, 0, -1], |
855 |
[2, 4, 1, 0], |
856 |
[3, 1, 0, 1], |
857 |
[4, 2, -1, 0], |
858 |
) { |
859 |
my ($tile, $tile2, $dx, $dy) = @$_; |
860 |
|
861 |
next if $block & (1 << $tile); |
862 |
my $block = $block | (1 << $tile2); |
863 |
|
864 |
my $gx = $gx + $dx; |
865 |
my $gy = $gy + $dy; |
866 |
|
867 |
next unless $flags & (1 << ($tile - 1)); |
868 |
next if $self->{neigh_grid}{$gx, $gy}++; |
869 |
|
870 |
my $neigh = $self->{neigh_map}{$hash} ||= []; |
871 |
if (my $info = $neigh->[$tile]) { |
872 |
my ($flags, $x, $y, $w, $h, $hash) = @$info; |
873 |
|
874 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
875 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
876 |
|
877 |
} else { |
878 |
my $gen = $self->{map_change_gen}; |
879 |
$self->send_mapinfo ("spatial $path$tile", sub { |
880 |
return unless $gen == $self->{map_change_gen}; |
881 |
|
882 |
my ($mode, $flags, $x, $y, $w, $h, $hash) = @_; |
883 |
|
884 |
return if $mode ne "spatial"; |
885 |
|
886 |
$x += $self->{map}->ox; |
887 |
$y += $self->{map}->oy; |
888 |
|
889 |
$self->load_map ($hash, $x, $y, $w, $h) |
890 |
unless $self->{neigh_map}{$hash}[5]++;#d# |
891 |
|
892 |
$neigh->[$tile] = [$flags, $x, $y, $w, $h, $hash]; |
893 |
|
894 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
895 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
896 |
}); |
897 |
} |
898 |
} |
899 |
} |
900 |
|
901 |
sub map_change { |
902 |
my ($self, $mode, $flags, $x, $y, $w, $h, $hash) = @_; |
903 |
|
904 |
$self->flush_map; |
905 |
|
906 |
++$self->{map_change_gen}; |
907 |
$self->{map_cache_old} = delete $self->{map_cache}; |
908 |
|
909 |
my ($ox, $oy) = ($::MAP->ox, $::MAP->oy); |
910 |
|
911 |
my $mapmapw = $self->{mapmap}->{w}; |
912 |
my $mapmaph = $self->{mapmap}->{h}; |
913 |
|
914 |
$self->{neigh_rect} = [ |
915 |
$ox - $mapmapw * 0.5, $oy - $mapmapw * 0.5, |
916 |
$ox + $mapmapw * 0.5 + $w, $oy + $mapmapw * 0.5 + $h, |
917 |
]; |
918 |
|
919 |
delete $self->{neigh_grid}; |
920 |
|
921 |
$x += $ox; |
922 |
$y += $oy; |
923 |
|
924 |
$self->{map_info} = [$hash, $x, $y, $w, $h]; |
925 |
|
926 |
(my $map = $hash) =~ s/^.*?\/([^\/]+)$/\1/; |
927 |
$::STATWIDS->{map}->set_text ("Map: " . $map); |
928 |
|
929 |
$self->load_map ($hash, $x, $y, $w, $h); |
930 |
$self->flood_fill (0, 0, 0, "", $hash, $flags); |
931 |
} |
932 |
|
933 |
sub face_find { |
934 |
my ($self, $facenum, $face, $cb) = @_; |
935 |
|
936 |
if ($face->{type} == 0) { # FT_FACE |
937 |
my $id = DC::DB::get_tile_id_sync $face->{name}; |
938 |
|
939 |
$face->{id} = $id; |
940 |
$self->{map}->set_tileid ($facenum => $id); |
941 |
|
942 |
DC::DB::get tilecache => $id, $cb; |
943 |
|
944 |
} elsif ($face->{type} & 1) { # with metadata |
945 |
DC::DB::get res_meta => $face->{name}, $cb; |
946 |
|
947 |
} else { # no metadata |
948 |
DC::DB::get res_data => $face->{name}, $cb; |
949 |
} |
950 |
} |
951 |
|
952 |
sub face_update { |
953 |
my ($self, $facenum, $face, $changed) = @_; |
954 |
|
955 |
if ($face->{type} == 0) { |
956 |
# image, FT_FACE |
957 |
DC::DB::put tilecache => $face->{id} => $face->{data}, sub { } |
958 |
if $changed; |
959 |
|
960 |
$self->have_tile ($face->{id}, delete $face->{data}); |
961 |
|
962 |
} elsif ($face->{type} & 1) { |
963 |
# split metadata case, FT_MUSIC, FT_SOUND |
964 |
if ($changed) { # new data |
965 |
my ($meta, $data) = unpack "(w/a*)*", $face->{data}; |
966 |
$face->{data} = $meta; |
967 |
|
968 |
# rely on strict ordering here and also on later fetch |
969 |
DC::DB::put res_data => $face->{name} => $data, sub { }; |
970 |
DC::DB::put res_meta => $face->{name} => $meta, sub { }; |
971 |
} |
972 |
|
973 |
$face->{data} = $self->{json_coder}->decode ($face->{data}); |
974 |
::add_license ($face); |
975 |
::message ({ markup => DC::asxml "downloaded resource '$face->{data}{name}', type $face->{type}." }) |
976 |
if $changed; |
977 |
|
978 |
if ($face->{type} == 3) { # FT_MUSIC |
979 |
&::audio_music_push ($facenum); |
980 |
} elsif ($face->{type} == 5) { # FT_SOUND |
981 |
&::audio_sound_push ($facenum); |
982 |
} |
983 |
|
984 |
} else { |
985 |
# flat resource case, FT_RSRC |
986 |
DC::DB::put res_data => $face->{name} => $face->{data}, sub { } |
987 |
if $changed; |
988 |
} |
989 |
|
990 |
if (my $cbs = $self->{face_cb}{$facenum}) { |
991 |
$_->($face, $changed) for @$cbs; |
992 |
} |
993 |
} |
994 |
|
995 |
sub smooth_update { |
996 |
my ($self, $facenum, $face) = @_; |
997 |
|
998 |
$self->{map}->set_smooth ($facenum, $face->{smoothface}, $face->{smoothlevel}); |
999 |
} |
1000 |
|
1001 |
sub have_tile { |
1002 |
my ($self, $tile, $data) = @_; |
1003 |
|
1004 |
return unless $self->{map}; |
1005 |
|
1006 |
my $tex = $self->{texture}[$tile] ||= |
1007 |
new DC::Texture |
1008 |
tile => $tile, |
1009 |
image => $data, delete_image => 1, |
1010 |
minify => 1; |
1011 |
|
1012 |
if (my $cbs = delete $self->{tile_cb}{$tile}) { |
1013 |
$_->($tex) for @$cbs; |
1014 |
} |
1015 |
} |
1016 |
|
1017 |
# call in non-void context registers a temporary |
1018 |
# hook with handle, otherwise its permanent |
1019 |
sub on_face_change { |
1020 |
my ($self, $num, $cb) = @_; |
1021 |
|
1022 |
push @{$self->{face_cb}{$num}}, $cb; |
1023 |
|
1024 |
defined wantarray |
1025 |
? Guard::guard { |
1026 |
@{$self->{face_cb}{$num}} |
1027 |
= grep $_ != $cb, |
1028 |
@{$self->{face_cb}{$num}}; |
1029 |
} |
1030 |
: () |
1031 |
} |
1032 |
|
1033 |
# call in non-void context registers a temporary |
1034 |
# hook with handle, otherwise its permanent |
1035 |
sub register_face_handler { |
1036 |
my ($self, $num, $cb) = @_; |
1037 |
|
1038 |
return unless $num; |
1039 |
|
1040 |
# invoke if available right now |
1041 |
$cb->($self->{face}[$num], 0) |
1042 |
unless exists $self->{face}[$num]{loading}; |
1043 |
|
1044 |
# future changes |
1045 |
$self->on_face_change ($num => $cb) |
1046 |
} |
1047 |
|
1048 |
sub sound_play { |
1049 |
my ($self, $type, $face, $dx, $dy, $vol) = @_; |
1050 |
|
1051 |
&::audio_sound_play ($face, $dx, $dy, $vol) |
1052 |
unless $type & 1; # odd types are silent for future expansion |
1053 |
} |
1054 |
|
1055 |
my $LAST_QUERY; # server is stupid, stupid, stupid |
1056 |
|
1057 |
sub query { |
1058 |
my ($self, $flags, $prompt) = @_; |
1059 |
|
1060 |
$prompt = $LAST_QUERY unless length $prompt; |
1061 |
$LAST_QUERY = $prompt; |
1062 |
|
1063 |
$self->{query}->($self, $flags, $prompt); |
1064 |
} |
1065 |
|
1066 |
our %NAME_TO_COLOR = ( |
1067 |
black => 0, |
1068 |
white => 1, |
1069 |
darkblue => 2, |
1070 |
red => 3, |
1071 |
orange => 4, |
1072 |
lightblue => 5, |
1073 |
darkorange => 6, |
1074 |
green => 7, |
1075 |
darkgreen => 8, |
1076 |
grey => 9, |
1077 |
brown => 10, |
1078 |
yellow => 11, |
1079 |
tan => 12, |
1080 |
); |
1081 |
|
1082 |
our @CF_COLOR = ( |
1083 |
[1.00, 1.00, 1.00], #[0.00, 0.00, 0.00], |
1084 |
[1.00, 1.00, 1.00], #[0.00, 0.00, 0.00], |
1085 |
[0.50, 0.50, 1.00], #[0.00, 0.00, 0.55], |
1086 |
[1.00, 0.00, 0.00], |
1087 |
[1.00, 0.54, 0.00], |
1088 |
[0.11, 0.56, 1.00], |
1089 |
[0.93, 0.46, 0.00], |
1090 |
[0.18, 0.54, 0.34], |
1091 |
[0.56, 0.73, 0.56], |
1092 |
[0.80, 0.80, 0.80], |
1093 |
[0.75, 0.61, 0.20], |
1094 |
[0.99, 0.77, 0.26], |
1095 |
[0.74, 0.65, 0.41], |
1096 |
); |
1097 |
|
1098 |
sub msg { |
1099 |
my ($self, $color, $type, $text, @extra) = @_; |
1100 |
|
1101 |
$text = DC::sanitise_cfxml $text; |
1102 |
|
1103 |
if (my $cb = $self->{cb_msg}{$type}) { |
1104 |
$_->($self, $color, $type, $text, @extra) for values %$cb; |
1105 |
} elsif ($type =~ /^(?:chargen-race-title|chargen-race-description)$/) { |
1106 |
$type =~ s/-/_/g; |
1107 |
$self->{$type} = $text; |
1108 |
} else { |
1109 |
$self->logprint ("msg: ", $text); |
1110 |
return if $color < 0; # negative color == ignore if not understood |
1111 |
|
1112 |
my $fg = $CF_COLOR[$color & NDI_COLOR_MASK] || [1, 0, 0]; |
1113 |
|
1114 |
::message ({ |
1115 |
fg => $fg, |
1116 |
markup => $text, |
1117 |
type => $type, |
1118 |
extra => [@extra], |
1119 |
color_flags => $color, #d# ugly, kill |
1120 |
}); |
1121 |
|
1122 |
# $color &= ~NDI_CLEAR; # only clear once for multiline messages |
1123 |
# # actually, this is an ugly design. _we_ should control the channels, |
1124 |
# # not some random other widget, as the channels are clearly protocol-specific. |
1125 |
# # then we could also react to flags such as CLEAR without resorting to |
1126 |
# # hacks such as color_flags, above. |
1127 |
|
1128 |
$self->{statusbox}->add ($text, |
1129 |
group => $text, |
1130 |
fg => $fg, |
1131 |
timeout => $color >= 2 ? 180 : 10, |
1132 |
tooltip_font => $::FONT_FIXED, |
1133 |
) if $type eq "info"; |
1134 |
} |
1135 |
} |
1136 |
|
1137 |
sub spell_add { |
1138 |
my ($self, $spell) = @_; |
1139 |
|
1140 |
$::SPELL_LIST->add_spell ($spell); |
1141 |
delete $::COMPLETER->{command_list}{spells}; |
1142 |
} |
1143 |
|
1144 |
sub spell_delete { |
1145 |
my ($self, $spell) = @_; |
1146 |
|
1147 |
$::SPELL_LIST->remove_spell ($spell); |
1148 |
delete $::COMPLETER->{command_list}{spells}; |
1149 |
} |
1150 |
|
1151 |
sub setup { |
1152 |
my ($self, $setup) = @_; |
1153 |
|
1154 |
$self->{map_widget}->set_tilesize ($self->{tilesize}); |
1155 |
$::MAP->resize ($self->{mapw}, $self->{maph}); |
1156 |
} |
1157 |
|
1158 |
sub eof { |
1159 |
my ($self) = @_; |
1160 |
|
1161 |
$::COMPLETER->reset; |
1162 |
|
1163 |
::stop_game (); |
1164 |
} |
1165 |
|
1166 |
sub update_floorbox { |
1167 |
$DC::UI::ROOT->on_refresh ($::FLOORBOX => sub { |
1168 |
return unless $::CONN; |
1169 |
|
1170 |
$::FLOORBOX->clear; |
1171 |
|
1172 |
my @add; |
1173 |
|
1174 |
my $row; |
1175 |
for (sort { $b->{count} <=> $a->{count} } values %{ $::CONN->{container}{$::CONN->{open_container} || 0} }) { |
1176 |
next if $_->{tag} & 0x80000000; |
1177 |
if ($row < 6) { |
1178 |
local $_->{face_widget}; # hack to force recreation of widget |
1179 |
local $_->{desc_widget}; # hack to force recreation of widget |
1180 |
DC::Item::update_widgets $_; |
1181 |
|
1182 |
push @add, |
1183 |
0, $row, $_->{face_widget}, |
1184 |
1, $row, $_->{desc_widget}; |
1185 |
|
1186 |
$row++; |
1187 |
} else { |
1188 |
push @add, 1, $row, new DC::UI::Button |
1189 |
text => "More...", |
1190 |
on_activate => sub { ::toggle_player_page ($::INVENTORY_PAGE); 0 }, |
1191 |
; |
1192 |
last; |
1193 |
} |
1194 |
} |
1195 |
if ($::CONN->{open_container}) { |
1196 |
push @add, 1, $row++, new DC::UI::Button |
1197 |
text => "Close container", |
1198 |
on_activate => sub { $::CONN->send ("apply $::CONN->{open_container}") } |
1199 |
; |
1200 |
} |
1201 |
|
1202 |
$::FLOORBOX->add_at (@add); |
1203 |
}); |
1204 |
|
1205 |
$::WANT_REFRESH = 1; |
1206 |
} |
1207 |
|
1208 |
sub set_opencont { |
1209 |
my ($conn, $tag, $name) = @_; |
1210 |
$conn->{open_container} = $tag; |
1211 |
update_floorbox; |
1212 |
|
1213 |
$::INVR_HB->clear; |
1214 |
$::INVR_HB->add (new DC::UI::Label expand => 1, text => $name); |
1215 |
|
1216 |
if ($tag != 0) { # Floor isn't closable, is it? |
1217 |
$::INVR_HB->add (new DC::UI::Button |
1218 |
text => "Close container", |
1219 |
tooltip => "Close the currently open container (if one is open)", |
1220 |
on_activate => sub { |
1221 |
$::CONN->send ("apply $tag") # $::CONN->{open_container}") |
1222 |
if $tag != 0; |
1223 |
0 |
1224 |
}, |
1225 |
); |
1226 |
} |
1227 |
|
1228 |
$::INVR->set_items ($conn->{container}{$tag}); |
1229 |
} |
1230 |
|
1231 |
sub update_containers { |
1232 |
my ($self) = @_; |
1233 |
|
1234 |
$DC::UI::ROOT->on_refresh ("update_containers_$self" => sub { |
1235 |
my $todo = delete $self->{update_container} |
1236 |
or return; |
1237 |
|
1238 |
for my $tag (keys %$todo) { |
1239 |
update_floorbox if $tag == 0 or $tag == $self->{open_container}; |
1240 |
if ($tag == 0) { |
1241 |
$::INVR->set_items ($self->{container}{0}) |
1242 |
if $tag == $self->{open_container}; |
1243 |
} elsif ($tag == $self->{player}{tag}) { |
1244 |
$::INV->set_items ($self->{container}{$tag}) |
1245 |
} else { |
1246 |
$::INVR->set_items ($self->{container}{$tag}) |
1247 |
if $tag == $self->{open_container}; |
1248 |
} |
1249 |
} |
1250 |
}); |
1251 |
} |
1252 |
|
1253 |
sub container_add { |
1254 |
my ($self, $tag, $items) = @_; |
1255 |
|
1256 |
$self->{update_container}{$tag}++; |
1257 |
$self->update_containers; |
1258 |
} |
1259 |
|
1260 |
sub container_clear { |
1261 |
my ($self, $tag) = @_; |
1262 |
|
1263 |
$self->{update_container}{$tag}++; |
1264 |
$self->update_containers; |
1265 |
} |
1266 |
|
1267 |
sub item_delete { |
1268 |
my ($self, @items) = @_; |
1269 |
|
1270 |
$self->{update_container}{$_->{container}}++ |
1271 |
for @items; |
1272 |
|
1273 |
$self->update_containers; |
1274 |
} |
1275 |
|
1276 |
sub item_update { |
1277 |
my ($self, $item) = @_; |
1278 |
|
1279 |
#print "item_update: $item->{tag} in $item->{container} pt($self->{player}{tag}) oc($::CONN->{open_container}) f($item->{flags})\n"; |
1280 |
|
1281 |
DC::Item::update_widgets $item; |
1282 |
|
1283 |
if ($item->{tag} == $::CONN->{open_container} && not ($item->{flags} & F_OPEN)) { |
1284 |
set_opencont ($::CONN, 0, "Floor"); |
1285 |
|
1286 |
} elsif ($item->{flags} & F_OPEN) { |
1287 |
set_opencont ($::CONN, $item->{tag}, DC::Item::desc_string $item); |
1288 |
|
1289 |
} else { |
1290 |
$self->{update_container}{$item->{container}}++; |
1291 |
$self->update_containers; |
1292 |
} |
1293 |
} |
1294 |
|
1295 |
sub player_update { |
1296 |
my ($self, $player) = @_; |
1297 |
|
1298 |
$self->update_weight; |
1299 |
} |
1300 |
|
1301 |
sub update_weight { |
1302 |
my ($self) = @_; |
1303 |
|
1304 |
my $weight = .001 * $self->{player}{weight}; |
1305 |
my $limit = .001 * $self->{stat}{+CS_STAT_WEIGHT_LIM}; |
1306 |
|
1307 |
$::STATWIDS->{weight}->set_text (sprintf "Weight: %.1fkg", $weight); |
1308 |
$::STATWIDS->{m_weight}->set_text (sprintf "Max Weight: %.1fkg", $limit); |
1309 |
$::STATWIDS->{i_weight}->set_text (sprintf "%.1f/%.1fkg", $weight, $limit); |
1310 |
} |
1311 |
|
1312 |
sub update_server_info { |
1313 |
my ($self) = @_; |
1314 |
|
1315 |
my @yesno = ("<span foreground='red'>no</span>", "<span foreground='green'>yes</span>"); |
1316 |
|
1317 |
my $version = JSON::XS->new->encode ($self->{s_version}); |
1318 |
|
1319 |
$::SERVER_INFO->set_markup ( |
1320 |
"server <tt>$self->{host}:$self->{port}</tt>\n" |
1321 |
. "protocol version <tt>$version</tt>\n" |
1322 |
. "editing support $yesno[!!$self->{editor_support}]\n" |
1323 |
. "client support $yesno[$self->{cfplus_ext} > 0]" |
1324 |
. ($self->{cfplus_ext} > 0 ? ", version $self->{cfplus_ext}" : "") ."\n" |
1325 |
. "map size $self->{mapw}×$self->{maph}\n" |
1326 |
); |
1327 |
|
1328 |
} |
1329 |
|
1330 |
sub logged_in { |
1331 |
my ($self) = @_; |
1332 |
|
1333 |
$self->send_ext_req (cfplus_support => version => 2, sub { |
1334 |
my (%msg) = @_; |
1335 |
|
1336 |
$self->{cfplus_ext} = $msg{version}; |
1337 |
$self->update_server_info; |
1338 |
|
1339 |
if ($self->{cfplus_ext} >= 2) { |
1340 |
$self->send_ext_req ("editor_support", sub { |
1341 |
$self->{editor_support} = { @_ }; |
1342 |
$self->update_server_info; |
1343 |
|
1344 |
0 |
1345 |
}); |
1346 |
} |
1347 |
|
1348 |
0 |
1349 |
}); |
1350 |
|
1351 |
$self->update_server_info; |
1352 |
|
1353 |
$self->send_command ("output-rate $::CFG->{output_rate}") if $::CFG->{output_rate} > 0; |
1354 |
$self->send_pickup ($::CFG->{pickup}); |
1355 |
} |
1356 |
|
1357 |
sub lookat { |
1358 |
my ($self, $x, $y) = @_; |
1359 |
|
1360 |
if ($self->{cfplus_ext}) { |
1361 |
$self->send_ext_req (lookat => $x, $y, sub { |
1362 |
my (%msg) = @_; |
1363 |
|
1364 |
if (exists $msg{npc_dialog}) { |
1365 |
# start npc chat dialog |
1366 |
$self->{w}{npc_dialog} = new DC::NPCDialog:: |
1367 |
token => $msg{npc_dialog}, |
1368 |
title => "$msg{npc_dialog}[0] (NPC)", |
1369 |
conn => $self, |
1370 |
; |
1371 |
} |
1372 |
}); |
1373 |
} |
1374 |
|
1375 |
$self->send ("lookat $x $y"); |
1376 |
} |
1377 |
|
1378 |
sub destroy { |
1379 |
my ($self) = @_; |
1380 |
|
1381 |
$_->destroy |
1382 |
for values %{ $self->{w} }; |
1383 |
|
1384 |
$self->SUPER::destroy; |
1385 |
|
1386 |
%$self = (); |
1387 |
} |
1388 |
|
1389 |
package DC::NPCDialog; |
1390 |
|
1391 |
our @ISA = 'DC::UI::Toplevel'; |
1392 |
|
1393 |
sub new { |
1394 |
my $class = shift; |
1395 |
|
1396 |
my $self = $class->SUPER::new ( |
1397 |
x => 'center', |
1398 |
y => 'center', |
1399 |
name => "npc_dialog", |
1400 |
force_w => $::WIDTH * 0.7, |
1401 |
force_h => $::HEIGHT * 0.7, |
1402 |
title => "NPC Dialog", |
1403 |
kw => { hi => 0, yes => 0, no => 0 }, |
1404 |
has_close_button => 1, |
1405 |
@_, |
1406 |
); |
1407 |
|
1408 |
DC::weaken (my $this = $self); |
1409 |
|
1410 |
$self->connect (delete => sub { $this->destroy; 1 }); |
1411 |
|
1412 |
# better use a pane... |
1413 |
$self->add (my $hbox = new DC::UI::HBox); |
1414 |
$hbox->add ($self->{textview} = new DC::UI::TextScroller expand => 1); |
1415 |
|
1416 |
$hbox->add (my $vbox = new DC::UI::VBox); |
1417 |
|
1418 |
$vbox->add (new DC::UI::Label text => "Message Entry:"); |
1419 |
$vbox->add ($self->{entry} = new DC::UI::Entry |
1420 |
tooltip => "#npc_message_entry", |
1421 |
on_activate => sub { |
1422 |
my ($entry, $text) = @_; |
1423 |
|
1424 |
return unless $text =~ /\S/; |
1425 |
|
1426 |
$entry->set_text (""); |
1427 |
$this->send ($text); |
1428 |
|
1429 |
0 |
1430 |
}, |
1431 |
); |
1432 |
|
1433 |
$vbox->add ($self->{options} = new DC::UI::VBox); |
1434 |
|
1435 |
$self->{bye_button} = new DC::UI::Button |
1436 |
text => "Bye (close)", |
1437 |
tooltip => "Use this button to end talking to the NPC. This also closes the dialog window.", |
1438 |
on_activate => sub { $this->destroy; 1 }, |
1439 |
; |
1440 |
|
1441 |
$self->update_options; |
1442 |
|
1443 |
$self->{id} = "npc-channel-" . $self->{conn}->token; |
1444 |
$self->{conn}->connect_ext ($self->{id} => sub { |
1445 |
$this->feed (@_) if $this; |
1446 |
}); |
1447 |
|
1448 |
$self->{conn}->send_ext_msg (npc_dialog_begin => $self->{id}, $self->{token}); |
1449 |
|
1450 |
$self->{entry}->grab_focus; |
1451 |
|
1452 |
$self->{textview}->add_paragraph ({ |
1453 |
fg => [1, 1, 0, 1], |
1454 |
markup => "<small>[starting conversation with <b>$self->{title}</b>]</small>\n\n", |
1455 |
}); |
1456 |
|
1457 |
$self->show; |
1458 |
$self |
1459 |
}; |
1460 |
|
1461 |
sub update_options { |
1462 |
my ($self) = @_; |
1463 |
|
1464 |
DC::weaken $self; |
1465 |
|
1466 |
$self->{options}->clear; |
1467 |
$self->{options}->add ($self->{bye_button}); |
1468 |
|
1469 |
for my $kw (sort keys %{ $self->{kw} }) { |
1470 |
$self->{options}->add (new DC::UI::Button |
1471 |
text => $kw, |
1472 |
on_activate => sub { |
1473 |
$self->send ($kw); |
1474 |
0 |
1475 |
}, |
1476 |
); |
1477 |
} |
1478 |
} |
1479 |
|
1480 |
sub feed { |
1481 |
my ($self, $type, @arg) = @_; |
1482 |
|
1483 |
DC::weaken $self; |
1484 |
|
1485 |
if ($type eq "update") { |
1486 |
my (%info) = @arg; |
1487 |
|
1488 |
$self->{kw}{$_} = 1 for @{$info{add_topics} || []}; |
1489 |
$self->{kw}{$_} = 0 for @{$info{del_topics} || []}; |
1490 |
|
1491 |
if (exists $info{msg}) { |
1492 |
my $text = "\n" . DC::sanitise_cfxml $info{msg}; |
1493 |
my $match = join "|", map "\\b\Q$_\E\\b", sort { (length $b) <=> (length $a) } keys %{ $self->{kw} }; |
1494 |
my @link; |
1495 |
$text =~ s{ |
1496 |
($match) |
1497 |
}{ |
1498 |
my $kw = $1; |
1499 |
|
1500 |
push @link, new DC::UI::Label |
1501 |
markup => "<span foreground='#c0c0ff' underline='single'>$kw</span>", |
1502 |
can_hover => 1, |
1503 |
can_events => 1, |
1504 |
padding_x => 0, |
1505 |
padding_y => 0, |
1506 |
on_button_up => sub { |
1507 |
$self->send ($kw); |
1508 |
}; |
1509 |
|
1510 |
"\x{fffc}" |
1511 |
}giex; |
1512 |
|
1513 |
$self->{textview}->add_paragraph ({ markup => $text, widget => \@link }); |
1514 |
$self->{textview}->scroll_to_bottom; |
1515 |
} |
1516 |
|
1517 |
$self->update_options; |
1518 |
} else { |
1519 |
$self->destroy; |
1520 |
} |
1521 |
|
1522 |
1 |
1523 |
} |
1524 |
|
1525 |
sub send { |
1526 |
my ($self, $msg) = @_; |
1527 |
|
1528 |
$self->{textview}->add_paragraph ({ |
1529 |
markup => |
1530 |
"\n<span foreground='#ffff00'><b>" |
1531 |
. (DC::asxml $msg) |
1532 |
. "</b></span>" |
1533 |
}); |
1534 |
$self->{textview}->scroll_to_bottom; |
1535 |
|
1536 |
$self->{conn}->send_ext_msg (npc_dialog_tell => $self->{id}, $msg); |
1537 |
} |
1538 |
|
1539 |
sub destroy { |
1540 |
my ($self) = @_; |
1541 |
|
1542 |
#Carp::cluck "debug\n";#d# #todo# enable: destroy gets called twice because scalar keys {} is 1 |
1543 |
|
1544 |
if ($self->{conn}) { |
1545 |
$self->{conn}->send_ext_msg (npc_dialog_end => $self->{id}) if $self->{id}; |
1546 |
delete $self->{conn}{w}{npc_dialog}; |
1547 |
$self->{conn}->disconnect_ext ($self->{id}); |
1548 |
} |
1549 |
|
1550 |
$self->SUPER::destroy; |
1551 |
} |
1552 |
|
1553 |
1 |
1554 |
|