package Crossfire::Client::Widget;

use strict;

use Scalar::Util;

use SDL::OpenGL;
use SDL::OpenGL::Constants;

our $FOCUS;  # the widget with current focus
#our @ACTIVE_WIDGETS;

# class methods for events
sub feed_sdl_key_down_event    { $FOCUS->key_down ($_[0])    if $FOCUS }
sub feed_sdl_key_up_event      { $FOCUS->key_up ($_[0])      if $FOCUS }
sub feed_sdl_button_down_event { }
sub feed_sdl_button_up_event   { }

sub new {
   my $class = shift;

   bless { @_ }, $class
}

#sub activate {
#   push @ACTIVE_WIDGETS, $_[0];
#   Scalar::Util::weaken $ACTIVE_WIDGETS[-1];
#}

#sub deactivate {
#   @ACTIVE_WIDGETS =
#      sort { $a->{z} <=> $b->{z} }
#         grep { $_ && $_ != $_[0] }
#            @ACTIVE_WIDGETS;
#}

sub move {
   my ($self, $x, $y, $z) = @_;
   $self->{x} = $x;
   $self->{y} = $y;
   $self->{z} = $z if defined $z;
}

sub needs_redraw {
   0
}

sub size_request {
   die "size_request is abtract";
}

sub focus_in {
   my ($widget) = @_;
   $FOCUS = $widget;
}

sub focus_out {
   my ($widget) = @_;
}

sub key_down {
   my ($widget, $sdlev) = @_;
}

sub key_up {
   my ($widget, $sdlev) = @_;
}

sub button_down {
   my ($widget, $sdlev) = @_;
}

sub button_up {
   my ($widget, $sdlev) = @_;
}

sub w { $_[0]->{w} }
sub h { $_[0]->{h} }
sub x { $_[0]->{x} = $_[1] if $_[1]; $_[0]->{x} }
sub y { $_[0]->{y} = $_[1] if $_[1]; $_[0]->{y} }
sub z { $_[0]->{z} = $_[1] if $_[1]; $_[0]->{z} }

sub draw {
   my ($self) = @_;

   glPushMatrix;
   glTranslate $self->{x}, $self->{y}, 0;
   $self->_draw;
   glPopMatrix;
}

sub _draw {
   my ($widget) = @_;
}

sub bbox {
   my ($self) = @_;
   my ($w, $h) = $self->size_request;
   (
     $self->{x},
     $self->{y},
     $self->{x} = $w,
     $self->{y} = $h
   )
}

sub del_parent { $_[0]->{parent} = undef }

sub set_parent {
   my ($self, $par) = @_;

   $self->{parent} = $par;
   Scalar::Util::weaken $self->{parent};
}

sub get_parent {
   $_[0]->{parent}
}

sub update {
   my ($self) = @_;

   $self->{parent}->update
      if $self->{parent};
}

sub DESTROY {
   my ($self) = @_;

   #$self->deactivate;
}

package Crossfire::Client::Widget::Container;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub add { $_[0]->{child} = $_[1]; $_[1]->set_parent ($_[0]); $_[1]->update }
sub get { $_[0]->{child} }
sub remove {
   my ($self, $chld) = @_;
   delete $self->{child}
      if $self->{child} == $chld;
}

sub size_request { $_[0]->{child}->size_request if $_[0]->{child} }

sub _draw { die "Containers can't be drawn!" }

package Crossfire::Client::Widget::Toplevel;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub add {
   my ($self, $chld) = @_;

   push @{$self->{childs}}, $chld;
   @{$self->{childs}} =
      sort { $a->{z} <=> $b->{z} }
         @{$self->{childs}};

   $chld->set_parent ($self);
}

sub remove {
   my ($self, $chld) = @_;
   @{$self->{childs}} =
      sort { $a->{z} <=> $b->{z} }
         grep { $_ && $_ != $_[0] }
            @{$self->{childs}}
}

sub update {
   my ($self) = @_;
   ::refresh ();
}

sub _draw {
   my ($self) = @_;

   $_->draw for @{$self->{childs}};
}

package Crossfire::Client::Widget::Window;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub add {
   my ($self, $chld) = @_;
   $self->SUPER::add ($chld);
   $chld->set_parent ($self);
   $self->update; #TODO: Move this to the size_request event propably?
}

