package Crossfire::Client::Widget;

use strict;
use SDL::OpenGL;
use SDL::OpenGL::Constants;

our $FOCUS;  # the widget with current focus
our @ACTIVE_WIDGETS;

# class methods for events
sub feed_sdl_key_down_event    { $FOCUS->key_down ($_[0])    if $FOCUS }
sub feed_sdl_key_up_event      { $FOCUS->key_up ($_[0])      if $FOCUS }
sub feed_sdl_button_down_event { $FOCUS->button_down ($_[0]) if $FOCUS }
sub feed_sdl_button_up_event   { $FOCUS->button_up ($_[0])   if $FOCUS }

sub new {
   my $class = shift;

   bless { @_ }, $class
}

sub activate {
   push @ACTIVE_WIDGETS, $_[0];
}

sub deactivate {
   @ACTIVE_WIDGETS =
      sort { $a->{z} <=> $b->{z} }
         grep { $_ != $_[0] }
            @ACTIVE_WIDGETS;
}

sub size_request {
   die "size_request is abtract";
}

sub focus_in {
   my ($widget) = @_;
   $FOCUS = $widget;
}

sub focus_out {
   my ($widget) = @_;
}

sub key_down {
   my ($widget, $sdlev) = @_;
}

sub key_up {
   my ($widget, $sdlev) = @_;
}

sub button_down {
   my ($widget, $sdlev) = @_;
}

sub button_up {
   my ($widget, $sdlev) = @_;
}

sub w { $_[0]->{w} }
sub h { $_[0]->{h} }
sub x { $_[0]->{x} = $_[1] if $_[1]; $_[0]->{x} }
sub y { $_[0]->{y} = $_[1] if $_[1]; $_[0]->{y} }
sub z { $_[0]->{z} = $_[1] if $_[1]; $_[0]->{z} }

sub draw {
   my ($self) = @_;

   glPushMatrix;
   glTranslate $self->{x}, $self->{y}, 0;
   $self->_draw;
   glPopMatrix;
}

sub _draw {
   my ($widget) = @_;
}

sub bbox {
   my ($widget) = @_;
}

package Crossfire::Client::Widget::Container;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub add { $_[0]->{child} = $_[1] }
sub get { $_[0]->{child} }

sub size_request { $_[0]->{child}->size_request if $_[0]->{child} }

sub _draw { die "Containers can't be drawn!" }

package Crossfire::Client::Widget::Frame;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub size_request {
   my ($self) = @_;
   my $chld = $self->get
      or return (0, 0);
   map { $_ + 4 } $chld->size_request;
}

sub _draw {
   my ($self) = @_;

   my $chld = $self->get;

   my ($w, $h) = $chld->size_request;

   glColor 1, 0, 0;
   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0      , 0;
   glTexCoord 0, 1; glVertex 0      , $h + 4;
   glTexCoord 1, 1; glVertex $w + 4 , $h + 4;
   glTexCoord 1, 0; glVertex $w + 4 , 0;
   glEnd;

   glPushMatrix;
   glTranslate (2, 2, 0);
   $chld->_draw;
   glPopMatrix;
}

package Crossfire::Client::Widget::Table;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub add {
   my ($self, $x, $y, $chld) = @_;
   $self->{childs}[$y][$x] = $chld;
}

sub max_row_height {
   my ($self, $row) = @_;

   my $hs = 0;
   for (my $xi = 0; $xi <= $#{$self->{childs}->[$row] || []}; $xi++) {
      my $c = $self->{childs}->[$row]->[$xi];
      my ($w, $h) = $c->size_request if $c;
      if ($hs < $h) { $hs = $h }
   }
   return $hs;
}

