Deliantra-Client/DC/UI.pm

package Crossfire::Client::Widget;

use strict;

use Scalar::Util;

use SDL::OpenGL;
use SDL::OpenGL::Constants;

our $FOCUS;  # the widget with current focus

# class methods for events
sub feed_sdl_key_down_event    { $FOCUS->key_down ($_[0])    if $FOCUS }
sub feed_sdl_key_up_event      { $FOCUS->key_up ($_[0])      if $FOCUS }
sub feed_sdl_button_down_event { }
sub feed_sdl_button_up_event   { }

sub new {
   my $class = shift;

   bless { @_ }, $class
}

sub move {
   my ($self, $x, $y, $z) = @_;
   $self->{x} = $x;
   $self->{y} = $y;
   $self->{z} = $z if defined $z;
}

sub needs_redraw {
   0
}

sub size_request {
   require Carp;
   Carp::confess "size_request is abtract";
}

sub size_allocate {
   my ($self, $w, $h) = @_;
   $self->w ($w);
   $self->h ($h);
}

sub focus_in {
   my ($widget) = @_;
   $FOCUS = $widget;
}

sub focus_out {
   my ($widget) = @_;
}

sub key_down {
   my ($widget, $sdlev) = @_;
}

sub key_up {
   my ($widget, $sdlev) = @_;
}

sub button_down {
   my ($widget, $sdlev) = @_;
}

sub button_up {
   my ($widget, $sdlev) = @_;
}

sub w { $_[0]->{w} = $_[1] if $_[1]; $_[0]->{w} }
sub h { $_[0]->{h} = $_[1] if $_[1]; $_[0]->{h} }
sub x { $_[0]->{x} = $_[1] if $_[1]; $_[0]->{x} }
sub y { $_[0]->{y} = $_[1] if $_[1]; $_[0]->{y} }
sub z { $_[0]->{z} = $_[1] if $_[1]; $_[0]->{z} }

sub draw {
   my ($self) = @_;

   glPushMatrix;
   glTranslate $self->{x}, $self->{y}, 0;
   $self->_draw;
   glPopMatrix;
}

sub _draw {
   my ($self) = @_;

   warn "no draw defined for $self\n";
}

sub bbox {
   my ($self) = @_;
   my ($w, $h) = $self->size_request;
   (
     $self->{x},
     $self->{y},
     $self->{x} = $w,
     $self->{y} = $h
   )
}

sub find_widget {
   my ($self, $x, $y) = @_;

   return $self
      if $x >= $self->{x} && $x < $self->{x} + $self->{w}
          && $y >= $self->{y} && $y < $self->{y} + $self->{h};

   ()
}

sub del_parent { $_[0]->{parent} = undef }

sub set_parent {
   my ($self, $par) = @_;

   $self->{parent} = $par;
   Scalar::Util::weaken $self->{parent};
}

sub get_parent {
   $_[0]->{parent}
}

sub update {
   my ($self) = @_;

   $self->{parent}->update
      if $self->{parent};
}

sub DESTROY {
   my ($self) = @_;

   #$self->deactivate;
}

#############################################################################

package Crossfire::Client::Widget::Container;

our @ISA = Crossfire::Client::Widget::;

sub new {
   my ($class, @widgets) = @_;

   my $self = $class->SUPER::new (children => []);
   $self->add ($_) for @widgets;

   $self
}

sub add {
   my ($self, $chld, $expand) = @_;

   $chld->{expand} = $expand;
   $chld->set_parent ($self);

   @{$self->{children}} =
      sort { $a->{z} <=> $b->{z} }
         @{$self->{children}}, $chld;

   $self->size_allocate ($self->{w}, $self->{h});
}

sub remove {
   my ($self, $widget) = @_;

   $self->{children} = [ grep $_ != $widget, @{ $self->{children} } ];

   $self->size_allocate ($self->{w}, $self->{h});
}

sub find_widget {
   my ($self, $x, $y) = @_;

   my $res;

   for (@{ $self->{children} }) {
      $res = $_->find_widget ($x, $y)
         and return $res;
   }

   ()
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);
   for (@{$self->{children} || []}) {
      my ($w, $h) = $_->size_request;
      $hs += $h;
      if ($ws < $w) { $ws = $w }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   $_->draw for @{$self->{children}};
}

#############################################################################

package Crossfire::Client::Widget::Bin;

our @ISA = Crossfire::Client::Widget::Container::;

