Deliantra-Client/DC/UI.pm

package CFClient::UI;

use utf8;
use strict;

use Scalar::Util ();
use List::Util ();

use CFClient;

our ($FOCUS, $HOVER, $GRAB); # various widgets

our $ROOT;
our $TOOLTIP;
our $BUTTON_STATE;

sub check_tooltip {
   if (!$GRAB) {
      for (my $widget = $HOVER; $widget; $widget = $widget->{parent}) {
         if (length $widget->{tooltip}) {

            if ($TOOLTIP->{owner} != $widget) {
               $TOOLTIP->{owner} = $widget;

               my $tip = $widget->{tooltip};

               $tip = $tip->($widget) if CODE:: eq ref $tip;
               
               $TOOLTIP->set_tooltip_from ($widget);
               $TOOLTIP->show;

               my ($x, $y) = $widget->coord2global ($widget->{w}, 0);

               if ($x + $TOOLTIP->{w} > $::WIDTH) {
                  ($x, $y) = $widget->coord2global (-$TOOLTIP->{w}, 0);
               }

               $TOOLTIP->move ($x, $y);
               $TOOLTIP->check_size;
               $TOOLTIP->update;
            }

            return;
         }
      }
   }

   $TOOLTIP->hide;
   delete $TOOLTIP->{owner};
}

# class methods for events
sub feed_sdl_key_down_event { 
   $FOCUS->emit (key_down => $_[0]) || $FOCUS->key_down ($_[0])
      if $FOCUS;
}

sub feed_sdl_key_up_event {
   $FOCUS->emit (key_up => $_[0]) || $FOCUS->key_up ($_[0])
      if $FOCUS;
}

sub feed_sdl_button_down_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->{x}, $ev->{y});

   if (!$BUTTON_STATE) {
      my $widget = $ROOT->find_widget ($x, $y);

      $GRAB = $widget;
      $GRAB->update if $GRAB;

      check_tooltip;
   }

   $BUTTON_STATE |= 1 << ($ev->{button} - 1);

   if ($GRAB) {
      ($x, $y) = $GRAB->coord2local ($x, $y);
      $GRAB->emit (button_down => $ev, $x, $y) || $GRAB->button_down ($ev, $x, $y);
   }
}

sub feed_sdl_button_up_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->{x}, $ev->{y});

   my $widget = $GRAB || $ROOT->find_widget ($x, $y);

   $BUTTON_STATE &= ~(1 << ($ev->{button} - 1));

   if ($GRAB) {
      ($x, $y) = $GRAB->coord2local ($x, $y);
      $GRAB->emit (button_up => $ev, $x, $y) || $GRAB->button_up ($ev, $x, $y);
   }

   if (!$BUTTON_STATE) {
      my $grab = $GRAB; undef $GRAB;
      $grab->update if $grab;
      $GRAB->update if $GRAB;

      check_tooltip;
   }
}

sub feed_sdl_motion_event {
   my ($ev) = @_;
   my ($x, $y) = ($ev->{x}, $ev->{y});

   my $widget = $GRAB || $ROOT->find_widget ($x, $y);

   if ($widget != $HOVER) {
      my $hover = $HOVER; $HOVER = $widget;

      $hover->update if $hover && $hover->{can_hover};
      $HOVER->update if $HOVER && $HOVER->{can_hover};

      check_tooltip;
   }

   if ($HOVER) {
      ($x, $y) = $HOVER->coord2local ($x, $y);
      $HOVER->emit (mouse_motion => $ev, $x, $y) || $HOVER->mouse_motion ($ev, $x, $y);
   }
}

# convert position array to integers
sub harmonize {
   my ($vals) = @_;

   my $rem = 0;

   for (@$vals) {
      my $i = int $_ + $rem;
      $rem += $_ - $i;
      $_ = $i;
   }
}

#############################################################################

package CFClient::UI::Base;

use strict;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   my $self = bless {
      x          => 0,
      y          => 0,
      z          => 0,
      can_events => 1,
      @_
   }, $class;

   for (keys %$self) {
      if (/^connect_(.*)$/) {
         $self->connect ($1 => delete $self->{$_});
      }
   }

   $self
}

sub destroy {
   my ($self) = @_;

   $self->hide;
   %$self = ();
}

sub show {
   my ($self) = @_;

   return if $self->{parent};

   $CFClient::UI::ROOT->add ($self);
}

sub hide {
   my ($self) = @_;

   undef $GRAB  if $GRAB  == $self;
   undef $HOVER if $HOVER == $self;

   $self->{parent}->remove ($self)
      if $self->{parent};
}

sub move {
   my ($self, $x, $y, $z) = @_;

   $self->{x} = int $x;
   $self->{y} = int $y;
   $self->{z} = $z if defined $z;

   $self->update;
}

sub set_size {
   my ($self, $w, $h) = @_;

   $self->{user_w} = $w;
   $self->{user_h} = $h;

   $self->check_size;
}

sub size_request {
   require Carp;
   Carp::confess "size_request is abstract";
}

sub configure {
   my ($self, $x, $y, $w, $h) = @_;

   if ($self->{aspect}) {
      my $w2 = List::Util::min $w, int $h * $self->{aspect};
      my $h2 = List::Util::min $h, int $w / $self->{aspect};

      # use alignment to adjust x, y

      $x += int +($w - $w2) * 0.5;
      $y += int +($h - $h2) * 0.5;

      ($w, $h) = ($w2, $h2);
   }

   if ($self->{x} != $x || $self->{y} != $y) {
      $self->{x} = $x;
      $self->{y} = $y;
      $self->update;
   }

   if ($self->{w} != $w || $self->{h} != $h) {
      $CFClient::UI::ROOT->{size_alloc}{$self} = [$self, $w, $h];
   }
}

sub size_allocate {
   # nothing to be done
}

sub children {
}

# call when resolution changes etc.
sub reconfigure {
   my ($self) = @_;

   $_->reconfigure
      for $self->children;

   $self->check_size (1);
   $self->update;
}

sub set_max_size {
   my ($self, $w, $h) = @_;

   delete $self->{max_w}; $self->{max_w} = $w if $w;
   delete $self->{max_h}; $self->{max_h} = $h if $h;
}

# translate global coordinates to local coordinate system
sub coord2local {
   my ($self, $x, $y) = @_;

   $self->{parent}->coord2local ($x  - $self->{x}, $y - $self->{y})
}

# translate local coordinates to global coordinate system
sub coord2global {
   my ($self, $x, $y) = @_;

   $self->{parent}->coord2global ($x + $self->{x}, $y + $self->{y})
}

sub focus_in {
   my ($self) = @_;

   return if $FOCUS == $self;
   return unless $self->{can_focus};

   my $focus = $FOCUS; $FOCUS = $self;

   $self->emit (focus_in => $focus);

   $focus->update if $focus;
   $FOCUS->update;
}

sub focus_out {
   my ($self) = @_;

   return unless $FOCUS == $self;

   my $focus = $FOCUS; undef $FOCUS;

   $self->emit (focus_out => $focus);

   $focus->update if $focus; #?
}

sub mouse_motion { }
sub button_up { }
sub key_down { }
sub key_up { }

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->focus_in;
}

sub w { $_[0]{w} = $_[1] if @_ > 1; $_[0]{w} }
sub h { $_[0]{h} = $_[1] if @_ > 1; $_[0]{h} }
sub x { $_[0]{x} = $_[1] if @_ > 1; $_[0]{x} }
sub y { $_[0]{y} = $_[1] if @_ > 1; $_[0]{y} }
sub z { $_[0]{z} = $_[1] if @_ > 1; $_[0]{z} }

sub draw {
   my ($self) = @_;

   return unless $self->{h} && $self->{w};

   glPushMatrix;
   glTranslate $self->{x}, $self->{y}, 0;
   $self->_draw;
   glPopMatrix;

   if ($self == $HOVER && $self->{can_hover}) {
      my ($x, $y) = @$self{qw(x y)};

      glColor 1, 0.8, 0.5, 0.2;
      glEnable GL_BLEND;
      glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
      glBegin GL_QUADS;
      glVertex $x             , $y;
      glVertex $x + $self->{w}, $y;
      glVertex $x + $self->{w}, $y + $self->{h};
      glVertex $x             , $y + $self->{h};
      glEnd;
      glDisable GL_BLEND;
   }

   if ($ENV{PCLIENT_DEBUG}) {
      glPushMatrix;
      glColor 1, 1, 0, 1;
      glTranslate $self->{x} + 0.375, $self->{y} + 0.375;
      glBegin GL_LINE_LOOP;
      glVertex 0         , 0;
      glVertex $self->{w}, 0;
      glVertex $self->{w}, $self->{h};
      glVertex 0         , $self->{h};
      glEnd;
      glPopMatrix;
      CFClient::UI::Label->new (w => $self->{w}, h => $self->{h}, text => $self, fontsize => 0)->_draw;
   }
}

