Deliantra-Client/DC/UI.pm

package CFClient::UI;

use strict;

use Scalar::Util ();
use List::Util ();

use CFClient;

our ($FOCUS, $HOVER, $GRAB); # various widgets

our $ROOT;
our $BUTTON_STATE;

# class methods for events
sub feed_sdl_key_down_event { 
   $FOCUS->key_down ($_[0]) if $FOCUS;
}

sub feed_sdl_key_up_event {
   $FOCUS->key_up ($_[0]) if $FOCUS;
}

sub feed_sdl_button_down_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->motion_x, $ev->motion_y);

   if (!$BUTTON_STATE) {
      my $widget = $ROOT->find_widget ($x, $y);

      $GRAB = $widget;
      $GRAB->update if $GRAB;
   }

   $BUTTON_STATE |= 1 << ($ev->button - 1);

   $GRAB->button_down ($ev, $GRAB->coord2local ($x, $y)) if $GRAB;
}

sub feed_sdl_button_up_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->motion_x, $ev->motion_y);

   my $widget = $GRAB || $ROOT->find_widget ($x, $y);

   $BUTTON_STATE &= ~(1 << ($ev->button - 1));

   $GRAB->button_up ($ev, $GRAB->coord2local ($x, $y)) if $GRAB;

   if (!$BUTTON_STATE) {
      my $grab = $GRAB; undef $GRAB;
      $grab->update if $grab;
      $GRAB->update if $GRAB;
   }
}

sub feed_sdl_motion_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->motion_x, $ev->motion_y);

   my $widget = $GRAB || $ROOT->find_widget ($x, $y);

   if ($widget != $HOVER) {
      my $hover = $HOVER; $HOVER = $widget;

      $hover->update if $hover && $hover->{can_hover};
      $HOVER->update if $HOVER && $HOVER->{can_hover};
   }

   $HOVER->mouse_motion ($ev, $HOVER->coord2local ($x, $y)) if $HOVER;
}

# convert position array to integers
sub harmonize {
   my ($vals) = @_;

   my $rem = 0;

   for (@$vals) {
      my $i = int $_ + $rem;
      $rem += $_ - $i;
      $_ = $i;
   }
}

#############################################################################

package CFClient::UI::Base;

use strict;

use SDL::OpenGL;

sub new {
   my $class = shift;

   my $self = bless {
      x => 0,
      y => 0,
      z => 0,
      w => -1,
      h => -1,
      @_
   }, $class;

   for (keys %$self) {
      if (/^connect_(.*)$/) {
         $self->connect ($1 => delete $self->{$_});
      }
   }

   $self
}

sub move {
   my ($self, $x, $y, $z) = @_;
   $self->{x} = int $x;
   $self->{y} = int $y;
   $self->{z} = $z if defined $z;
}

sub needs_redraw {
   0
}

sub size_request {
   require Carp;
   Carp::confess "size_request is abtract";
}

sub _size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->{x} = $x;
   $self->{y} = $y;

   return unless $self->{w} != $w || $self->{h} != $h;

   $self->{w} = $w;
   $self->{h} = $h;

   1
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h);
}

# return top left coordinates
sub _topleft {
   my ($self, $x, $y) = @_;

   $self->{parent}->_topleft ($x + $self->{x}, $y + $self->{y});
}

# translate global coordinates to local coordinate system
sub coord2local {
   my ($self, $x, $y) = @_;

   my ($X, $Y) = $self->_topleft;
   ($x - $X, $y - $Y)
}

# translate local coordinates to global coordinate system
sub coord2global {
   my ($self, $x, $y) = @_;

   my ($X, $Y) = $self->_topleft;
   ($x + $X, $y + $Y)
}

sub focus_in {
   my ($self) = @_;

   return if $FOCUS == $self;
   return unless $self->{can_focus};

   my $focus = $FOCUS; $FOCUS = $self;

   $self->emit (focus_in => $focus);

   $focus->update if $focus;
   $FOCUS->update;
}

sub focus_out {
   my ($self) = @_;

   return unless $FOCUS == $self;

   my $focus = $FOCUS; undef $FOCUS;

   $self->emit (focus_out => $focus);

   $focus->update if $focus; #?
}

sub mouse_motion { }
sub button_up { }
sub key_down { }
sub key_up { }

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;
}

sub w { $_[0]{w} = $_[1] if @_ > 1; $_[0]{w} }
sub h { $_[0]{h} = $_[1] if @_ > 1; $_[0]{h} }
sub x { $_[0]{x} = $_[1] if @_ > 1; $_[0]{x} }
sub y { $_[0]{y} = $_[1] if @_ > 1; $_[0]{y} }
sub z { $_[0]{z} = $_[1] if @_ > 1; $_[0]{z} }

sub draw {
   my ($self) = @_;

   return unless $self->{h} && $self->{w};

   glPushMatrix;
   glTranslate $self->{x}, $self->{y}, 0;
   $self->_draw;
   glPopMatrix;

   if ($self == $HOVER && $self->{can_hover}) {
      my ($x, $y) = @$self{qw(x y)};

      glColor 1, 0.8, 0.5, 0.2;
      glEnable GL_BLEND;
      glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
      glBegin GL_QUADS;
      glVertex $x             , $y;
      glVertex $x + $self->{w}, $y;
      glVertex $x + $self->{w}, $y + $self->{h};
      glVertex $x             , $y + $self->{h};
      glEnd;
      glDisable GL_BLEND;
   }
}

sub _draw {
   my ($self) = @_;

   warn "no draw defined for $self\n";
}

