package CFClient::Protocol;

use utf8;
use strict;

use Crossfire::Protocol::Constants;

use CFClient::UI;

use base 'Crossfire::Protocol::Base';

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (@_);

   $self->{map_widget}->clr_commands;

   my $parser = new Pod::POM;
   my $pod = $parser->parse_file (CFClient::find_rcfile "pod/command_help.pod");

   for my $head2 ($pod->head1->[-2]->head2) {
      $head2->title =~ /^(\S+) (?:\s+ \( ([^\)]*) \) )?/x
         or next;

      my $cmd = $1;
      my @args = split /\|/, $2;
      @args = (".*") unless @args;

      my $text = CFClient::pod_to_pango $head2->content;

      for my $arg (@args) {
         $arg = $arg eq ".*" ? "" : " $arg";

         $self->{map_widget}->add_command ("$cmd$arg", $text);
      }
   }

   $self->{noface} = new_from_file CFClient::Texture
      CFClient::find_rcfile "noface.png", minify => 1, mipmap => 1;

   $self->{open_container} = 0;

   # "global"
   $self->{tilecache} = CFClient::db_table "tilecache";
   $self->{facemap}   = CFClient::db_table "facemap";

   # per server
   $self->{mapcache}  = CFClient::db_table "mapcache_$self->{host}_$self->{port}";

   $self
}

sub stats_update {
   my ($self, $stats) = @_;

   if (my $exp = $stats->{CS_STAT_EXP64}) {
      my $diff = $exp - $self->{prev_exp};
      $self->{statusbox}->add ("$diff experience gained", group => "experience $diff", fg => [0.5, 1, 0.5, 0.8], timeout => 5)
         if exists $self->{prev_exp} && $diff;
      $self->{prev_exp} = $exp;
   }

   ::update_stats_window ($stats);
}

sub user_send {
   my ($self, $command) = @_;

   $self->send_command ($command);
   ::status $command;
}

sub map_scroll {
   my ($self, $dx, $dy) = @_;

   $self->{map}->scroll ($dx, $dy);
}

sub feed_map1a {
   my ($self, $data) = @_;

   $self->{map}->map1a_update ($data);
   $self->{map_widget}->update;
}

sub flush_map {
   my ($self) = @_;

   my $map_info = delete $self->{map_info}
      or return;

   my ($hash, $x, $y, $w, $h) = @$map_info;

   my $data = $self->{map}->get_rect ($x, $y, $w, $h);
   $self->{mapcache}->put ($hash => Compress::LZF::compress $data);
   #warn sprintf "SAVEmap[%s] length %d\n", $hash, length $data;#d#
}

sub map_clear {
   my ($self) = @_;

   $self->flush_map;
   delete $self->{neigh_map};

   $self->{map}->clear;
}


sub load_map($$$) {
   my ($self, $hash, $x, $y) = @_;

   if (defined (my $data = $self->{mapcache}->get ($hash))) {
      $data = Compress::LZF::decompress $data;
      #warn sprintf "LOADmap[%s,%d,%d] length %d\n", $hash, $x, $y, length $data;#d#
      for my $id ($self->{map}->set_rect ($x, $y, $data)) {
         my $data = $self->{tilecache}->get ($id)
            or next;

         $self->set_texture ($id => $data);
      }
   }
}

# hardcode /world/world_xxx_xxx map names, the savings are enourmous,
# (server resource,s latency, bandwidth), so this hack is warranted.
# the right fix is to make real tiled maps with an overview file
sub send_mapinfo {
   my ($self, $data, $cb) = @_;

   if ($self->{map_info}[0] =~ m%^/world/world_(\d\d\d)_(\d\d\d)$%) {
      my ($wx, $wy) = ($1, $2);

      if ($data =~ /^spatial ([1-4]+)$/) {
         my @dx = (0, 0, 1, 0, -1);
         my @dy = (0, -1, 0, 1, 0);
         my ($dx, $dy);

         for (split //, $1) {
            $dx += $dx[$_];
            $dy += $dy[$_];
         }

         $cb->(spatial => 15,
            $self->{map_info}[1] - $self->{map}->ox + $dx * 50,
            $self->{map_info}[2] - $self->{map}->oy + $dy * 50,
            50, 50,
            sprintf "/world/world_%03d_%03d", $wx + $dx, $wy + $dy
         );

         return;
      }
   }

   $self->SUPER::send_mapinfo ($data, $cb);
}

