| 1 |
package CFPlus::Protocol; |
| 2 |
|
| 3 |
use utf8; |
| 4 |
use strict; |
| 5 |
|
| 6 |
use Crossfire::Protocol::Constants; |
| 7 |
|
| 8 |
use CFPlus; |
| 9 |
use CFPlus::UI; |
| 10 |
use CFPlus::Pod; |
| 11 |
|
| 12 |
use Crossfire::Protocol::Base 0.95; |
| 13 |
|
| 14 |
use base 'Crossfire::Protocol::Base'; |
| 15 |
|
| 16 |
sub new { |
| 17 |
my $class = shift; |
| 18 |
|
| 19 |
my $self = $class->SUPER::new (@_, setup_req => { extmap => 1 }); |
| 20 |
|
| 21 |
$self->{map_widget}->clr_commands; |
| 22 |
|
| 23 |
my @cmd_help = map { |
| 24 |
$_->{kw}[0] =~ /^(\S+) (?:\s+ \( ([^\)]*) \) )?/x |
| 25 |
or die "unparseable command help: $_->{kw}[0]"; |
| 26 |
|
| 27 |
my $cmd = $1; |
| 28 |
my @args = split /\|/, $2; |
| 29 |
@args = (".*") unless @args; |
| 30 |
|
| 31 |
my (undef, @par) = CFPlus::Pod::section_of $_; |
| 32 |
my $text = CFPlus::Pod::as_label @par; |
| 33 |
|
| 34 |
$_ = $_ eq ".*" ? "" : " $_" |
| 35 |
for @args; |
| 36 |
|
| 37 |
map ["$cmd$_", $text], |
| 38 |
sort { (length $a) <=> (length $b) } |
| 39 |
@args |
| 40 |
} sort { $a->{par} <=> $b->{par} } |
| 41 |
CFPlus::Pod::find command => "*"; |
| 42 |
|
| 43 |
$self->{map_widget}->add_command (@$_) |
| 44 |
for @cmd_help; |
| 45 |
|
| 46 |
$self->{noface} = new_from_file CFPlus::Texture |
| 47 |
CFPlus::find_rcfile "noface.png", minify => 1, mipmap => 1; |
| 48 |
|
| 49 |
{ |
| 50 |
$self->{dialogue} = my $tex = new_from_file CFPlus::Texture |
| 51 |
CFPlus::find_rcfile "dialogue.png", minify => 1, mipmap => 1; |
| 52 |
$self->{map}->set_texture (1, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
| 53 |
} |
| 54 |
|
| 55 |
$self->{open_container} = 0; |
| 56 |
|
| 57 |
# "global" |
| 58 |
$self->{tilecache} = CFPlus::db_table "tilecache" |
| 59 |
or die "tilecache: unable to open database table"; |
| 60 |
$self->{facemap} = CFPlus::db_table "facemap" |
| 61 |
or die "facemap: unable to open database table"; |
| 62 |
|
| 63 |
# per server |
| 64 |
$self->{mapcache} = CFPlus::db_table "mapcache_$self->{host}_$self->{port}" |
| 65 |
or die "mapcache_$self->{host}_$self->{port}: unable to open database table"; |
| 66 |
|
| 67 |
$self |
| 68 |
} |
| 69 |
|
| 70 |
sub logprint { |
| 71 |
my ($self, @a) = @_; |
| 72 |
|
| 73 |
$self->{log_fh} ||= do { |
| 74 |
my $path = "$Crossfire::VARDIR/log.$self->{host}"; |
| 75 |
|
| 76 |
open my $fh, ">>:utf8", $path |
| 77 |
or die "Couldn't open logfile $path: $!"; |
| 78 |
|
| 79 |
$fh->autoflush (1); |
| 80 |
|
| 81 |
$fh; |
| 82 |
}; |
| 83 |
|
| 84 |
my ($sec, $min, $hour, $mday, $mon, $year) = localtime time; |
| 85 |
|
| 86 |
my $ts = sprintf "%04d-%02d-%02d %02d:%02d:%02d", |
| 87 |
$year + 1900, $mon + 1, $mday, $hour, $min, $sec; |
| 88 |
|
| 89 |
print {$self->{log_fh}} "$ts ", @a, "\n"; |
| 90 |
} |
| 91 |
|
| 92 |
sub _stat_numdiff { |
| 93 |
my ($self, $name, $old, $new) = @_; |
| 94 |
|
| 95 |
my $diff = $new - $old; |
| 96 |
|
| 97 |
$diff = 0.01 * int $diff * 100; |
| 98 |
|
| 99 |
0.1 >= abs $diff ? () |
| 100 |
: $diff < 0 ? "$name$diff" : "$name+$diff" |
| 101 |
} |
| 102 |
|
| 103 |
sub _stat_skillmaskdiff { |
| 104 |
my ($self, $name, $old, $new) = @_; |
| 105 |
|
| 106 |
my $diff = $old ^ $new |
| 107 |
or return; |
| 108 |
|
| 109 |
my @diff = map |
| 110 |
{ |
| 111 |
$diff & $_ |
| 112 |
? (($new & $_ ? "+" : "-") . $self->{spell_paths}{$_}) |
| 113 |
: () |
| 114 |
} |
| 115 |
sort { $a <=> $b } keys %{$self->{spell_paths}}; |
| 116 |
|
| 117 |
join "", @diff |
| 118 |
} |
| 119 |
|
| 120 |
# all stats that are chacked against changes |
| 121 |
my @statchange = ( |
| 122 |
[&CS_STAT_STR => \&_stat_numdiff, "Str"], |
| 123 |
[&CS_STAT_INT => \&_stat_numdiff, "Int"], |
| 124 |
[&CS_STAT_WIS => \&_stat_numdiff, "Wis"], |
| 125 |
[&CS_STAT_DEX => \&_stat_numdiff, "Dex"], |
| 126 |
[&CS_STAT_CON => \&_stat_numdiff, "Con"], |
| 127 |
[&CS_STAT_CHA => \&_stat_numdiff, "Cha"], |
| 128 |
[&CS_STAT_POW => \&_stat_numdiff, "Pow"], |
| 129 |
[&CS_STAT_WC => \&_stat_numdiff, "Wc"], |
| 130 |
[&CS_STAT_AC => \&_stat_numdiff, "Ac"], |
| 131 |
[&CS_STAT_DAM => \&_stat_numdiff, "Dam"], |
| 132 |
[&CS_STAT_SPEED => \&_stat_numdiff, "Speed"], |
| 133 |
[&CS_STAT_WEAP_SP => \&_stat_numdiff, "WSp"], |
| 134 |
[&CS_STAT_MAXHP => \&_stat_numdiff, "HP"], |
| 135 |
[&CS_STAT_MAXSP => \&_stat_numdiff, "Mana"], |
| 136 |
[&CS_STAT_MAXGRACE => \&_stat_numdiff, "Grace"], |
| 137 |
[&CS_STAT_WEIGHT_LIM => \&_stat_numdiff, "Weight"], |
| 138 |
[&CS_STAT_SPELL_ATTUNE => \&_stat_skillmaskdiff, "attuned"], |
| 139 |
[&CS_STAT_SPELL_REPEL => \&_stat_skillmaskdiff, "repelled"], |
| 140 |
[&CS_STAT_SPELL_DENY => \&_stat_skillmaskdiff, "denied"], |
| 141 |
[&CS_STAT_RES_PHYS => \&_stat_numdiff, "phys"], |
| 142 |
[&CS_STAT_RES_MAG => \&_stat_numdiff, "magic"], |
| 143 |
[&CS_STAT_RES_FIRE => \&_stat_numdiff, "fire"], |
| 144 |
[&CS_STAT_RES_ELEC => \&_stat_numdiff, "electricity"], |
| 145 |
[&CS_STAT_RES_COLD => \&_stat_numdiff, "cold"], |
| 146 |
[&CS_STAT_RES_CONF => \&_stat_numdiff, "confusion"], |
| 147 |
[&CS_STAT_RES_ACID => \&_stat_numdiff, "acid"], |
| 148 |
[&CS_STAT_RES_DRAIN => \&_stat_numdiff, "drain"], |
| 149 |
[&CS_STAT_RES_GHOSTHIT => \&_stat_numdiff, "ghosthit"], |
| 150 |
[&CS_STAT_RES_POISON => \&_stat_numdiff, "poison"], |
| 151 |
[&CS_STAT_RES_SLOW => \&_stat_numdiff, "slow"], |
| 152 |
[&CS_STAT_RES_PARA => \&_stat_numdiff, "paralyse"], |
| 153 |
[&CS_STAT_TURN_UNDEAD => \&_stat_numdiff, "turnundead"], |
| 154 |
[&CS_STAT_RES_FEAR => \&_stat_numdiff, "fear"], |
| 155 |
[&CS_STAT_RES_DEPLETE => \&_stat_numdiff, "depletion"], |
| 156 |
[&CS_STAT_RES_DEATH => \&_stat_numdiff, "death"], |
| 157 |
[&CS_STAT_RES_HOLYWORD => \&_stat_numdiff, "godpower"], |
| 158 |
[&CS_STAT_RES_BLIND => \&_stat_numdiff, "blind"], |
| 159 |
); |
| 160 |
|
| 161 |
sub stats_update { |
| 162 |
my ($self, $stats) = @_; |
| 163 |
|
| 164 |
my $prev = $self->{prev_stats} || { }; |
| 165 |
|
| 166 |
if (my @diffs = |
| 167 |
( |
| 168 |
($stats->{+CS_STAT_EXP64} > $prev->{+CS_STAT_EXP64} ? ($stats->{+CS_STAT_EXP64} - $prev->{+CS_STAT_EXP64}) . " experience gained" : ()), |
| 169 |
map { |
| 170 |
$stats->{$_} && $prev->{$_} |
| 171 |
&& $stats->{$_}[1] > $prev->{$_}[1] ? "($self->{skill_info}{$_}+" . ($stats->{$_}[1] - $prev->{$_}[1]) . ")" : () |
| 172 |
} sort { $a <=> $b } keys %{$self->{skill_info}} |
| 173 |
) |
| 174 |
) { |
| 175 |
my $msg = join " ", @diffs; |
| 176 |
$self->{statusbox}->add ($msg, group => "experience $msg", fg => [0.5, 1, 0.5, 0.8], timeout => 5); |
| 177 |
} |
| 178 |
|
| 179 |
if ( |
| 180 |
my @diffs = map $_->[1]->($self, $_->[2], $prev->{$_->[0]}, $stats->{$_->[0]}), @statchange |
| 181 |
) { |
| 182 |
my $msg = "<b>stat change</b>: " . (join " ", @diffs); |
| 183 |
$self->{statusbox}->add ($msg, group => "stat $msg", fg => [0.8, 1, 0.2, 1], timeout => 10); |
| 184 |
} |
| 185 |
|
| 186 |
$self->update_stats_window ($stats, $prev); |
| 187 |
|
| 188 |
$self->{prev_stats} = { %$stats }; |
| 189 |
} |
| 190 |
|
| 191 |
my %RES_TBL = ( |
| 192 |
phys => CS_STAT_RES_PHYS, |
| 193 |
magic => CS_STAT_RES_MAG, |
| 194 |
fire => CS_STAT_RES_FIRE, |
| 195 |
elec => CS_STAT_RES_ELEC, |
| 196 |
cold => CS_STAT_RES_COLD, |
| 197 |
conf => CS_STAT_RES_CONF, |
| 198 |
acid => CS_STAT_RES_ACID, |
| 199 |
drain => CS_STAT_RES_DRAIN, |
| 200 |
ghit => CS_STAT_RES_GHOSTHIT, |
| 201 |
pois => CS_STAT_RES_POISON, |
| 202 |
slow => CS_STAT_RES_SLOW, |
| 203 |
para => CS_STAT_RES_PARA, |
| 204 |
tund => CS_STAT_TURN_UNDEAD, |
| 205 |
fear => CS_STAT_RES_FEAR, |
| 206 |
depl => CS_STAT_RES_DEPLETE, |
| 207 |
deat => CS_STAT_RES_DEATH, |
| 208 |
holyw => CS_STAT_RES_HOLYWORD, |
| 209 |
blind => CS_STAT_RES_BLIND, |
| 210 |
); |
| 211 |
|
| 212 |
sub update_stats_window { |
| 213 |
my ($self, $stats, $prev) = @_; |
| 214 |
|
| 215 |
# I love text protocols... |
| 216 |
|
| 217 |
my $hp = $stats->{+CS_STAT_HP} * 1; |
| 218 |
my $hp_m = $stats->{+CS_STAT_MAXHP} * 1; |
| 219 |
my $sp = $stats->{+CS_STAT_SP} * 1; |
| 220 |
my $sp_m = $stats->{+CS_STAT_MAXSP} * 1; |
| 221 |
my $fo = $stats->{+CS_STAT_FOOD} * 1; |
| 222 |
my $fo_m = 999; |
| 223 |
my $gr = $stats->{+CS_STAT_GRACE} * 1; |
| 224 |
my $gr_m = $stats->{+CS_STAT_MAXGRACE} * 1; |
| 225 |
|
| 226 |
$::GAUGES->{hp} ->set_value ($hp, $hp_m); |
| 227 |
$::GAUGES->{mana} ->set_value ($sp, $sp_m); |
| 228 |
$::GAUGES->{food} ->set_value ($fo, $fo_m); |
| 229 |
$::GAUGES->{grace} ->set_value ($gr, $gr_m); |
| 230 |
$::GAUGES->{exp} ->set_text ("Exp: " . (::formsep ($stats->{+CS_STAT_EXP64})) |
| 231 |
. " (lvl " . ($stats->{+CS_STAT_LEVEL} * 1) . ")"); |
| 232 |
my $rng = $stats->{+CS_STAT_RANGE}; |
| 233 |
$rng =~ s/^Range: //; # thank you so much dear server |
| 234 |
$::GAUGES->{range} ->set_text ("Rng: " . $rng); |
| 235 |
my $title = $stats->{+CS_STAT_TITLE}; |
| 236 |
$title =~ s/^Player: //; |
| 237 |
$::STATWIDS->{title} ->set_text ("Title: " . $title); |
| 238 |
|
| 239 |
$::STATWIDS->{st_str} ->set_text (sprintf "%d" , $stats->{+CS_STAT_STR}); |
| 240 |
$::STATWIDS->{st_dex} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DEX}); |
| 241 |
$::STATWIDS->{st_con} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CON}); |
| 242 |
$::STATWIDS->{st_int} ->set_text (sprintf "%d" , $stats->{+CS_STAT_INT}); |
| 243 |
$::STATWIDS->{st_wis} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WIS}); |
| 244 |
$::STATWIDS->{st_pow} ->set_text (sprintf "%d" , $stats->{+CS_STAT_POW}); |
| 245 |
$::STATWIDS->{st_cha} ->set_text (sprintf "%d" , $stats->{+CS_STAT_CHA}); |
| 246 |
$::STATWIDS->{st_wc} ->set_text (sprintf "%d" , $stats->{+CS_STAT_WC}); |
| 247 |
$::STATWIDS->{st_ac} ->set_text (sprintf "%d" , $stats->{+CS_STAT_AC}); |
| 248 |
$::STATWIDS->{st_dam} ->set_text (sprintf "%d" , $stats->{+CS_STAT_DAM}); |
| 249 |
$::STATWIDS->{st_arm} ->set_text (sprintf "%d" , $stats->{+CS_STAT_RES_PHYS}); |
| 250 |
$::STATWIDS->{st_spd} ->set_text (sprintf "%.1f", $stats->{+CS_STAT_SPEED}); |
| 251 |
$::STATWIDS->{st_wspd}->set_text (sprintf "%.1f", $stats->{+CS_STAT_WEAP_SP}); |
| 252 |
|
| 253 |
$self->update_weight; |
| 254 |
|
| 255 |
$::STATWIDS->{"res_$_"}->set_text (sprintf "%d%", $stats->{$RES_TBL{$_}}) |
| 256 |
for keys %RES_TBL; |
| 257 |
|
| 258 |
my $sktbl = $::STATWIDS->{skill_tbl}; |
| 259 |
my @skills = keys %{ $self->{skill_info} }; |
| 260 |
|
| 261 |
if (grep +(exists $stats->{$_}) != (exists $prev->{$_}), @skills) { |
| 262 |
$sktbl->clear; |
| 263 |
|
| 264 |
$sktbl->add (0, 0, new CFPlus::UI::Label text => "Experience", align => 1); |
| 265 |
$sktbl->add (1, 0, new CFPlus::UI::Label text => "Lvl.", align => 1); |
| 266 |
$sktbl->add (2, 0, new CFPlus::UI::Label text => "Skill", expand => 1); |
| 267 |
$sktbl->add (3, 0, new CFPlus::UI::Label text => "Experience", align => 1); |
| 268 |
$sktbl->add (4, 0, new CFPlus::UI::Label text => "Lvl.", align => 1); |
| 269 |
$sktbl->add (5, 0, new CFPlus::UI::Label text => "Skill", expand => 1); |
| 270 |
|
| 271 |
my $TOOLTIP_ALL = "\n\n<small>Left click - ready skill\nMiddle click - use spell\nRight click - further options</small>"; |
| 272 |
|
| 273 |
my @TOOLTIP_LVL = (tooltip => "<b>Level</b>. The level of the skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
| 274 |
my @TOOLTIP_EXP = (tooltip => "<b>Experience</b>. The experience points you have in this skill.$TOOLTIP_ALL", can_events => 1, can_hover => 1); |
| 275 |
|
| 276 |
my ($x, $y) = (0, 1); |
| 277 |
for ( |
| 278 |
sort { $stats->{$b->[0]}[1] <=> $stats->{$a->[0]}[1] or $a->[1] cmp $b->[1] } |
| 279 |
map [$_, $self->{skill_info}{$_}], |
| 280 |
grep exists $stats->{$_}, |
| 281 |
@skills |
| 282 |
) { |
| 283 |
my ($idx, $name) = @$_; |
| 284 |
|
| 285 |
my $spell_cb = sub { |
| 286 |
my ($widget, $ev) = @_; |
| 287 |
|
| 288 |
if ($ev->{button} == 1) { |
| 289 |
$::CONN->user_send ("ready_skill $name"); |
| 290 |
} elsif ($ev->{button} == 2) { |
| 291 |
$::CONN->user_send ("use_skill $name"); |
| 292 |
} elsif ($ev->{button} == 3) { |
| 293 |
my $shortname = CFPlus::shorten $name, 14; |
| 294 |
(new CFPlus::UI::Menu |
| 295 |
items => [ |
| 296 |
["bind <i>ready_skill $shortname</i> to a key" => sub { $::BIND_EDITOR->do_quick_binding (["ready_skill $name"]) }], |
| 297 |
["bind <i>use_skill $shortname</i> to a key" => sub { $::BIND_EDITOR->do_quick_binding (["use_skill $name"]) }], |
| 298 |
], |
| 299 |
)->popup ($ev); |
| 300 |
} else { |
| 301 |
return 0; |
| 302 |
} |
| 303 |
|
| 304 |
1 |
| 305 |
}; |
| 306 |
|
| 307 |
$sktbl->add ($x * 3 + 0, $y, $self->{stat_widget_exp}{$idx} = new CFPlus::UI::Label |
| 308 |
text => "0", align => 1, font => $::FONT_FIXED, fg => [1, 1, 0], on_button_down => $spell_cb, @TOOLTIP_EXP); |
| 309 |
$sktbl->add ($x * 3 + 1, $y, $self->{stat_widget_lvl}{$idx} = new CFPlus::UI::Label |
| 310 |
text => "0", align => 1, font => $::FONT_FIXED, fg => [0, 1, 0], padding_x => 4, on_button_down => $spell_cb, @TOOLTIP_LVL); |
| 311 |
$sktbl->add ($x * 3 + 2, $y, new CFPlus::UI::Label text => $name, on_button_down => $spell_cb, |
| 312 |
can_events => 1, can_hover => 1, tooltip => (CFPlus::Pod::section_label skill_description => $name) . $TOOLTIP_ALL); |
| 313 |
|
| 314 |
$x++ and ($x, $y) = (0, $y + 1); |
| 315 |
} |
| 316 |
} |
| 317 |
|
| 318 |
for (grep exists $stats->{$_}, @skills) { |
| 319 |
$self->{stat_widget_exp}{$_}->set_text (::formsep ($stats->{$_}[1])); |
| 320 |
$self->{stat_widget_lvl}{$_}->set_text ($stats->{$_}[0] * 1); |
| 321 |
} |
| 322 |
} |
| 323 |
|
| 324 |
sub user_send { |
| 325 |
my ($self, $command) = @_; |
| 326 |
|
| 327 |
push @{$self->{record}}, $command |
| 328 |
if $self->{record}; |
| 329 |
|
| 330 |
$self->logprint ("send: ", $command); |
| 331 |
$self->send_command ($command); |
| 332 |
::status ($command); |
| 333 |
} |
| 334 |
|
| 335 |
sub start_record { |
| 336 |
my ($self) = @_; |
| 337 |
|
| 338 |
$self->{record} = []; |
| 339 |
} |
| 340 |
|
| 341 |
sub stop_record { |
| 342 |
my ($self) = @_; |
| 343 |
return delete $self->{record}; |
| 344 |
} |
| 345 |
|
| 346 |
sub map_scroll { |
| 347 |
my ($self, $dx, $dy) = @_; |
| 348 |
|
| 349 |
$self->{map}->scroll ($dx, $dy); |
| 350 |
} |
| 351 |
|
| 352 |
sub feed_map1a { |
| 353 |
my ($self, $data) = @_; |
| 354 |
|
| 355 |
$self->{map}->map1a_update ($data, $self->{setup}{extmap}); |
| 356 |
$self->{map_widget}->update; |
| 357 |
} |
| 358 |
|
| 359 |
sub magicmap { |
| 360 |
my ($self, $w, $h, $x, $y, $data) = @_; |
| 361 |
|
| 362 |
$self->{map_widget}->set_magicmap ($w, $h, $x, $y, $data); |
| 363 |
} |
| 364 |
|
| 365 |
sub flush_map { |
| 366 |
my ($self) = @_; |
| 367 |
|
| 368 |
my $map_info = delete $self->{map_info} |
| 369 |
or return; |
| 370 |
|
| 371 |
my ($hash, $x, $y, $w, $h) = @$map_info; |
| 372 |
|
| 373 |
my $data = $self->{map}->get_rect ($x, $y, $w, $h); |
| 374 |
$self->{mapcache}->put ($hash => Compress::LZF::compress $data); |
| 375 |
#warn sprintf "SAVEmap[%s] length %d\n", $hash, length $data;#d# |
| 376 |
} |
| 377 |
|
| 378 |
sub map_clear { |
| 379 |
my ($self) = @_; |
| 380 |
|
| 381 |
$self->flush_map; |
| 382 |
delete $self->{neigh_map}; |
| 383 |
|
| 384 |
$self->{map}->clear; |
| 385 |
delete $self->{map_widget}{magicmap}; |
| 386 |
} |
| 387 |
|
| 388 |
|
| 389 |
sub load_map($$$) { |
| 390 |
my ($self, $hash, $x, $y) = @_; |
| 391 |
|
| 392 |
if (defined (my $data = $self->{mapcache}->get ($hash))) { |
| 393 |
$data = Compress::LZF::decompress $data; |
| 394 |
#warn sprintf "LOADmap[%s,%d,%d] length %d\n", $hash, $x, $y, length $data;#d# |
| 395 |
for my $id ($self->{map}->set_rect ($x, $y, $data)) { |
| 396 |
my $data = $self->{tilecache}->get ($id) |
| 397 |
or next; |
| 398 |
|
| 399 |
$self->set_texture ($id => $data); |
| 400 |
} |
| 401 |
} |
| 402 |
} |
| 403 |
|
| 404 |
# hardcode /world/world_xxx_xxx map names, the savings are enourmous, |
| 405 |
# (server resource,s latency, bandwidth), so this hack is warranted. |
| 406 |
# the right fix is to make real tiled maps with an overview file |
| 407 |
sub send_mapinfo { |
| 408 |
my ($self, $data, $cb) = @_; |
| 409 |
|
| 410 |
if ($self->{map_info}[0] =~ m%^/world/world_(\d\d\d)_(\d\d\d)$%) { |
| 411 |
my ($wx, $wy) = ($1, $2); |
| 412 |
|
| 413 |
if ($data =~ /^spatial ([1-4]+)$/) { |
| 414 |
my @dx = (0, 0, 1, 0, -1); |
| 415 |
my @dy = (0, -1, 0, 1, 0); |
| 416 |
my ($dx, $dy); |
| 417 |
|
| 418 |
for (split //, $1) { |
| 419 |
$dx += $dx[$_]; |
| 420 |
$dy += $dy[$_]; |
| 421 |
} |
| 422 |
|
| 423 |
$cb->(spatial => 15, |
| 424 |
$self->{map_info}[1] - $self->{map}->ox + $dx * 50, |
| 425 |
$self->{map_info}[2] - $self->{map}->oy + $dy * 50, |
| 426 |
50, 50, |
| 427 |
sprintf "/world/world_%03d_%03d", $wx + $dx, $wy + $dy |
| 428 |
); |
| 429 |
|
| 430 |
return; |
| 431 |
} |
| 432 |
} |
| 433 |
|
| 434 |
$self->SUPER::send_mapinfo ($data, $cb); |
| 435 |
} |
| 436 |
|
| 437 |
# this method does a "flood fill" into every tile direction |
| 438 |
# it assumes that tiles are arranged in a rectangular grid, |
| 439 |
# i.e. a map is the same as the left of the right map etc. |
| 440 |
# failure to comply are harmless and result in display errors |
| 441 |
# at worst. |
| 442 |
sub flood_fill { |
| 443 |
my ($self, $block, $gx, $gy, $path, $hash, $flags) = @_; |
| 444 |
|
| 445 |
# the server does not allow map paths > 6 |
| 446 |
return if 7 <= length $path; |
| 447 |
|
| 448 |
my ($x0, $y0, $x1, $y1) = @{$self->{neigh_rect}}; |
| 449 |
|
| 450 |
for ( |
| 451 |
[1, 3, 0, -1], |
| 452 |
[2, 4, 1, 0], |
| 453 |
[3, 1, 0, 1], |
| 454 |
[4, 2, -1, 0], |
| 455 |
) { |
| 456 |
my ($tile, $tile2, $dx, $dy) = @$_; |
| 457 |
|
| 458 |
next if $block & (1 << $tile); |
| 459 |
my $block = $block | (1 << $tile2); |
| 460 |
|
| 461 |
my $gx = $gx + $dx; |
| 462 |
my $gy = $gy + $dy; |
| 463 |
|
| 464 |
next unless $flags & (1 << ($tile - 1)); |
| 465 |
next if $self->{neigh_grid}{$gx, $gy}++; |
| 466 |
|
| 467 |
my $neigh = $self->{neigh_map}{$hash} ||= []; |
| 468 |
if (my $info = $neigh->[$tile]) { |
| 469 |
my ($flags, $x, $y, $w, $h, $hash) = @$info; |
| 470 |
|
| 471 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
| 472 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
| 473 |
|
| 474 |
} else { |
| 475 |
$self->send_mapinfo ("spatial $path$tile", sub { |
| 476 |
my ($mode, $flags, $x, $y, $w, $h, $hash) = @_; |
| 477 |
|
| 478 |
return if $mode ne "spatial"; |
| 479 |
|
| 480 |
$x += $self->{map}->ox; |
| 481 |
$y += $self->{map}->oy; |
| 482 |
|
| 483 |
$self->load_map ($hash, $x, $y) |
| 484 |
unless $self->{neigh_map}{$hash}[5]++;#d# |
| 485 |
|
| 486 |
$neigh->[$tile] = [$flags, $x, $y, $w, $h, $hash]; |
| 487 |
|
| 488 |
$self->flood_fill ($block, $gx, $gy, "$path$tile", $hash, $flags) |
| 489 |
if $x >= $x0 && $x + $w < $x1 && $y >= $y0 && $y + $h < $y1; |
| 490 |
}); |
| 491 |
} |
| 492 |
} |
| 493 |
} |
| 494 |
|
| 495 |
sub map_change { |
| 496 |
my ($self, $mode, $flags, $x, $y, $w, $h, $hash) = @_; |
| 497 |
|
| 498 |
$self->flush_map; |
| 499 |
|
| 500 |
my ($ox, $oy) = ($::MAP->ox, $::MAP->oy); |
| 501 |
|
| 502 |
my $mapmapw = $self->{mapmap}->{w}; |
| 503 |
my $mapmaph = $self->{mapmap}->{h}; |
| 504 |
|
| 505 |
$self->{neigh_rect} = [ |
| 506 |
$ox - $mapmapw * 0.5, $oy - $mapmapw * 0.5, |
| 507 |
$ox + $mapmapw * 0.5 + $w, $oy + $mapmapw * 0.5 + $h, |
| 508 |
]; |
| 509 |
|
| 510 |
delete $self->{neigh_grid}; |
| 511 |
|
| 512 |
$x += $ox; |
| 513 |
$y += $oy; |
| 514 |
|
| 515 |
$self->{map_info} = [$hash, $x, $y, $w, $h]; |
| 516 |
|
| 517 |
(my $map = $hash) =~ s/^.*?\/([^\/]+)$/\1/; |
| 518 |
$::STATWIDS->{map}->set_text ("Map: " . $map); |
| 519 |
|
| 520 |
$self->load_map ($hash, $x, $y); |
| 521 |
$self->flood_fill (0, 0, 0, "", $hash, $flags); |
| 522 |
} |
| 523 |
|
| 524 |
sub face_find { |
| 525 |
my ($self, $facenum, $face) = @_; |
| 526 |
|
| 527 |
my $hash = "$face->{chksum},$face->{name}"; |
| 528 |
|
| 529 |
my $id = $self->{facemap}->get ($hash); |
| 530 |
|
| 531 |
unless ($id) { |
| 532 |
# create new id for face |
| 533 |
# I love transactions |
| 534 |
for (1..100) { |
| 535 |
my $txn = $CFPlus::DB_ENV->txn_begin; |
| 536 |
my $status = $self->{facemap}->db_get (id => $id); |
| 537 |
if ($status == 0 || $status == BerkeleyDB::DB_NOTFOUND) { |
| 538 |
$id = ($id || 64) + 1; |
| 539 |
if ($self->{facemap}->put (id => $id) == 0 |
| 540 |
&& $self->{facemap}->put ($hash => $id) == 0) { |
| 541 |
$txn->txn_commit; |
| 542 |
|
| 543 |
goto gotid; |
| 544 |
} |
| 545 |
} |
| 546 |
$txn->txn_abort; |
| 547 |
} |
| 548 |
|
| 549 |
CFPlus::fatal "maximum number of transaction retries reached - database problems?"; |
| 550 |
} |
| 551 |
|
| 552 |
gotid: |
| 553 |
$face->{id} = $id; |
| 554 |
$self->{map}->set_face ($facenum => $id); |
| 555 |
$self->{faceid}[$facenum] = $id;#d# |
| 556 |
|
| 557 |
my $face = $self->{tilecache}->get ($id); |
| 558 |
|
| 559 |
if ($face) { |
| 560 |
#$self->face_prefetch; |
| 561 |
$face |
| 562 |
} else { |
| 563 |
my $tex = $self->{noface}; |
| 564 |
$self->{map}->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
| 565 |
undef |
| 566 |
}; |
| 567 |
} |
| 568 |
|
| 569 |
sub face_update { |
| 570 |
my ($self, $facenum, $face, $changed) = @_; |
| 571 |
|
| 572 |
$self->{tilecache}->put ($face->{id} => $face->{image}) if $changed; |
| 573 |
|
| 574 |
$self->set_texture ($face->{id} => delete $face->{image}); |
| 575 |
} |
| 576 |
|
| 577 |
sub set_texture { |
| 578 |
my ($self, $id, $data) = @_; |
| 579 |
|
| 580 |
$self->{texture}[$id] ||= do { |
| 581 |
my $tex = |
| 582 |
new_from_image CFPlus::Texture |
| 583 |
$data, minify => 1, mipmap => 1; |
| 584 |
|
| 585 |
$self->{map}->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}}); |
| 586 |
$self->{map_widget}->update; |
| 587 |
|
| 588 |
$tex |
| 589 |
}; |
| 590 |
} |
| 591 |
|
| 592 |
sub sound_play { |
| 593 |
my ($self, $x, $y, $soundnum, $type) = @_; |
| 594 |
|
| 595 |
$self->{sound_play}->($x, $y, $soundnum, $type); |
| 596 |
} |
| 597 |
|
| 598 |
my $LAST_QUERY; # server is stupid, stupid, stupid |
| 599 |
|
| 600 |
sub query { |
| 601 |
my ($self, $flags, $prompt) = @_; |
| 602 |
|
| 603 |
$prompt = $LAST_QUERY unless length $prompt; |
| 604 |
$LAST_QUERY = $prompt; |
| 605 |
|
| 606 |
$self->{query}-> ($self, $flags, $prompt); |
| 607 |
} |
| 608 |
|
| 609 |
sub drawinfo { |
| 610 |
my ($self, $color, $text) = @_; |
| 611 |
|
| 612 |
my @color = ( |
| 613 |
[1.00, 1.00, 1.00], #[0.00, 0.00, 0.00], |
| 614 |
[1.00, 1.00, 1.00], |
| 615 |
[0.50, 0.50, 1.00], #[0.00, 0.00, 0.55] |
| 616 |
[1.00, 0.00, 0.00], |
| 617 |
[1.00, 0.54, 0.00], |
| 618 |
[0.11, 0.56, 1.00], |
| 619 |
[0.93, 0.46, 0.00], |
| 620 |
[0.18, 0.54, 0.34], |
| 621 |
[0.56, 0.73, 0.56], |
| 622 |
[0.80, 0.80, 0.80], |
| 623 |
[0.75, 0.61, 0.20], |
| 624 |
[0.99, 0.77, 0.26], |
| 625 |
[0.74, 0.65, 0.41], |
| 626 |
); |
| 627 |
|
| 628 |
$self->logprint ("info: ", $text); |
| 629 |
|
| 630 |
# try to create single paragraphs of multiple lines sent by the server |
| 631 |
$text =~ s/(?<=\S)\n(?=\w)/ /g; |
| 632 |
|
| 633 |
$text = CFPlus::asxml $text; |
| 634 |
$text =~ s/\[b\](.*?)\[\/b\]/<b>\1<\/b>/g; |
| 635 |
$text =~ s/\[color=(.*?)\](.*?)\[\/color\]/<span foreground='\1'>\2<\/span>/g; |
| 636 |
|
| 637 |
::message ({ fg => $color[$color], markup => $_ }) |
| 638 |
for split /\n/, $text; |
| 639 |
|
| 640 |
$self->{statusbox}->add ($text, |
| 641 |
group => $text, |
| 642 |
fg => $color[$color], |
| 643 |
timeout => $color >= 2 ? 180 : 10, |
| 644 |
tooltip_font => $::FONT_FIXED, |
| 645 |
); |
| 646 |
} |
| 647 |
|
| 648 |
sub drawextinfo { |
| 649 |
my ($self, $color, $type, $subtype, $message) = @_; |
| 650 |
|
| 651 |
$self->drawinfo ($color, $message); |
| 652 |
} |
| 653 |
|
| 654 |
sub spell_add { |
| 655 |
my ($self, $spell) = @_; |
| 656 |
|
| 657 |
# try to create single paragraphs out of the multiple lines sent by the server |
| 658 |
$spell->{message} =~ s/(?<=\S)\n(?=\w)/ /g; |
| 659 |
$spell->{message} =~ s/\n+$//; |
| 660 |
$spell->{message} ||= "Server did not provide a description for this spell."; |
| 661 |
|
| 662 |
$::SPELL_LIST->add_spell ($spell); |
| 663 |
|
| 664 |
$self->{map_widget}->add_command ("invoke $spell->{name}", CFPlus::asxml $spell->{message}); |
| 665 |
$self->{map_widget}->add_command ("cast $spell->{name}", CFPlus::asxml $spell->{message}); |
| 666 |
} |
| 667 |
|
| 668 |
sub spell_delete { |
| 669 |
my ($self, $spell) = @_; |
| 670 |
|
| 671 |
$::SPELL_LIST->remove_spell ($spell); |
| 672 |
} |
| 673 |
|
| 674 |
sub setup { |
| 675 |
my ($self, $setup) = @_; |
| 676 |
|
| 677 |
$::MAP->resize ($self->{mapw}, $self->{maph}); |
| 678 |
} |
| 679 |
|
| 680 |
sub addme_success { |
| 681 |
my ($self) = @_; |
| 682 |
|
| 683 |
my %skill_help; |
| 684 |
|
| 685 |
for my $node (CFPlus::Pod::find skill_description => "*") { |
| 686 |
my (undef, @par) = CFPlus::Pod::section_of $node; |
| 687 |
$skill_help{$node->{kw}[0]} = CFPlus::Pod::as_label @par; |
| 688 |
}; |
| 689 |
|
| 690 |
for my $skill (values %{$self->{skill_info}}) { |
| 691 |
$self->{map_widget}->add_command ("ready_skill $skill", |
| 692 |
(CFPlus::asxml "Ready the skill '$skill'\n\n") |
| 693 |
. $skill_help{$skill}); |
| 694 |
$self->{map_widget}->add_command ("use_skill $skill", |
| 695 |
(CFPlus::asxml "Immediately use the skill '$skill'\n\n") |
| 696 |
. $skill_help{$skill}); |
| 697 |
} |
| 698 |
} |
| 699 |
|
| 700 |
sub eof { |
| 701 |
my ($self) = @_; |
| 702 |
|
| 703 |
$self->{map_widget}->clr_commands; |
| 704 |
|
| 705 |
::stop_game (); |
| 706 |
} |
| 707 |
|
| 708 |
sub image_info { |
| 709 |
my ($self, $numfaces) = @_; |
| 710 |
|
| 711 |
$self->{num_faces} = $numfaces; |
| 712 |
$self->{face_prefetch} = [1 .. $numfaces]; |
| 713 |
$self->face_prefetch; |
| 714 |
} |
| 715 |
|
| 716 |
sub face_prefetch { |
| 717 |
my ($self) = @_; |
| 718 |
|
| 719 |
return unless $::CFG->{face_prefetch}; |
| 720 |
|
| 721 |
if ($self->{num_faces}) { |
| 722 |
return if @{ $self->{send_queue} || [] }; |
| 723 |
my $todo = @{ $self->{face_prefetch} } |
| 724 |
or return; |
| 725 |
|
| 726 |
my ($face) = splice @{ $self->{face_prefetch} }, + rand @{ $self->{face_prefetch} }, 1, (); |
| 727 |
|
| 728 |
$self->send ("requestinfo image_sums $face $face"); |
| 729 |
|
| 730 |
$self->{statusbox}->add (CFPlus::asxml "prefetching $todo", |
| 731 |
group => "prefetch", timeout => 3, fg => [1, 1, 0, 0.5]); |
| 732 |
} elsif (!exists $self->{num_faces}) { |
| 733 |
$self->send ("requestinfo image_info"); |
| 734 |
|
| 735 |
$self->{num_faces} = 0; |
| 736 |
|
| 737 |
$self->{statusbox}->add (CFPlus::asxml "starting to prefetch", |
| 738 |
group => "prefetch", timeout => 3, fg => [1, 1, 0, 0.5]); |
| 739 |
} |
| 740 |
} |
| 741 |
|
| 742 |
sub update_floorbox { |
| 743 |
$CFPlus::UI::ROOT->on_refresh ($::FLOORBOX => sub { |
| 744 |
return unless $::CONN; |
| 745 |
|
| 746 |
$::FLOORBOX->clear; |
| 747 |
|
| 748 |
my $row; |
| 749 |
for (sort { $a->{count} <=> $b->{count} } values %{ $::CONN->{container}{$::CONN->{open_container} || 0} }) { |
| 750 |
if ($row < 6) { |
| 751 |
local $_->{face_widget}; # hack to force recreation of widget |
| 752 |
local $_->{desc_widget}; # hack to force recreation of widget |
| 753 |
CFPlus::Item::update_widgets $_; |
| 754 |
|
| 755 |
$::FLOORBOX->add (0, $row, $_->{face_widget}); |
| 756 |
$::FLOORBOX->add (1, $row, $_->{desc_widget}); |
| 757 |
|
| 758 |
$row++; |
| 759 |
} else { |
| 760 |
$::FLOORBOX->add (1, $row, new CFPlus::UI::Button |
| 761 |
text => "More...", |
| 762 |
on_activate => sub { ::toggle_player_page ($::INVENTORY_PAGE); 0 }, |
| 763 |
); |
| 764 |
last; |
| 765 |
} |
| 766 |
} |
| 767 |
if ($::CONN->{open_container}) { |
| 768 |
$::FLOORBOX->add (1, $row++, new CFPlus::UI::Button |
| 769 |
text => "Close container", |
| 770 |
on_activate => sub { $::CONN->send ("apply $::CONN->{open_container}") } |
| 771 |
); |
| 772 |
} |
| 773 |
}); |
| 774 |
|
| 775 |
$::WANT_REFRESH++; |
| 776 |
} |
| 777 |
|
| 778 |
sub set_opencont { |
| 779 |
my ($conn, $tag, $name) = @_; |
| 780 |
$conn->{open_container} = $tag; |
| 781 |
update_floorbox; |
| 782 |
|
| 783 |
$::INV_RIGHT_HB->clear (); |
| 784 |
$::INV_RIGHT_HB->add (new CFPlus::UI::Label align => 0, expand => 1, text => $name); |
| 785 |
|
| 786 |
if ($tag != 0) { # Floor isn't closable, is it? |
| 787 |
$::INV_RIGHT_HB->add (new CFPlus::UI::Button |
| 788 |
text => "Close container", |
| 789 |
tooltip => "Close the currently open container (if one is open)", |
| 790 |
on_activate => sub { |
| 791 |
$::CONN->send ("apply $tag") # $::CONN->{open_container}") |
| 792 |
if $tag != 0; |
| 793 |
#if $CONN->{open_container} != 0; |
| 794 |
0 |
| 795 |
}, |
| 796 |
); |
| 797 |
} |
| 798 |
|
| 799 |
$::INVR->set_items ($conn->{container}{$tag}); |
| 800 |
} |
| 801 |
|
| 802 |
sub update_containers { |
| 803 |
my ($self) = @_; |
| 804 |
|
| 805 |
$CFPlus::UI::ROOT->on_refresh ("update_containers_$self" => sub { |
| 806 |
my $todo = delete $self->{update_container} |
| 807 |
or return; |
| 808 |
|
| 809 |
for my $tag (keys %$todo) { |
| 810 |
update_floorbox if $tag == 0 or $tag == $self->{open_container}; |
| 811 |
if ($tag == 0) { |
| 812 |
$::INVR->set_items ($self->{container}{0}) |
| 813 |
if $tag == $self->{open_container}; |
| 814 |
} elsif ($tag == $self->{player}{tag}) { |
| 815 |
$::INV->set_items ($self->{container}{$tag}) |
| 816 |
} else { |
| 817 |
$::INVR->set_items ($self->{container}{$tag}) |
| 818 |
if $tag == $self->{open_container}; |
| 819 |
} |
| 820 |
} |
| 821 |
}); |
| 822 |
} |
| 823 |
|
| 824 |
sub container_add { |
| 825 |
my ($self, $tag, $items) = @_; |
| 826 |
|
| 827 |
$self->{update_container}{$tag}++; |
| 828 |
$self->update_containers; |
| 829 |
} |
| 830 |
|
| 831 |
sub container_clear { |
| 832 |
my ($self, $tag) = @_; |
| 833 |
|
| 834 |
$self->{update_container}{$tag}++; |
| 835 |
$self->update_containers; |
| 836 |
} |
| 837 |
|
| 838 |
sub item_delete { |
| 839 |
my ($self, @items) = @_; |
| 840 |
|
| 841 |
$self->{update_container}{$_->{container}}++ |
| 842 |
for @items; |
| 843 |
|
| 844 |
$self->update_containers; |
| 845 |
} |
| 846 |
|
| 847 |
sub item_update { |
| 848 |
my ($self, $item) = @_; |
| 849 |
|
| 850 |
#d# print "item_update: $item->{tag} in $item->{container} ($self->{player}{tag}) ($::CONN->{open_container})\n"; |
| 851 |
|
| 852 |
CFPlus::Item::update_widgets $item; |
| 853 |
|
| 854 |
if ($item->{tag} == $::CONN->{open_container} && not ($item->{flags} & F_OPEN)) { |
| 855 |
set_opencont ($::CONN, 0, "Floor"); |
| 856 |
|
| 857 |
} elsif ($item->{flags} & F_OPEN) { |
| 858 |
set_opencont ($::CONN, $item->{tag}, CFPlus::Item::desc_string $item); |
| 859 |
|
| 860 |
} else { |
| 861 |
$self->{update_container}{$item->{container}}++; |
| 862 |
$self->update_containers; |
| 863 |
} |
| 864 |
} |
| 865 |
|
| 866 |
sub player_update { |
| 867 |
my ($self, $player) = @_; |
| 868 |
|
| 869 |
$self->update_weight; |
| 870 |
} |
| 871 |
|
| 872 |
sub update_weight { |
| 873 |
my ($self) = @_; |
| 874 |
|
| 875 |
my $weight = .001 * $self->{player}{weight}; |
| 876 |
my $limit = .001 * $self->{stat}{+CS_STAT_WEIGHT_LIM}; |
| 877 |
|
| 878 |
$::STATWIDS->{weight}->set_text (sprintf "Weight: %.1fkg", $weight); |
| 879 |
$::STATWIDS->{m_weight}->set_text (sprintf "%.1fkg", $limit); |
| 880 |
$::STATWIDS->{i_weight}->set_text (sprintf "%.1f/%.1fkg", $weight, $limit); |
| 881 |
} |
| 882 |
|
| 883 |
sub update_server_info { |
| 884 |
my ($self) = @_; |
| 885 |
|
| 886 |
my @yesno = ("<span foreground='red'>no</span>", "<span foreground='green'>yes</span>"); |
| 887 |
|
| 888 |
$::SERVER_INFO->set_markup ( |
| 889 |
"server <tt>$self->{host}:$self->{port}</tt>\n" |
| 890 |
. "protocol version <tt>$self->{version}</tt>\n" |
| 891 |
. "minimap support $yesno[$self->{setup}{mapinfocmd} > 0]\n" |
| 892 |
. "extended command support $yesno[$self->{setup}{extcmd} > 0]\n" |
| 893 |
. "editing support $yesno[!!$self->{editor_support}]\n" |
| 894 |
. "map attributes $yesno[$self->{setup}{extmap} > 0]\n" |
| 895 |
. "cfplus support $yesno[$self->{cfplus_ext} > 0]" |
| 896 |
. ($self->{cfplus_ext} > 0 ? ", version $self->{cfplus_ext}" : "") ."\n" |
| 897 |
. "map size $self->{mapw}×$self->{maph}\n" |
| 898 |
); |
| 899 |
|
| 900 |
::setup_build_button ($self->{editor_support}->{builder_ui}); |
| 901 |
} |
| 902 |
|
| 903 |
sub logged_in { |
| 904 |
my ($self) = @_; |
| 905 |
|
| 906 |
$self->send_ext_req (cfplus_support => version => 1, sub { |
| 907 |
$self->{cfplus_ext} = $_[0]{version}; |
| 908 |
$self->update_server_info; |
| 909 |
|
| 910 |
if ($self->{cfplus_ext} >= 2) { |
| 911 |
$self->send_ext_req ("editor_support", sub { |
| 912 |
$self->{editor_support} = $_[0]; |
| 913 |
$self->update_server_info; |
| 914 |
|
| 915 |
0 |
| 916 |
}); |
| 917 |
} |
| 918 |
|
| 919 |
0 |
| 920 |
}); |
| 921 |
|
| 922 |
$self->update_server_info; |
| 923 |
|
| 924 |
$self->send_command ("output-sync $::CFG->{output_sync}"); |
| 925 |
$self->send_command ("output-count $::CFG->{output_count}"); |
| 926 |
$self->send_command ("pickup $::CFG->{pickup}"); |
| 927 |
} |
| 928 |
|
| 929 |
sub buildat { |
| 930 |
my ($self, $builditem, $x, $y) = @_; |
| 931 |
|
| 932 |
if ($self->{cfplus_ext}) { |
| 933 |
$self->send_ext_msg (builder_build => dx => $x, dy => $y, (ref ($builditem) eq 'HASH') ? %$builditem : (item => $builditem)); |
| 934 |
} |
| 935 |
} |
| 936 |
|
| 937 |
sub lookat { |
| 938 |
my ($self, $x, $y) = @_; |
| 939 |
|
| 940 |
if ($self->{cfplus_ext}) { |
| 941 |
$self->send_ext_req (lookat => dx => $x, dy => $y, sub { |
| 942 |
my ($msg) = @_; |
| 943 |
|
| 944 |
if (exists $msg->{npc_dialog}) { |
| 945 |
# start npc chat dialog |
| 946 |
$self->{npc_dialog} = new CFPlus::NPCDialog:: |
| 947 |
dx => $x, |
| 948 |
dy => $y, |
| 949 |
title => "$msg->{npc_dialog} (NPC)", |
| 950 |
conn => $self, |
| 951 |
; |
| 952 |
} |
| 953 |
}); |
| 954 |
} |
| 955 |
|
| 956 |
$self->send ("lookat $x $y"); |
| 957 |
} |
| 958 |
|
| 959 |
sub destroy { |
| 960 |
my ($self) = @_; |
| 961 |
|
| 962 |
(delete $self->{npc_dialog})->destroy |
| 963 |
if $self->{npc_dialog}; |
| 964 |
|
| 965 |
$self->SUPER::destroy; |
| 966 |
} |
| 967 |
|
| 968 |
package CFPlus::NPCDialog; |
| 969 |
|
| 970 |
our @ISA = 'CFPlus::UI::Toplevel'; |
| 971 |
|
| 972 |
sub new { |
| 973 |
my $class = shift; |
| 974 |
|
| 975 |
my $self = $class->SUPER::new ( |
| 976 |
x => 'center', |
| 977 |
y => 'center', |
| 978 |
name => "npc_dialog", |
| 979 |
force_w => $::WIDTH * 0.7, |
| 980 |
force_h => $::HEIGHT * 0.7, |
| 981 |
title => "NPC Dialog", |
| 982 |
kw => { hi => 0, yes => 0, no => 0 }, |
| 983 |
has_close_button => 1, |
| 984 |
@_, |
| 985 |
); |
| 986 |
|
| 987 |
Scalar::Util::weaken (my $this = $self); |
| 988 |
|
| 989 |
$self->connect (delete => sub { $this->destroy; 1 }); |
| 990 |
|
| 991 |
# better use a pane... |
| 992 |
$self->add (my $hbox = new CFPlus::UI::HBox); |
| 993 |
$hbox->add ($self->{textview} = new CFPlus::UI::TextScroller expand => 1); |
| 994 |
|
| 995 |
$hbox->add (my $vbox = new CFPlus::UI::VBox); |
| 996 |
|
| 997 |
$vbox->add (new CFPlus::UI::Label text => "Message Entry:"); |
| 998 |
$vbox->add ($self->{entry} = new CFPlus::UI::Entry |
| 999 |
tooltip => "#npc_message_entry", |
| 1000 |
on_activate => sub { |
| 1001 |
my ($entry, $text) = @_; |
| 1002 |
|
| 1003 |
return unless $text =~ /\S/; |
| 1004 |
|
| 1005 |
$entry->set_text (""); |
| 1006 |
$this->send ($text); |
| 1007 |
|
| 1008 |
0 |
| 1009 |
}, |
| 1010 |
); |
| 1011 |
|
| 1012 |
$vbox->add ($self->{options} = new CFPlus::UI::VBox); |
| 1013 |
|
| 1014 |
$self->{bye_button} = new CFPlus::UI::Button |
| 1015 |
text => "Bye (close)", |
| 1016 |
tooltip => "Use this button to end talking to the NPC. This also closes the dialog window.", |
| 1017 |
on_activate => sub { $this->destroy; 1 }, |
| 1018 |
; |
| 1019 |
|
| 1020 |
$self->update_options; |
| 1021 |
|
| 1022 |
$self->{id} = $self->{conn}->send_ext_req ( |
| 1023 |
npc_dialog_begin => dx => $self->{dx}, dy => $self->{dy}, |
| 1024 |
sub { $this && $this->feed (@_) } |
| 1025 |
); |
| 1026 |
|
| 1027 |
$self->{entry}->grab_focus; |
| 1028 |
|
| 1029 |
$self->{textview}->add_paragraph ({ |
| 1030 |
fg => [1, 1, 0, 1], |
| 1031 |
markup => "<small>[starting conversation with <b>$self->{title}</b>]</small>\n\n", |
| 1032 |
}); |
| 1033 |
|
| 1034 |
$self->show; |
| 1035 |
$self |
| 1036 |
}; |
| 1037 |
|
| 1038 |
sub update_options { |
| 1039 |
my ($self) = @_; |
| 1040 |
|
| 1041 |
Scalar::Util::weaken $self; |
| 1042 |
|
| 1043 |
$self->{options}->clear; |
| 1044 |
$self->{options}->add ($self->{bye_button}); |
| 1045 |
|
| 1046 |
for my $kw (sort keys %{ $self->{kw} }) { |
| 1047 |
$self->{options}->add (new CFPlus::UI::Button |
| 1048 |
text => $kw, |
| 1049 |
on_activate => sub { |
| 1050 |
$self->send ($kw); |
| 1051 |
0 |
| 1052 |
}, |
| 1053 |
); |
| 1054 |
} |
| 1055 |
} |
| 1056 |
|
| 1057 |
sub feed { |
| 1058 |
my ($self, $msg) = @_; |
| 1059 |
|
| 1060 |
Scalar::Util::weaken $self; |
| 1061 |
|
| 1062 |
if ($msg->{msgtype} eq "reply") { |
| 1063 |
$self->{kw}{$_} = 1 for @{$msg->{add_topics} || []}; |
| 1064 |
$self->{kw}{$_} = 0 for @{$msg->{del_topics} || []}; |
| 1065 |
|
| 1066 |
my $text = "\n" . CFPlus::asxml $msg->{msg}; |
| 1067 |
my $match = join "|", map "\\b\Q$_\E\\b", sort { (length $b) <=> (length $a) } keys %{ $self->{kw} }; |
| 1068 |
my @link; |
| 1069 |
$text =~ s{ |
| 1070 |
($match) |
| 1071 |
}{ |
| 1072 |
my $kw = $1; |
| 1073 |
|
| 1074 |
push @link, new CFPlus::UI::Label |
| 1075 |
markup => "<span foreground='#c0c0ff' underline='single'>$kw</span>", |
| 1076 |
can_hover => 1, |
| 1077 |
can_events => 1, |
| 1078 |
padding_x => 0, |
| 1079 |
padding_y => 0, |
| 1080 |
on_button_up => sub { |
| 1081 |
$self->send ($kw); |
| 1082 |
}; |
| 1083 |
|
| 1084 |
"\x{fffc}" |
| 1085 |
}giex; |
| 1086 |
|
| 1087 |
$self->{textview}->add_paragraph ({ markup => $text, widget => \@link }); |
| 1088 |
$self->{textview}->scroll_to_bottom; |
| 1089 |
$self->update_options; |
| 1090 |
} else { |
| 1091 |
$self->destroy; |
| 1092 |
} |
| 1093 |
|
| 1094 |
1 |
| 1095 |
} |
| 1096 |
|
| 1097 |
sub send { |
| 1098 |
my ($self, $msg) = @_; |
| 1099 |
|
| 1100 |
$self->{textview}->add_paragraph ({ markup => "\n" . CFPlus::asxml $msg }); |
| 1101 |
$self->{textview}->scroll_to_bottom; |
| 1102 |
|
| 1103 |
$self->{conn}->send_ext_msg (npc_dialog_tell => msgid => $self->{id}, msg => $msg); |
| 1104 |
} |
| 1105 |
|
| 1106 |
sub destroy { |
| 1107 |
my ($self) = @_; |
| 1108 |
|
| 1109 |
#Carp::cluck "debug\n";#d# #todo# enable: destroy gets called twice because scalar keys {} is 1 |
| 1110 |
|
| 1111 |
if ($self->{conn}) { |
| 1112 |
$self->{conn}->send_ext_msg (npc_dialog_end => msgid => $self->{id}) if $self->{id}; |
| 1113 |
delete $self->{conn}{npc_dialog}; |
| 1114 |
$self->{conn}->disconnect_ext ($self->{id}); |
| 1115 |
} |
| 1116 |
|
| 1117 |
$self->SUPER::destroy; |
| 1118 |
} |
| 1119 |
|
| 1120 |
1 |
| 1121 |
|
