1 |
package Crossfire::Client::Widget; |
2 |
|
3 |
use strict; |
4 |
|
5 |
use Scalar::Util; |
6 |
|
7 |
use SDL::OpenGL; |
8 |
use SDL::OpenGL::Constants; |
9 |
|
10 |
use Crossfire::Client; |
11 |
|
12 |
# class methods for events |
13 |
sub feed_sdl_key_down_event { $::FOCUS->key_down ($_[0]) if $::FOCUS } |
14 |
sub feed_sdl_key_up_event { $::FOCUS->key_up ($_[0]) if $::FOCUS } |
15 |
sub feed_sdl_button_down_event { } |
16 |
sub feed_sdl_button_up_event { } |
17 |
|
18 |
sub new { |
19 |
my $class = shift; |
20 |
|
21 |
bless { @_ }, $class |
22 |
} |
23 |
|
24 |
sub move { |
25 |
my ($self, $x, $y, $z) = @_; |
26 |
$self->{x} = $x; |
27 |
$self->{y} = $y; |
28 |
$self->{z} = $z if defined $z; |
29 |
} |
30 |
|
31 |
sub needs_redraw { |
32 |
0 |
33 |
} |
34 |
|
35 |
sub size_request { |
36 |
require Carp; |
37 |
Carp::confess "size_request is abtract"; |
38 |
} |
39 |
|
40 |
sub size_allocate { |
41 |
my ($self, $w, $h) = @_; |
42 |
|
43 |
$self->{w} = $w; |
44 |
$self->{h} = $h; |
45 |
} |
46 |
|
47 |
sub focus_in { |
48 |
my ($widget) = @_; |
49 |
$::FOCUS = $widget; |
50 |
} |
51 |
|
52 |
sub focus_out { |
53 |
my ($widget) = @_; |
54 |
} |
55 |
|
56 |
sub key_down { |
57 |
my ($widget, $sdlev) = @_; |
58 |
} |
59 |
|
60 |
sub key_up { |
61 |
my ($widget, $sdlev) = @_; |
62 |
} |
63 |
|
64 |
sub button_down { |
65 |
my ($widget, $sdlev) = @_; |
66 |
} |
67 |
|
68 |
sub button_up { |
69 |
my ($widget, $sdlev) = @_; |
70 |
} |
71 |
|
72 |
sub w { $_[0]->{w} = $_[1] if $_[1]; $_[0]->{w} } |
73 |
sub h { $_[0]->{h} = $_[1] if $_[1]; $_[0]->{h} } |
74 |
sub x { $_[0]->{x} = $_[1] if $_[1]; $_[0]->{x} } |
75 |
sub y { $_[0]->{y} = $_[1] if $_[1]; $_[0]->{y} } |
76 |
sub z { $_[0]->{z} = $_[1] if $_[1]; $_[0]->{z} } |
77 |
|
78 |
sub draw { |
79 |
my ($self) = @_; |
80 |
|
81 |
glPushMatrix; |
82 |
glTranslate $self->{x}, $self->{y}, 0; |
83 |
$self->_draw; |
84 |
if ($self == $::HOVER) { |
85 |
glColor 1, 1, 1, 0.4; |
86 |
glBegin GL_QUADS; |
87 |
glVertex 0, 0; |
88 |
glVertex $self->{w} - 1, 0; |
89 |
glVertex $self->{w} - 1, $self->{h} - 1; |
90 |
glVertex 0, $self->{h} - 1; |
91 |
glEnd; |
92 |
} |
93 |
glPopMatrix; |
94 |
} |
95 |
|
96 |
sub _draw { |
97 |
my ($self) = @_; |
98 |
|
99 |
warn "no draw defined for $self\n"; |
100 |
} |
101 |
|
102 |
sub bbox { |
103 |
my ($self) = @_; |
104 |
my ($w, $h) = $self->size_request; |
105 |
( |
106 |
$self->{x}, |
107 |
$self->{y}, |
108 |
$self->{x} = $w, |
109 |
$self->{y} = $h |
110 |
) |
111 |
} |
112 |
|
113 |
sub find_widget { |
114 |
my ($self, $x, $y) = @_; |
115 |
|
116 |
return $self |
117 |
if $x >= $self->{x} && $x < $self->{x} + $self->{w} |
118 |
&& $y >= $self->{y} && $y < $self->{y} + $self->{h}; |
119 |
|
120 |
() |
121 |
} |
122 |
|
123 |
sub del_parent { $_[0]->{parent} = undef } |
124 |
|
125 |
sub set_parent { |
126 |
my ($self, $par) = @_; |
127 |
|
128 |
$self->{parent} = $par; |
129 |
Scalar::Util::weaken $self->{parent}; |
130 |
} |
131 |
|
132 |
sub get_parent { |
133 |
$_[0]->{parent} |
134 |
} |
135 |
|
136 |
sub update { |
137 |
my ($self) = @_; |
138 |
|
139 |
$self->{parent}->update |
140 |
if $self->{parent}; |
141 |
} |
142 |
|
143 |
sub DESTROY { |
144 |
my ($self) = @_; |
145 |
|
146 |
#$self->deactivate; |
147 |
} |
148 |
|
149 |
############################################################################# |
150 |
|
151 |
package Crossfire::Client::Widget::Container; |
152 |
|
153 |
our @ISA = Crossfire::Client::Widget::; |
154 |
|
155 |
sub new { |
156 |
my ($class, @widgets) = @_; |
157 |
|
158 |
my $self = $class->SUPER::new (children => []); |
159 |
$self->add ($_) for @widgets; |
160 |
|
161 |
$self |
162 |
} |
163 |
|
164 |
sub add { |
165 |
my ($self, $chld, $expand) = @_; |
166 |
|
167 |
$chld->{expand} = $expand; |
168 |
$chld->set_parent ($self); |
169 |
|
170 |
@{$self->{children}} = |
171 |
sort { $a->{z} <=> $b->{z} } |
172 |
@{$self->{children}}, $chld; |
173 |
|
174 |
$self->size_allocate ($self->{w}, $self->{h}) |
175 |
if $self->{w}; #TODO: check for "realised state" |
176 |
} |
177 |
|
178 |
sub remove { |
179 |
my ($self, $widget) = @_; |
180 |
|
181 |
$self->{children} = [ grep $_ != $widget, @{ $self->{children} } ]; |
182 |
|
183 |
$self->size_allocate ($self->{w}, $self->{h}); |
184 |
} |
185 |
|
186 |
sub find_widget { |
187 |
my ($self, $x, $y) = @_; |
188 |
|
189 |
$x -= $self->{x}; |
190 |
$y -= $self->{y}; |
191 |
|
192 |
my $res; |
193 |
|
194 |
for (reverse @{ $self->{children} }) { |
195 |
$res = $_->find_widget ($x, $y) |
196 |
and return $res; |
197 |
} |
198 |
|
199 |
$self->SUPER::find_widget ($x + $self->{x}, $y + $self->{y}) |
200 |
} |
201 |
|
202 |
sub _draw { |
203 |
my ($self) = @_; |
204 |
|
205 |
$_->draw for @{$self->{children}}; |
206 |
} |
207 |
|
208 |
############################################################################# |
209 |
|
210 |
package Crossfire::Client::Widget::Bin; |
211 |
|
212 |
our @ISA = Crossfire::Client::Widget::Container::; |
213 |
|
214 |
sub child { $_[0]->{children}[0] } |
215 |
|
216 |
sub size_request { |
217 |
$_[0]{children}[0]->size_request if $_[0]{children}[0]; |
218 |
} |
219 |
|
220 |
sub size_allocate { |
221 |
my ($self, $w, $h) = @_; |
222 |
|
223 |
$self->SUPER::size_allocate ($w, $h); |
224 |
$self->{children}[0]->size_allocate ($w, $h) |
225 |
if $self->{children}[0] |
226 |
} |
227 |
|
228 |
############################################################################# |
229 |
|
230 |
package Crossfire::Client::Widget::Toplevel; |
231 |
|
232 |
our @ISA = Crossfire::Client::Widget::Container::; |
233 |
|
234 |
sub update { |
235 |
my ($self) = @_; |
236 |
|
237 |
::refresh (); |
238 |
} |
239 |
|
240 |
sub add { |
241 |
my ($self, $widget) = @_; |
242 |
|
243 |
$self->SUPER::add ($widget); |
244 |
|
245 |
$widget->size_allocate ($widget->size_request); |
246 |
} |
247 |
|
248 |
############################################################################# |
249 |
|
250 |
package Crossfire::Client::Widget::Window; |
251 |
|
252 |
our @ISA = Crossfire::Client::Widget::Bin::; |
253 |
|
254 |
use SDL::OpenGL; |
255 |
|
256 |
sub new { |
257 |
my ($class, $x, $y, $z, $w, $h) = @_; |
258 |
|
259 |
my $self = $class->SUPER::new; |
260 |
|
261 |
@$self{qw(x y z w h)} = ($x, $y, $z, $w, $h); |
262 |
} |
263 |
|
264 |
sub update { |
265 |
my ($self) = @_; |
266 |
|
267 |
$self->render_chld; |
268 |
$self->SUPER::update; |
269 |
} |
270 |
|
271 |
sub render_chld { |
272 |
my ($self) = @_; |
273 |
|
274 |
$self->{texture} = |
275 |
Crossfire::Client::Texture->new_from_opengl ( |
276 |
$self->{w}, $self->{h}, sub { $self->child->draw } |
277 |
); |
278 |
} |
279 |
|
280 |
sub size_allocate { |
281 |
my ($self, $w, $h) = @_; |
282 |
|
283 |
$self->{w} = $w; |
284 |
$self->{h} = $h; |
285 |
|
286 |
$self->child->size_allocate ($w, $h); |
287 |
|
288 |
$self->render_chld; |
289 |
} |
290 |
|
291 |
sub _draw { |
292 |
my ($self) = @_; |
293 |
|
294 |
my ($w, $h) = ($self->w, $self->h); |
295 |
|
296 |
my $tex = $self->{texture} |
297 |
or return; |
298 |
|
299 |
glEnable GL_BLEND; |
300 |
glEnable GL_TEXTURE_2D; |
301 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE; |
302 |
glBindTexture GL_TEXTURE_2D, $tex->{name}; |
303 |
|
304 |
glBegin GL_QUADS; |
305 |
glTexCoord 0, 0; glVertex 0, 0; |
306 |
glTexCoord 0, 1; glVertex 0, $h; |
307 |
glTexCoord 1, 1; glVertex $w, $h; |
308 |
glTexCoord 1, 0; glVertex $w, 0; |
309 |
glEnd; |
310 |
|
311 |
glDisable GL_BLEND; |
312 |
glDisable GL_TEXTURE_2D; |
313 |
} |
314 |
|
315 |
############################################################################# |
316 |
|
317 |
package Crossfire::Client::Widget::Frame; |
318 |
|
319 |
our @ISA = Crossfire::Client::Widget::Bin::; |
320 |
|
321 |
use SDL::OpenGL; |
322 |
|
323 |
sub size_request { |
324 |
my ($self) = @_; |
325 |
my $chld = $self->child |
326 |
or return (0, 0); |
327 |
|
328 |
$chld->move (2, 2); |
329 |
|
330 |
map { $_ + 4 } $chld->size_request; |
331 |
} |
332 |
|
333 |
sub size_allocate { |
334 |
my ($self, $w, $h) = @_; |
335 |
|
336 |
$self->{w} = $w; |
337 |
$self->{h} = $h; |
338 |
|
339 |
$self->child->size_allocate ($w - 4, $h - 4); |
340 |
$self->child->move (2, 2); |
341 |
} |
342 |
|
343 |
sub _draw { |
344 |
my ($self) = @_; |
345 |
|
346 |
my $chld = $self->child; |
347 |
|
348 |
my ($w, $h) = $chld->size_request; |
349 |
|
350 |
glBegin GL_QUADS; |
351 |
glColor 0, 0, 0; |
352 |
glTexCoord 0, 0; glVertex 0 , 0; |
353 |
glTexCoord 0, 1; glVertex 0 , $h + 4; |
354 |
glTexCoord 1, 1; glVertex $w + 4 , $h + 4; |
355 |
glTexCoord 1, 0; glVertex $w + 4 , 0; |
356 |
glEnd; |
357 |
|
358 |
$chld->draw; |
359 |
} |
360 |
|
361 |
############################################################################# |
362 |
|
363 |
package Crossfire::Client::Widget::FancyFrame; |
364 |
|
365 |
our @ISA = Crossfire::Client::Widget::Bin::; |
366 |
|
367 |
use SDL::OpenGL; |
368 |
|
369 |
my @tex = |
370 |
map { new_from_file Crossfire::Client::Texture Crossfire::Client::find_rcfile $_ } |
371 |
qw(d1_bg.png d1_border_top.png d1_border_right.png d1_border_left.png d1_border_bottom.png); |
372 |
|
373 |
sub size_request { |
374 |
my ($self) = @_; |
375 |
|
376 |
my ($w, $h) = $self->SUPER::size_request; |
377 |
|
378 |
$h += $tex[1]->{height}; |
379 |
$h += $tex[4]->{height}; |
380 |
$w += $tex[2]->{width}; |
381 |
$w += $tex[3]->{width}; |
382 |
|
383 |
($w, $h) |
384 |
} |
385 |
|
386 |
sub size_allocate { |
387 |
my ($self, $w, $h) = @_; |
388 |
|
389 |
$self->SUPER::size_allocate ($w, $h); |
390 |
|
391 |
$h -= $tex[1]->{height}; |
392 |
$h -= $tex[4]->{height}; |
393 |
$w -= $tex[2]->{width}; |
394 |
$w -= $tex[3]->{width}; |
395 |
|
396 |
$h = $h < 0 ? 0 : $h; |
397 |
$w = $w < 0 ? 0 : $w; |
398 |
|
399 |
$self->child->size_allocate ($w, $h); |
400 |
$self->child->move ($tex[3]->{width}, $tex[1]->{height}); |
401 |
} |
402 |
|
403 |
sub _draw { |
404 |
my ($self) = @_; |
405 |
|
406 |
my ($w, $h) = ($self->{w}, $self->{h}); |
407 |
my ($cw, $ch) = ($self->child->{w}, $self->child->{h}); |
408 |
|
409 |
glEnable GL_BLEND; |
410 |
glEnable GL_TEXTURE_2D; |
411 |
glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA; |
412 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE; |
413 |
|
414 |
my $top = $tex[1]; |
415 |
glBindTexture GL_TEXTURE_2D, $top->{name}; |
416 |
|
417 |
glBegin GL_QUADS; |
418 |
glTexCoord 0, 0; glVertex 0 , 0; |
419 |
glTexCoord 0, 1; glVertex 0 , $top->{height}; |
420 |
glTexCoord 1, 1; glVertex $w , $top->{height}; |
421 |
glTexCoord 1, 0; glVertex $w , 0; |
422 |
glEnd; |
423 |
|
424 |
my $left = $tex[3]; |
425 |
glBindTexture GL_TEXTURE_2D, $left->{name}; |
426 |
|
427 |
glBegin GL_QUADS; |
428 |
glTexCoord 0, 0; glVertex 0 , $top->{height}; |
429 |
glTexCoord 0, 1; glVertex 0 , $top->{height} + $ch; |
430 |
glTexCoord 1, 1; glVertex $left->{width}, $top->{height} + $ch; |
431 |
glTexCoord 1, 0; glVertex $left->{width}, $top->{height}; |
432 |
glEnd; |
433 |
|
434 |
my $right = $tex[2]; |
435 |
glBindTexture GL_TEXTURE_2D, $right->{name}; |
436 |
|
437 |
glBegin GL_QUADS; |
438 |
glTexCoord 0, 0; glVertex $w - $right->{width}, $top->{height}; |
439 |
glTexCoord 0, 1; glVertex $w - $right->{width}, $top->{height} + $ch; |
440 |
glTexCoord 1, 1; glVertex $w , $top->{height} + $ch; |
441 |
glTexCoord 1, 0; glVertex $w , $top->{height}; |
442 |
glEnd; |
443 |
|
444 |
my $bottom = $tex[4]; |
445 |
glBindTexture GL_TEXTURE_2D, $bottom->{name}; |
446 |
|
447 |
glBegin GL_QUADS; |
448 |
glTexCoord 0, 0; glVertex 0 , $h - $bottom->{height}; |
449 |
glTexCoord 0, 1; glVertex 0 , $h; |
450 |
glTexCoord 1, 1; glVertex $w , $h; |
451 |
glTexCoord 1, 0; glVertex $w , $h - $bottom->{height}; |
452 |
glEnd; |
453 |
|
454 |
my $bg = $tex[0]; |
455 |
glBindTexture GL_TEXTURE_2D, $bg->{name}; |
456 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE; |
457 |
glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_S, GL_REPEAT; |
458 |
glTexParameter GL_TEXTURE_2D, GL_TEXTURE_WRAP_T, GL_REPEAT; |
459 |
|
460 |
my $rep_x = $cw / $bg->{width}; |
461 |
my $rep_y = $ch / $bg->{height}; |
462 |
|
463 |
glBegin GL_QUADS; |
464 |
glTexCoord 0, 0; glVertex $left->{width}, $top->{height}; |
465 |
glTexCoord 0, $rep_y; glVertex $left->{width}, $top->{height} + $ch; |
466 |
glTexCoord $rep_x, $rep_y; glVertex $left->{width} + $cw , $top->{height} + $ch; |
467 |
glTexCoord $rep_x, 0; glVertex $left->{width} + $cw , $top->{height}; |
468 |
glEnd; |
469 |
|
470 |
glDisable GL_BLEND; |
471 |
glDisable GL_TEXTURE_2D; |
472 |
|
473 |
$self->child->draw; |
474 |
|
475 |
} |
476 |
|
477 |
############################################################################# |
478 |
|
479 |
package Crossfire::Client::Widget::Table; |
480 |
|
481 |
our @ISA = Crossfire::Client::Widget::Bin::; |
482 |
|
483 |
use SDL::OpenGL; |
484 |
|
485 |
sub add { |
486 |
my ($self, $x, $y, $chld) = @_; |
487 |
my $old_chld = $self->{children}[$y][$x]; |
488 |
|
489 |
$self->{children}[$y][$x] = $chld; |
490 |
$chld->set_parent ($self); |
491 |
$self->update; |
492 |
} |
493 |
|
494 |
sub max_row_height { |
495 |
my ($self, $row) = @_; |
496 |
|
497 |
my $hs = 0; |
498 |
for (my $xi = 0; $xi <= $#{$self->{children}->[$row] || []}; $xi++) { |
499 |
my $c = $self->{children}->[$row]->[$xi]; |
500 |
if ($c) { |
501 |
my ($w, $h) = $c->size_request; |
502 |
if ($hs < $h) { $hs = $h } |
503 |
} |
504 |
} |
505 |
return $hs; |
506 |
} |
507 |
|
508 |
sub max_col_width { |
509 |
my ($self, $col) = @_; |
510 |
|
511 |
my $ws = 0; |
512 |
for (my $yi = 0; $yi <= $#{$self->{children} || []}; $yi++) { |
513 |
my $c = ($self->{children}->[$yi] || [])->[$col]; |
514 |
if ($c) { |
515 |
my ($w, $h) = $c->size_request; |
516 |
if ($ws < $w) { $ws = $w } |
517 |
} |
518 |
} |
519 |
return $ws; |
520 |
} |
521 |
|
522 |
sub size_request { |
523 |
my ($self) = @_; |
524 |
|
525 |
my ($hs, $ws) = (0, 0); |
526 |
|
527 |
for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) { |
528 |
$hs += $self->max_row_height ($yi); |
529 |
} |
530 |
|
531 |
for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) { |
532 |
my $wm = 0; |
533 |
for (my $xi = 0; $xi <= $#{$self->{children}->[$yi]}; $xi++) { |
534 |
$wm += $self->max_col_width ($xi) |
535 |
} |
536 |
if ($ws < $wm) { $ws = $wm } |
537 |
} |
538 |
|
539 |
return ($ws, $hs); |
540 |
} |
541 |
|
542 |
sub _draw { |
543 |
my ($self) = @_; |
544 |
|
545 |
my $y = 0; |
546 |
for (my $yi = 0; $yi <= $#{$self->{children}}; $yi++) { |
547 |
my $x = 0; |
548 |
|
549 |
for (my $xi = 0; $xi <= $#{$self->{children}->[$yi]}; $xi++) { |
550 |
|
551 |
my $c = $self->{children}->[$yi]->[$xi]; |
552 |
if ($c) { |
553 |
$c->move ($x, $y, 0); #TODO: Move to size_request |
554 |
$c->draw if $c; |
555 |
} |
556 |
|
557 |
$x += $self->max_col_width ($xi); |
558 |
} |
559 |
|
560 |
$y += $self->max_row_height ($yi); |
561 |
} |
562 |
} |
563 |
|
564 |
############################################################################# |
565 |
|
566 |
package Crossfire::Client::Widget::VBox; |
567 |
|
568 |
our @ISA = Crossfire::Client::Widget::Container::; |
569 |
|
570 |
use SDL::OpenGL; |
571 |
|
572 |
sub size_request { |
573 |
my ($self) = @_; |
574 |
|
575 |
my @alloc = map [$_->size_request], @{$self->{children}}; |
576 |
|
577 |
( |
578 |
(List::Util::max map $_->[0], @alloc), |
579 |
(List::Util::sum map $_->[1], @alloc), |
580 |
) |
581 |
} |
582 |
|
583 |
sub size_allocate { |
584 |
my ($self, $w, $h) = @_; |
585 |
|
586 |
$self->w ($w); |
587 |
$self->h ($h); |
588 |
|
589 |
my $exp; |
590 |
my @oth; |
591 |
# find expand widget |
592 |
for (@{$self->{children}}) { |
593 |
if ($_->{expand}) { |
594 |
$exp = $_; |
595 |
last; |
596 |
} |
597 |
push @oth, $_; |
598 |
} |
599 |
|
600 |
my ($ow, $oh); |
601 |
|
602 |
# get sizes of other widgets |
603 |
for (@oth) { |
604 |
my ($w, $h) = $_->size_request; |
605 |
$oh += $h; |
606 |
if ($ow < $w) { $ow = $w } |
607 |
} |
608 |
|
609 |
my $y = 0; |
610 |
for (@{$self->{children}}) { |
611 |
$_->move (0, $y); |
612 |
|
613 |
if ($_ == $exp) { |
614 |
$_->size_allocate ($w, $h - $oh); |
615 |
$y += $h - $oh; |
616 |
} else { |
617 |
my ($cw, $h) = $_->size_request; |
618 |
$_->size_allocate ($w, $h); |
619 |
$y += $h; |
620 |
} |
621 |
} |
622 |
} |
623 |
|
624 |
############################################################################# |
625 |
|
626 |
package Crossfire::Client::Widget::Label; |
627 |
|
628 |
our @ISA = Crossfire::Client::Widget::; |
629 |
|
630 |
use SDL::OpenGL; |
631 |
|
632 |
sub new { |
633 |
my ($class, $x, $y, $z, $height, $text) = @_; |
634 |
|
635 |
# TODO: color, and make height, xyz etc. optional |
636 |
my $self = $class->SUPER::new (x => $x, y => $y, z => $z, height => $height); |
637 |
|
638 |
$self->set_text ($text); |
639 |
|
640 |
$self |
641 |
} |
642 |
|
643 |
sub set_text { |
644 |
my ($self, $text) = @_; |
645 |
|
646 |
$self->{text} = $text; |
647 |
$self->{texture} = new_from_text Crossfire::Client::Texture $text, $self->{height}; |
648 |
|
649 |
$self->update; |
650 |
} |
651 |
|
652 |
sub get_text { |
653 |
my ($self, $text) = @_; |
654 |
|
655 |
$self->{text} |
656 |
} |
657 |
|
658 |
sub size_request { |
659 |
my ($self) = @_; |
660 |
|
661 |
( |
662 |
$self->{texture}{width}, |
663 |
$self->{texture}{height}, |
664 |
) |
665 |
} |
666 |
|
667 |
sub _draw { |
668 |
my ($self) = @_; |
669 |
|
670 |
my $tex = $self->{texture}; |
671 |
|
672 |
glEnable GL_BLEND; |
673 |
glEnable GL_TEXTURE_2D; |
674 |
glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA; |
675 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE; |
676 |
glBindTexture GL_TEXTURE_2D, $tex->{name}; |
677 |
|
678 |
glColor 1, 0, 0, 1; # TODO color |
679 |
|
680 |
glBegin GL_QUADS; |
681 |
glTexCoord 0, 0; glVertex 0 , 0; |
682 |
glTexCoord 0, 1; glVertex 0 , $tex->{height}; |
683 |
glTexCoord 1, 1; glVertex $tex->{width}, $tex->{height}; |
684 |
glTexCoord 1, 0; glVertex $tex->{width}, 0; |
685 |
glEnd; |
686 |
|
687 |
glDisable GL_BLEND; |
688 |
glDisable GL_TEXTURE_2D; |
689 |
} |
690 |
|
691 |
############################################################################# |
692 |
|
693 |
package Crossfire::Client::Widget::TextEntry; |
694 |
|
695 |
our @ISA = Crossfire::Client::Widget::Label::; |
696 |
|
697 |
use SDL; |
698 |
use SDL::OpenGL; |
699 |
|
700 |
sub key_down { |
701 |
my ($self, $ev) = @_; |
702 |
|
703 |
my $mod = $ev->key_mod; |
704 |
my $sym = $ev->key_sym; |
705 |
|
706 |
$ev->set_unicode (1); |
707 |
my $uni = $ev->key_unicode; |
708 |
|
709 |
my $text = $self->get_text; |
710 |
|
711 |
if ($sym == SDLK_BACKSPACE) { |
712 |
substr $text, -1, 1, ''; |
713 |
|
714 |
} elsif ($uni) { |
715 |
$text .= chr $uni; |
716 |
} |
717 |
$self->set_text ($text); |
718 |
} |
719 |
|
720 |
############################################################################# |
721 |
|
722 |
package Crossfire::Client::Widget::MapWidget; |
723 |
|
724 |
use strict; |
725 |
|
726 |
use List::Util qw(min max); |
727 |
|
728 |
use SDL; |
729 |
use SDL::OpenGL; |
730 |
use SDL::OpenGL::Constants; |
731 |
|
732 |
our @ISA = Crossfire::Client::Widget::; |
733 |
|
734 |
sub key_down { |
735 |
print "MAPKEYDOWN\n"; |
736 |
} |
737 |
|
738 |
sub key_up { |
739 |
} |
740 |
|
741 |
sub size_request { |
742 |
|
743 |
} |
744 |
|
745 |
sub size_allocate { |
746 |
} |
747 |
|
748 |
sub _draw { |
749 |
my ($self) = @_; |
750 |
|
751 |
my $mx = $::CONN->{mapx}; |
752 |
my $my = $::CONN->{mapy}; |
753 |
|
754 |
my $map = $::CONN->{map}; |
755 |
|
756 |
my ($xofs, $yofs); |
757 |
|
758 |
my $sw = 1 + int $::WIDTH / 32; |
759 |
my $sh = 1 + int $::HEIGHT / 32; |
760 |
|
761 |
if ($::CONN->{mapw} > $sw) { |
762 |
$xofs = $mx + ($::CONN->{mapw} - $sw) * 0.5; |
763 |
} else { |
764 |
$xofs = $self->{xofs} = min $mx, max $mx + $::CONN->{mapw} - $sw + 1, $self->{xofs}; |
765 |
} |
766 |
|
767 |
if ($::CONN->{maph} > $sh) { |
768 |
$yofs = $my + ($::CONN->{maph} - $sh) * 0.5; |
769 |
} else { |
770 |
$yofs = $self->{yofs} = min $my, max $my + $::CONN->{maph} - $sh + 1, $self->{yofs}; |
771 |
} |
772 |
|
773 |
glEnable GL_TEXTURE_2D; |
774 |
glEnable GL_BLEND; |
775 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_REPLACE; |
776 |
|
777 |
my $sw4 = ($sw + 3) & ~3; |
778 |
my $lighting = "\x00" x ($sw4 * $sh); |
779 |
|
780 |
for my $x (0 .. $sw - 1) { |
781 |
for my $y (0 .. $sh - 1) { |
782 |
|
783 |
my $cell = $map->[$x + $xofs][$y + $yofs] |
784 |
or next; |
785 |
|
786 |
my $darkness = $cell->[0] * (1 / 255); |
787 |
if ($darkness < 0) { |
788 |
$darkness = 0.15; |
789 |
} |
790 |
substr $lighting, $y * $sw4 + $x, 1, chr 255 - $darkness * 255; |
791 |
|
792 |
for my $num (grep $_, @$cell[1,2,3]) { |
793 |
my $tex = $::CONN->{face}[$num]{texture} || next; |
794 |
|
795 |
glBindTexture GL_TEXTURE_2D, $tex->{name}; |
796 |
|
797 |
my $w = $tex->{width}; |
798 |
my $h = $tex->{height}; |
799 |
|
800 |
my $px = ($x + 1) * 32 - $w; |
801 |
my $py = ($y + 1) * 32 - $h; |
802 |
|
803 |
glBegin GL_QUADS; |
804 |
glTexCoord 0, 0; glVertex $px , $py; |
805 |
glTexCoord 0, 1; glVertex $px , $py + $h; |
806 |
glTexCoord 1, 1; glVertex $px + $w, $py + $h; |
807 |
glTexCoord 1, 0; glVertex $px + $w, $py; |
808 |
glEnd; |
809 |
} |
810 |
} |
811 |
} |
812 |
|
813 |
# if (1) { # higher quality darkness |
814 |
# $lighting =~ s/(.)/$1$1$1/gs; |
815 |
# my $pb = new_from_data Gtk2::Gdk::Pixbuf $lighting, "rgb", 0, 8, $sw4, $sh, $sw4 * 3; |
816 |
# |
817 |
# $pb = $pb->scale_simple ($sw4 * 0.5, $sh * 0.5, "bilinear"); |
818 |
# |
819 |
# $lighting = $pb->get_pixels; |
820 |
# $lighting =~ s/(.)../$1/gs; |
821 |
# } |
822 |
|
823 |
$lighting = new Crossfire::Client::Texture |
824 |
width => $sw4, |
825 |
height => $sh, |
826 |
data => $lighting, |
827 |
internalformat => GL_ALPHA4, |
828 |
format => GL_ALPHA; |
829 |
|
830 |
glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA; |
831 |
glColor 0, 0, 0, 0.75; |
832 |
glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE; |
833 |
glBindTexture GL_TEXTURE_2D, $lighting->{name}; |
834 |
glTexParameter GL_TEXTURE_2D, GL_TEXTURE_MAG_FILTER, GL_LINEAR; |
835 |
glBegin GL_QUADS; |
836 |
glTexCoord 0, 0; glVertex 0 , 0; |
837 |
glTexCoord 0, 1; glVertex 0 , $sh * 32; |
838 |
glTexCoord 1, 1; glVertex $sw4 * 32, $sh * 32; |
839 |
glTexCoord 1, 0; glVertex $sw4 * 32, 0; |
840 |
glEnd; |
841 |
|
842 |
glDisable GL_TEXTURE_2D; |
843 |
glDisable GL_BLEND; |
844 |
} |
845 |
|
846 |
my %DIR = ( |
847 |
SDLK_KP8, [1, "north"], |
848 |
SDLK_KP9, [2, "northeast"], |
849 |
SDLK_KP6, [3, "east"], |
850 |
SDLK_KP3, [4, "southeast"], |
851 |
SDLK_KP2, [5, "south"], |
852 |
SDLK_KP1, [6, "southwest"], |
853 |
SDLK_KP4, [7, "west"], |
854 |
SDLK_KP7, [8, "northwest"], |
855 |
|
856 |
SDLK_UP, [1, "north"], |
857 |
SDLK_RIGHT, [3, "east"], |
858 |
SDLK_DOWN, [5, "south"], |
859 |
SDLK_LEFT, [7, "west"], |
860 |
); |
861 |
|
862 |
sub key_down { |
863 |
my ($self, $ev) = @_; |
864 |
|
865 |
my $mod = $ev->key_mod; |
866 |
my $sym = $ev->key_sym; |
867 |
|
868 |
if ($sym == SDLK_KP5) { |
869 |
$::CONN->send ("command stay fire"); |
870 |
} elsif (exists $DIR{$sym}) { |
871 |
if ($mod & KMOD_SHIFT) { |
872 |
$self->{shft}++; |
873 |
$::CONN->send ("command fire $DIR{$sym}[0]"); |
874 |
} elsif ($mod & KMOD_CTRL) { |
875 |
$self->{ctrl}++; |
876 |
$::CONN->send ("command run $DIR{$sym}[0]"); |
877 |
} else { |
878 |
$::CONN->send ("command $DIR{$sym}[1]"); |
879 |
} |
880 |
} |
881 |
} |
882 |
|
883 |
sub key_up { |
884 |
my ($self, $ev) = @_; |
885 |
|
886 |
my $mod = $ev->key_mod; |
887 |
my $sym = $ev->key_sym; |
888 |
|
889 |
if (!($mod & KMOD_SHIFT) && delete $self->{shft}) { |
890 |
$::CONN->send ("command fire_stop"); |
891 |
} |
892 |
if (!($mod & KMOD_CTRL ) && delete $self->{ctrl}) { |
893 |
$::CONN->send ("command run_stop"); |
894 |
} |
895 |
} |
896 |
|
897 |
############################################################################# |
898 |
|
899 |
package Crossfire::Client::Widget::Animator; |
900 |
|
901 |
use SDL::OpenGL; |
902 |
|
903 |
our @ISA = Crossfire::Client::Widget::Bin::; |
904 |
|
905 |
sub moveto { |
906 |
my ($self, $x, $y) = @_; |
907 |
|
908 |
$self->{moveto} = [$self->{x}, $self->{y}, $x, $y]; |
909 |
$self->{speed} = 0.2; |
910 |
$self->{time} = 1; |
911 |
|
912 |
::animation_start $self; |
913 |
} |
914 |
|
915 |
sub animate { |
916 |
my ($self, $interval) = @_; |
917 |
|
918 |
$self->{time} -= $interval * $self->{speed}; |
919 |
if ($self->{time} <= 0) { |
920 |
$self->{time} = 0; |
921 |
::animation_stop $self; |
922 |
} |
923 |
|
924 |
my ($x0, $y0, $x1, $y1) = @{$self->{moveto}}; |
925 |
|
926 |
$self->{x} = $x0 * $self->{time} + $x1 * (1 - $self->{time}); |
927 |
$self->{y} = $y0 * $self->{time} + $y1 * (1 - $self->{time}); |
928 |
} |
929 |
|
930 |
sub _draw { |
931 |
my ($self) = @_; |
932 |
|
933 |
glPushMatrix; |
934 |
glRotate $self->{time} * 10000, 0, 1, 0; |
935 |
$self->{children}[0]->draw; |
936 |
glPopMatrix; |
937 |
} |
938 |
|
939 |
1; |
940 |
|