sub _draw {
   my ($self) = @_;

   warn "no draw defined for $self\n";
}

sub find_widget {
   my ($self, $x, $y) = @_;

   return () unless $self->{can_events};

   return $self
      if $x >= $self->{x} && $x < $self->{x} + $self->{w}
          && $y >= $self->{y} && $y < $self->{y} + $self->{h};

   ()
}

sub set_parent {
   my ($self, $parent) = @_;

   Scalar::Util::weaken ($self->{parent} = $parent);


   # TODO: req_w _does_change after ->reconfigure
   $self->check_size
      unless exists $self->{req_w};
}

sub check_size {
   my ($self, $forced) = @_;

   $self->{force_alloc} = 1 if $forced;
   $CFClient::UI::ROOT->{check_size}{$self} = $self;
}

sub update {
   my ($self) = @_;

   $self->{parent}->update
      if $self->{parent};
}

sub connect {
   my ($self, $signal, $cb) = @_;

   push @{ $self->{signal_cb}{$signal} }, $cb;
}

sub emit {
   my ($self, $signal, @args) = @_;

   List::Util::sum map $_->($self, @args), @{$self->{signal_cb}{$signal} || []}
}

sub DESTROY {
   my ($self) = @_;

   #$self->deactivate;
}

#############################################################################

package CFClient::UI::DrawBG;

our @ISA = CFClient::UI::Base::;

use strict;
use CFClient::OpenGL;

sub new {
   my $class = shift;

   # range [value, low, high, page]

   $class->SUPER::new (
      bg        => [0, 0, 0, 0.2],
      active_bg => [1, 1, 1, 0.5],
      @_
   )
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = @$self{qw(w h)};

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glColor @{ $FOCUS == $self ? $self->{active_bg} : $self->{bg} };

   glBegin GL_QUADS;
   glVertex 0 , 0;
   glVertex 0 , $h;
   glVertex $w, $h;
   glVertex $w, 0;
   glEnd;

   glDisable GL_BLEND;
}

#############################################################################

package CFClient::UI::Empty;

our @ISA = CFClient::UI::Base::;

sub new {
   my ($class, %arg) = @_;
   $class->SUPER::new (can_events => 0, %arg);
}

sub size_request {
   (0, 0)
}

sub draw { }

#############################################################################

package CFClient::UI::Container;

our @ISA = CFClient::UI::Base::;

sub new {
   my ($class, %arg) = @_;

   my $children = delete $arg{children} || [];

   my $self = $class->SUPER::new (
      children   => [],
      can_events => 0,
      %arg,
   );
   $self->add ($_) for @$children;

   $self
}

sub add {
   my ($self, @widgets) = @_;

   $_->set_parent ($self)
      for @widgets;

   use sort 'stable';

   $self->{children} = [
      sort { $a->{z} <=> $b->{z} }
         @{$self->{children}}, @widgets
   ];

   $self->check_size (1);
   $self->update;
}

sub children {
   @{ $_[0]{children} }
}

sub remove {
   my ($self, $child) = @_;

   delete $child->{parent};
   $child->hide;

   $self->{children} = [ grep $_ != $child, @{ $self->{children} } ];

   $self->check_size;
   $self->update;
}

sub clear {
   my ($self) = @_;

   my $children = delete $self->{children};
   $self->{children} = [];

   for (@$children) {
      delete $_->{parent};
      $_->hide;
   }

   $self->check_size;
   $self->update;
}

sub find_widget {
   my ($self, $x, $y) = @_;

   $x -= $self->{x};
   $y -= $self->{y};

   my $res;

   for (reverse @{ $self->{children} }) {
      $res = $_->find_widget ($x, $y)
         and return $res;
   }

   $self->SUPER::find_widget ($x + $self->{x}, $y + $self->{y})
}

sub _draw {
   my ($self) = @_;

   $_->draw for @{$self->{children}};
}

#############################################################################

package CFClient::UI::Bin;

our @ISA = CFClient::UI::Container::;

sub new {
   my ($class, %arg) = @_;

   my $child = (delete $arg{child}) || new CFClient::UI::Empty::;

   $class->SUPER::new (children => [$child], %arg)
}

sub add {
   my ($self, $child) = @_;

   $self->{children} = [];
   
   $self->SUPER::add ($child);
}

sub remove {
   my ($self, $widget) = @_;

   $self->SUPER::remove ($widget);

   $self->{children} = [new CFClient::UI::Empty]
      unless @{$self->{children}};
}

sub child { $_[0]->{children}[0] }

sub size_request {
   $_[0]{children}[0]->size_request
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->{children}[0]->configure (0, 0, $w, $h);
}

#############################################################################

package CFClient::UI::Window;

our @ISA = CFClient::UI::Bin::;

use CFClient::OpenGL;

sub new {
   my ($class, %arg) = @_;

   my $self = $class->SUPER::new (%arg);
}

sub update {
   my ($self) = @_;

   $ROOT->on_post_alloc ($self => sub { $self->render_child });
   $self->SUPER::update;
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);
   $self->update;
}

sub _render {
   $_[0]{children}[0]->draw;
}

