Deliantra-Client/DC/Texture.pm

=head1 NAME

CFPlus::Texture - tetxure class for CFPlus

=head1 SYNOPSIS

 use CFPlus::Texture;

=head1 DESCRIPTION

=over 4

=cut

package CFPlus::Texture;

use strict;

use List::Util qw(max min);
use CFPlus::OpenGL;

my %TEXTURES;
my ($MAX_W, $MAX_H) = (4096, 4096); # maximum texture size attempted by this module

sub new {
   my ($class, %data) = @_;

   my $self = bless {
      internalformat => GL_RGBA,
      format         => GL_RGBA,
      type           => GL_UNSIGNED_BYTE,
      %data,
   }, $class;

   CFPlus::weaken ($TEXTURES{$self+0} = $self);

   $self->upload;

   $self
}

sub new_from_image {
   my ($class, $image, %arg) = @_;

   Carp::confess "tried to create texture from undefined image"
      unless defined $image;

   $class->new (image => $image, internalformat => undef, %arg)
}

sub new_from_file {
   my ($class, $path, %arg) = @_;

   open my $fh, "<:raw", $path
      or die "$path: $!";

   local $/;
   $class->new_from_image (<$fh>, %arg)
}

#sub new_from_surface {
#   my ($class, $surface) = @_;
#
#   $surface->rgba;
#
#   $class->new (
#      data   => $surface->pixels,
#      w      => $surface->width,
#      h      => $surface->height,
#   )
#}

#sub new_from_layout {
#   my ($class, $layout, %arg) = @_;
#
#   my ($w, $h, $data, $format, $internalformat) = $layout->render;
#
#   $class->new (
#      w              => $w,
#      h              => $h,
#      data           => $data,
#      format         => $format,
#      internalformat => $format,
#      type           => GL_UNSIGNED_BYTE,
#      %arg,
#   )
#}

sub new_from_opengl {
   my ($class, $w, $h, $cb) = @_;

   $class->new (w => $w || 1, h => $h || 1, render_cb => $cb, nearest => 1)
}