# this method does a "flood fill" into every tile direction
# it assumes that tiles are arranged in a rectangular grid,
# i.e. a map is the same as the left of the right map etc.
# failure to comply are harmless and result in display errors
# at worst.
sub flood_fill {
   my ($self, $block, $gx, $gy, $path, $hash, $flags) = @_;

   # the server does not allow map paths > 6
   return if 7 <= length $path;

   my ($x0, $y0, $x1, $y1) = @{$self->{neigh_rect}};

   for (
      [1, 3,  0, -1],
      [2, 4,  1,  0],
      [3, 1,  0,  1],
      [4, 2, -1,  0],
   ) {
      my ($tile, $tile2, $dx, $dy) = @$_;

      next if $block & (1 << $tile);
      my $block = $block | (1 << $tile2);

      my $gx = $gx + $dx;
      my $gy = $gy + $dy;

      next unless $flags & (1 << ($tile - 1));
      next if $self->{neigh_grid}{$gx, $gy}++;

      my $neigh = $self->{neigh_map}{$hash} ||= [];
      if (my $info = $neigh->[$tile]) {
         my ($flags, $x, $y, $w, $h, $hash) = @$info;

         $self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags)
            if $x >= $x0 && $x + $w < $x1 && $y >= $y0  && $y + $h < $y1;

      } else {
         $self->send_mapinfo ("spatial $path$tile", sub {
            my ($mode, $flags, $x, $y, $w, $h, $hash) = @_;

            return if $mode ne "spatial";

            $x += $self->{map}->ox;
            $y += $self->{map}->oy;

            $self->load_map ($hash, $x, $y)
               unless $self->{neigh_map}{$hash}[5]++;#d#

            $neigh->[$tile] = [$flags, $x, $y, $w, $h, $hash];

            $self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags)
               if $x >= $x0 && $x + $w < $x1 && $y >= $y0  && $y + $h < $y1;
         });
      }
   }
}

sub map_change {
   my ($self, $mode, $flags, $x, $y, $w, $h, $hash) = @_;

   $self->flush_map;

   my ($ox, $oy) = ($::MAP->ox, $::MAP->oy);

   my $mapmapw = $self->{mapmap}->{w};
   my $mapmaph = $self->{mapmap}->{h};

   $self->{neigh_rect} = [
      $ox - $mapmapw * 0.5,      $oy - $mapmapw * 0.5,
      $ox + $mapmapw * 0.5 + $w, $oy + $mapmapw * 0.5 + $h,
   ];
   
   delete $self->{neigh_grid};

   $x += $ox;
   $y += $oy;

   $self->{map_info} = [$hash, $x, $y, $w, $h];

   (my $map = $hash) =~ s/^.*?\/([^\/]+)$/\1/;
   $::STATWIDS->{map}->set_text ("Map: " . $map);

   $self->load_map ($hash, $x, $y);
   $self->flood_fill (0, 0, 0, "", $hash, $flags);
}

sub face_find {
   my ($self, $facenum, $face) = @_;

   my $hash = "$face->{chksum},$face->{name}";

   my $id = $self->{facemap}->get ($hash);

   unless ($id) {
      # create new id for face
      # I love transactions
      for (1..100) {
         my $txn = $CFClient::DB_ENV->txn_begin;
         my $status = $self->{facemap}->db_get (id => $id, BerkeleyDB::DB_RMW);
         if ($status == 0 || $status == BerkeleyDB::DB_NOTFOUND) {
            $id = ($id || 16) + 1;
            if ($self->{facemap}->put (id => $id) == 0
                && $self->{facemap}->put ($hash => $id) == 0) {
               $txn->txn_commit;

               goto gotid;
            }
         }
         $txn->abort;
      }

      CFClient::fatal "maximum number of transaction retries reached - database problems?";
   }

gotid:
   $face->{id} = $id;
   $self->{map}->set_face ($facenum => $id);
   $self->{faceid}[$facenum] = $id;#d#

   my $face = $self->{tilecache}->get ($id);
   
   if ($face) {
      #$self->face_prefetch;
      $face
   } else {
      my $tex = $self->{noface};
      $self->{map}->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}});
      undef
   };
}

sub face_update {
   my ($self, $facenum, $face) = @_;

   $self->{tilecache}->put ($face->{id} => $face->{image}); #TODO: try to avoid duplicate writes

   $self->set_texture ($face->{id} => delete $face->{image});
}

sub set_texture {
   my ($self, $id, $data) = @_;

   $self->{texture}[$id] ||= do {
      my $tex =
         new_from_image CFClient::Texture
            $data, minify => 1, mipmap => 1;

      $self->{map}->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}});
      $self->{map_widget}->update;

      $tex
   };
}

sub sound_play {
   my ($self, $x, $y, $soundnum, $type) = @_;

   $self->{sound_play}->($x, $y, $soundnum, $type);
}

my $LAST_QUERY; # server is stupid, stupid, stupid