sub render_child {
   my ($self) = @_;

   $self->{texture} = new_from_opengl CFClient::Texture $self->{w}, $self->{h}, sub {
      glClearColor 0, 0, 0, 0;
      glClear GL_COLOR_BUFFER_BIT;

      $self->_render;
#      glColorMask 1, 1, 1, 0;
#      glEnable GL_BLEND;
#      glBlendFunc GL_SRC_ALPHA, GL_ZERO;
#      glRasterPos 0, 0;
#      glCopyPixels 0, 0, $self->{w}, $self->{h};
#      glDisable GL_BLEND;
#      glColorMask 1, 1, 1, 1;
   };
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = ($self->w, $self->h);

   my $tex = $self->{texture}
      or return;

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glColor 0, 0, 0, 1;

   $tex->draw_quad_alpha_premultiplied (0, 0, $w, $h);

   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::ViewPort;

our @ISA = CFClient::UI::Window::;

sub size_request {
   my ($self) = @_;

   @$self{qw(child_w child_h)} = @{$self->child}{qw(req_w req_h)};
   $self->child->configure (0, 0, @$self{qw(child_w child_h)});

   @$self{qw(child_w child_h)}
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->update;
}

sub set_offset {
   my ($self, $x, $y) = @_;

   $self->{view_x} = int $x;
   $self->{view_y} = int $y;

   $self->update;
}

# hmm, this does not work for topleft of $self... but we should not ask for that
sub coord2local {
   my ($self, $x, $y) = @_;

   $self->SUPER::coord2local ($x + $self->{view_x}, $y + $self->{view_y})
}

sub coord2global {
   my ($self, $x, $y) = @_;

   $x = List::Util::min $self->{w}, $x - $self->{view_x};
   $y = List::Util::min $self->{h}, $y - $self->{view_y};

   $self->SUPER::coord2global ($x, $y)
}

sub find_widget {
   my ($self, $x, $y) = @_;

   if (   $x >= $self->{x} && $x < $self->{x} + $self->{w}
       && $y >= $self->{y} && $y < $self->{y} + $self->{h}
   ) {
       $self->child->find_widget ($x + $self->{view_x}, $y + $self->{view_y})
   } else {
      $self->CFClient::UI::Base::find_widget ($x, $y)
   }
}

sub _render {
   my ($self) = @_;

   CFClient::OpenGL::glTranslate -$self->{view_x}, -$self->{view_y};

   $self->SUPER::_render;
}

#############################################################################

package CFClient::UI::ScrolledWindow;

our @ISA = CFClient::UI::HBox::;

sub new {
   my $class = shift;

   my $self;

   my $slider = new CFClient::UI::Slider
      vertical        => 1,
      range           => [0, 0, 1, 0.01], # HACK fix
      connect_changed => sub {
         $self->{vp}->set_offset (0, $_[1] * ($self->{vp}{child_h} - $self->{vp}{h}));
      },
   ;

   $self = $class->SUPER::new (
      vp     => (new CFClient::UI::ViewPort),
      slider => $slider,
      @_,
   );

   $self->{vp}->add ($self->{scrolled});
   $self->add ($self->{vp});
   $self->add ($self->{slider});

   $self
}

#TODO# update range on size_allocate depeneing on child
# update viewport offset on scroll

#############################################################################

package CFClient::UI::Frame;

our @ISA = CFClient::UI::Bin::;

use CFClient::OpenGL;

#############################################################################

package CFClient::UI::FancyFrame;

our @ISA = CFClient::UI::Bin::;

use CFClient::OpenGL;

my @tex = 
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw(d1_bg.png d1_border_top.png d1_border_right.png d1_border_left.png d1_border_bottom.png);

sub new {
   my $class = shift;

   # TODO: user_x, user_y, overwrite moveto?

   my $self = $class->SUPER::new (
      bg         => [1, 1, 1, 1],
      border_bg  => [1, 1, 1, 1],
      border     => 0.6,
      can_events => 1,
      @_
   );

   $self->{title} &&= new CFClient::UI::Label
      align    => 0,
      valign   => 1,
      text     => $self->{title},
      fontsize => $self->{border};

   $self
}

sub border {
   int $_[0]{border} * $::FONTSIZE
}

sub size_request {
   my ($self) = @_;

   my ($w, $h) = $self->SUPER::size_request;

   (
      $w + $self->border * 2,
      $h + $self->border * 2,
   )
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $h -= List::Util::max 0, $self->border * 2;
   $w -= List::Util::max 0, $self->border * 2;

   $self->{title}->configure ($self->border, $self->border - $::FONTSIZE * 2, $w, $::FONTSIZE * 2)
      if $self->{title};

   $self->child->configure ($self->border, $self->border, $w, $h);
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   my ($w, $h) = @$self{qw(w h)};
   my $border = $self->border;

   my $lr = ($x >= 0 && $x < $border) || ($x > $w - $border && $x < $w);
   my $td = ($y >= 0 && $y < $border) || ($y > $h - $border && $y < $h);

   if ($lr & $td) {
      my ($wx, $wy) = ($self->{x}, $self->{y});
      my ($ox, $oy) = ($ev->{x}, $ev->{y});
      my ($bw, $bh) = ($self->{w}, $self->{h});

      my $mx = $x < $border;
      my $my = $y < $border;

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         my $dx = $ev->{x} - $ox;
         my $dy = $ev->{y} - $oy;

         $self->{user_w} = $bw + $dx * ($mx ? -1 : 1);
         $self->{user_h} = $bh + $dy * ($my ? -1 : 1);
         $self->move ($wx + $dx * $mx, $wy + $dy * $my);
         $self->check_size;
      };

   } elsif ($lr ^ $td) {
      my ($ox, $oy) = ($ev->{x}, $ev->{y});
      my ($bx, $by) = ($self->{x}, $self->{y});

      $self->{motion} = sub {
         my ($ev, $x, $y) = @_;

         ($x, $y) = ($ev->{x}, $ev->{y});

         $self->move ($bx + $x - $ox, $by + $y - $oy);
         $self->update;
      };
   }
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   delete $self->{motion};
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   $self->{motion}->($ev, $x, $y) if $self->{motion};
}

sub _draw {
   my ($self) = @_;

   my ($w,  $h ) = ($self->{w}, $self->{h});
   my ($cw, $ch) = ($self->child->{w}, $self->child->{h});

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

   my $border = $self->border;

   glColor @{ $self->{border_bg} };
   $tex[1]->draw_quad_alpha (0, 0, $w, $border);
   $tex[3]->draw_quad_alpha (0, $border, $border, $ch);
   $tex[2]->draw_quad_alpha ($w - $border, $border, $border, $ch);
   $tex[4]->draw_quad_alpha (0, $h - $border, $w, $border);

   if (@{$self->{bg}} < 4 || $self->{bg}[3]) {
      my $bg = $tex[0];

      # TODO: repeat texture not scale
      my $rep_x = $cw / $bg->{w};
      my $rep_y = $ch / $bg->{h};

      glColor @{ $self->{bg} };

      $bg->{s} = $rep_x;
      $bg->{t} = $rep_y;
      $bg->{wrap_mode} = 1;
      $bg->draw_quad_alpha ($border, $border, $cw, $ch);
   }

   glDisable GL_TEXTURE_2D;

   $self->{title}->draw if $self->{title};

   $self->child->draw;
}

#############################################################################

package CFClient::UI::Table;

our @ISA = CFClient::UI::Base::;

use List::Util qw(max sum);

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      col_expand => [],
      @_
   )
}

sub add {
   my ($self, $x, $y, $child) = @_;

   $child->set_parent ($self);
   $self->{children}[$y][$x] = $child;

   $child->check_size;
}

sub children {
   grep $_, map @$_, grep $_, @{ $_[0]{children} }
}

# TODO: move to container class maybe? send childs a signal on removal?
sub clear {
   my ($self) = @_;

   my @children = $self->children;
   delete $self->{children};
   
   for (@children) {
      delete $_->{parent};
      $_->hide;
   }

   $self->update;
}

sub get_wh {
   my ($self) = @_;

   my (@w, @h);

   for my $y (0 .. $#{$self->{children}}) {
      my $row = $self->{children}[$y]
         or next;

      for my $x (0 .. $#$row) {
         my $widget = $row->[$x]
            or next;
         my ($w, $h) = @$widget{qw(req_w req_h)};

         $w[$x] = max $w[$x], $w;
         $h[$y] = max $h[$y], $h;
      }
   }

   (\@w, \@h)
}

sub size_request {
   my ($self) = @_;

   my ($ws, $hs) = $self->get_wh;

   (
      (sum @$ws),
      (sum @$hs),
   )
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   my ($ws, $hs) = $self->get_wh;

   my $req_w = sum @$ws;
   my $req_h = sum @$hs;

   # TODO: nicer code && do row_expand
   my @col_expand = @{$self->{col_expand}};
   @col_expand = (1) x @$ws unless @col_expand;
   my $col_expand = (sum @col_expand) || 1;

   # linearly scale sizes
   $ws->[$_] += $col_expand[$_] / $col_expand * ($w - $req_w) for 0 .. $#$ws;
   $hs->[$_] *= 1 * $h / $req_h for 0 .. $#$hs;

   CFClient::UI::harmonize $ws;
   CFClient::UI::harmonize $hs;

   my $y;

   for my $r (0 .. $#{$self->{children}}) {
      my $row = $self->{children}[$r]
         or next;

      my $x = 0;
      my $row_h = $hs->[$r];
      
      for my $c (0 .. $#$row) {
         my $col_w = $ws->[$c];

         if (my $widget = $row->[$c]) {
            $widget->configure ($x, $y, $col_w, $row_h);
         }

         $x += $col_w;
      }

      $y += $row_h;
   }

}

sub find_widget {
   my ($self, $x, $y) = @_;

   $x -= $self->{x};
   $y -= $self->{y};

   my $res;

   for (grep $_, map @$_, grep $_, @{ $self->{children} }) {
      $res = $_->find_widget ($x, $y)
         and return $res;
   }

   $self->SUPER::find_widget ($x + $self->{x}, $y + $self->{y})
}

sub _draw {
   my ($self) = @_;

   for (grep $_, @{$self->{children}}) {
      $_->draw for grep $_, @$_;
   }
}

#############################################################################

package CFClient::UI::HBox;

# TODO: wrap into common Box base class

our @ISA = CFClient::UI::Container::;

sub size_request {
   my ($self) = @_;

   my @alloc = map [$_->size_request], @{$self->{children}};

   (
      (List::Util::sum map $_->[0], @alloc),
      (List::Util::max map $_->[1], @alloc),
   )
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   ($h, $w) = ($w, $h);

   my $children = $self->{children};

   my @h = map $_->{req_w}, @$children;

   my $req_h = List::Util::sum @h;

   if ($req_h > $h) {
      # ah well, not enough space
      $_ *= $h / $req_h for @h;
   } else {
      my $exp = List::Util::sum map $_->{expand}, @$children;
      $exp ||= 1;
      
      for (0 .. $#$children) {
         my $child = $children->[$_];

         my $alloc_h = $h[$_];
         $alloc_h += ($h - $req_h) * $child->{expand} / $exp;
         $h[$_] = $alloc_h;
      }
   }

   CFClient::UI::harmonize \@h;

   my $y = 0;
   for (0 .. $#$children) {
      my $child = $children->[$_];
      my $h = $h[$_];
      $child->configure ($y, 0, $h, $w);

      $y += $h;
   }

   1
}