sub upload {
   my ($self) = @_;

   return unless $GL_VERSION;

   # $tw,$th texture
   # $rw,$rh rendered/used size
   # $dw,$dh $data

   my ($data, $dw, $dh);

   if (exists $self->{data}) {
      $data = $self->{data};
      ($dw, $dh) = @$self{qw(w h)};

   } elsif (exists $self->{render_cb}) {
      ($dw, $dh) = @$self{qw(w h)};

   } elsif (exists $self->{image}) {
      ($self->{w}, $self->{h}, $data, my $internalformat, $self->{format}, $self->{type})
         = CFPlus::load_image_inline $self->{image};

      $self->{internalformat} ||= $internalformat;
      ($dw, $dh) = @$self{qw(w h)};
   } else {
      Carp::confess "tried to create texture that is not data, render or image";
   }

   my ($tw, $th) = ($dw, $dh);

   defined $data or $self->{render_cb} or die; # some sanity check

   $self->{minified} ||= [CFPlus::average $dw, $dh, $data]
      if $self->{minify};

   # against rather broken cards we enforce a maximum texture size
   $tw = min $MAX_W, minpot $tw;
   $th = min $MAX_H, minpot $th;

   # if only pot-textures are allowed, pot'ify tw/th
   unless ($GL_NPOT && 0) {#d#
      $tw = minpot $tw;
      $th = minpot $th;
   }

   # now further decrease texture size until the
   # card does accept it
   while (!texture_valid_2d $self->{internalformat}, $tw, $th, $self->{format}, $self->{type}) {
      # quarter the texture size
      $tw >>= 1;
      $th >>= 1;
   }

   # decide the amount of space used in the texture
   my ($rw, $rh);
   my ($ox, $oy); # area shift to lessen effetc of buggy opengl implementations (nvida, ati)
   my $render;

   if ($self->{render_cb}) {
      # use only part of the texture
      #$rw >>= 1 while $rw > $tw;
      #$rh >>= 1 while $rh > $th;
      $rw = min $dw, $tw;
      $rh = min $dh, $th;
      ++$render;
   } else {
      if ($self->{wrap} || $tw < $dw || $th < $dh) {
         # scale to the full texture size
         ($rw, $rh) = ($tw, $th);
         ++$render;
      } else {
         # pad
         pad $data, $dw, $dh, $tw, $th;
         ($rw, $rh) = ($dw, $dh);
         ($dw, $dh) = ($tw, $th);
      }
   }

   if ($render) {
      $ox = int .5 * ($::WIDTH  - $rw);
      $oy = int .5 * ($::HEIGHT - $rh);

      glViewport $ox, $oy, $tw, $th;
      #glScissor 0, 0, $tw, $th;
      #glEnable GL_SCISSOR_TEST;
      glMatrixMode GL_PROJECTION;
      glLoadIdentity;
      glOrtho 0, $tw, 0, $th, -10000, 10000;
      glMatrixMode GL_MODELVIEW;
      glLoadIdentity;

      if ($self->{render_cb}) {
         glScale $rw / $dw, $rh / $dh;
         $self->{render_cb}->($self, $rw, $rh);
      } else {
         glClearColor 0, 0, 0, 0;
         glClear GL_COLOR_BUFFER_BIT;
         glPixelZoom $tw / $dw, $th / $dh;
         glRasterPos 0, 0;
         glDrawPixels $dw, $dh,
                      $self->{format},
                      $self->{type},
                      $data;
         glPixelZoom 1, 1;
      }
   }

   glBindTexture GL_TEXTURE_2D, $self->{name} ||= glGenTexture;

   if ($self->{wrap}) {
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT;
   } else {
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, $GL_VERSION >= 1.2 ? GL_CLAMP_TO_EDGE : GL_CLAMP;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, $GL_VERSION >= 1.2 ? GL_CLAMP_TO_EDGE : GL_CLAMP;
   }

   if ($::FAST || $self->{nearest}) {
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST;
   } elsif ($self->{mipmap} && $GL_VERSION >= 1.4) {
      glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, 1;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR;
   } else {
      glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, $self->{mipmap};
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
      glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR;
   }
   
   glGetError;

   if ($render) {
      glCopyTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   $ox, $oy,
                   $tw, $th,
                   0;
      gl_check "copying to texture %dx%d if=%x",
               $tw, $th, $self->{internalformat};

      #glDisable GL_SCISSOR_TEST;
   } else {
      glTexImage2D GL_TEXTURE_2D, 0,
                   $self->{internalformat},
                   $dw, $dh,
                   0,
                   $self->{format},
                   $self->{type},
                   $data;
      gl_check "uploading texture %dx%d if=%x f=%x t=%x",
               $tw, $th, $self->{internalformat},  $self->{format}, $self->{type};
   }

   $self->{s} = $rw / $tw;
   $self->{t} = $rh / $th;
}

sub shutdown {
   my ($self) = @_;

   glDeleteTexture $self->{name}
      if $self->{name};
} 

sub DESTROY {
   my ($self) = @_;

   delete $TEXTURES{$self+0};

   $self->shutdown;
}

$CFPlus::OpenGL::INIT_HOOK{"CFPlus::Texture"} = sub {
   # first mark all existing texture names as in-use, in case the context lost textures
   glBindTexture GL_TEXTURE_2D, $_->{name}
      for values %TEXTURES;
   $_->upload
      for values %TEXTURES;
};

$CFPlus::OpenGL::SHUTDOWN_HOOK{"CFPlus::Texture"} = sub {
   $_->shutdown
      for values %TEXTURES;
};

1;

=back

=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

=cut