sub find_widget {
   my ($self, $x, $y) = @_;

   return $self
      if $x >= $self->{x} && $x < $self->{x} + $self->{w}
          && $y >= $self->{y} && $y < $self->{y} + $self->{h};

   ()
}

sub set_parent {
   my ($self, $parent) = @_;

   Scalar::Util::weaken ($self->{parent} = $parent);
}

sub update {
   my ($self) = @_;

   $self->{parent}->update
      if $self->{parent};
}

sub connect {
   my ($self, $signal, $cb) = @_;

   push @{ $self->{cb}{$signal} }, $cb;
}

sub emit {
   my ($self, $signal, @args) = @_;

   $_->($self, @args)
      for @{$self->{cb}{$signal} || []};
}

sub DESTROY {
   my ($self) = @_;

   #$self->deactivate;
}

#############################################################################

package CFClient::UI::DrawBG;

our @ISA = CFClient::UI::Base::;

use strict;
use SDL::OpenGL;

sub new {
   my $class = shift;

   # range [value, low, high, page]

   $class->SUPER::new (
      bg        => [0, 0, 0, 0.2],
      active_bg => [1, 1, 1, 0.5],
      @_
   )
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = @$self{qw(w h)};

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glColor @{ $FOCUS == $self ? $self->{active_bg} : $self->{bg} };

   glBegin GL_QUADS;
   glVertex 0 , 0;
   glVertex 0 , $h;
   glVertex $w, $h;
   glVertex $w, 0;
   glEnd;

   glDisable GL_BLEND;
}

#############################################################################

package CFClient::UI::Empty;

our @ISA = CFClient::UI::Base::;

sub size_request {
   (0, 0)
}

sub draw { }

#############################################################################

package CFClient::UI::Container;

our @ISA = CFClient::UI::Base::;

sub new {
   my ($class, %arg) = @_;

   my $children = delete $arg{children} || [];

   my $self = $class->SUPER::new (children => [], %arg);
   $self->add ($_) for @$children;

   $self
}

sub add {
   my ($self, $child) = @_;

   $child->set_parent ($self);

   use sort 'stable';

   $self->{children} = [
      sort { $a->{z} <=> $b->{z} }
         @{$self->{children}}, $child
   ];

   $self->{w} = $self->{h} = -1;
   $self->update;
}

sub remove {
   my ($self, $widget) = @_;

   $self->{children} = [ grep $_ != $widget, @{ $self->{children} } ];

   $self->size_allocate (0, 0, $self->{w}, $self->{h});
}

sub find_widget {
   my ($self, $x, $y) = @_;

   $x -= $self->{x};
   $y -= $self->{y};

   my $res;

   for (reverse @{ $self->{children} }) {
      $res = $_->find_widget ($x, $y)
         and return $res;
   }

   $self->SUPER::find_widget ($x + $self->{x}, $y + $self->{y})
}

sub _draw {
   my ($self) = @_;

   $_->draw for @{$self->{children}};
}

#############################################################################

package CFClient::UI::Bin;

our @ISA = CFClient::UI::Container::;

sub new {
   my ($class, %arg) = @_;

   my $child = (delete $arg{child}) || new CFClient::UI::Empty::;

   $class->SUPER::new (children => [$child], %arg)
}

sub add {
   my ($self, $widget) = @_;

   $self->{children} = [];
   
   $self->SUPER::add ($widget);
}

sub remove {
   my ($self, $widget) = @_;

   $self->SUPER::remove ($widget);

   $self->{children} = [new CFClient::UI::Empty]
      unless @{$self->{children}};
}

sub child { $_[0]->{children}[0] }

sub size_request {
   $_[0]{children}[0]->size_request
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h) or return;

   $self->{children}[0]->size_allocate (0, 0, $w, $h);
}

#############################################################################

package CFClient::UI::Window;

our @ISA = CFClient::UI::Bin::;

use SDL::OpenGL;

sub new {
   my ($class, %arg) = @_;

   my $self = $class->SUPER::new (%arg);
}

sub update {
   my ($self) = @_;

   # we want to do this delayed...
   $self->render_chld;
   $self->SUPER::update;
}

sub render_chld {
   my ($self) = @_;

   $self->{texture} = new_from_opengl CFClient::Texture $self->{w}, $self->{h}, sub {
      glClearColor 0, 0, 0, 1;
      glClear GL_COLOR_BUFFER_BIT;
      $self->child->draw;
   };
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h) or return;

   $self->child->size_allocate (0, 0, $w, $h);

   $self->render_chld;
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = ($self->w, $self->h);

   my $tex = $self->{texture}
      or return;

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   $tex->draw_quad (0, 0, $w, $h);

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::Frame;

our @ISA = CFClient::UI::Bin::;

use SDL::OpenGL;

sub size_request {
   my ($self) = @_;
   my $chld = $self->child
      or return (0, 0);

   $chld->move (2, 2);

   map { $_ + 4 } $chld->size_request;
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;
   
   $self->_size_allocate ($x, $y, $w, $h) or return;

   $self->child->size_allocate (2, 2, $w - 4, $h - 4);
}

sub _draw {
   my ($self) = @_;

   my $chld = $self->child;

   my ($w, $h) = $chld->size_request;

   glBegin GL_QUADS;
   glColor 0, 0, 0;
   glVertex 0      , 0;
   glVertex 0      , $h + 4;
   glVertex $w + 4 , $h + 4;
   glVertex $w + 4 , 0;
   glEnd;

   $chld->draw;
}

#############################################################################

package CFClient::UI::FancyFrame;

our @ISA = CFClient::UI::Bin::;

use SDL::OpenGL;

my @tex = 
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_ }
         qw(d1_bg.png d1_border_top.png d1_border_right.png d1_border_left.png d1_border_bottom.png);