#############################################################################

package CFClient::UI::VBox;

# TODO: wrap into common Box base class

our @ISA = CFClient::UI::Container::;

sub size_request {
   my ($self) = @_;

   my @alloc = map [$_->size_request], @{$self->{children}};

   (
      (List::Util::max map $_->[0], @alloc),
      (List::Util::sum map $_->[1], @alloc),
   )
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   Carp::confess "negative size" if $w < 0 || $h < 0;#d#

   my $children = $self->{children};

   my @h = map $_->{req_h}, @$children;

   my $req_h = List::Util::sum @h;

   if ($req_h > $h) {
      # ah well, not enough space
      $_ *= $h / $req_h for @h;
   } else {
      my $exp = List::Util::sum map $_->{expand}, @$children;
      $exp ||= 1;
      
      for (0 .. $#$children) {
         my $child = $children->[$_];

         $h[$_] += ($h - $req_h) * $child->{expand} / $exp;
      }
   }

   CFClient::UI::harmonize \@h;

   my $y = 0;
   for (0 .. $#$children) {
      my $child = $children->[$_];
      my $h = $h[$_];
      $child->configure (0, $y, $w, $h);

      $y += $h;
   }

   1
}

#############################################################################

package CFClient::UI::Label;

our @ISA = CFClient::UI::Base::;

use CFClient::OpenGL;

sub new {
   my ($class, %arg) = @_;

   my $self = $class->SUPER::new (
      fg         => [1, 1, 1],
      #font      => default_font
      #text      => initial text
      #markup    => initial narkup
      layout     => (new CFClient::Layout),
      fontsize   => 1,
      align      => -1,
      valign     => -1,
      padding    => 2,
      can_events => 0,
      %arg
   );

   if (exists $self->{template}) {
      my $layout = new CFClient::Layout;
      $layout->set_text (delete $self->{template});
      $self->{template} = $layout;
   }

   if (exists $self->{markup}) {
      $self->set_markup (delete $self->{markup});
   } else {
      $self->set_text (delete $self->{text});
   }

   $self
}

sub escape {
   local $_ = $_[1];

   s/&/&amp;/g;
   s/>/&gt;/g;
   s/</&lt;/g;

   $_[1]
}

sub update {
   my ($self) = @_;

   delete $self->{texture};
   $self->SUPER::update;
}

sub set_text {
   my ($self, $text) = @_;

   return if $self->{text} eq "T$text";
   $self->{text} = "T$text";

   $self->{layout} = new CFClient::Layout if $self->{layout}->is_rgba;
   $self->{layout}->set_text ($text);

   $self->update;
   $self->check_size;
}

sub set_markup {
   my ($self, $markup) = @_;

   return if $self->{text} eq "M$markup";
   $self->{text} = "M$markup";

   my $rgba = $markup =~ /span.*(?:foreground|background)/;

   $self->{layout} = new CFClient::Layout $rgba if $self->{layout}->is_rgba != $rgba;
   $self->{layout}->set_markup ($markup);

   $self->update;
   $self->check_size;
}

sub size_request {
   my ($self) = @_;

   $self->{layout}->set_font ($self->{font}) if $self->{font};
   $self->{layout}->set_width ($self->{max_w} || -1);
   $self->{layout}->set_height ($self->{fontsize} * $::FONTSIZE);

   my ($w, $h) = $self->{layout}->size;

   if (exists $self->{template}) {
      $self->{template}->set_font ($self->{font}) if $self->{font};
      $self->{template}->set_height ($self->{fontsize} * $::FONTSIZE);

      my ($w2, $h2) = $self->{template}->size;

      $w = List::Util::max $w, $w2;
      $h = List::Util::max $h, $h2;
   }

   (
      $w + $self->{padding} * 2,
      $h + $self->{padding} * 2,
   )
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   delete $self->{texture};
}

sub set_fontsize {
   my ($self, $fontsize) = @_;

   $self->{fontsize} = $fontsize;
   delete $self->{texture};

   $self->update;
   $self->check_size;
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{texture} ||= do {
      $self->{layout}->set_foreground (@{$self->{fg}});
      $self->{layout}->set_font ($self->{font}) if $self->{font};
      $self->{layout}->set_width ($self->{w});
      $self->{layout}->set_height (List::Util::min $self->{h}, $self->{fontsize} * $::FONTSIZE);

      my $tex = new_from_layout CFClient::Texture $self->{layout};

      $self->{ox} = int $self->{align} < 0 ? $self->{padding}
                      : $self->{align} > 0 ? $self->{w} - $tex->{w} - $self->{padding}
                      :                      ($self->{w} - $tex->{w}) * 0.5;

      $self->{oy} = int $self->{valign} < 0 ? $self->{padding}
                      : $self->{valign} > 0 ? $self->{h} - $tex->{h} - $self->{padding}
                      :                       ($self->{h} - $tex->{h}) * 0.5;

      $tex
   };

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   if ($tex->{format} == GL_ALPHA) {
      glColor @{$self->{fg}};
      $tex->draw_quad_alpha ($self->{ox}, $self->{oy});
   } else {
      $tex->draw_quad_alpha_premultiplied ($self->{ox}, $self->{oy});
   }

   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::EntryBase;

our @ISA = CFClient::UI::Label::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      fg         => [1, 1, 1],
      bg         => [0, 0, 0, 0.2],
      active_bg  => [1, 1, 1, 0.5],
      active_fg  => [0, 0, 0],
      can_hover  => 1,
      can_focus  => 1,
      valign     => 0,
      can_events => 1,
      @_
   )
}