sub remove {
   my ($self) = @_;
   # TODO FIXME: removing a child from a window will crash, see render_chld
   $self->update;
}

sub update {
   my ($self) = @_;
   $self->render_chld;
}

sub render_chld {
   my ($self) = @_;
   my $chld = $self->get;
   my ($w, $h) = $self->size_request;

   $self->{texture} =
      Crossfire::Client::Texture->new_from_opengl (
         $w, $h, sub { $chld->draw }
      );
   $self->{texture}->upload;
}

sub size_request {
   my ($self) = @_;
   my $chld = $self->get
      or return (0, 0);
   $chld->size_request
}

sub _draw {
   my ($self) = @_;

   my ($w, $h) = $self->size_request;#TODO# use width/height of texture

   my $tex = $self->{texture}
      or return;

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glColor 1, 0, 1;

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex  0,  0;
   glTexCoord 0, 1; glVertex  0, $h;
   glTexCoord 1, 1; glVertex $w, $h;
   glTexCoord 1, 0; glVertex $w,  0;
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

package Crossfire::Client::Widget::Frame;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub size_request {
   my ($self) = @_;
   my $chld = $self->get
      or return (0, 0);

   $chld->move (2, 2);

   map { $_ + 4 } $chld->size_request;
}

sub _draw {
   my ($self) = @_;

   my $chld = $self->get;

   my ($w, $h) = $chld->size_request;

   glBegin GL_QUADS;
   glColor 0, 0, 0;
   glTexCoord 0, 0; glVertex 0      , 0;
   glTexCoord 0, 1; glVertex 0      , $h + 4;
   glTexCoord 1, 1; glVertex $w + 4 , $h + 4;
   glTexCoord 1, 0; glVertex $w + 4 , 0;
   glEnd;

   $chld->draw;
}

package Crossfire::Client::Widget::FancyFrame;

our @ISA = Crossfire::Client::Widget::Frame::;

use SDL::OpenGL;

#TODO: implement themed frame

package Crossfire::Client::Widget::Table;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub add {
   my ($self, $x, $y, $chld) = @_;
   my $old_chld = $self->{childs}[$y][$x];

   $self->{childs}[$y][$x] = $chld;
   $chld->set_parent ($self);
   $self->update;
}

sub max_row_height {
   my ($self, $row) = @_;

   my $hs = 0;
   for (my $xi = 0; $xi <= $#{$self->{childs}->[$row] || []}; $xi++) {
      my $c = $self->{childs}->[$row]->[$xi];
      if ($c) {
         my ($w, $h) = $c->size_request;
         if ($hs < $h) { $hs = $h }
      }
   }
   return $hs;
}

sub max_col_width {
   my ($self, $col) = @_;

   my $ws = 0;
   for (my $yi = 0; $yi <= $#{$self->{childs} || []}; $yi++) {
      my $c = ($self->{childs}->[$yi] || [])->[$col];
      if ($c) {
         my ($w, $h) = $c->size_request;
         if ($ws < $w) { $ws = $w }
      }
   }
   return $ws;
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);

   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      $hs += $self->max_row_height ($yi);
   }

   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      my $wm = 0;
      for (my $xi = 0; $xi <= $#{$self->{childs}->[$yi]}; $xi++) {
         $wm += $self->max_col_width ($xi)
      }
      if ($ws < $wm) { $ws = $wm }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   my $y = 0;
   for (my $yi = 0; $yi <= $#{$self->{childs}}; $yi++) {
      my $x = 0;

      for (my $xi = 0; $xi <= $#{$self->{childs}->[$yi]}; $xi++) {

         my $c = $self->{childs}->[$yi]->[$xi];
         if ($c) {
            $c->move ($x, $y, 0); #TODO: Move to size_request
            $c->draw if $c;
         }

         $x += $self->max_col_width ($xi);
      }

      $y += $self->max_row_height ($yi);
   }
}

package Crossfire::Client::Widget::VBox;

our @ISA = Crossfire::Client::Widget::Container::;

use SDL::OpenGL;

sub add {
   my ($self, $chld) = @_;
   push @{$self->{childs}}, $chld;
   $chld->set_parent ($self);
   $self->update;
}