sub child { $_[0]->{children}[0] }

sub size_request {
   $_[0]{children}[0]->size_request if $_[0]{children}[0];
}

sub size_allocate {
   my ($self, $w, $h) = @_;
   $self->SUPER::size_allocate ($w, $h);
   $self->{children}[0]->size_allocate ($w, $h)
      if $self->{children}[0]
}

#############################################################################

package Crossfire::Client::Widget::Toplevel;

our @ISA = Crossfire::Client::Widget::Container::;

sub update {
   my ($self) = @_;

   ::refresh ();
}

#############################################################################

package Crossfire::Client::Widget::Window;

our @ISA = Crossfire::Client::Widget::Bin::;

use SDL::OpenGL;

sub add {
   my ($self, $chld) = @_;
   warn "ADD $chld\n";
   $self->SUPER::add ($chld);
   $chld->set_parent ($self);
}

sub remove {
   my ($self) = @_;
   # TODO FIXME: removing a child from a window will crash, see render_chld
   # $self->update;
}

sub update {
   my ($self) = @_;
   $self->render_chld;
}

sub render_chld {
   my ($self) = @_;
   my $chld = $self->get;
   my ($w, $h) = $self->size_request;

   require Carp;
   Carp::cluck "RENDERCHI $w $h";
   warn "RENDERCHI $w $h\n";
   $self->{texture} =
      Crossfire::Client::Texture->new_from_opengl (
         $w, $h, sub { $chld->draw }
      );
   $self->{texture}->upload;
}

sub size_request {
   my ($self) = @_;
   ($self->w, $self->h)
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->w ($w);
   $self->h ($h);
   $self->get->size_allocate ($w, $h);

   $self->update; #TODO: Move this to the size_request event propably?
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = ($self->w, $self->h);

   my $tex = $self->{texture}
      or return;

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex  0,  0;
   glTexCoord 0, 1; glVertex  0, $h;
   glTexCoord 1, 1; glVertex $w, $h;
   glTexCoord 1, 0; glVertex $w,  0;
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package Crossfire::Client::Widget::Frame;

our @ISA = Crossfire::Client::Widget::Bin::;

use SDL::OpenGL;

sub size_request {
   my ($self) = @_;
   my $chld = $self->child
      or return (0, 0);

   $chld->move (2, 2);

   map { $_ + 4 } $chld->size_request;
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->w ($w);
   $self->h ($h);

   $self->child->size_allocate ($w - 4, $h - 4);
   $self->child->move (2, 2);
}

sub _draw {
   my ($self) = @_;

   my $chld = $self->child;

   my ($w, $h) = $chld->size_request;

   glBegin GL_QUADS;
   glColor 0, 0, 0;
   glTexCoord 0, 0; glVertex 0      , 0;
   glTexCoord 0, 1; glVertex 0      , $h + 4;
   glTexCoord 1, 1; glVertex $w + 4 , $h + 4;
   glTexCoord 1, 0; glVertex $w + 4 , 0;
   glEnd;

   $chld->draw;
}

#############################################################################

package Crossfire::Client::Widget::FancyFrame;

our @ISA = Crossfire::Client::Widget::Frame::;

use SDL::OpenGL;

sub new {
   my ($self, $theme) = @_;
   $self = $self->SUPER::new;

   $self->{txts} = [
      map { new_from_file Crossfire::Client::Texture Crossfire::Client::find_rcfile $_ }
         qw/d1_bg.png d1_border_top.png d1_border_right.png d1_border_left.png d1_border_bottom.png/
   ];
   $self
}

sub size_request {
   my ($self) = @_;

   my ($w, $h) = $self->SUPER::size_request;

   $h += $self->{txts}->[1]->{height};
   $h += $self->{txts}->[4]->{height};
   $w += $self->{txts}->[2]->{width};
   $w += $self->{txts}->[3]->{width};

   ($w, $h)
}

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->w ($w);
   $self->h ($h);
   $h -= $self->{txts}->[1]->{height};
   $h -= $self->{txts}->[4]->{height};
   $w -= $self->{txts}->[2]->{width};
   $w -= $self->{txts}->[3]->{width};

   $h = $h < 0 ? 0 : $h;
   $w = $w < 0 ? 0 : $w;
   warn "CHILD:$w $h\n";
   $self->child->size_allocate ($w, $h);
   $self->child->move ($self->{txts}->[3]->{width}, $self->{txts}->[1]->{height});
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = ($self->w, $self->h);
   my ($cw, $ch) = ($self->child->w, $self->child->h);

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   my $top = $self->{txts}->[1];
   glBindTexture GL_TEXTURE_2D, $top->{name};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , 0;
   glTexCoord 0, 1; glVertex 0            , $top->{height};
   glTexCoord 1, 1; glVertex $w           , $top->{height};
   glTexCoord 1, 0; glVertex $w           , 0;
   glEnd;

   my $left = $self->{txts}->[3];
   glBindTexture GL_TEXTURE_2D, $left->{name};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            ,  $top->{height};
   glTexCoord 0, 1; glVertex 0            ,  $top->{height} + $ch;
   glTexCoord 1, 1; glVertex $left->{width}, $top->{height} + $ch;
   glTexCoord 1, 0; glVertex $left->{width}, $top->{height};
   glEnd;

   my $right = $self->{txts}->[2];
   glBindTexture GL_TEXTURE_2D, $right->{name};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex $w - $right->{width}, $top->{height};
   glTexCoord 0, 1; glVertex $w - $right->{width}, $top->{height} + $ch;
   glTexCoord 1, 1; glVertex $w                  , $top->{height} + $ch;
   glTexCoord 1, 0; glVertex $w                  , $top->{height};
   glEnd;

   my $bottom = $self->{txts}->[4];
   glBindTexture GL_TEXTURE_2D, $bottom->{name};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , $h - $bottom->{height};
   glTexCoord 0, 1; glVertex 0            , $h;
   glTexCoord 1, 1; glVertex $w           , $h;
   glTexCoord 1, 0; glVertex $w           , $h - $bottom->{height};
   glEnd;

   my $bg = $self->{txts}->[0];
   glBindTexture GL_TEXTURE_2D, $bg->{name};
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;
   glTexParameter  GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT;
   glTexParameter  GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT;

   my $rep_x = $cw / $bg->{width};
   my $rep_y = $ch / $bg->{height};

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex $left->{width}, $top->{height};
   glTexCoord 0, $rep_y; glVertex $left->{width}, $top->{height} + $ch;
   glTexCoord $rep_x, $rep_y; glVertex $left->{width} + $cw , $top->{height} + $ch;
   glTexCoord $rep_x, 0; glVertex $left->{width} + $cw , $top->{height};
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;

   $self->child->draw;

}