sub _set_text {
   my ($self, $text) = @_;

   delete $self->{cur_h};

   return if $self->{text} eq $text;

   delete $self->{texture};

   $self->{last_activity} = $::NOW;
   $self->{text} = $text;

   $text =~ s/./*/g if $self->{hidden};
   $self->{layout}->set_text ("$text ");

   $self->emit (changed => $self->{text});
}

sub set_text {
   my ($self, $text) = @_;

   $self->{cursor} = length $text;
   $self->_set_text ($text);
   $self->check_size;
   $self->update;
}

sub get_text {
   $_[0]{text}
}

sub size_request {
   my ($self) = @_;

   my ($w, $h) = $self->SUPER::size_request;

   ($w + 1, $h) # add 1 for cursor
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->_set_text (delete $self->{text});#d# don't check for == inside _set_text
}

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->{mod};
   my $sym = $ev->{sym};
   my $uni = $ev->{unicode};

   my $text = $self->get_text;

   if ($sym == 8) {
      substr $text, --$self->{cursor}, 1, "" if $self->{cursor};
   } elsif ($sym == 127) {
      substr $text, $self->{cursor}, 1, "";
   } elsif ($sym == CFClient::SDLK_LEFT) {
      --$self->{cursor} if $self->{cursor};
   } elsif ($sym == CFClient::SDLK_RIGHT) {
      ++$self->{cursor} if $self->{cursor} < length $self->{text};
   } elsif ($sym == CFClient::SDLK_HOME) {
      $self->{cursor} = 0;
   } elsif ($sym == CFClient::SDLK_END) {
      $self->{cursor} = length $text;
   } elsif ($sym == 27) {
      $self->emit ('escape');
   } elsif ($uni) {
      substr $text, $self->{cursor}++, 0, chr $uni;
   }

   $self->_set_text ($text);
   $self->update;
}

sub focus_in {
   my ($self) = @_;

   $self->{last_activity} = $::NOW;

   $self->SUPER::focus_in;
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->SUPER::button_down ($ev, $x, $y);

   my $idx = $self->{layout}->xy_to_index ($x, $y);

   # byte-index to char-index
   my $text = $self->{text};
   utf8::encode $text;
   $self->{cursor} = length substr $text, 0, $idx;

   $self->_set_text ($self->{text});
   $self->update;
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;
#   printf "M %d,%d %d,%d\n", $ev->motion_x, $ev->motion_y, $x, $y;#d#
}

sub _draw {
   my ($self) = @_;

   local $self->{fg} = $self->{fg};

   if ($FOCUS == $self) {
      glColor @{$self->{active_bg}};
      $self->{fg} = $self->{active_fg};
   } else {
      glColor @{$self->{bg}};
   }

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glBegin GL_QUADS;
   glVertex 0         , 0;
   glVertex 0         , $self->{h};
   glVertex $self->{w}, $self->{h};
   glVertex $self->{w}, 0;
   glEnd;
   glDisable GL_BLEND;

   $self->SUPER::_draw;

   #TODO: force update every cursor change :(
   if ($FOCUS == $self && (($::NOW - $self->{last_activity}) & 1023) < 600) {

      unless (exists $self->{cur_h}) {
         my $text = substr $self->{text}, 0, $self->{cursor};
         utf8::encode $text;

         @$self{qw(cur_x cur_y cur_h)} = $self->{layout}->cursor_pos (length $text)
      }

      glColor @{$self->{fg}};
      glBegin GL_LINES;
      glVertex $self->{cur_x} + $self->{ox}, $self->{cur_y} + $self->{oy};
      glVertex $self->{cur_x} + $self->{ox}, $self->{cur_y} + $self->{oy} + $self->{cur_h};
      glEnd;
   }
}

package CFClient::UI::Entry;

our @ISA = CFClient::UI::EntryBase::;

use CFClient::OpenGL;

sub key_down {
   my ($self, $ev) = @_;

   my $sym = $ev->{sym};

   if ($sym == 13) {
      unshift @{$self->{history}},
         my $txt = $self->get_text;
      $self->{history_pointer} = -1;
      $self->{history_saveback} = '';
      $self->emit (activate => $txt);
      $self->update;

   } elsif ($sym == CFClient::SDLK_UP) {
      if ($self->{history_pointer} < 0) {
         $self->{history_saveback} = $self->get_text;
      }
      if (@{$self->{history} || []} > 0) {
         $self->{history_pointer}++;
         if ($self->{history_pointer} >= @{$self->{history} || []}) {
            $self->{history_pointer} = @{$self->{history} || []} - 1;
         }
         $self->set_text ($self->{history}->[$self->{history_pointer}]);
      }

   } elsif ($sym == CFClient::SDLK_DOWN) {
      $self->{history_pointer}--;
      $self->{history_pointer} = -1 if $self->{history_pointer} < 0;

      if ($self->{history_pointer} >= 0) {
         $self->set_text ($self->{history}->[$self->{history_pointer}]);
      } else {
         $self->set_text ($self->{history_saveback});
      }

   } else {
      $self->SUPER::key_down ($ev);
   }

}

#############################################################################

package CFClient::UI::Button;

our @ISA = CFClient::UI::Label::;

use CFClient::OpenGL;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw(b1_button_active.png);

sub new {
   my $class = shift;

   $class->SUPER::new (
      padding    => 4,
      fg         => [1, 1, 1],
      bg         => [1, 1, 1, 0.2],
      active_fg  => [0, 0, 1],
      can_hover  => 1,
      align      => 0,
      valign     => 0,
      can_events => 1,
      @_
   )
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   if ($x >= 0 && $x < $self->{w}
       && $y >= 0 && $y < $self->{h}) {
      $self->emit ("activate");
   }
}

sub _draw {
   my ($self) = @_;

   local $self->{fg} = $self->{fg};

   if ($GRAB == $self) {
      $self->{fg} = $self->{active_fg};
   }

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glColor 0, 0, 0, 1;

   $tex[0]->draw_quad_alpha (0, 0, $self->{w}, $self->{h});

   glDisable GL_TEXTURE_2D;

   $self->SUPER::_draw;
}

#############################################################################

package CFClient::UI::CheckBox;

our @ISA = CFClient::UI::DrawBG::;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw(c1_checkbox_bg.png c1_checkbox_active.png);

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      padding   => 2,
      fg        => [1, 1, 1],
      active_fg => [1, 1, 0],
      state     => 0,
      can_hover => 1,
      @_
   )
}

sub size_request {
   my ($self) = @_;

   ($self->{padding} * 2 + 6) x 2
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   if ($x >= $self->{padding} && $x < $self->{w} - $self->{padding}
       && $y >= $self->{padding} && $y < $self->{h} - $self->{padding}) {
      $self->{state} = !$self->{state};
      $self->emit (changed => $self->{state});
   }
}

sub _draw {
   my ($self) = @_;

   $self->SUPER::_draw;

   glTranslate $self->{padding} + 0.375, $self->{padding} + 0.375, 0;

   my $s = (List::Util::min @$self{qw(w h)}) - $self->{padding} * 2;

   glColor @{ $FOCUS == $self ? $self->{active_fg} : $self->{fg} };

   my $tex = $self->{state} ? $tex[1] : $tex[0];

   glEnable GL_TEXTURE_2D;
   $tex->draw_quad_alpha (0, 0, $s, $s);
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::Image;

our @ISA = CFClient::UI::Base::;

use CFClient::OpenGL;
use Carp qw/confess/;

our %loaded_images;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (can_events => 0, @_);

   $self->{image} or confess "Image has 'image' not set. This is a fatal error!";

   $loaded_images{$self->{image}} ||=
      new_from_file CFClient::Texture CFClient::find_rcfile $self->{image}, mipmap => 1;

   my $tex = $self->{tex} = $loaded_images{$self->{image}};

   Scalar::Util::weaken $loaded_images{$self->{image}};

   $self->{aspect} = $tex->{w} / $tex->{h};

   $self
}

sub size_request {
   my ($self) = @_;

   ($self->{tex}->{w}, $self->{tex}->{h})
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{tex};

   my ($w, $h) = ($self->{w}, $self->{h});

   if ($self->{rot90}) {
      glRotate 90, 0, 0, 1;
      glTranslate 0, -$self->{w}, 0;

      ($w, $h) = ($h, $w);
   }

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   $tex->draw_quad_alpha (0, 0, $w, $h);

   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::VGauge;

our @ISA = CFClient::UI::Base::;

use List::Util qw(min max);

use CFClient::OpenGL;

my %tex = (
   food => [
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw/g1_food_gauge_empty.png g1_food_gauge_full.png/
   ],
   grace => [
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw/g1_grace_gauge_empty.png g1_grace_gauge_full.png g1_grace_gauge_overflow.png/
   ],
   hp => [
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw/g1_hp_gauge_empty.png g1_hp_gauge_full.png/
   ],
   mana => [
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_, mipmap => 1 }
         qw/g1_mana_gauge_empty.png g1_mana_gauge_full.png g1_mana_gauge_overflow.png/
   ],
);

# eg. VGauge->new (gauge => 'food'), default gauge: food
sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      type  => 'food',
      @_
   );

   $self->{aspect} = $tex{$self->{type}}[0]{w} / $tex{$self->{type}}[0]{h};

   $self
}

sub size_request {
   my ($self) = @_;

   #my $tex = $tex{$self->{type}}[0];
   #@$tex{qw(w h)}
   (0, 0)
}

sub set_max {
   my ($self, $max) = @_;

   return if $self->{max_val} == $max;

   $self->{max_val} = $max;
   $self->update;
}

sub set_value {
   my ($self, $val, $max) = @_;

   $self->set_max ($max)
      if defined $max;

   return if $self->{val} == $val;

   $self->{val} = $val;
   $self->update;
}

sub _draw {
   my ($self) = @_;

   my $tex = $tex{$self->{type}};
   my ($t1, $t2, $t3) = @$tex;

   my ($w, $h) = ($self->{w}, $self->{h});

   if ($self->{vertical}) {
      glRotate 90, 0, 0, 1;
      glTranslate 0, -$self->{w}, 0;

      ($w, $h) = ($h, $w);
   }

   my $ycut = $self->{val} / ($self->{max_val} || 1);

   my $ycut1 = max 0, min 1, $ycut;
   my $ycut2 = max 0, min 1, $ycut - 1;

   my $h1 = $self->{h} * (1 - $ycut1);
   my $h2 = $self->{h} * (1 - $ycut2);

   glEnable GL_BLEND;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   glBindTexture GL_TEXTURE_2D, $t1->{name};
   glBegin GL_QUADS;
   glTexCoord 0       , 0;                       glVertex 0 , 0;
   glTexCoord 0       , $t1->{t} * (1 - $ycut1); glVertex 0 , $h1;
   glTexCoord $t1->{s}, $t1->{t} * (1 - $ycut1); glVertex $w, $h1;
   glTexCoord $t1->{s}, 0;                       glVertex $w, 0;
   glEnd;

   my $ycut1 = List::Util::min 1, $ycut;
   glBindTexture GL_TEXTURE_2D, $t2->{name};
   glBegin GL_QUADS;
   glTexCoord 0       , $t2->{t} * (1 - $ycut1); glVertex 0 , $h1;
   glTexCoord 0       , $t2->{t} * (1 - $ycut2); glVertex 0 , $h2;
   glTexCoord $t2->{s}, $t2->{t} * (1 - $ycut2); glVertex $w, $h2;
   glTexCoord $t2->{s}, $t2->{t} * (1 - $ycut1); glVertex $w, $h1;
   glEnd;

   if ($t3) {
      glBindTexture GL_TEXTURE_2D, $t3->{name};
      glBegin GL_QUADS;
      glTexCoord 0       , $t3->{t} * (1 - $ycut2); glVertex 0 , $h2;
      glTexCoord 0       , $t3->{t};                glVertex 0 , $self->{h};
      glTexCoord $t3->{s}, $t3->{t};                glVertex $w, $self->{h};
      glTexCoord $t3->{s}, $t3->{t} * (1 - $ycut2); glVertex $w, $h2;
      glEnd;
   }

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::Gauge;

our @ISA = CFClient::UI::VBox::;

sub new {
   my ($class, %arg) = @_;

   my $self = $class->SUPER::new (
      tooltip    => $arg{type},
      can_hover  => 1,
      can_events => 1,
      %arg,
   );

   $self->add ($self->{value} = new CFClient::UI::Label valign => +1, align => 0, template => "999");
   $self->add ($self->{gauge} = new CFClient::UI::VGauge type => $self->{type}, expand => 1, can_hover => 1);
   $self->add ($self->{max}   = new CFClient::UI::Label valign => -1, align => 0, template => "999");

   $self
}

sub set_fontsize {
   my ($self, $fsize) = @_;

   $self->{value}->set_fontsize ($fsize);
   $self->{max}  ->set_fontsize ($fsize);
}

sub set_max {
   my ($self, $max) = @_;

   $self->{gauge}->set_max ($max);
   $self->{max}->set_text ($max);
}

sub set_value {
   my ($self, $val, $max) = @_;

   $self->set_max ($max)
      if defined $max;

   $self->{gauge}->set_value ($val, $max);
   $self->{value}->set_text ($val);
}

#############################################################################

package CFClient::UI::Slider;

use strict;

use CFClient::OpenGL;

our @ISA = CFClient::UI::DrawBG::;

my @tex =
      map { new_from_file CFClient::Texture CFClient::find_rcfile $_ }
         qw(s1_slider.png s1_slider_bg.png);

sub new {
   my $class = shift;

   # range [value, low, high, page]

   # TODO: 0-width page
   # TODO: req_w/h are wrong with vertical
   # TODO: calculations are off
   my $self = $class->SUPER::new (
      fg        => [1, 1, 1],
      active_fg => [0, 0, 0],
      range     => [0, 0, 100, 10],
      req_w     => $::WIDTH / 80,
      req_h     => $::WIDTH / 80,
      vertical  => 0,
      can_hover => 1,
      inner_pad => 5,
      @_
   );

   $self
}

sub size_request {
   my ($self) = @_;

   my $w = $self->{req_w};
   my $h = $self->{req_h};

   $self->{vertical} ? ($h, $w) : ($w, $h)
}

sub button_down {
   my ($self, $ev, $x, $y) = @_;

   $self->SUPER::button_down ($ev, $x, $y);
   $self->mouse_motion ($ev, $x, $y);
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   if ($GRAB == $self) {
      my ($value, $lo, $hi, $page) = @{$self->{range}};

      my ($x, $w) = $self->{vertical} ? ($y, $self->{h}) : ($x, $self->{w});

      my $inner_pad_px = $self->_calc_inner_pad_px ($w);
      my $inner_w = $w - $inner_pad_px * 2;               # * 2 for left & right

      $x -= $inner_pad_px;  # substract the padding
      $x = $x * ($hi - $lo) / $inner_w + $lo;
      $x = $lo         if $x < $lo;
      $x = $hi - $page if $x > $hi - $page;
      $self->{range}[0] = $x;

      $self->emit (changed => $x);
      $self->update;
   }
}

# the inner_* stuff is for generating a padding for the slider handle,
# so that the handle doesn't leave the texture. This calculation isn't 100%
# correct propably, but it does the job for now
sub _calc_inner_pad_px {
   my ($self, $w) = @_;
   ($w / 100) * $self->{inner_pad} # % to pixels
}

sub _draw {
   my ($self) = @_;

   $self->SUPER::_draw ();

   my ($w, $h) = @$self{qw(w h)};

   if ($self->{vertical}) {
      # draw a vertical slider like a rotated horizontal slider
 
      glRotate 90, 0, 0, 1;
      glTranslate 0, -$self->{w}, 0;

      ($w, $h) = ($h, $w);
   }

   my $fg = $FOCUS == $self ? $self->{active_fg} : $self->{fg};
   my $bg = $FOCUS == $self ? $self->{active_bg} : $self->{bg};

   my ($value, $lo, $hi, $page) = @{$self->{range}};

   $hi = $value + 1 if $lo == $hi;

   my $inner_pad_px = $self->_calc_inner_pad_px ($w);
   my $inner_w = $w - $inner_pad_px * 2;               # * 2 for left & right

   $page  = int $page * $inner_w / ($hi - $lo);
   $value = int +($value - $lo) * $inner_w / ($hi - $lo);

   $w -= $page;
   $page &= ~1;
   glTranslate $page * 0.5, 0, 0;
   $page ||= 2;

   my $knob_a = $inner_pad_px + ($value - $page * 0.5);
   my $knob_b = $inner_pad_px + ($value + $page * 0.5);

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   # draw background
   $tex[1]->draw_quad_alpha (0, 0, $w, $h);

   # draw handle
   $tex[0]->draw_quad_alpha ($knob_a, 0, $knob_b - $knob_a, $h);

   glDisable GL_TEXTURE_2D;
}

#############################################################################

package CFClient::UI::TextView;

our @ISA = CFClient::UI::HBox::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      fontsize   => 1,
      can_events => 0,
      #font      => default_font
      @_,
                 
      layout     => (new CFClient::Layout 1),
      par        => [],
      height     => 0,
      children   => [
         (new CFClient::UI::Empty expand => 1),
         (new CFClient::UI::Slider vertical => 1),
      ],
   );

   $self->{children}[1]->connect (changed => sub { $self->update });

   $self
}

sub set_fontsize {
   my ($self, $fontsize) = @_;

   $self->{fontsize} = $fontsize;
   $self->reflow;
}

sub text_height {
   my ($self, $text) = @_;

   my $layout = $self->{layout};

   $layout->set_height ($self->{fontsize} * $::FONTSIZE);
   $layout->set_width ($self->{children}[0]{w});
   $layout->set_markup ($text);
   
   ($layout->size)[1]
}

sub reflow {
   my ($self) = @_;

   $self->{need_reflow}++;
   $self->update;
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w, $h);

   $self->{layout}->set_font ($self->{font}) if $self->{font};
   $self->{layout}->set_height ($self->{fontsize} * $::FONTSIZE);
   $self->{layout}->set_width ($self->{children}[0]{w});

   $self->reflow;
}

sub add_paragraph {
   my ($self, $color, $text) = @_;

   #TODO: intelligently "reformat" paragraph

   my $height = $self->text_height ($text);

   $self->{height} += $height;

   push @{$self->{par}}, [$height, $color, $text];

   $self->{children}[1]{range} = [$self->{height} - $self->{h}, 0, $self->{height}, $self->{h}];
   $self->{children}[1]->update;
}

sub update {
   my ($self) = @_;

   $self->SUPER::update;

   return unless $self->{h} > 0;

   delete $self->{texture};

   $ROOT->on_post_alloc ($self, sub {
      if (delete $self->{need_reflow}) {
         my $height = 0;

         $height += $_->[0] = $self->text_height ($_->[2])
            for @{$self->{par}};

         $self->{height} = $height;

         $self->{children}[1]{range} = [$height - $self->{h}, 0, $height, $self->{h}];
         
         delete $self->{texture};
      }

      $self->{texture} ||= new_from_opengl CFClient::Texture $self->{children}[0]{w}, $self->{children}[0]{h}, sub {
         glClearColor 0, 0, 0, 0;
         glClear GL_COLOR_BUFFER_BIT;

         glEnable GL_TEXTURE_2D;
         glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

         my $top = int $self->{children}[1]{range}[0];

         my $y0 = $top;
         my $y1 = $top + $self->{h};

         my $y = 0;

         my $layout = $self->{layout};

         $layout->set_font ($self->{font}) if $self->{font};

         for my $par (@{$self->{par}}) {
            my $h = $par->[0];

            if ($y0 < $y + $h && $y < $y1) {
               $layout->set_foreground (@{ $par->[1] });
               $layout->set_markup ($par->[2]);

               my ($W, $H) = $layout->size;
               CFClient::Texture->new_from_layout ($layout)->draw_quad_alpha_premultiplied (0, $y - $y0);
            }

            $y += $h;
         }

         glDisable GL_TEXTURE_2D;
      };
   });
}

sub _draw {
   my ($self) = @_;

   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glColor 1, 1, 1, 1;
   $self->{texture}->draw_quad_alpha_premultiplied (0, 0, $self->{children}[0]{w}, $self->{children}[0]{h});
   glDisable GL_TEXTURE_2D;

   $self->{children}[1]->draw;

}

#############################################################################

package CFClient::UI::Animator;

use CFClient::OpenGL;

our @ISA = CFClient::UI::Bin::;

sub moveto {
   my ($self, $x, $y) = @_;

   $self->{moveto} = [$self->{x}, $self->{y}, $x, $y];
   $self->{speed}  = 0.001;
   $self->{time}   = 1;
   
   ::animation_start $self;
}

sub animate {
   my ($self, $interval) = @_;

   $self->{time} -= $interval * $self->{speed};
   if ($self->{time} <= 0) {
      $self->{time} = 0;
      ::animation_stop $self;
   }

   my ($x0, $y0, $x1, $y1) = @{$self->{moveto}};
      
   $self->{x} = $x0 * $self->{time} + $x1 * (1 - $self->{time});
   $self->{y} = $y0 * $self->{time} + $y1 * (1 - $self->{time});
}

sub _draw {
   my ($self) = @_;

   glPushMatrix;
   glRotate $self->{time} * 1000, 0, 1, 0;
   $self->{children}[0]->draw;
   glPopMatrix;
}

#############################################################################

package CFClient::UI::Flopper;

our @ISA = CFClient::UI::Button::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      state            => 0,
      connect_activate => \&toggle_flopper,
      @_
   );

   if ($self->{state}) {
      $self->{state} = 0;
      $self->toggle_flopper;
   }

   $self
}

sub toggle_flopper {
   my ($self) = @_;

   # TODO: use animation
   if ($self->{state} = !$self->{state}) {
      $CFClient::UI::ROOT->add ($self->{other});
      $self->{other}->move ($self->coord2global (0, $self->{h}));
      $self->emit ("open");
   } else {
      $CFClient::UI::ROOT->remove ($self->{other});
      $self->emit ("close");
   }

   $self->emit (changed => $self->{state});
}

#############################################################################

package CFClient::UI::Tooltip;

our @ISA = CFClient::UI::Bin::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      @_,
      can_events => 0,
   )
}

sub set_tooltip_from {
   my ($self, $widget) = @_;

   $self->add (new CFClient::UI::Label
      markup   => $widget->{tooltip},
      max_w    => ($widget->{tooltip_width} || 0.25) * $::WIDTH,
      fontsize => 0.8,
      fg       => [0, 0, 0, 1],
      font     => ($widget->{tooltip_font} || $::FONT_PROP),
   );
}

sub size_request {
   my ($self) = @_;

   my ($w, $h) = @{$self->child}{qw(req_w req_h)};

   ($w + 4, $h + 4)
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->SUPER::size_allocate ($w - 4, $h - 4);
}

sub _draw {
   my ($self) = @_;

   glTranslate 0.375, 0.375;

   my ($w, $h) = @$self{qw(w h)};

   glColor 1, 0.8, 0.4;
   glBegin GL_QUADS;
   glVertex 0 , 0;
   glVertex 0 , $h;
   glVertex $w, $h;
   glVertex $w, 0;
   glEnd;
   
   glColor 0, 0, 0;
   glBegin GL_LINE_LOOP;
   glVertex 0 , 0;
   glVertex 0 , $h;
   glVertex $w, $h;
   glVertex $w, 0;
   glEnd;
   
   glTranslate 2 - 0.375, 2 - 0.375;
   $self->SUPER::_draw;
}

#############################################################################

package CFClient::UI::Face;

our @ISA = CFClient::UI::Base::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      aspect => 1,
      @_,
   )
}

sub size_request {
   (32, 8)
}

sub _draw {
   my ($self) = @_;

   return unless $::CONN;#d# manage and cache textures differently
   my $tex = $::CONN->{texture}[$::CONN->{faceid}[$self->{face}]];

   # TODO animation
   if ($tex) {
      glEnable GL_TEXTURE_2D;
      glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
      glColor 1, 1, 1, 1;
      $tex->draw_quad_alpha (0, 0, $self->{w}, $self->{h});
      glDisable GL_TEXTURE_2D;
   }
}

#############################################################################

package CFClient::UI::InventoryItem;

our @ISA = CFClient::UI::HBox::;

sub new {
   my $class = shift;

   my %args = @_;

   my $item = delete $args{item};

   my $desc = $item->{nrof} < 2
      ? $item->{name}
      : "$item->{nrof} $item->{name_pl}";


   my $self = $class->SUPER::new (
      can_hover => 1,
      can_events => 1,
      tooltip => (CFClient::UI::Label->escape ($desc)
                 . "\n<small>leftclick - pick up\nmiddle click - apply\nrightclick - menu</small>"),
      connect_button_down => sub {
         my ($self, $ev, $x, $y) = @_;

         # todo: maybe put examine on 1? but should just be a tooltip :(
         if ($ev->{button} == 1) {
            $::CONN->send ("move $::CONN->{player}{tag} $item->{tag} 0");
         } elsif ($ev->{button} == 2) {
            $::CONN->send ("apply $item->{tag}");
         } elsif ($ev->{button} == 3) {
            CFClient::UI::Menu->new (
               items => [
                  ["examine", sub { $::CONN->send ("examine $item->{tag}") }],
                  [
                     $item->{flags} & Crossfire::Protocol::F_LOCKED ? "lock" : "unlock",
                     sub { $::CONN->send ("lock $item->{tag}") },
                  ],
                  ["mark", sub { $::CONN->send ("mark $item->{tag}") }],
                  ["apply", sub { $::CONN->send ("apply $item->{tag}") }],
                  ["drop", sub { $::CONN->send ("move 0 $item->{tag} 0") }],
               ],
            )->popup ($ev);
         }

         1
      },
      %args
   );

   $self->add (new CFClient::UI::Face
      can_events => 0,
      face       => $item->{face},
      anim       => $item->{anim},
      animspeed  => $item->{animspeed},
   );

   $self->add (new CFClient::UI::Label
      can_events => 0,
      text       => $desc,
   );

   $self
}

#############################################################################

package CFClient::UI::Inventory;

our @ISA = CFClient::UI::ScrolledWindow::;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      scrolled => (new CFClient::UI::VBox),
      @_,
   );

   $self
}

sub set_items {
   my ($self, $items) = @_;

   $self->{scrolled}->clear;
   return unless $items;

   my @items = sort { $a->{type} <=> $b->{type} } @$items;

   $self->{real_items} = \@items;

   for my $item (@items) {
      my $desc = $item->{nrof} < 2
                     ? $item->{name}
                     : "$item->{nrof} $item->{name_pl}";

      $self->{scrolled}->add ($item->{widget} ||= new CFClient::UI::InventoryItem item => $item);
   }

#   $range->{range} = [$self->{pos}, 0, $self->{max_pos}, $page];
}

sub size_request {
   my ($self) = @_;
   ($self->{req_w}, $self->{req_h});
}

#############################################################################

package CFClient::UI::Menu;

our @ISA = CFClient::UI::FancyFrame::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   my $self = $class->SUPER::new (
      items => [],
      z     => 100,
      @_,
   );

   $self->add ($self->{vbox} = new CFClient::UI::VBox);

   for my $item (@{ $self->{items} }) {
      my ($widget, $cb) = @$item;

      # handle various types of items, only text for now
      if (!ref $widget) {
         $widget = new CFClient::UI::Label
            can_hover  => 1,
            can_events => 1,
            text       => $widget;
      }

      $self->{item}{$widget} = $item;

      $self->{vbox}->add ($widget);
   }

   $self
}

# popup given the event (must be a mouse button down event currently)
sub popup {
   my ($self, $ev) = @_;

   $self->emit ("popdown");

   # maybe save $GRAB? must be careful about events...
   $GRAB = $self;
   $self->{button} = $ev->{button};

   $self->show;
   $self->move ($ev->{x} - $self->{w} * 0.5, $ev->{y} - $self->{h} * 0.5);
}

sub mouse_motion {
   my ($self, $ev, $x, $y) = @_;

   # TODO: should use vbox->find_widget or so
   $HOVER = $ROOT->find_widget ($ev->{x}, $ev->{y});
   $self->{hover} = $self->{item}{$HOVER};
}

sub button_up {
   my ($self, $ev, $x, $y) = @_;

   if ($ev->{button} == $self->{button}) {
      undef $GRAB;
      $self->hide;

      $self->emit ("popdown");
      $self->{hover}[1]->() if $self->{hover};
   }
}

#############################################################################

package CFClient::UI::Statusbox;

our @ISA = CFClient::UI::VBox::;

sub reorder {
   my ($self) = @_;
   my $NOW = time;

   while (my ($k, $v) = each %{ $self->{item} }) {
      delete $self->{item}{$k} if $v->{timeout} < $NOW;
   }

   my @widgets;

   my @items = sort {
                  $a->{pri} <=> $b->{pri}
                     or $b->{id} <=> $a->{id}
               } values %{ $self->{item} };

   my $count = 10 + 1;
   for my $item (@items) {
      last unless --$count;

      push @widgets, $item->{label} ||= do {
         # TODO: doesn't handle markup well (read as: at all)
         my $short = $item->{count} > 1
                     ? "<b>$item->{count} ×</b> $item->{text}"
                     : $item->{text};

         for ($short) {
            s/^\s+//;
            s/\012.*/…/s;
            my $len = int 40 / $item->{fontsize};
            substr $_, $len, length, "…" if $len < length;
         }

         new CFClient::UI::Label
            markup        => $short,
            tooltip       => $item->{tooltip},
            tooltip_font  => $::FONT_PROP,
            tooltip_width => 0.67,
            fontsize      => $item->{fontsize},
            color         => $item->{color},
            can_events    => 1,
            can_hover     => 1
      };
   }

   $self->clear;
   $self->SUPER::add (reverse @widgets);
}