sub query {
   my ($self, $flags, $prompt) = @_;

   $prompt = $LAST_QUERY unless length $prompt;
   $LAST_QUERY = $prompt;

   my $dialog = new CFClient::UI::FancyFrame
      title => "Query",
      child => my $vbox = new CFClient::UI::VBox;

   $vbox->add (new CFClient::UI::Label
      max_w => $::WIDTH * 0.4,
      ellipsise => 0,
      text => $prompt);

   if ($flags & CS_QUERY_YESNO) {
      $vbox->add (my $hbox = new CFClient::UI::HBox);
      $hbox->add (new CFClient::UI::Button
         text => "No",
         connect_activate => sub {
            $self->send ("reply n");
            $dialog->destroy;
            $self->{map_widget}->focus_in;
         }
      );
      $hbox->add (new CFClient::UI::Button
         text => "Yes",
         connect_activate => sub {
            $self->send ("reply y");
            $dialog->destroy;
         },
      );

      $dialog->focus_in;

   } elsif ($flags & CS_QUERY_SINGLECHAR) {
      $dialog->{tooltip} = "Press a key (click on the entry to make sure it has keyboard focus)";
      $vbox->add (my $entry = new CFClient::UI::Entry
         connect_changed => sub {
            $self->send ("reply $_[1]");
            $dialog->destroy;
         },
      );

      $entry->focus_in;

   } else {
      $dialog->{tooltip} = "Enter the reply and press return (click on the entry to make sure it has keyboard focus)";

      $vbox->add (my $entry = new CFClient::UI::Entry
         $flags & CS_QUERY_HIDEINPUT ? (hiddenchar => "*") : (),
         connect_activate => sub {
            $self->send ("reply $_[1]");
            $dialog->destroy;
         },
      );

      $entry->focus_in;
   }

   $dialog->show_centered;
}

sub drawinfo {
   my ($self, $color, $text) = @_;

   my @color = (
      [1.00, 1.00, 1.00], #[0.00, 0.00, 0.00],
      [1.00, 1.00, 1.00],
      [0.50, 0.50, 1.00], #[0.00, 0.00, 0.55]
      [1.00, 0.00, 0.00],
      [1.00, 0.54, 0.00],
      [0.11, 0.56, 1.00],
      [0.93, 0.46, 0.00],
      [0.18, 0.54, 0.34],
      [0.56, 0.73, 0.56],
      [0.80, 0.80, 0.80],
      [0.55, 0.41, 0.13],
      [0.99, 0.77, 0.26],
      [0.74, 0.65, 0.41],
   );

   my $time = sprintf "%02d:%02d:%02d", (localtime time)[2,1,0];

   $text = CFClient::UI::Label::escape $text;
   $text =~ s/\[b\](.*?)\[\/b\]/<b>\1<\/b>/g;
   $text =~ s/\[color=(.*?)\](.*?)\[\/color\]/<span foreground='\1'>\2<\/span>/g;

   $self->{logview}->add_paragraph ($color[$color],
      join "\n", map "$time $_", split /\n/, $text);

   $self->{statusbox}->add ($text,
      group        => $text,
      fg           => $color[$color],
      timeout      => 10,
      tooltip_font => $::FONT_FIXED,
   );
}

sub drawextinfo {
   my ($self, $color, $type, $subtype, $message) = @_;

   $self->drawinfo ($color, $message);
}

sub spell_add {
   my ($self, $spell) = @_;

   # TODO
   # create a widget dynamically, using spell face (CF::Protocol downloads them)
   $self->{map_widget}->add_command ("invoke $spell->{name}", CFClient::UI::Label::escape $spell->{message});
   $self->{map_widget}->add_command ("cast $spell->{name}", CFClient::UI::Label::escape $spell->{message});
}

sub spell_delete {
   my ($self, $spell) = @_;
}

sub addme_success {
   my ($self) = @_;

   $self->send ("command output-sync $::CFG->{output_sync}");
   $self->send ("command output-count $::CFG->{output_count}");

   my $parser = new Pod::POM;
   my $pod = $parser->parse_file (CFClient::find_rcfile "pod/skill_help.pod");

   my %skill_tooltip;

   for my $head2 ($pod->head1->[-2]->head2) {
      $skill_tooltip{$head2->title} = CFClient::pod_to_pango $head2->content;
   }

   for my $skill (values %{$self->{skill_info}}) {
      $self->{map_widget}->add_command ("ready_skill $skill",
                                        (CFClient::UI::Label::escape "Ready the skill '$skill'\n\n")
                                        . $skill_tooltip{$skill});
      $self->{map_widget}->add_command ("use_skill $skill",
                                        (CFClient::UI::Label::escape "Immediately use the skill '$skill'\n\n")
                                        . $skill_tooltip{$skill});
   }
}

sub eof {
   my ($self) = @_;

   $self->{map_widget}->clr_commands;

   ::stop_game ();
}

sub image_info {
   my ($self, $numfaces) = @_;

   $self->{num_faces} = $numfaces;
   $self->{face_prefetch} = [1 .. $numfaces];
   $self->face_prefetch;
}