#############################################################################

package Crossfire::Client::Widget::Table;

our @ISA = Crossfire::Client::Widget::Bin::;

use SDL::OpenGL;

sub add {
   my ($self, $x, $y, $chld) = @_;
   my $old_chld = $self->{children}[$y][$x];

   $self->{children}[$y][$x] = $chld;
   $chld->set_parent ($self);
   $self->update;
}

sub max_row_height {
   my ($self, $row) = @_;

   my $hs = 0;
   for (my $xi = 0; $xi <= $#{$self->{children}->[$row] || []}; $xi++) {
      my $c = $self->{children}->[$row]->[$xi];
      if ($c) {
         my ($w, $h) = $c->size_request;
         if ($hs < $h) { $hs = $h }
      }
   }
   return $hs;
}

sub max_col_width {
   my ($self, $col) = @_;

   my $ws = 0;
   for (my $yi = 0; $yi <= $#{$self->{children} || []}; $yi++) {
      my $c = ($self->{children}->[$yi] || [])->[$col];
      if ($c) {
         my ($w, $h) = $c->size_request;
         if ($ws < $w) { $ws = $w }
      }
   }
   return $ws;
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);

   for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) {
      $hs += $self->max_row_height ($yi);
   }

   for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) {
      my $wm = 0;
      for (my $xi = 0; $xi <= $#{$self->{children}->[$yi]}; $xi++) {
         $wm += $self->max_col_width ($xi)
      }
      if ($ws < $wm) { $ws = $wm }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   my $y = 0;
   for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) {
      my $x = 0;

      for (my $xi = 0; $xi <= $#{$self->{children}->[$yi]}; $xi++) {

         my $c = $self->{children}->[$yi]->[$xi];
         if ($c) {
            $c->move ($x, $y, 0); #TODO: Move to size_request
            $c->draw if $c;
         }

         $x += $self->max_col_width ($xi);
      }

      $y += $self->max_row_height ($yi);
   }
}

#############################################################################