sub new {
   my $class = shift;

   # TODO: user_x, user_y, overwrite moveto?

   $class->SUPER::new (
      bg        => [1, 1, 1, 1],
      border_bg => [1, 1, 1, 1],
      border    => int $::FONTSIZE * 0.8,
      @_
   )
}

sub size_request {
   my ($self) = @_;

   return ($self->{user_w}, $self->{user_h}) if $self->{user_w} && $self->{user_h};

   my ($w, $h) = $self->SUPER::size_request;

   (
      $w + $self->{border} * 2,
      $h + $self->{border} * 2,
   )
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h) or return;

   $h -= List::Util::max 0, $self->{border} * 2;
   $w -= List::Util::max 0, $self->{border} * 2;

   $self->child->size_allocate ($self->{border}, $self->{border}, $w, $h);
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   if ($x < $self->{w} && $x >= $self->{w} - $self->{border}
       && $y < $self->{h} && $y >= $self->{h} - $self->{border}) {

      my ($ox, $oy) = ($ev->button_x, $ev->button_y);
      my ($bw, $bh) = ($self->{w}, $self->{h});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->motion_x, $ev->motion_y);

         $self->{user_w} = $bw + $x - $ox;
         $self->{user_h} = $bh + $y - $oy;
         $self->update;
      };

   } elsif ($x >= 0 && $x < $self->{w}
            && $y >= 0 && $y < $self->{border}) {

      my ($ox, $oy) = ($ev->button_x, $ev->button_y);
      my ($bx, $by) = ($self->{x}, $self->{y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->motion_x, $ev->motion_y);

         $self->move ($bx + $x - $ox, $by + $y - $oy);
         $self->update;
      };
   }
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   $self->{motion}->($ev, $x, $y) if $self->{motion};
}

sub _draw {
   my ($self) = @_;

   my ($w,  $h ) = ($self->{w}, $self->{h});
   my ($cw, $ch) = ($self->child->{w}, $self->child->{h});

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

   glColor @{ $self->{border_bg} };
   $tex[1]->draw_quad (0, 0, $w, $self->{border});
   $tex[3]->draw_quad (0, $self->{border}, $self->{border}, $ch);
   $tex[2]->draw_quad ($w - $self->{border}, $self->{border}, $self->{border}, $ch);
   $tex[4]->draw_quad (0, $h - $self->{border}, $w, $self->{border});

   my $bg = $tex[0];

   # TODO: repeat texture not scale
   my $rep_x = $cw / $bg->{w};
   my $rep_y = $ch / $bg->{h};

   glColor @{ $self->{bg} };

   $bg->{s} = $rep_x;
   $bg->{t} = $rep_y;
   $bg->{wrap_mode} = 1;
   $bg->draw_quad ($self->{border}, $self->{border}, $cw, $ch);

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;

   $self->child->draw;
}

#############################################################################

package CFClient::UI::Table;

our @ISA = CFClient::UI::Base::;

use List::Util qw(max sum);

use SDL::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      col_expand => [],
      @_
   )
}

sub add {
   my ($self, $x, $y, $child) = @_;

   $child->set_parent ($self);
   $self->{children}[$y][$x] = $child;

   $self->{w} = $self->{h} = -1;
   $self->update;
}

# TODO: move to container class maybe? send childs a signal on removal?
sub clear {
   my ($self) = @_;

   delete $self->{children};
   $self->update;
}

sub get_wh {
   my ($self) = @_;

   my (@w, @h);

   for my $y (0 .. $#{$self->{children}}) {
      my $row = $self->{children}[$y]
         or next;

      for my $x (0 .. $#$row) {
         my $widget = $row->[$x]
            or next;
         my ($w, $h) = $widget->size_request;

         $w[$x] = max $w[$x], $w;
         $h[$y] = max $h[$y], $h;
      }
   }

   (\@w, \@h)
}

sub size_request {
   my ($self) = @_;

   my ($ws, $hs) = $self->get_wh;

   (
      (sum @$ws),
      (sum @$hs),
   )
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h) or return;

   my ($ws, $hs) = $self->get_wh;

   my $req_w = sum @$ws;
   my $req_h = sum @$hs;

   # TODO: nicer code && do row_expand
   my @col_expand = @{$self->{col_expand}};
   @col_expand = (1) x @$ws unless @col_expand;
   my $col_expand = (sum @col_expand) || 1;

   # linearly scale sizes
   $ws->[$_] += $col_expand[$_] / $col_expand * ($w - $req_w) for 0 .. $#$ws;
   $hs->[$_] *= 1 * $h / $req_h for 0 .. $#$hs;

   CFClient::UI::harmonize $ws;
   CFClient::UI::harmonize $hs;

   my $y;

   for my $r (0 .. $#{$self->{children}}) {
      my $row = $self->{children}[$r]
         or next;

      my $x = 0;
      my $row_h = $hs->[$r];
      
      for my $c (0 .. $#$row) {
         my $col_w = $ws->[$c];

         if (my $widget = $row->[$c]) {
            $widget->size_allocate ($x, $y, $col_w, $row_h);
         }

         $x += $col_w;
      }

      $y += $row_h;
   }

}

sub find_widget {
   my ($self, $x, $y) = @_;

   $x -= $self->{x};
   $y -= $self->{y};

   my $res;

   for (grep $_, map @$_, grep $_, @{ $self->{children} }) {
      $res = $_->find_widget ($x, $y)
         and return $res;
   }

   $self->SUPER::find_widget ($x + $self->{x}, $y + $self->{y})
}

sub _draw {
   my ($self) = @_;

   for (grep $_, @{$self->{children}}) {
      $_->draw for grep $_, @$_;
   }
}