sub face_prefetch {
   my ($self) = @_;

   return unless $::CFG->{face_prefetch};

   if ($self->{num_faces}) {
      return if @{ $self->{send_queue} || [] };
      my $todo = @{ $self->{face_prefetch} }
         or return;

      my ($face) = splice @{ $self->{face_prefetch} }, + rand @{ $self->{face_prefetch} }, 1, ();

      $self->send ("requestinfo image_sums $face $face");

      $self->{statusbox}->add (CFClient::UI::Label::escape "prefetching $todo",
         group => "prefetch", timeout => 2, fg => [1, 1, 0, 0.5]);
   } elsif (!exists $self->{num_faces}) {
      $self->send ("requestinfo image_info");

      $self->{num_faces} = 0;

      $self->{statusbox}->add (CFClient::UI::Label::escape "starting to prefetch",
         group => "prefetch", timeout => 2, fg => [1, 1, 0, 0.5]);
   }
}

sub update_floorbox {
   $CFClient::UI::ROOT->on_refresh ($::FLOORBOX => sub {
      return unless $::CONN;
         
      $::FLOORBOX->clear;

      my $row;
      for (@{ $::CONN->{container}{0} }) {
         if ($row < 7) {
            local $_->{face_widget}; # hack to force recreation of widget
            local $_->{desc_widget}; # hack to force recreation of widget
            CFClient::Item::update_widgets $_;

            $::FLOORBOX->add (0, $row, $_->{face_widget});
            $::FLOORBOX->add (1, $row, $_->{desc_widget});

            $row++;
         } else {
            $::FLOORBOX->add (1, $row, new CFClient::UI::Label text => "More...");
            last;
         }
      }
   });
   
   $::WANT_REFRESH++;
}

sub set_opencont {
   my ($conn, $tag, $name) = @_;
   $conn->{open_container} = $tag;
   $::INVR_LBL->set_text ($name);
   $::INVR->set_items ($conn->{container}{$tag});
}

sub update_container {
   my ($tag) = @_;

   $::INVR->set_items ($::CONN->{container}{$::CONN->{open_container}})
      if $tag == $::CONN->{open_container};
}

sub container_add {
   my ($self, $tag, $items) = @_;

   #d# print "container_add: container $tag ($self->{player}{tag})\n";

   if ($tag == 0) {
      update_floorbox;
      update_container (0);
   } elsif ($tag == $self->{player}{tag}) {
      $::INV->set_items ($self->{container}{$self->{player}{tag}})
   } else {
      update_container ($tag);
   }

   # $self-<{player}{tag} => player inv
   #use PApp::Util; warn PApp::Util::dumpval $self->{container}{$self->{player}{tag}};
}

sub container_clear {
   my ($self, $tag) = @_;

   #d# print "container_clear: container $tag ($self->{player}{tag})\n";

   if ($tag == 0) {
      update_floorbox;
      update_container (0);
   } elsif ($tag == $self->{player}{tag}) {
      $::INV->set_items ($self->{container}{$tag})
   }

#   use PApp::Util; warn PApp::Util::dumpval $self->{container}{0};
}

sub item_delete {
   my ($self, @items) = @_;

   for (@items) {
      #d# print "item_delete: $_->{tag} from $_->{container} ($self->{player}{tag})\n";

      if ($_->{container} == 0) {
         update_floorbox;
         update_container ($_->{tag});
      } elsif ($_->{container} == $self->{player}{tag}) {
         $::INV->set_items ($self->{container}{$self->{player}{tag}})
      } else {
         update_container ($_->{tag});
      }
   }
}

sub item_update {
   my ($self, $item) = @_;

   #d# print "item_update: $item->{tag} in $item->{container} ($self->{player}{tag}) ($::CONN->{open_container})\n";

   if ($item->{tag} == $self->{player}{tag}) {
      $::STATWIDS->{weight}->set_text (sprintf "Weight: %.1fkg", $item->{weight} / 1000);
      return;
   }

   CFClient::Item::update_widgets $item;

   if ($item->{tag} == $::CONN->{open_container} && not ($item->{flags} & F_OPEN)) {
      set_opencont ($::CONN, 0, "Floor");

   } elsif ($item->{flags} & F_OPEN) {
      set_opencont ($::CONN, $item->{tag}, CFClient::Item::desc_string $item);
   } else {
      if ($item->{container} == 0) {
         update_floorbox;
         update_container (0);
      } elsif ($item->{container} == $self->{player}{tag}) {
         $::INV->set_items ($self->{container}{$item->{container}})
      }
   }
}

sub player_update {
   my ($self, $player) = @_;
   $::STATWIDS->{weight}->set_text (sprintf "Weight: %.1fkg", $player->{weight} / 1000);
}

1;