Revision:	1.24
Committed:	Sun Jul 29 03:58:26 2007 UTC (16 years, 10 months ago) by root
Branch:	MAIN
Changes since 1.23:	+6 -1 lines
Log Message:	much improved sdl_mixer support - abstracted rwops - enabled (experimental?) Mix_LoadMUS_RW - abstracted channels - implemented effects api - partial rewrite on perl side only (no need to store resources as separate data files anymore). - catch more bugs w.r.t. textures.
#	Content
1	=head1 NAME
2
3	CFPlus::Texture - tetxure class for CFPlus
4
5	=head1 SYNOPSIS
6
7	use CFPlus::Texture;
8
9	=head1 DESCRIPTION
10
11	=over 4
12
13	=cut
14
15	package CFPlus::Texture;
16
17	use strict;
18
19	use List::Util qw(max min);
20	use CFPlus::OpenGL;
21
22	my %TEXTURES;
23	my ($MAX_W, $MAX_H) = (4096, 4096); # maximum texture size attempted by this module
24
25	sub new {
26	my ($class, %data) = @_;
27
28	my $self = bless {
29	internalformat => GL_RGBA,
30	format => GL_RGBA,
31	type => GL_UNSIGNED_BYTE,
32	%data,
33	}, $class;
34
35	CFPlus::weaken ($TEXTURES{$self+0} = $self);
36
37	$self->upload;
38
39	$self
40	}
41
42	sub new_from_image {
43	my ($class, $image, %arg) = @_;
44
45	Carp::confess "tried to create texture from undefined image"
46	unless defined $image;
47
48	$class->new (image => $image, internalformat => undef, %arg)
49	}
50
51	sub new_from_file {
52	my ($class, $path, %arg) = @_;
53
54	open my $fh, "<:raw", $path
55	or die "$path: $!";
56
57	local $/;
58	$class->new_from_image (<$fh>, %arg)
59	}
60
61	#sub new_from_surface {
62	# my ($class, $surface) = @_;
63	#
64	# $surface->rgba;
65	#
66	# $class->new (
67	# data => $surface->pixels,
68	# w => $surface->width,
69	# h => $surface->height,
70	# )
71	#}
72
73	#sub new_from_layout {
74	# my ($class, $layout, %arg) = @_;
75	#
76	# my ($w, $h, $data, $format, $internalformat) = $layout->render;
77	#
78	# $class->new (
79	# w => $w,
80	# h => $h,
81	# data => $data,
82	# format => $format,
83	# internalformat => $format,
84	# type => GL_UNSIGNED_BYTE,
85	# %arg,
86	# )
87	#}
88
89	sub new_from_opengl {
90	my ($class, $w, $h, $cb) = @_;
91
92	$class->new (w => $w \|\| 1, h => $h \|\| 1, render_cb => $cb, nearest => 1)
93	}
94
95	sub upload {
96	my ($self) = @_;
97
98	return unless $GL_VERSION;
99
100	# $tw,$th texture
101	# $rw,$rh rendered/used size
102	# $dw,$dh $data
103
104	my ($data, $dw, $dh);
105
106	if (exists $self->{data}) {
107	$data = $self->{data};
108	($dw, $dh) = @$self{qw(w h)};
109
110	} elsif (exists $self->{render_cb}) {
111	($dw, $dh) = @$self{qw(w h)};
112
113	} elsif (exists $self->{image}) {
114	($self->{w}, $self->{h}, $data, my $internalformat, $self->{format}, $self->{type})
115	= CFPlus::load_image_inline $self->{image};
116
117	$self->{internalformat} \|\|= $internalformat;
118	($dw, $dh) = @$self{qw(w h)};
119	} else {
120	Carp::confess "tried to create texture that is not data, render or image";
121	}
122
123	my ($tw, $th) = ($dw, $dh);
124
125	defined $data or $self->{render_cb} or die; # some sanity check
126
127	$self->{minified} \|\|= [CFPlus::average $dw, $dh, $data]
128	if $self->{minify};
129
130	# against rather broken cards we enforce a maximum texture size
131	$tw = min $MAX_W, minpot $tw;
132	$th = min $MAX_H, minpot $th;
133
134	# if only pot-textures are allowed, pot'ify tw/th
135	unless ($GL_NPOT && 0) {#d#
136	$tw = minpot $tw;
137	$th = minpot $th;
138	}
139
140	# now further decrease texture size until the
141	# card does accept it
142	while (!texture_valid_2d $self->{internalformat}, $tw, $th, $self->{format}, $self->{type}) {
143	# quarter the texture size
144	$tw >>= 1;
145	$th >>= 1;
146	}
147
148	# decide the amount of space used in the texture
149	my ($rw, $rh);
150	my ($ox, $oy); # area shift to lessen effetc of buggy opengl implementations (nvida, ati)
151	my $render;
152
153	if ($self->{render_cb}) {
154	# use only part of the texture
155	#$rw >>= 1 while $rw > $tw;
156	#$rh >>= 1 while $rh > $th;
157	$rw = min $dw, $tw;
158	$rh = min $dh, $th;
159	++$render;
160	} else {
161	if ($self->{wrap} \|\| $tw < $dw \|\| $th < $dh) {
162	# scale to the full texture size
163	($rw, $rh) = ($tw, $th);
164	++$render;
165	} else {
166	# pad
167	pad $data, $dw, $dh, $tw, $th;
168	($rw, $rh) = ($dw, $dh);
169	($dw, $dh) = ($tw, $th);
170	}
171	}
172
173	if ($render) {
174	$ox = int .5 * ($::WIDTH - $rw);
175	$oy = int .5 * ($::HEIGHT - $rh);
176
177	glViewport $ox, $oy, $tw, $th;
178	#glScissor 0, 0, $tw, $th;
179	#glEnable GL_SCISSOR_TEST;
180	glMatrixMode GL_PROJECTION;
181	glLoadIdentity;
182	glOrtho 0, $tw, 0, $th, -10000, 10000;
183	glMatrixMode GL_MODELVIEW;
184	glLoadIdentity;
185
186	if ($self->{render_cb}) {
187	glScale $rw / $dw, $rh / $dh;
188	$self->{render_cb}->($self, $rw, $rh);
189	} else {
190	glClearColor 0, 0, 0, 0;
191	glClear GL_COLOR_BUFFER_BIT;
192	glPixelZoom $tw / $dw, $th / $dh;
193	glRasterPos 0, 0;
194	glDrawPixels $dw, $dh,
195	$self->{format},
196	$self->{type},
197	$data;
198	glPixelZoom 1, 1;
199	}
200	}
201
202	glBindTexture GL_TEXTURE_2D, $self->{name} \|\|= glGenTexture;
203
204	if ($self->{wrap}) {
205	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT;
206	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT;
207	} else {
208	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, $GL_VERSION >= 1.2 ? GL_CLAMP_TO_EDGE : GL_CLAMP;
209	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, $GL_VERSION >= 1.2 ? GL_CLAMP_TO_EDGE : GL_CLAMP;
210	}
211
212	if ($::FAST \|\| $self->{nearest}) {
213	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_NEAREST;
214	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_NEAREST;
215	} elsif ($self->{mipmap} && $GL_VERSION >= 1.4) {
216	glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, 1;
217	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
218	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR_MIPMAP_LINEAR;
219	} else {
220	glTexParameter GL_TEXTURE_2D, GL_GENERATE_MIPMAP, $self->{mipmap};
221	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
222	glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MIN_FILTER, GL_LINEAR;
223	}
224
225	glGetError;
226
227	if ($render) {
228	glCopyTexImage2D GL_TEXTURE_2D, 0,
229	$self->{internalformat},
230	$ox, $oy,
231	$tw, $th,
232	0;
233	gl_check "copying to texture %dx%d if=%x",
234	$tw, $th, $self->{internalformat};
235
236	#glDisable GL_SCISSOR_TEST;
237	} else {
238	glTexImage2D GL_TEXTURE_2D, 0,
239	$self->{internalformat},
240	$dw, $dh,
241	0,
242	$self->{format},
243	$self->{type},
244	$data;
245	gl_check "uploading texture %dx%d if=%x f=%x t=%x",
246	$tw, $th, $self->{internalformat}, $self->{format}, $self->{type};
247	}
248
249	$self->{s} = $rw / $tw;
250	$self->{t} = $rh / $th;
251	}
252
253	sub shutdown {
254	my ($self) = @_;
255
256	glDeleteTexture $self->{name}
257	if $self->{name};
258	}
259
260	sub DESTROY {
261	my ($self) = @_;
262
263	delete $TEXTURES{$self+0};
264
265	$self->shutdown;
266	}
267
268	$CFPlus::OpenGL::INIT_HOOK{"CFPlus::Texture"} = sub {
269	# first mark all existing texture names as in-use, in case the context lost textures
270	glBindTexture GL_TEXTURE_2D, $_->{name}
271	for values %TEXTURES;
272	$_->upload
273	for values %TEXTURES;
274	};
275
276	$CFPlus::OpenGL::SHUTDOWN_HOOK{"CFPlus::Texture"} = sub {
277	$_->shutdown
278	for values %TEXTURES;
279	};
280
281	1;
282
283	=back
284
285	=head1 AUTHOR
286
287	Marc Lehmann <schmorp@schmorp.de>
288	http://home.schmorp.de/
289
290	=cut
291