#############################################################################

package CFClient::UI::HBox;

# TODO: wrap into common Box base class

our @ISA = CFClient::UI::Container::;

sub size_request {
   my ($self) = @_;

   my @alloc = map [$_->size_request], @{$self->{children}};

   (
      (List::Util::sum map $_->[0], @alloc),
      (List::Util::max map $_->[1], @alloc),
   )
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h);

   ($h, $w) = ($w, $h);

   my $children = $self->{children};

   my @h = map +($_->size_request)[0], @$children;

   my $req_h = List::Util::sum @h;

   if ($req_h > $h) {
      # ah well, not enough space
      $_ *= $h / $req_h for @h;
   } else {
      my $exp = List::Util::sum map $_->{expand}, @$children;
      $exp ||= 1;
      
      for (0 .. $#$children) {
         my $child = $children->[$_];

         my $alloc_h = $h[$_];
         $alloc_h += ($h - $req_h) * $child->{expand} / $exp;
         $h[$_] = $alloc_h;
      }
   }

   CFClient::UI::harmonize \@h;

   my $y = 0;
   for (0 .. $#$children) {
      my $child = $children->[$_];
      my $h = $h[$_];
      $child->size_allocate ($y, 0, $h, $w);

      $y += $h;
   }
}

#############################################################################

package CFClient::UI::VBox;

# TODO: wrap into common Box base class

our @ISA = CFClient::UI::Container::;

sub size_request {
   my ($self) = @_;

   my @alloc = map [$_->size_request], @{$self->{children}};

   (
      (List::Util::max map $_->[0], @alloc),
      (List::Util::sum map $_->[1], @alloc),
   )
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h);

   my $children = $self->{children};

   my @h = map +($_->size_request)[1], @$children;

   my $req_h = List::Util::sum @h;

   if ($req_h > $h) {
      # ah well, not enough space
      $_ *= $h / $req_h for @h;
   } else {
      my $exp = List::Util::sum map $_->{expand}, @$children;
      $exp ||= 1;
      
      for (0 .. $#$children) {
         my $child = $children->[$_];

         $h[$_] += ($h - $req_h) * $child->{expand} / $exp;
      }
   }

   CFClient::UI::harmonize \@h;

   my $y = 0;
   for (0 .. $#$children) {
      my $child = $children->[$_];
      my $h = $h[$_];
      $child->size_allocate (0, $y, $w, $h);

      $y += $h;
   }
}

#############################################################################

package CFClient::UI::Label;

our @ISA = CFClient::UI::Base::;

use SDL::OpenGL;

sub new {
   my ($class, %arg) = @_;

   my $self = $class->SUPER::new (
      fg       => [1, 1, 1],
      fontsize => $::FONTSIZE,
      text     => "",
      align    => -1,
      valign   => -1,
      padding  => 2,
      layout   => new CFClient::Layout,
      %arg
   );

   $self->{xxx}++ if $self->{text} eq "Client Setup" && $self->{align};#d#

   $self->set_text   (delete $self->{text})   if exists $self->{text};
   $self->set_markup (delete $self->{markup}) if exists $self->{markup};

   $self
}

sub escape_text {
   local $_ = $_[1];

   s/&/&amp;/g;
   s/>/&gt;/g;
   s/</&lt;/g;

   $_[1]
}

sub set_text {
   my ($self, $text) = @_;

   $self->{layout}->set_text ($text);

   delete $self->{texture};
   $self->update;
}

sub set_markup {
   my ($self, $markup) = @_;

   $self->{layout}->set_markup ($markup);

   delete $self->{texture};
   $self->update;
}

sub size_request {
   my ($self) = @_;

   $self->{layout}->set_width;
   $self->{layout}->set_height ($self->{fontsize});

   my ($w, $h) = $self->{layout}->size;

   (
      $w + $self->{padding} * 2,
      $h + $self->{padding} * 2,
   )
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h) or return;

   delete $self->{texture};
}

sub update {
   my ($self) = @_;

   delete $self->{texture};
   $self->SUPER::update;
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{texture} ||= do {
      $self->{layout}->set_width ($self->{w});
      $self->{layout}->set_height (List::Util::min $self->{h}, $self->{fontsize});
      new_from_layout CFClient::Texture $self->{layout}
   };

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   glColor @{$self->{fg}};

   $self->{ox} = int (
      $self->{align} < 0 ? $self->{padding}
    : $self->{align} > 0 ? $self->{w} - $tex->{w} - $self->{padding}
    :                      ($self->{w} - $tex->{w}) * 0.5
   );

   $self->{oy} = int (
      $self->{valign} < 0 ? $self->{padding}
    : $self->{valign} > 0 ? $self->{h} - $tex->{h} - $self->{padding}
    :                       ($self->{h} - $tex->{h}) * 0.5
   );

   $tex->draw_quad ($self->{ox}, $self->{oy});

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;
}

#############################################################################

package CFClient::UI::EntryBase;

our @ISA = CFClient::UI::Label::;

use SDL;
use SDL::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      fg        => [1, 1, 1],
      bg        => [0, 0, 0, 0.2],
      active_bg => [1, 1, 1, 0.5],
      active_fg => [0, 0, 0],
      can_hover => 1,
      can_focus => 1,
      valign    => 0,
      @_
   )
}