package Crossfire::Client::Widget::VBox;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub size_allocate {
   my ($self, $w, $h) = @_;

   $self->w ($w);
   $self->h ($h);

   my $exp;
   my @oth;
   # find expand widget
   for (@{$self->{children}}) {
      if ($_->{expand}) {
         $exp = $_;
         last;
      }
      push @oth, $_;
   }

   my ($ow, $oh);

   # get sizes of other widgets
   for (@oth) {
      my ($w, $h) = $_->size_request;
      $oh += $h;
      if ($ow < $w) { $ow = $w }
   }

   my $y = 0;
   for (@{$self->{children}}) {
      $_->move (0, $y);

      if ($_ == $exp) {
         $_->size_allocate ($w, $h - $oh);
         $y += $h - $oh;
      } else {
         my ($cw, $h) = $_->size_request;
         $_->size_allocate ($w, $h);
         $y += $h;
      }
   }
}

sub _draw {
   my ($self) = @_;

   my ($x, $y);
   for (@{$self->{children} || []}) {
      $_->draw;
      $y += $_->h;
   }
}

#############################################################################

package Crossfire::Client::Widget::Label;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub new {
   my ($class, $x, $y, $z, $height, $text) = @_;

   # TODO: color, and make height, xyz etc. optional
   my $self = $class->SUPER::new (x => $x, y => $y, z => $z, height => $height);

   $self->set_text ($text);

   $self
}

sub set_text {
   my ($self, $text) = @_;

   $self->{text} = $text;
   $self->{texture} = new_from_text Crossfire::Client::Texture $text, $self->{height};

   $self->update;
}

sub get_text {
   my ($self, $text) = @_;

   $self->{text}
}

sub size_request {
   my ($self) = @_;

   (
      $self->{texture}{width},
      $self->{texture}{height},
   )
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{texture};

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glColor 1, 0, 0, 1; # TODO color

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , 0;
   glTexCoord 0, 1; glVertex 0            , $tex->{height};
   glTexCoord 1, 1; glVertex $tex->{width}, $tex->{height};
   glTexCoord 1, 0; glVertex $tex->{width}, 0;
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

#############################################################################

package Crossfire::Client::Widget::TextEntry;

our @ISA = Crossfire::Client::Widget::Label::;

use SDL;
use SDL::OpenGL;

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   $ev->set_unicode (1);
   my $uni = $ev->key_unicode;

   my $text = $self->get_text;

   if ($sym == SDLK_BACKSPACE) {
      substr $text, -1, 1, '';

   } elsif ($uni) {
      $text .= chr $uni;
   }
   $self->set_text ($text);
}

#############################################################################

package Crossfire::Client::Widget::MapWidget;

use strict;

use List::Util qw(min max);

use SDL;
use SDL::OpenGL;
use SDL::OpenGL::Constants;

our @ISA = Crossfire::Client::Widget::;

sub key_down {
   print "MAPKEYDOWN\n";
}

sub key_up {
}

sub size_request {

}

sub size_allocate {
}