sub max_col_width {
   my ($self, $col) = @_;

   my $ws = 0;
   for (my $yi = 0; $yi <= $#{$self->{childs} || []}; $yi++) {
      my $c = ($self->{childs}->[$yi] || [])->[$col];
      my ($w, $h) = $c->size_request if $c;
      if ($ws < $w) { $ws = $w }
   }
   return $ws;
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);

   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      $hs += $self->max_row_height ($yi);
   }

   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      my $wm = 0;
      for (my $xi = 0; $xi <= $#{$self->{childs}->[$yi]}; $xi++) {
         $wm += $self->max_col_width ($xi)
      }
      if ($ws < $wm) { $ws = $wm }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   my $y = 0;
   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      my $x = 0;

      for (my $xi = 0; $xi <= $#{$self->{childs}->[$yi]}; $xi++) {

         glPushMatrix;
         glTranslate ($x, $y, 0);
         my $c = $self->{childs}->[$yi]->[$xi];
         $c->_draw if $c;
         glPopMatrix;

         $x += $self->max_col_width ($xi);
      }

      $y += $self->max_row_height ($yi);
   }
}

package Crossfire::Client::Widget::VBox;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub add {
   my ($self, $chld) = @_;
   push @{$self->{childs}}, $chld;
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);
   for (@{$self->{childs} || []}) {
      my ($w, $h) = $_->size_request;
      $hs += $h;
      if ($ws < $w) { $ws = $w }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   my ($x, $y);
   for (@{$self->{childs} || []}) {
      glPushMatrix;
      glTranslate (0, $y, 0);
      $_->_draw;
      glPopMatrix;
      my ($w, $h) = $_->size_request;
      $y += $h;
   }
}

package Crossfire::Client::Widget::Label;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub new {
   my ($class, $x, $y, $z, $ttf, $text) = @_;

   my $self = $class->SUPER::new (x => $x, y => $y, z => $z, ttf => $ttf);

   $self->set_text ($text);

   $self
}

sub set_text {
   my ($self, $text) = @_;
   $self->{texture} = new_from_ttf Crossfire::Client::Texture $self->{ttf}, $self->{text} = $text;
}

sub get_text {
   my ($self, $text) = @_;
   $self->{text}
}

sub size_request {
   my ($self) = @_;

   (
      $self->{texture}{width},
      $self->{texture}{height},
   )
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{texture};

   $self->{x}--;

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glColor 1, 1, 1;

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , 0;
   glTexCoord 0, 1; glVertex 0            , $tex->{height};
   glTexCoord 1, 1; glVertex $tex->{width}, $tex->{height};
   glTexCoord 1, 0; glVertex $tex->{width}, 0;
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

package Crossfire::Client::Widget::TextView;

use strict;

our @ISA = qw/Crossfire::Client::Widget/;

use SDL::OpenGL;
use SDL::OpenGL::Constants;

sub add_line {
   my ($self, $line) = @_;
   push @{$self->{lines}}, $line;
}

sub _draw {
   my ($self) = @_;

}

package Crossfire::Client::Widget::MapWidget;

use strict;

our @ISA = qw/Crossfire::Client::Widget/;

use SDL::OpenGL;
use SDL::OpenGL::Constants;

sub key_down {
   print "MAPKEYDOWN\n";
}

sub key_up {
}

sub _draw {
   glEnable GL_TEXTURE_2D;
   glEnable GL_BLEND;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

   my $map = $::CONN->{map};

   for my $x (0 .. $::CONN->{mapw} - 1) {
      for my $y (0 .. $::CONN->{maph} - 1) {

         my $cell = $map->[$x][$y]
            or next;

         my $darkness = $cell->[3] * (1 / 255);
         glColor $darkness, $darkness, $darkness;

         for my $num (grep $_, $cell->[0], $cell->[1], $cell->[2]) {
            my $tex = $::CONN->{face}[$num]{texture} || next;

            glBindTexture GL_TEXTURE_2D, $tex->{name};

            glBegin GL_QUADS;
            glTexCoord 0, 0; glVertex $x * 32     , $y * 32;
            glTexCoord 0, 1; glVertex $x * 32     , $y * 32 + 32;
            glTexCoord 1, 1; glVertex $x * 32 + 32, $y * 32 + 32;
            glTexCoord 1, 0; glVertex $x * 32 + 32, $y * 32;
            glEnd;
         }
      }
   }

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;
}

1;