sub _set_text {
   my ($self, $text) = @_;

   delete $self->{cur_h};

   return if $self->{text} eq $text;

   $self->{last_activity} = $::NOW;
   $self->{text} = $text;

   $text =~ s/./*/g if $self->{hidden};
   $self->{layout}->set_text ("$text ");

   $self->emit (changed => $self->{text});
}

sub get_text {
   $_[0]{text}
}

sub size_request {
   my ($self) = @_;

   my ($w, $h) = $self->SUPER::size_request;

   ($w + 1, $h) # add 1 for cursor
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->SUPER::size_allocate ($x, $y, $w, $h);

   $self->_set_text ($self->{text});
}

sub set_text {
   my ($self, $text) = @_;

   $self->{cursor} = length $text;
   $self->_set_text ($text);
   $self->update;
}

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   my $uni = $ev->key_unicode;

   my $text = $self->get_text;

   if ($sym == SDLK_BACKSPACE) {
      substr $text, --$self->{cursor}, 1, "" if $self->{cursor};
   } elsif ($sym == SDLK_DELETE) {
      substr $text, $self->{cursor}, 1, "";
   } elsif ($sym == SDLK_LEFT) {
      --$self->{cursor} if $self->{cursor};
   } elsif ($sym == SDLK_RIGHT) {
      ++$self->{cursor} if $self->{cursor} < length $self->{text};
   } elsif ($sym == SDLK_HOME) {
      $self->{cursor} = 0;
   } elsif ($sym == SDLK_END) {
      $self->{cursor} = length $text;
   } elsif ($sym == SDLK_ESCAPE) {
      $self->emit ('escape');
   } elsif ($uni) {
      substr $text, $self->{cursor}++, 0, chr $uni;
   }

   $self->_set_text ($text);
   $self->update;
}

sub focus_in {
   my ($self) = @_;

   $self->{last_activity} = $::NOW;

   $self->SUPER::focus_in;
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->SUPER::button_down ($ev, $x, $y);

   my $idx = $self->{layout}->xy_to_index ($x, $y);

   # byte-index to char-index
   my $text = $self->{text};
   utf8::encode $text;
   $self->{cursor} = length substr $text, 0, $idx;

   $self->_set_text ($self->{text});
   $self->update;
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;
#   printf "M %d,%d %d,%d\n", $ev->motion_x, $ev->motion_y, $x, $y;#d#
}

sub _draw {
   my ($self) = @_;

   local $self->{fg} = $self->{fg};

   if ($FOCUS == $self) {
      glColor @{$self->{active_bg}};
      $self->{fg} = $self->{active_fg};
   } else {
      glColor @{$self->{bg}};
   }

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glBegin GL_QUADS;
   glVertex 0         , 0;
   glVertex 0         , $self->{h};
   glVertex $self->{w}, $self->{h};
   glVertex $self->{w}, 0;
   glEnd;
   glDisable GL_BLEND;

   $self->SUPER::_draw;

   #TODO: force update every cursor change :(
   if ($FOCUS == $self && (($::NOW - $self->{last_activity}) & 1023) < 600) {

      unless (exists $self->{cur_h}) {
         my $text = substr $self->{text}, 0, $self->{cursor};
         utf8::encode $text;

         @$self{qw(cur_x cur_y cur_h)} = $self->{layout}->cursor_pos (length $text)
      }

      glColor @{$self->{fg}};
      glBegin GL_LINES;
      glVertex $self->{cur_x} + $self->{ox}, $self->{cur_y} + $self->{oy};
      glVertex $self->{cur_x} + $self->{ox}, $self->{cur_y} + $self->{oy} + $self->{cur_h};
      glEnd;
   }
}

package CFClient::UI::Entry;

our @ISA = CFClient::UI::EntryBase::;

use SDL;
use SDL::OpenGL;

sub key_down {
   my ($self, $ev) = @_;

   my $sym = $ev->key_sym;

   if ($sym == SDLK_RETURN) {
      $self->emit (activate => $self->get_text);
      $self->update;

   } else {
      $self->SUPER::key_down ($ev);
   }

}

#############################################################################

package CFClient::UI::Button;

our @ISA = CFClient::UI::Label::;

use SDL;
use SDL::OpenGL;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_ }
         qw(b1_button_active.png);

sub new {
   my $class = shift;

   $class->SUPER::new (
      padding   => 4,
      fg        => [1, 1, 1],
      bg        => [1, 1, 1, 0.2],
      active_fg => [1, 1, 0],
      can_hover => 1,
      @_
   )
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   if ($x >= 0 && $x < $self->{w}
       && $y >= 0 && $y < $self->{h}) {
      $self->emit ("activate");
   }
}

sub _draw {
   my ($self) = @_;

   local $self->{fg} = $self->{fg};

   if ($GRAB == $self) {
      $self->{fg} = $self->{active_fg};
   }

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glColor 0, 0, 0, 1;

   $tex[0]->draw_quad (0, 0, $self->{w}, $self->{h});

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;

   $self->SUPER::_draw;
}

#############################################################################

package CFClient::UI::CheckBox;

our @ISA = CFClient::UI::DrawBG::;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_ }
         qw(c1_checkbox_bg.png c1_checkbox_active.png);

use SDL;
use SDL::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      padding   => 2,
      fg        => [1, 1, 1],
      active_fg => [1, 1, 0],
      state     => 0,
      can_hover => 1,
      @_
   )
}

sub size_request {
   my ($self) = @_;

   ($self->{padding} * 2 + 6) x 2
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h);
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   if ($x >= $self->{padding} && $x < $self->{w} - $self->{padding}
       && $y >= $self->{padding} && $y < $self->{h} - $self->{padding}) {
      $self->{state} = !$self->{state};
      $self->emit (changed => $self->{state});
   }
}

sub _draw {
   my ($self) = @_;

   $self->SUPER::_draw;

   glTranslate $self->{padding} + 0.375, $self->{padding} + 0.375, 0;

   my $s = (List::Util::min @$self{qw(w h)}) - $self->{padding} * 2;

   glColor @{ $FOCUS == $self ? $self->{active_fg} : $self->{fg} };

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;

   my $tex = $self->{state} ? $tex[1] : $tex[0];

   $tex->draw_quad (0, 0, $s, $s);

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;
}

#############################################################################

package CFClient::UI::Slider;

use strict;

use SDL::OpenGL;

our @ISA = CFClient::UI::DrawBG::;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_ }
         qw(s1_slider.png s1_slider_bg.png);

sub new {
   my $class = shift;

   # range [value, low, high, page]

   # TODO: 0-width page
   # TODO: req_w/h are wrong with vertical
   # TODO: calculations are off
   my $self = $class->SUPER::new (
      fg        => [1, 1, 1],
      active_fg => [0, 0, 0],
      range     => [0, 0, 100, 10],
      req_w     => 40,
      req_h     => 13,
      vertical  => 0,
      can_hover => 1,
      inner_pad => 5,
      @_
   );

   $self
}

sub size_request {
   my ($self) = @_;

   my $w = $self->{req_w};
   my $h = $self->{req_h};

   $self->{vertical} ? ($h, $w) : ($w, $h)
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->SUPER::button_down ($ev, $x, $y);
   $self->mouse_motion ($ev, $x, $y);
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   if ($GRAB == $self) {
      my ($value, $lo, $hi, $page) = @{$self->{range}};

      my ($x, $w) = $self->{vertical} ? ($y, $self->{h}) : ($x, $self->{w});

      my $inner_pad_px = $self->_calc_inner_pad_px ($w);
      my $inner_w = $w - $inner_pad_px * 2;               # * 2 for left & right

      $x -= $inner_pad_px;  # substract the padding
      $x = $x * ($hi - $lo) / $inner_w + $lo;
      $x = $lo         if $x < $lo;
      $x = $hi - $page if $x > $hi - $page;
      $self->{range}[0] = $x;

      $self->emit (changed => $x);
      $self->update;
   }
}

# the inner_* stuff is for generating a padding for the slider handle,
# so that the handle doesn't leave the texture. This calculation isn't 100%
# correct propably, but it does the job for now
sub _calc_inner_pad_px {
   my ($self, $w) = @_;
   ($w / 100) * $self->{inner_pad} # % to pixels
}

sub _draw {
   my ($self) = @_;

   $self->SUPER::_draw ();

   my ($w, $h) = @$self{qw(w h)};

   if ($self->{vertical}) {
      # draw a vertical slider like a rotated horizontal slider
 
      glRotate 90, 0, 0, 1;
      glTranslate 0, -$self->{w}, 0;

      ($w, $h) = ($h, $w);
   }

   my $fg = $FOCUS == $self ? $self->{active_fg} : $self->{fg};
   my $bg = $FOCUS == $self ? $self->{active_bg} : $self->{bg};

   my ($value, $lo, $hi, $page) = @{$self->{range}};

   $hi = $value + 1 if $lo == $hi;

   my $inner_pad_px = $self->_calc_inner_pad_px ($w);
   my $inner_w = $w - $inner_pad_px * 2;               # * 2 for left & right

   $page  = int $page * $inner_w / ($hi - $lo);
   $value = int +($value - $lo) * $inner_w / ($hi - $lo);

   $w -= $page;
   $page &= ~1;
   glTranslate $page * 0.5, 0, 0;
   $page ||= 2;

   my $knob_a = $inner_pad_px + ($value - $page * 0.5);
   my $knob_b = $inner_pad_px + ($value + $page * 0.5);

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   # draw background
   $tex[1]->draw_quad (0, 0, $w, $h);

   # draw handle
   $tex[0]->draw_quad ($knob_a, 0, $knob_b - $knob_a, $h);

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::TextView;

our @ISA = CFClient::UI::HBox::;

use SDL::OpenGL;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      req_w    => $::WIDTH / 6,
      req_h    => $::HEIGHT / 6,
      fontsize => $::FONTSIZE,
      @_,

      layout   => (new CFClient::Layout),
      par      => [],
      height   => 0,
      children => [
         (new CFClient::UI::Empty expand => 1),
         (new CFClient::UI::Slider vertical => 1),
      ],
   );

   $self->{children}[1]->connect (changed => sub {
      $self->update;
   });

   $self
}

sub set_fontsize {
   my ($self, $fontsize) = @_;

   $self->{fontsize} = $fontsize;
   $self->reflow;
}

sub text_height {
   my ($self, $text) = @_;

   my $layout = $self->{layout};

   $layout->set_height ($self->{fontsize});
   $layout->set_width ($self->{w});
   $layout->set_text ($text);
   
   ($layout->size)[1]
}

sub reflow {
   my ($self) = @_;

   $self->{need_reflow}++;
   $self->update;
}

sub size_request {
   my ($self) = @_;

   ($self->{req_w}, $self->{req_h})
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->SUPER::size_allocate ($x, $y, $w, $h);

   $self->{layout}->set_height ($self->{fontsize});
   $self->{layout}->set_width ($self->{w});

   $self->reflow;
}

sub add_paragraph {
   my ($self, $color, $text) = @_;

   #TODO: intelligently "reformat" paragraph

   my $height = $self->text_height ($text);

   $self->{height} += $height;

   push @{$self->{par}}, [$height, $color, $text];

   $self->{children}[1]{range} = [$self->{height} - $self->{h}, 0, $self->{height}, $self->{h}];
   $self->{children}[1]->update;
}

sub update {
   my ($self) = @_;

   $self->SUPER::update;

   return unless $self->{h} > 0;

   delete $self->{texture};

   $ROOT->on_refresh ($self, sub {
      if (delete $self->{need_reflow}) {
         my $height = 0;

         $height += $_->[0] = $self->text_height ($_->[2])
            for @{$self->{par}};

         $self->{height} = $height;

         $self->{children}[1]{range} = [$height - $self->{h}, 0, $height, $self->{h}];
         
         delete $self->{texture};
      }

      $self->{texture} ||= new_from_opengl CFClient::Texture $self->{w}, $self->{h}, sub {
         glClearColor 0, 0, 0, 1;
         glClear GL_COLOR_BUFFER_BIT;

         glEnable GL_BLEND;
         glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
         glEnable GL_TEXTURE_2D;
         glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

         my $top = int $self->{children}[1]{range}[0];

         my $y0 = $top;
         my $y1 = $top + $self->{h};

         my $y = 0;

         my $layout = $self->{layout};

         for my $par (@{$self->{par}}) {
            my $h = $par->[0];

            if ($y0 < $y + $h && $y < $y1) {
               $layout->set_text ($par->[2]);

               glColor @{ $par->[1] };
               my ($W, $H) = $layout->size;
               CFClient::Texture->new_from_layout ($layout)->draw_quad (0, $y - $y0);
            }

            $y += $h;
         }

         glDisable GL_TEXTURE_2D;
         glDisable GL_BLEND;
      };
   });
}

sub _draw {
   my ($self) = @_;

   if ($self->{texture}) {
      glEnable GL_TEXTURE_2D;
      glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
      $self->{texture}->draw_quad (0, 0, $self->{w}, $self->{h});
      glDisable GL_TEXTURE_2D;
   }

   $self->{children}[1]->draw;

}

#############################################################################

package CFClient::UI::MapWidget;

use strict;

use List::Util qw(min max);

use SDL;
use SDL::OpenGL;

our @ISA = CFClient::UI::Base::;

sub new {
   my $class = shift;

   $class->SUPER::new (
      z         => -1,
      can_focus => 1,
      list      => (glGenLists 1),
      @_
   )
}

sub key_down {
   print "MAPKEYDOWN\n";
}

sub key_up {
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;

   if ($ev->button == 2) {
      my ($ox, $oy) = ($ev->button_x, $ev->button_y);
      my ($bw, $bh) = ($::CFG->{map_shift_x}, $::CFG->{map_shift_y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->motion_x, $ev->motion_y);

         $::CFG->{map_shift_x} = $bw + $x - $ox;
         $::CFG->{map_shift_y} = $bh + $y - $oy;

         $self->update;
      };
   }
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   $self->{motion}->($ev, $x, $y) if $self->{motion};
}

sub size_request {
   (
      1 + 32 * int $::WIDTH  / 32,
      1 + 32 * int $::HEIGHT / 32,
   )
}

sub update {
   my ($self) = @_;

   $self->{need_update} = 1;
   $self->SUPER::update;
}

sub draw {
   my ($self) = @_;

   if (delete $self->{need_update}) {
      glNewList $self->{list}, GL_COMPILE;

      if ($::MAP) {
         my $sw = int $::WIDTH  / 32;
         my $sh = int $::HEIGHT / 32;

         my $sx = $::CFG->{map_shift_x}; my $sx0 = $sx & 31; $sx = ($sx - $sx0) / 32;
         my $sy = $::CFG->{map_shift_y}; my $sy0 = $sy & 31; $sy = ($sy - $sy0) / 32;

         glTranslate $sx0 - 32, $sy0 - 32, 0;

         my ($w, $h, $data) = $::MAP->draw ($sx, $sy, 0, 0, $sw + 1, $sh + 1);

         if ($::CFG->{fow_enable}) {
            if ($::CFG->{fow_smooth}) { # smooth fog of war
               glConvolutionParameter GL_CONVOLUTION_2D, GL_CONVOLUTION_BORDER_MODE, GL_CONSTANT_BORDER;
               glConvolutionFilter2D
                  GL_CONVOLUTION_2D,
                  GL_ALPHA,
                  3, 3,
                  GL_ALPHA, GL_FLOAT,
                  pack "f*",
                     0.1, 0.1, 0.1,
                     0.1, 0.2, 0.1,
                     0.1, 0.1, 0.1,
               ;
               glEnable GL_CONVOLUTION_2D;
            }

            $self->{fow_texture} = new CFClient::Texture
               w              => $w,
               h              => $h,
               data           => $data,
               internalformat => GL_ALPHA,
               format         => GL_ALPHA;

            glDisable GL_CONVOLUTION_2D if $::CFG->{fow_smooth};

            glEnable GL_BLEND;
            glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
            glEnable GL_TEXTURE_2D;
            glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

            glColor +($::CFG->{fow_intensity}) x 3, 1;
            $self->{fow_texture}->draw_quad (0, 0, $w * 32, $h * 32);

            glDisable GL_TEXTURE_2D;
            glDisable GL_BLEND;
         }

         # HACK BEGIN
         {
           glTranslate -($sx0 - 32), -($sy0 - 32), 0;#remove
           my ($w, $h) = (250, 250);

           glEnable GL_BLEND;
           glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
           glEnable GL_TEXTURE_2D;
           glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

           $self->{mapmap_texture} =
              new CFClient::Texture
                 w    => $w,
                 h    => $h,
                 data => $::MAP->mapmap ($w, $h),
                 type => GL_UNSIGNED_INT_8_8_8_8_REV;

           $self->{mapmap_texture}->draw_quad (100, 100);

           glDisable GL_TEXTURE_2D;
           glDisable GL_BLEND;
         }
         # HACK END
      }

      glEndList;
   }

   glPushMatrix;
   glCallList $self->{list};
   glPopMatrix;

   if ($FOCUS != $self) {
      glColor 64/255, 64/255, 64/255;
      glLogicOp GL_AND;
      glEnable GL_COLOR_LOGIC_OP;
      glBegin GL_QUADS;
      glVertex 0, 0;
      glVertex 0, $::HEIGHT;
      glVertex $::WIDTH, $::HEIGHT;
      glVertex $::WIDTH, 0;
      glEnd;
      glDisable GL_COLOR_LOGIC_OP;
   }
}

my %DIR = (
   SDLK_KP8, [1, "north"],
   SDLK_KP9, [2, "northeast"],
   SDLK_KP6, [3, "east"],
   SDLK_KP3, [4, "southeast"],
   SDLK_KP2, [5, "south"],
   SDLK_KP1, [6, "southwest"],
   SDLK_KP4, [7, "west"],
   SDLK_KP7, [8, "northwest"],

   SDLK_UP,    [1, "north"],
   SDLK_RIGHT, [3, "east"],
   SDLK_DOWN,  [5, "south"],
   SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if ($sym == SDLK_KP5) {
      $::CONN->user_send ("stay fire");
   } elsif ($sym == SDLK_a) {
      $::CONN->user_send ("apply");
   } elsif ($sym == SDLK_QUOTE) {
      $self->emit ('activate_console');
   } elsif ($sym == SDLK_SLASH) {
      $self->emit ('activate_console' => '/');
   } elsif (exists $DIR{$sym}) {
      if ($mod & KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->user_send ("fire $DIR{$sym}[0]");
      } elsif ($mod & KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->user_send ("run $DIR{$sym}[0]");
      } else {
         $::CONN->user_send ("$DIR{$sym}[1]");
      }
   }
}

sub key_up {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if (!($mod & KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->user_send ("fire_stop");
   }
   if (!($mod & KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->user_send ("run_stop");
   }
}

#############################################################################

package CFClient::UI::Animator;

use SDL::OpenGL;

our @ISA = CFClient::UI::Bin::;

sub moveto {
   my ($self, $x, $y) = @_;

   $self->{moveto} = [$self->{x}, $self->{y}, $x, $y];
   $self->{speed}  = 0.001;
   $self->{time}   = 1;
   
   ::animation_start $self;
}

sub animate {
   my ($self, $interval) = @_;

   $self->{time} -= $interval * $self->{speed};
   if ($self->{time} <= 0) {
      $self->{time} = 0;
      ::animation_stop $self;
   }

   my ($x0, $y0, $x1, $y1) = @{$self->{moveto}};
      
   $self->{x} = $x0 * $self->{time} + $x1 * (1 - $self->{time});
   $self->{y} = $y0 * $self->{time} + $y1 * (1 - $self->{time});
}

sub _draw {
   my ($self) = @_;

   glPushMatrix;
   glRotate $self->{time} * 1000, 0, 1, 0;
   $self->{children}[0]->draw;
   glPopMatrix;
}

#############################################################################

package CFClient::UI::Flopper;

our @ISA = CFClient::UI::Button::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      state => 0,
      connect_activate => \&toggle_flopper,
      @_
   );

   if ($self->{state}) {
      $self->{state} = 0;
      $self->toggle_flopper;
   }

   $self
}

sub toggle_flopper {
   my ($self) = @_;

   # TODO: use animation
   if ($self->{state} = !$self->{state}) {
      $CFClient::UI::ROOT->add ($self->{other});
      $self->{other}->move ($self->coord2global (0, $self->{h}));
      $self->emit ("open");
   } else {
      $CFClient::UI::ROOT->remove ($self->{other});
      $self->emit ("close");
   }

   $self->emit (changed => $self->{state});
}

#############################################################################

package CFClient::UI::Root;

our @ISA = CFClient::UI::Container::;

use SDL::OpenGL;

sub size_request {
   ($::WIDTH, $::HEIGHT)
}

sub size_allocate {
   my ($self, $x, $y, $w, $h) = @_;

   $self->_size_allocate ($x, $y, $w, $h);

   $_->size_allocate ($_->{x}, $_->{y}, $_->size_request)
      for @{$self->{children}};
}

sub _topleft {
   my ($self, $x, $y) = @_;

   ($x, $y)
}

sub update {
   my ($self) = @_;

   $self->size_allocate (0, 0, $::WIDTH, $::HEIGHT);
   ::refresh ();
}

sub add {
   my ($self, $widget) = @_;

   $self->SUPER::add ($widget);

   $widget->size_allocate (int $widget->{x}, int $widget->{y}, $widget->size_request);
}

sub on_refresh {
   my ($self, $id, $cb) = @_;

   $self->{refresh_hook}{$id} = $cb;
}

sub draw  {
   my ($self) = @_;

   while (my $rcb = delete $self->{refresh_hook}) {
      $_->() for values %$rcb;
   }

   glViewport 0, 0, $::WIDTH, $::HEIGHT;
   glClearColor +($::CFG->{fow_intensity}) x 3, 1;
   glClear GL_COLOR_BUFFER_BIT;

   glMatrixMode GL_PROJECTION;
   glLoadIdentity;
   glOrtho 0, $::WIDTH, $::HEIGHT, 0, -10000 , 10000;
   glMatrixMode GL_MODELVIEW;
   glLoadIdentity;

   $self->_draw;
}

#############################################################################

package CFClient::UI;

$ROOT = new CFClient::UI::Root;

1

Revision:	1.122
Committed:	Mon Apr 17 19:36:27 2006 UTC (18 years, 1 month ago) by root
Branch:	MAIN
Changes since 1.121:	+17 -15 lines
Log Message:	more utf8