sub add {
   my ($self, $text, %arg) = @_;

   $text =~ s/^\s+//;
   $text =~ s/\s+$//;

   my $timeout = time + ((delete $arg{timeout}) || 60);

   my $group = exists $arg{group} ? $arg{group} : ++$self->{id};

   if (my $item = $self->{item}{$group}) {
      if ($item->{text} eq $text) {
         $item->{count}++;
      } else {
         $item->{count} = 1;
         $item->{text} = $item->{tooltip} = $text;
      }
      $item->{id} = ++$self->{id};
      $item->{timeout} = $timeout;
      delete $item->{label};
   } else {
      $self->{item}{$group} = {
         id       => ++$self->{id},
         text     => $text,
         timeout  => $timeout,
         tooltip  => $text,
         fontsize => 0.8,
         color    => [0.8, 0.8, 0.8, 0.8],
         pri      => 0,
         count    => 1,
         %arg,
      };
   }

   $self->reorder;
}

#############################################################################

package CFClient::UI::Root;

our @ISA = CFClient::UI::Container::;

use CFClient::OpenGL;

sub new {
   my $class = shift;

   $class->SUPER::new (
      @_,
   )
}

sub configure {
   my ($self, $x, $y, $w, $h) = @_;

   $self->{w} = $w;
   $self->{h} = $h;
}