sub size_request {
   my ($self) = @_;

   my ($hs, $ws) = (0, 0);
   for (@{$self->{childs} || []}) {
      my ($w, $h) = $_->size_request;
      $hs += $h;
      if ($ws < $w) { $ws = $w }
   }

   return ($ws, $hs);
}

sub _draw {
   my ($self) = @_;

   my ($x, $y);
   for (@{$self->{childs} || []}) {
      $_->move (0, $y, 0); #TODO: move to size_request
      $_->draw;
      my ($w, $h) = $_->size_request;
      $y += $h;
   }
}

package Crossfire::Client::Widget::Label;

our @ISA = Crossfire::Client::Widget::;

use SDL::OpenGL;

sub new {
   my ($class, $x, $y, $z, $height, $text) = @_;

   my $self = $class->SUPER::new (x => $x, y => $y, z => $z, height => $height);

   $self->set_text ($text);

   $self
}

sub set_text {
   my ($self, $text) = @_;

   $self->{text} = $text;
   $self->{texture} = new_from_text Crossfire::Client::Texture $text, $self->{height};

   $self->update;
}

sub get_text {
   my ($self, $text) = @_;

   $self->{text}
}

sub size_request {
   my ($self) = @_;

   (
      $self->{texture}{width},
      $self->{texture}{height},
   )
}

sub _draw {
   my ($self) = @_;

   my $tex = $self->{texture};

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;
   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glColor 1, 1, 1, 0.8;

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , 0;
   glTexCoord 0, 1; glVertex 0            , $tex->{height};
   glTexCoord 1, 1; glVertex $tex->{width}, $tex->{height};
   glTexCoord 1, 0; glVertex $tex->{width}, 0;
   glEnd;

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

package Crossfire::Client::Widget::TextEntry;

our @ISA = Crossfire::Client::Widget::Label::;

use SDL;
use SDL::OpenGL;

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   $ev->set_unicode (1);
   my $uni = $ev->key_unicode;

   my $text = $self->get_text;

   if ($sym == SDLK_BACKSPACE) {
      substr $text, -1, 1, '';

   } elsif ($uni) {
      $text .= chr $uni;
   }
   $self->set_text ($text);
}


# XXX: TextView isn't neccessary with pango multiline text rendering
package Crossfire::Client::Widget::TextView;

use strict;

our @ISA = qw/Crossfire::Client::Widget/;

use SDL::OpenGL;
use SDL::OpenGL::Constants;

sub new {
   my ($class, $text, $h) = @_;
   my $self = $class->SUPER::new ();

   $self->{txt_height} = $h;
   @{$self->{lines}} = split /\r?\n/, $text;

   for (split /\r?\n/, $text) {
      $self->add_line ($_);
   }
   $self
}

#sub render_lines {
#   my ($self) = @_;
#
#   $self->{txt_lines} = [];
#
#   for (@{$self->{lines}}) {
#      push @{$self->{txt_lines}},
#         new_from_ttf Crossfire::Client::Texture $self->{ttf}, $_;
#   }
#}

sub add_line {
   my ($self, $line) = @_;
   push @{$self->{lines}}, $line;

   push @{$self->{txt_lines}},
     new_from_text Crossfire::Client::Texture $line, $self->{txt_height};
}

sub size_request {
   my ($self) = @_;

   my $w = 0;
   my $h = 0;

   for (@{$self->{txt_lines}}) {
      if ($w < $_->{width}) { $w = $_->{width} }
      $h += $_->{height};
   }

   return ($w, $h);
}

sub draw_line {
   my ($self, $tex, $y) = @_;

   glBindTexture GL_TEXTURE_2D, $tex->{name};

   glColor 1, 0, 1;

   glBegin GL_QUADS;
   glTexCoord 0, 0; glVertex 0            , $y;
   glTexCoord 0, 1; glVertex 0            , $y + $tex->{height};
   glTexCoord 1, 1; glVertex $tex->{width}, $y + $tex->{height};
   glTexCoord 1, 0; glVertex $tex->{width}, $y;
   glEnd;
}

sub _draw {
   my ($self) = @_;

   glEnable GL_BLEND;
   glEnable GL_TEXTURE_2D;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;#DECAL;

   my $l = 0;
   for (@{$self->{txt_lines}}) {
      $self->draw_line ($_, $l);
      $l += $_->{height};
   }

   glDisable GL_BLEND;
   glDisable GL_TEXTURE_2D;
}