sub _draw {
   my ($self) = @_;

   my $mx = $::CONN->{mapx};
   my $my = $::CONN->{mapy};

   my $map = $::CONN->{map};

   my ($xofs, $yofs);

   my $sw = 1 + int $::WIDTH  / 32;
   my $sh = 1 + int $::HEIGHT / 32;

   if ($::CONN->{mapw} > $sw) {
      $xofs = $mx + ($::CONN->{mapw} - $sw) * 0.5;
   } else {
      $xofs = $self->{xofs} = min $mx, max $mx + $::CONN->{mapw} - $sw + 1, $self->{xofs};
   }

   if ($::CONN->{maph} > $sh) {
      $yofs = $my + ($::CONN->{maph} - $sh) * 0.5;
   } else {
      $yofs = $self->{yofs} = min $my, max $my + $::CONN->{maph} - $sh + 1, $self->{yofs};
   }

   glEnable GL_TEXTURE_2D;
   glEnable GL_BLEND;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE;

   my $sw4 = ($sw + 3) & ~3;
   my $lighting = "\x00" x ($sw4 * $sh);

   for my $x (0 .. $sw - 1) {
      for my $y (0 .. $sh - 1) {

         my $cell = $map->[$x + $xofs][$y + $yofs]
            or next;

         my $darkness = $cell->[0] * (1 / 255);
         if ($darkness < 0) {
            $darkness = 0.15;
         }
         substr $lighting, $y * $sw4 + $x, 1, chr 255 - $darkness * 255;

         for my $num (grep $_, @$cell[1,2,3]) {
            my $tex = $::CONN->{face}[$num]{texture} || next;

            glBindTexture GL_TEXTURE_2D, $tex->{name};

            my $w = $tex->{width};
            my $h = $tex->{height};

            my $px = ($x + 1) * 32 - $w;
            my $py = ($y + 1) * 32 - $h;

            glBegin GL_QUADS;
            glTexCoord 0, 0; glVertex $px     , $py;
            glTexCoord 0, 1; glVertex $px     , $py + $h;
            glTexCoord 1, 1; glVertex $px + $w, $py + $h;
            glTexCoord 1, 0; glVertex $px + $w, $py;
            glEnd;
         }
      }
   }

#   if (1) { # higher quality darkness
#      $lighting =~ s/(.)/$1$1$1/gs;
#      my $pb = new_from_data Gtk2::Gdk::Pixbuf $lighting, "rgb", 0, 8, $sw4, $sh, $sw4 * 3;
#
#      $pb = $pb->scale_simple ($sw4 * 0.5, $sh * 0.5, "bilinear");
#
#      $lighting = $pb->get_pixels;
#      $lighting =~ s/(.)../$1/gs;
#   }

   $lighting = new Crossfire::Client::Texture
      width          => $sw4,
      height         => $sh,
      data           => $lighting,
      internalformat => GL_ALPHA4,
      format         => GL_ALPHA;

   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glColor 0, 0, 0, 0.75;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
   glBindTexture GL_TEXTURE_2D, $lighting->{name};
   glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR;
   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0        , 0;
   glTexCoord 0, 1; glVertex 0        , $sh * 32;
   glTexCoord 1, 1; glVertex $sw4 * 32, $sh * 32;
   glTexCoord 1, 0; glVertex $sw4 * 32, 0;
   glEnd;

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;
}

my %DIR = (
   SDLK_KP8, [1, "north"],
   SDLK_KP9, [2, "northeast"],
   SDLK_KP6, [3, "east"],
   SDLK_KP3, [4, "southeast"],
   SDLK_KP2, [5, "south"],
   SDLK_KP1, [6, "southwest"],
   SDLK_KP4, [7, "west"],
   SDLK_KP7, [8, "northwest"],

   SDLK_UP,    [1, "north"],
   SDLK_RIGHT, [3, "east"],
   SDLK_DOWN,  [5, "south"],
   SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if ($sym == SDLK_KP5) {
      $::CONN->send ("command stay fire");
   } elsif (exists $DIR{$sym}) {
      if ($mod & KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->send ("command fire $DIR{$sym}[0]");
      } elsif ($mod & KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->send ("command run $DIR{$sym}[0]");
      } else {
         $::CONN->send ("command $DIR{$sym}[1]");
      }
   }
}

sub key_up {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if (!($mod & KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->send ("command fire_stop");
   }
   if (!($mod & KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->send ("command run_stop");
   }
}

#############################################################################

package Crossfire::Client::Widget::Animator;

use SDL::OpenGL;

our @ISA = Crossfire::Client::Widget::Bin::;

sub moveto {
   my ($self, $x, $y) = @_;

   $self->{moveto} = [$self->{x}, $self->{y}, $x, $y];
   $self->{speed}  = 0.2;
   $self->{time}   = 1;
   
   ::animation_start $self;
}

sub animate {
   my ($self, $interval) = @_;

   $self->{time} -= $interval * $self->{speed};
   if ($self->{time} <= 0) {
      $self->{time} = 0;
      ::animation_stop $self;
   }

   my ($x0, $y0, $x1, $y1) = @{$self->{moveto}};
      
   $self->{x} = $x0 * $self->{time} + $x1 * (1 - $self->{time});
   $self->{y} = $y0 * $self->{time} + $y1 * (1 - $self->{time});
}

sub _draw {
   my ($self) = @_;

   glPushMatrix;
   glRotate $self->{time} * 10000, 0, 1, 0;
   $self->{children}[0]->draw;
   glPopMatrix;
}

1;

Revision:	1.39
Committed:	Sun Apr 9 21:39:08 2006 UTC (18 years, 2 months ago) by root
Branch:	MAIN
Changes since 1.38:	+35 -10 lines
Log Message:	cleanup, but somewhat broken now