sub check_size {
   my ($self) = @_;

   $self->size_allocate ($self->{w}, $self->{h})
      if $self->{w};
}

sub size_request {
   my ($self) = @_;

   ($self->{w}, $self->{h})
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   my $old_w = $self->{old_w};
   my $old_h = $self->{old_h};

   if ($old_w && $old_h) {
      for my $child ($self->children) {
         $child->{x}      = int 0.5 + $child->{x}      * $w / $old_w;
         $child->{w}      = int 0.5 + $child->{w}      * $w / $old_w;
         $child->{req_w}  = int 0.5 + $child->{req_w}  * $w / $old_w if exists $child->{req_w};
         $child->{user_w} = int 0.5 + $child->{user_w} * $w / $old_w if exists $child->{user_w};
         $child->{y}      = int 0.5 + $child->{y}      * $h / $old_h;
         $child->{h}      = int 0.5 + $child->{h}      * $h / $old_h;
         $child->{req_h}  = int 0.5 + $child->{req_h}  * $h / $old_h if exists $child->{req_h};
         $child->{user_h} = int 0.5 + $child->{user_h} * $h / $old_h if exists $child->{user_h};
      }
   }

   for my $child ($self->children) {
      my ($X, $Y, $W, $H) = @$child{qw(x y req_w req_h)};

      $X = List::Util::max 0, List::Util::min $w - $W, $X;
      $Y = List::Util::max 0, List::Util::min $h - $H, $Y;
      $child->configure ($X, $Y, $W, $H);
   }

   $self->{old_w} = $w;
   $self->{old_h} = $h;
}