package Crossfire::Client::Widget::MapWidget;

use strict;

use List::Util qw(min max);

use SDL;
use SDL::OpenGL;
use SDL::OpenGL::Constants;

our @ISA = Crossfire::Client::Widget::;

sub key_down {
   print "MAPKEYDOWN\n";
}

sub key_up {
}

sub _draw {
   my ($self) = @_;

   my $mx = $::CONN->{mapx};
   my $my = $::CONN->{mapy};

   my $map = $::CONN->{map};

   my ($xofs, $yofs);

   my $sw = 1 + int $::WIDTH  / 32;
   my $sh = 1 + int $::HEIGHT / 32;

   if ($::CONN->{mapw} > $sw) {
      $xofs = $mx + ($::CONN->{mapw} - $sw) * 0.5;
   } else {
      $xofs = $self->{xofs} = min $mx, max $mx + $::CONN->{mapw} - $sw + 1, $self->{xofs};
   }

   if ($::CONN->{maph} > $sh) {
      $yofs = $my + ($::CONN->{maph} - $sh) * 0.5;
   } else {
      $yofs = $self->{yofs} = min $my, max $my + $::CONN->{maph} - $sh + 1, $self->{yofs};
   }

   glEnable GL_TEXTURE_2D;
   glEnable GL_BLEND;
   glTexEnv GL_TEXTURE_ENV, GL_TEXTURE_ENV_MODE, GL_MODULATE;

   for my $x (0 .. $sw - 1) {
      for my $y (0 .. $sh - 1) {

         my $cell = $map->[$x + $xofs][$y + $yofs]
            or next;

         my $darkness = $cell->[0] * (1 / 255);
         if ($darkness < 0) {
            glColor 0.3, 0.3, 0.3;
         } else {
            glColor $darkness, $darkness, $darkness;
         }

         for my $num (grep $_, @$cell[1,2,3]) {
            my $tex = $::CONN->{face}[$num]{texture} || next;

            glBindTexture GL_TEXTURE_2D, $tex->{name};

            my $w = $tex->{width};
            my $h = $tex->{height};

            my $px = ($x + 1) * 32 - $w;
            my $py = ($y + 1) * 32 - $h;

            glBegin GL_QUADS;
            glTexCoord 0, 0; glVertex $px     , $py;
            glTexCoord 0, 1; glVertex $px     , $py + $h;
            glTexCoord 1, 1; glVertex $px + $w, $py + $h;
            glTexCoord 1, 0; glVertex $px + $w, $py;
            glEnd;
         }
      }
   }

   glDisable GL_TEXTURE_2D;
   glDisable GL_BLEND;
}

my %DIR = (
   SDLK_KP8, [1, "north"],
   SDLK_KP9, [2, "northeast"],
   SDLK_KP6, [3, "east"],
   SDLK_KP3, [4, "southeast"],
   SDLK_KP2, [5, "south"],
   SDLK_KP1, [6, "southwest"],
   SDLK_KP4, [7, "west"],
   SDLK_KP7, [8, "northwest"],

   SDLK_UP,    [1, "north"],
   SDLK_RIGHT, [3, "east"],
   SDLK_DOWN,  [5, "south"],
   SDLK_LEFT,  [7, "west"],
);

sub key_down {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if ($sym == SDLK_KP5) {
      $::CONN->send ("command stay fire");
   } elsif (exists $DIR{$sym}) {
      if ($mod & KMOD_SHIFT) {
         $self->{shft}++;
         $::CONN->send ("command fire $DIR{$sym}[0]");
      } elsif ($mod & KMOD_CTRL) {
         $self->{ctrl}++;
         $::CONN->send ("command run $DIR{$sym}[0]");
      } else {
         $::CONN->send ("command $DIR{$sym}[1]");
      }
   }
}

sub key_up {
   my ($self, $ev) = @_;

   my $mod = $ev->key_mod;
   my $sym = $ev->key_sym;

   if (!($mod & KMOD_SHIFT) && delete $self->{shft}) {
      $::CONN->send ("command fire_stop");
   }
   if (!($mod & KMOD_CTRL ) && delete $self->{ctrl}) {
      $::CONN->send ("command run_stop");
   }
}

1;