sub coord2local {
   my ($self, $x, $y) = @_;

   ($x, $y)
}

sub coord2global {
   my ($self, $x, $y) = @_;

   ($x, $y)
}

sub update {
   my ($self) = @_;

   $self->check_size;
   $::WANT_REFRESH++;
}

sub add {
   my ($self, $child) = @_;

   # integerise window positions
   $child->{x} = int $child->{x};
   $child->{y} = int $child->{y};

   $self->SUPER::add ($child);
}

sub on_refresh {
   my ($self, $id, $cb) = @_;

   $self->{refresh_hook}{$id} = $cb;
}

sub on_post_alloc {
   my ($self, $id, $cb) = @_;

   $self->{post_alloc_hook}{$id} = $cb;
}

sub draw {
   my ($self) = @_;

   while ($self->{refresh_hook}) {
      $_->()
         for values %{delete $self->{refresh_hook}};
   }

   if ($self->{check_size}) {
      my @queue = ([], []);

      for (;;) {
         if ($self->{check_size}) {
            # heuristic: check containers last
            push @{ $queue[ ! ! $_->isa ("CFClient::UI::Container") ] }, $_
               for values %{delete $self->{check_size}}
         }

         my $widget = (pop @{ $queue[0] }) || (pop @{ $queue[1] }) || last;

         my ($w, $h) = $widget->{user_w} && $widget->{user_h}
            ? @$widget{qw(user_w user_h)}
            : $widget->size_request;

         if (delete $widget->{force_alloc}
             or $w != $widget->{req_w} or $h != $widget->{req_h}) {
            Carp::confess "$widget: size_request is negative" if $w < 0 || $h < 0;#d#
            
            $widget->{req_w} = $w;
            $widget->{req_h} = $h;

            $self->{size_alloc}{$widget} = [$widget, $widget->{w} || $w, $widget->{h} || $h];

            $widget->{parent}->check_size
               if $widget->{parent};
         }
       }
   }

   while ($self->{size_alloc}) {
      for (values %{delete $self->{size_alloc}}) {
         my ($widget, $w, $h) = @$_;

         $w = 0 if $w < 0;
         $h = 0 if $h < 0;

         $widget->{w} = $w;
         $widget->{h} = $h;
         $widget->size_allocate ($w, $h);
         $widget->emit (size_allocate => $w, $h);
      }
   }

   while ($self->{post_alloc_hook}) {
      $_->()
         for values %{delete $self->{post_alloc_hook}};
   }

   glViewport 0, 0, $::WIDTH, $::HEIGHT;
   glClearColor +($::CFG->{fow_intensity}) x 3, 1;
   glClear GL_COLOR_BUFFER_BIT;

   glMatrixMode GL_PROJECTION;
   glLoadIdentity;
   glOrtho 0, $::WIDTH, $::HEIGHT, 0, -10000 , 10000;
   glMatrixMode GL_MODELVIEW;
   glLoadIdentity;

   $self->_draw;
}

#############################################################################

package CFClient::UI;

$ROOT = new CFClient::UI::Root;
$TOOLTIP = new CFClient::UI::Tooltip;

1

Revision:	1.198
Committed:	Fri May 12 02:08:52 2006 UTC (18 years, 1 month ago) by root
Branch:	MAIN
Changes since 1.197:	+23 -7 lines
Log Message:	small fixes