[ViewVC] Contents of: cvs/deliantra/Deliantra-Client/bin/cfplus

#!/opt/bin/perl

use strict;
use utf8;

# do things only needed for single-binary version (par)
BEGIN {
   if (%PAR::LibCache) {
      @INC = grep ref, @INC; # weed out all paths except pars loader refs

      while (my ($filename, $zip) = each %PAR::LibCache) {
         for ($zip->memberNames) {
            next unless /^\/root\/(.*)/;
            $zip->extractMember ($_, "$ENV{PAR_TEMP}/$1")
               unless -e "$ENV{PAR_TEMP}/$1";
         }
      }

      # TODO: pango-rc file, anybody?

      unshift @INC, $ENV{PAR_TEMP};
   }
}

# need to do it again because that pile of garbage called PAR nukes it before main
unshift @INC, $ENV{PAR_TEMP}
   if %PAR::LibCache;

use Time::HiRes 'time';
use Pod::POM;
use Event;

use Crossfire;
use Crossfire::Protocol::Constants;

use Compress::LZF;

use CFClient;
use CFClient::OpenGL ();
use CFClient::Protocol;
use CFClient::UI;
use CFClient::MapWidget;

$Event::DIED = sub {
   # TODO: display dialog box or so
   CFClient::error $_[1];
};

#$SIG{__WARN__} = sub { Carp::cluck  $_[0] };#d#

our $VERSION = '0.1';

my $MAX_FPS = 60;
my $MIN_FPS =  5; # unused as of yet

our $META_SERVER = "crossfire.real-time.com:13326";

our $LAST_REFRESH;
our $NOW;

our $CFG;
our $CONN;
our $FAST; # fast, low-quality mode, possibly useful for software-rendering

our $WANT_REFRESH;
our $CAN_REFRESH;

our @SDL_MODES;
our $WIDTH;
our $HEIGHT;
our $FULLSCREEN;
our $FONTSIZE;

our $FONT_PROP;
our $FONT_FIXED;

our $MAP;
our $MAPMAP;
our $MAPWIDGET;
our $BUTTONBAR;
our $LOGVIEW;
our $CONSOLE;
our $METASERVER;
our $LOGIN_BUTTON;
our $QUIT_DIALOG;

our $FLOORBOX;
our $GAUGES;
our $STATWIDS;

our $SDL_ACTIVE;
our %SDL_CB;

our $SDL_MIXER;
our @SOUNDS;       # event => file mapping
our %AUDIO_CHUNKS; # audio files

our $ALT_ENTER_MESSAGE;
our $STATUSBOX;
our $DEBUG_STATUS;

our $INV;
our $INVR;
our $INVR_LBL;

sub status {
   $STATUSBOX->add (CFClient::UI::Label::escape $_[0], pri => -10, group => "status", timeout => 10, fg => [1, 1, 0, 1]);
}

sub debug {
   $DEBUG_STATUS->set_text ($_[0]);
   my ($w, $h) = $DEBUG_STATUS->size_request;
   $DEBUG_STATUS->move ($WIDTH - $w, 0);
}

sub start_game {
   status "logging in...";

   my $mapsize = List::Util::min 32, List::Util::max 11, int $WIDTH * $CFG->{mapsize} * 0.01 / 32;

   my ($host, $port) = split /:/, $CFG->{host};

   $MAP = new CFClient::Map $mapsize, $mapsize;
   
   $CONN = eval {
      new CFClient::Protocol
         host => $host,
         port => $port || 13327,
         user => $CFG->{user},
         pass => $CFG->{password},
         mapw => $mapsize,
         maph => $mapsize,

         map_widget => $MAPWIDGET,
         logview    => $LOGVIEW,
         statusbox  => $STATUSBOX,
         map        => $MAP,
         mapmap     => $MAPMAP,

         sound_play => sub {
            my ($x, $y, $soundnum, $type) = @_;

            $SDL_MIXER
               or return;

            my $chunk = $AUDIO_CHUNKS{$SOUNDS[$soundnum]}
               or return;

            $chunk->play;
         },
   };

   if ($CONN) {
      CFClient::lowdelay fileno $CONN->{fh};

      $LOGIN_BUTTON->set_text ("Logout");
      status "login successful";

      $BUTTONBAR->{children}[1]->emit ("activate")
         if $BUTTONBAR->{children}[1]->{state};

   } else {
      status "unable to connect";
      stop_game();
   }
}

sub stop_game {
   return unless $CONN;

   status "connection closed";
   $LOGIN_BUTTON->set_text ("Login");
   $CONN->destroy;
   $CONN = 0; # false, does not autovivify

   $BUTTONBAR->{children}[1]->emit ("activate")
      unless $BUTTONBAR->{children}[1]->{state};
}

sub client_setup {
   my $dialog = new CFClient::UI::FancyFrame
      req_x => 1,
      req_y => $HEIGHT * (1/8),
      name => "client_setup",
      title => "Client Setup",
      child => (my $vbox = new CFClient::UI::VBox);
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);

   $table->add (0, 0, new CFClient::UI::Label valign => 0, align => 1, text => "Video Mode");
   $table->add (1, 0, my $hbox = new CFClient::UI::HBox);

   $hbox->add (my $mode_slider = new CFClient::UI::Slider expand => 1, req_w => 100, range => [$CFG->{sdl_mode}, 0, $#SDL_MODES, 0, 1]);
   $hbox->add (my $mode_label = new CFClient::UI::Label align => 0, valign => 0, height => 0.8, template => "9999x9999");

   $mode_slider->connect (changed => sub {
      my ($self, $value) = @_;

      $CFG->{sdl_mode} = $self->{range}[0] = $value = int $value;
      $mode_label->set_text (sprintf "%dx%d", @{$SDL_MODES[$value]});
   });
   $mode_slider->emit (changed => $mode_slider->{range}[0]);

   my $row = 1;

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Fullscreen");
   $table->add (1, $row++, new CFClient::UI::CheckBox
      state => $CFG->{fullscreen},
      tooltip => "Bring the client into fullscreen mode.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{fullscreen} = $value;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Fast & Ugly");
   $table->add (1, $row++, new CFClient::UI::CheckBox
      state => $CFG->{fast},
      tooltip => "Lower the visual quality considerably to speed up rendering.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{fast} = $value;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Map Scale");
   $table->add (1, $row++, new CFClient::UI::Slider
      range      => [(log $CFG->{map_scale}) / (log 2), -3, 1, 0, 1],
      tooltip    => "Enlarge or shrink the displayed map. Changes are instant.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{map_scale} = 2 ** $value;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Fog of War");
   $table->add (1, $row++, new CFClient::UI::CheckBox
      state => $CFG->{fow_enable},
      tooltip => "<b>Fog-of-War</b> marks areas that cannot be seen by the player. Changes are instant.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{fow_enable} = $value;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "FoW Intensity");
   $table->add (1, $row++, new CFClient::UI::Slider
      range => [$CFG->{fow_intensity}, 0, 1, 0, 1 / 256],
      tooltip => "<b>Fog of War Lightness.</b> The higher the intensity, the lighter the Fog-of-War color. Changes are instant.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{fow_intensity} = $value;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "FoW Smooth");
   $table->add (1, $row++, new CFClient::UI::CheckBox
      state => $CFG->{fow_smooth},
      tooltip => "Smooth the Fog-of-War a bit to make it more realistic. Changes are instant.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{fow_smooth} = $value;
         status "Fog of War smoothing requires OpenGL 1.2 or higher" if $CFClient::OpenGL::GL_VERSION < 1.2;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "GUI Fontsize");
   $table->add (1, $row++, new CFClient::UI::Slider
      range => [$CFG->{gui_fontsize}, 0.5, 2, 0, 0.1],
      tooltip => "The base font size used by most GUI elements that do not have their own setting.",
      on_changed => sub { $CFG->{gui_fontsize} = $_[1] },
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Message Fontsize");
   $table->add (1, $row++, new CFClient::UI::Slider
      range => [$CFG->{log_fontsize}, 0.5, 2, 0, 0.1],
      tooltip => "The font size used by the <b>message/server log</b> window only. Changes are instant.",
      on_changed => sub { $LOGVIEW->set_fontsize ($CFG->{log_fontsize} = $_[1]) },
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Stats Fontsize");

   $table->add (1, $row++, new CFClient::UI::Slider
      range => [$CFG->{stat_fontsize}, 0.5, 2, 0, 0.1],
      tooltip => "The font size used by the <b>statistics window</b> only. Changes are instant.",
      on_changed => sub {
         $CFG->{stat_fontsize} = $_[1];
         &set_stats_window_fontsize;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Gauge fontsize");
   $table->add (1, $row++, new CFClient::UI::Slider
      range => [$CFG->{gauge_fontsize}, 0.5, 2, 0, 0.1],
      tooltip => "Adjusts the fontsize of the gauges at the bottom right. Changes are instant.",
      on_changed => sub {
         $CFG->{gauge_fontsize} = $_[1];
         &set_gauge_window_fontsize;
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Gauge size");
   $table->add (1, $row++, new CFClient::UI::Slider
      range      => [$CFG->{gauge_size}, 0.2, 0.8],
      tooltip    => "Adjust the size of the stats gauges at the bottom right. Changes are instant.",
      on_changed => sub {
         $CFG->{gauge_size} = $_[1];
         $GAUGES->{win}->set_size ($WIDTH, int $HEIGHT * $CFG->{gauge_size});
      }
   );

   $table->add (1, $row++, new CFClient::UI::Button
      expand => 1, align => 0, text => "Apply",
      tooltip => "Apply the video settings",
      on_activate => sub {
         video_shutdown ();
         video_init ();
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Audio Enable");
   $table->add (1, $row++, new CFClient::UI::CheckBox
      state => $CFG->{audio_enable},
      tooltip => "<b>Master Audio Enable.</b> If enabled, sound effects and music will be played. If disabled, no audio will be used and the soundcard will not be opened.",
      on_changed => sub {
         $CFG->{audio_enable} = $_[1];
      }
   );
#   $table->add (0, 9, new CFClient::UI::Label valign => 0, align => 1, text => "Effects Volume");
#   $table->add (1, 8, new CFClient::UI::Slider range => [$CFG->{effects_volume}, 0, 128, 1], on_changed => sub {
#      $CFG->{effects_volume} = $_[1];
#   });
   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Background Music");
   $table->add (1, $row++, my $hbox = new CFClient::UI::HBox);
   $hbox->add (new CFClient::UI::CheckBox
      expand => 1, state => $CFG->{bgm_enable},
      tooltip => "If enabled, playing of background music is enabled. If disabled, no background music will be played.",
      on_changed => sub {
         $CFG->{bgm_enable} = $_[1];
      }
   );
   $hbox->add (new CFClient::UI::Slider
      expand => 1, range => [$CFG->{bgm_volume}, 0, 1, 0, 1/128],
      tooltip => "The volume of the background music. Changes are instant.",
      on_changed => sub {
         $CFG->{bgm_volume} = $_[1];
         CFClient::MixMusic::volume $_[1] * 128;
      }
   );

   $table->add (1, $row++, new CFClient::UI::Button
      expand => 1, align => 0, text => "Apply",
      tooltip => "Apply the audio settings",
      on_activate => sub {
         audio_shutdown ();
         audio_init ();
      }
   );

   $table->add (0, $row, new CFClient::UI::Label valign => 0, align => 1, text => "Chat Command");
   $table->add (1, $row++, my $saycmd = new CFClient::UI::Entry
      text => $CFG->{say_command},
      tooltip => "This is the command that will be used if you write a line in the message window entry or press <b>\"</b> in the map window. "
                . "Usually you want to enter something like 'say' or 'shout' or 'gsay' here. "
                . "But you could also set it to <b>tell <i>playername</i></b> to only chat with that user.",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{say_command} = $value;
      }
   );

   $dialog
}

sub set_stats_window_fontsize {
   for (values %{$STATWIDS}) {
      $_->set_fontsize ($::CFG->{stat_fontsize});
   }
}

sub set_gauge_window_fontsize {
   for (map { $GAUGES->{$_} } grep { $_ ne 'win' } keys %{$GAUGES}) {
      $_->set_fontsize ($::CFG->{gauge_fontsize});
   }
}

sub make_gauge_window {
   my $gh = int $HEIGHT * $CFG->{gauge_size};

   my $win = new CFClient::UI::Frame (
      req_x => 0,
      req_y => -1,
      def_w => $WIDTH,
      def_h => $gh,
   );

   $win->add (my $hbox = new CFClient::UI::HBox
      children => [
         (new CFClient::UI::HBox expand => 1),
         (new CFClient::UI::VBox children => [
            (new CFClient::UI::Empty expand => 1),
            (new CFClient::UI::Frame bg => [0, 0, 0, 0.4], child => ($FLOORBOX = new CFClient::UI::Table)),
         ]),
         (my $vbox = new CFClient::UI::VBox),
      ],
   );

   $vbox->add (new CFClient::UI::HBox
      expand => 1,
      children => [
         (new CFClient::UI::Empty expand => 1),
         (my $hb = new CFClient::UI::HBox),
      ],
   );

   $hb->add (my $hg = new CFClient::UI::Gauge type => 'hp',
      tooltip => "<b>Health points</b>. Measures of how much damage you can take before dying. Hit points are determined from your level and are influenced by the value of your Con. Hp value may range between 1 to beyond 500 and higher values indicate a greater ability to withstand punishment.");
   $hb->add (my $mg = new CFClient::UI::Gauge type => 'mana',
      tooltip => "<b>Spell points</b>. Measures of how much \"fuel\" you have for casting spells and incantations. Mana is calculated from your level and your Pow. Mana values can range between 1 to beyond 500 (glowing crystals can increase the current spell points beyond your normal maximum). Higher values indicate greater amounts of mana.");
   $hb->add (my $gg = new CFClient::UI::Gauge type => 'grace',
      tooltip => "<b>Grace points</b> - how favored you are by your god. In game terms, how much divine magic you can cast. Your level, Wis and Pow effect what the value of grace is. Prayong on an altar of your god can increase this value beyond your normal maximum. Grace can take on large positive and negative values. Positive values indicate favor by the gods.");
   $hb->add (my $fg = new CFClient::UI::Gauge type => 'food',
      tooltip => "<b>Food</b>. Ranges between 0 (starving) and 999 (satiated). At a value of 0 the character begins to die. Some magic can speed up or slow down the character digestion. Healing wounds will speed up digestion too.");

   $vbox->add (my $exp = new CFClient::UI::Label valign => 0, align => 1, can_hover => 1, can_events => 1,
      tooltip => "<b>Experience points and overall level</b> - experience is increased as a reward for appropriate action (such as killing monsters) and may decrease as a result of a magical attack or dying. Level is directly derived from the experience value. As the level of the character increases, the character becomes able to succeed at more difficult tasks. A character's level starts at a value of 0 and may range up beyond 100.");
   $vbox->add (my $rng = new CFClient::UI::Label valign => 0, align => 1, can_hover => 1, can_events => 1,
      tooltip => "<b>Ranged attack</b> - how you attack when you press shift-cursor (spell, skill, weapon etc.)");

   $GAUGES = {
      exp => $exp, win => $win, range => $rng,
      food => $fg, mana => $mg, hp => $hg, grace => $gg
   };

   &set_gauge_window_fontsize;

   $win
}

sub make_stats_window {
   my $tgw = new CFClient::UI::FancyFrame
      req_y => $HEIGHT * (2/8),
      req_x => -1,
      title => "Stats",
      name => "stats_window";

   $tgw->add (new CFClient::UI::Window child => my $vb = new CFClient::UI::VBox);
   $vb->add ($STATWIDS->{title} = new CFClient::UI::Label valign => 0, align => -1, text => "Title:", expand => 1,
      can_hover => 1, can_events => 1,
      tooltip => "Your name and title. You can change your title by using the <b>title</b> command, if supported by the server.");
   $vb->add ($STATWIDS->{map} = new CFClient::UI::Label valign => 0, align => -1, text => "Map:", expand => 1,
      can_hover => 1, can_events => 1,
      tooltip => "The map you are currently on (if supported by the server).");

   $vb->add (my $hb0 = new CFClient::UI::HBox);
   $hb0->add ($STATWIDS->{weight} = new CFClient::UI::Label valign => 0, align => -1, text => "Weight:", expand => 1,
      can_hover => 1, can_events => 1,
      tooltip => "The weight of the player including all inventory items.");
   $hb0->add ($STATWIDS->{m_weight} = new CFClient::UI::Label valign => 0, align => -1, text => "Max weight:", expand => 1,
      can_hover => 1, can_events => 1,
      tooltip => "The weight limit: you cannot carry more than this.");


   $vb->add (my $hb = new CFClient::UI::HBox expand => 1);
   $hb->add (my $tbl = new CFClient::UI::Table expand => 1);

   my $color2 = [1, 1, 0];

   for (
      [0, 0, st_str => "Str", 30, "<b>Physical Strength</b>, determines damage dealt with weapons, how much you can carry, and how often you can attack"],
      [0, 1, st_dex => "Dex", 30, "<b>Dexterity</b>, your physical agility. Determines chance of being hit and affects armor class and speed"],
      [0, 2, st_con => "Con", 30, "<b>Constitution</b>, physical health and toughness. Determines how many healthpoints you can have"],
      [0, 3, st_int => "Int", 30, "<b>Intelligence</b>, your ability to learn and use skills and incantations (both prayers and magic) and determines how much spell points you can have"],
      [0, 4, st_wis => "Wis", 30, "<b>Wisdom</b>, the ability to learn and use divine magic (prayers). Determines how many grace points you can have"],
      [0, 5, st_pow => "Pow", 30, "<b>Power</b>, your magical potential. Influences the strength of spell effects, and also how much your spell and grace points increase when leveling up"],
      [0, 6, st_cha => "Cha", 30, "<b>Charisma</b>, how well you are received by NPCs. Affects buying and selling prices in shops."],

      [2, 0, st_wc   => "Wc", -120,   "<b>Weapon Class</b>, effectiveness of melee/missile attacks. Lower is more potent. Current weapon, level and Str are some things which effect the value of Wc. The value of Wc may range between 25 and -72."],
      [2, 1, st_ac   => "Ac", -120,   "<b>Armour Class</b>, how protected you are from being hit by any attack. Lower values are better. Ac is based on your race and is modified by the Dex and current armour worn. For characters that cannot wear armour, Ac improves as their level increases."],
      [2, 2, st_dam  => "Dam", 120,   "<b>Damage</b>, how much damage your melee/missile attack inflicts. Higher values indicate a greater amount of damage will be inflicted with each attack."],
      [2, 3, st_arm  => "Arm", 120,   "<b>Armour</b>, how much damage (from physical attacks) will be subtracted from successful hits made upon you. This value ranges between 0 to 99%. Current armour worn primarily determines Arm value."],
      [2, 4, st_spd  => "Spd", 10.54, "<b>Speed</b>, how fast you can move. The value of speed may range between nearly 0 (\"very slow\") to higher than 5 (\"lightning fast\"). Base speed is determined from the Dex and modified downward proportionally by the amount of weight carried which exceeds the Max Carry limit. The armour worn also sets the upper limit on speed."],
      [2, 5, st_wspd => "WSp", 10.54, "<b>Weapon Speed</b>, how many attacks you may make per unit of time (0.120s). Higher values indicate faster attack speed. Current weapon and Dex effect the value of weapon speed."],
   ) {
      my ($col, $row, $id, $label, $template, $tooltip) = @$_;

      $tbl->add ($col    , $row, $STATWIDS->{$id} = new CFClient::UI::Label
         font => $FONT_FIXED, can_hover => 1, can_events => 1, valign => 0, align => +1, template => $template, tooltip => $tooltip);
      $tbl->add ($col + 1, $row, $STATWIDS->{"$id\_lbl"} = new CFClient::UI::Label
         font => $FONT_FIXED, can_hover => 1, can_events => 1, fg => $color2, valign => 0, align => -1, text => $label, tooltip => $tooltip);
   }

   $hb->add (my $tbl2 = new CFClient::UI::Table expand => 1);

   my $row = 0;
   my $col = 0;

   my %resist_names = (
      slow  => "<b>Slow</b> (slows you down when you are hit by the spell. Monsters will have an opportunity to come near you faster and hit you more often.)",
      holyw => "<b>Holy Word</b> (resistance you against getting the fear when someone whose god doesn't like you spells the holy word on you.)",
      conf  => "<b>Confusion</b> (If you are hit by confusion you will move into random directions, and likely into monsters.)",
      fire  => "<b>Fire</b> (just your resistance to fire spells like burning hands, dragonbreath, meteor swarm fire, ...)",
      depl  => "<b>Depletion</b> (some monsters and other effects can cause stats depletion)",
      magic => "<b>Magic</b> (resistance to magic spells like magic missile or similar)",
      drain => "<b>Draining</b> (some monsters (e.g. vampires) and other effects can steal experience)",
      acid  => "<b>Acid</b> (resistance to acid, acid hurts pretty much and also corrodes your weapons)",
      pois  => "<b>Poison</b> (resistance to getting poisoned)",
      para  => "<b>Paralysation</b> (this resistance affects the chance you get paralysed)",
      deat  => "<b>Death</b> (resistance against death spells)",
      phys  => "<b>Physical</b> (this is the resistance against physical attacks, like when a monster hit you in melee combat)",
      blind => "<b>Blind</b> (blind resistance affects the chance of a successful blinding attack)",
      fear  => "<b>Fear</b> (this attack will drive you away from monsters who cast this and hit you successfully, being resistant to this helps a lot when fighting those monsters)",
      tund  => "<b>Turn undead</b> (affects your resistancy to various forms of 'turn undead' spells. Only relevant when you are, in fact, undead...",
      elec  => "<b>Electricity</b> (resistance against electricity, spells like large lightning, small lightning, ...)",
      cold  => "<b>Cold</b> (this is your resistance against cold spells like icestorm, snowstorm, ...)",
      ghit  => "<b>Ghost hit</b> (special attack used by ghosts and ghost-like beings)",
   );
   for (qw/slow holyw conf fire depl magic
           drain acid pois para deat phys
           blind fear tund elec cold ghit/)
   {
      $tbl2->add ($col, $row,
         $STATWIDS->{"res_$_"} =
            new CFClient::UI::Label
               font       => $FONT_FIXED,
               template   => "-100%",
               align      => +1,
               valign     => 0,
               can_events => 1,
               can_hover  => 1,
               tooltip    => $resist_names{$_},
      );
      $tbl2->add ($col + 1, $row, new CFClient::UI::Image
         font       => $FONT_FIXED,
         can_hover  => 1,
         can_events => 1,
         image      => "ui/resist/resist_$_.png",
         tooltip    => $resist_names{$_},
      );

      $row++;
      if ($row % 6 == 0) {
         $col += 2;
         $row = 0;
      }
   }

   &set_stats_window_fontsize;
   update_stats_window ({});

   $tgw
}

sub formsep {
   reverse join ",", grep length, split /(...)/, reverse $_[0] * 1
}

sub update_stats_window {
   my ($stats) = @_;

   # I love text protocols...

   my $hp   = $stats->{+CS_STAT_HP} * 1;
   my $hp_m = $stats->{+CS_STAT_MAXHP} * 1;
   my $sp   = $stats->{+CS_STAT_SP} * 1;
   my $sp_m = $stats->{+CS_STAT_MAXSP} * 1;
   my $fo   = $stats->{+CS_STAT_FOOD} * 1;
   my $fo_m = 999;
   my $gr   = $stats->{+CS_STAT_GRACE} * 1;
   my $gr_m = $stats->{+CS_STAT_MAXGRACE} * 1;

   $GAUGES->{hp}      ->set_value ($hp, $hp_m);
   $GAUGES->{mana}    ->set_value ($sp, $sp_m);
   $GAUGES->{food}    ->set_value ($fo, $fo_m);
   $GAUGES->{grace}   ->set_value ($gr, $gr_m);
   $GAUGES->{exp}     ->set_text ("Exp: " . (formsep $stats->{+CS_STAT_EXP64})
                                  . " (lvl " . ($stats->{+CS_STAT_LEVEL} * 1) . ")");
   my $rng = $stats->{+CS_STAT_RANGE};
   $rng =~ s/^Range: //;    # thank you so much dear server
   $GAUGES->{range}   ->set_text ("Rng: "  . $rng);
   my $title = $stats->{+CS_STAT_TITLE};
   $title =~ s/^Player: //;
   $STATWIDS->{title} ->set_text ("Title: " . $title);

   $STATWIDS->{st_str} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_STR});
   $STATWIDS->{st_dex} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_DEX});
   $STATWIDS->{st_con} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_CON});
   $STATWIDS->{st_int} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_INT});
   $STATWIDS->{st_wis} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_WIS});
   $STATWIDS->{st_pow} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_POW});
   $STATWIDS->{st_cha} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_CHA});
   $STATWIDS->{st_wc}  ->set_text (sprintf "%d"  , $stats->{+CS_STAT_WC});
   $STATWIDS->{st_ac}  ->set_text (sprintf "%d"  , $stats->{+CS_STAT_AC});
   $STATWIDS->{st_dam} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_DAM});
   $STATWIDS->{st_arm} ->set_text (sprintf "%d"  , $stats->{+CS_STAT_ARMOUR});
   $STATWIDS->{st_spd} ->set_text (sprintf "%.1f", $stats->{+CS_STAT_SPEED});
   $STATWIDS->{st_wspd}->set_text (sprintf "%.1f", $stats->{+CS_STAT_WEAP_SP});

   $STATWIDS->{m_weight}->set_text (sprintf "Max weight: %.1fkg", $stats->{+CS_STAT_WEIGHT_LIM} / 1000);

   # TODO: replace by CS_STAT_RES_xxx constants
   my %tbl = (
      phys  => 100,
      magic => 101,
      fire  => 102,
      elec  => 103,
      cold  => 104,
      conf  => 105,
      acid  => 106,
      drain => 107,
      ghit  => 108,
      pois  => 109,
      slow  => 110,
      para  => 111,
      tund  => 112,
      fear  => 113,
      depl  => 113,
      deat  => 115,
      holyw => 116,
      blind => 117,
   );

   $STATWIDS->{"res_$_"}->set_text (sprintf "%d%", $stats->{$tbl{$_}})
      for keys %tbl;
}

sub metaserver_dialog {
   my $dialog = new CFClient::UI::FancyFrame
      title => "Server List",
      child => (my $vbox = new CFClient::UI::VBox);

   $vbox->add ($dialog->{table} = new CFClient::UI::Table);

   $dialog
}

my $METASERVER_ATIME;

sub update_metaserver {
   my ($HOST) = @_;

   return if $METASERVER_ATIME > time;
   $METASERVER_ATIME = time + 60;

   my $table = $METASERVER->{table};
   $table->clear;
   $table->add (0, 0, my $label = new CFClient::UI::Label max_w => $WIDTH * 0.8, text => "fetching server list...");

   my $buf;

   my $fh = new IO::Socket::INET PeerHost => $META_SERVER, Blocking => 0;

   unless ($fh) {
      $label->set_text ("unable to contact metaserver: $!");
      return;
   }

   Event->io (fd => $fh, poll => 'r', cb => sub {
      my $res = sysread $fh, $buf, 8192, length $buf;

      if (!defined $res) {
         $_[0]->w->cancel;
         $label->set_text ("error while retrieving server list: $!");
      } elsif ($res == 0) {
         $_[0]->w->cancel;
         status "server list retrieved";

         utf8::decode $buf if utf8::valid $buf;

         $table->clear;

         my @col = qw(Use #Users Host Uptime Version Description);
         $table->add ($_, 0, new CFClient::UI::Label align => 0, fg => [1, 1, 0], text => $col[$_])
            for 0 .. $#col;

         my @align = qw(1 0 1 1 -1);

         my $y = 0;
         for my $m (sort { $b->[3] <=> $a->[3] } map [split /\|/], split /\015?\012/, $buf) {
            my ($ip, $last, $host, $users, $version, $desc, $ibytes, $obytes, $uptime) = @$m;

            for ($desc) {
               s/<br>/\n/gi;
               s/<li>/\n· /gi;
               s/<.*?>//sgi;
               s/&/&amp;/g;
               s/</&lt;/g;
               s/>/&gt;/g;
            }

            $uptime = sprintf "%dd %02d:%02d:%02d",
               (int $m->[8] / 86400),
               (int $m->[8] / 3600) % 24,
               (int $m->[8] / 60) % 60,
               $m->[8] % 60;

            $m = [$users, $host, $uptime, $version, $desc];

            $y++;

            $table->add (0, $y, new CFClient::UI::VBox children => [
               (new CFClient::UI::Button text => "Use", on_activate => sub {
                  $HOST->set_text ($CFG->{host} = $host);
               }),
               (new CFClient::UI::Empty expand => 1),
            ]);
            
            $table->add ($_ + 1, $y, new CFClient::UI::Label
                  ellipsise => 0, align => $align[$_], text => $m->[$_], fontsize => 0.8)
               for 0 .. $#$m;
         }
      }
   });
}

sub server_setup {
   my $dialog = new CFClient::UI::FancyFrame
      x                    => $WIDTH  * (1/3),
      y                    => $HEIGHT * (1/8),
      name                 => "server_setup",
      title                => "Server Setup",
      child                => (my $vbox = new CFClient::UI::VBox),
      on_visibility_change => sub {
         my ($self, $visible) = @_;
         $self->center if $visible;
      },
   ;

   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);
   $table->add (0, 2, new CFClient::UI::Label valign => 0, align => 1, text => "Host:Port");

   {
      $table->add (1, 2, my $vbox = new CFClient::UI::VBox);

      $vbox->add (
         my $HOST = new CFClient::UI::Entry
            expand => 1,
            text => $CFG->{host},
            tooltip => "The hostname or ip address of the Crossfire(+) server to connect to",
            on_changed => sub {
               my ($self, $value) = @_;
               $CFG->{host} = $value;
            }
      );

      $METASERVER = metaserver_dialog;

      $vbox->add (new CFClient::UI::Flopper
         expand => 1,
         text => "Server List",
         other => $METASERVER,
         tooltip => "Show a list of available crossfire servers",
         on_open => sub {
            update_metaserver $HOST;
         }
      );
   }

   $table->add (0, 4, new CFClient::UI::Label valign => 0, align => 1, text => "Username");
   $table->add (1, 4, new CFClient::UI::Entry
      text => $CFG->{user},
      tooltip => "The name of your character on the server",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{user} = $value;
      }
   );

   $table->add (0, 5, new CFClient::UI::Label valign => 0, align => 1, text => "Password");
   $table->add (1, 5, new CFClient::UI::Entry
      text => $CFG->{password},
      hidden => 1,
      tooltip => "The password for your character",
      on_changed => sub {
         my ($self, $value) = @_;
         $CFG->{password} = $value;
      }
   );

   $table->add (0, 7, new CFClient::UI::Label valign => 0, align => 1, text => "Map Size");
   $table->add (1, 7, new CFClient::UI::Slider
      req_w => 100,
      range => [$CFG->{mapsize}, 10, 100, 0, 1],
      tooltip => "This is the size of the portion of the map update the server sends you. "
               . "If you set this to a high value you will be able to see further, "
               . "but you also increase bandwidth requirements and latency. "
               . "This option is only used once at log-in.",
      on_changed => sub {
         my ($self, $value) = @_;

         $CFG->{mapsize} = $self->{range}[0] = $value = int $value;
      },
   );

   $table->add (0, 8, new CFClient::UI::Label valign => 0, align => 1, text => "Face Prefetch");
   $table->add (1, 8, new CFClient::UI::CheckBox
      state => $CFG->{face_prefetch},
      tooltip => "<b>Background Image Prefetch</b>\n\n"
               . "If enabled, the client automatically pre-fetches images from the server. "
               . "This might increase or create lag, but increases the chances "
               . "of faces being ready for display when you encounter them. "
               . "It also uses up server bandwidth on every connect, "
               . "so only set it if you really need to prefetch images. "
               . "This option can be set and unset any time.",
      on_changed => sub { $CFG->{face_prefetch} = $_[1] },
   );

   $table->add (0, 9, new CFClient::UI::Label valign => 0, align => 1, text => "Output-Count");
   $table->add (1, 9, new CFClient::UI::Entry
      text => $CFG->{output_count},
      tooltip => "Should be set to 1 unless you know what you are doing. This option is only used once at log-in.",
      on_changed => sub { $CFG->{output_count} = $_[1] },
   );

   $table->add (0, 10, new CFClient::UI::Label valign => 0, align => 1, text => "Output-Sync");
   $table->add (1, 10, new CFClient::UI::Entry
      text => $CFG->{output_sync},
      tooltip => "Should be set to 1 unless you know what you are doing. This option is only used once at log-in.",
      on_changed => sub { $CFG->{output_sync} = $_[1] },
   );

   $table->add (1, 11, $LOGIN_BUTTON = new CFClient::UI::Button
      expand => 1,
      align => 0,
      text => "Login",
      on_activate => sub {
         $CONN ? stop_game
               : start_game;
      },
   );

   $dialog
}

sub message_window {
   my $window = new CFClient::UI::FancyFrame
      name      => "message_window",
      title     => "Messages",
      border_bg => [1, 1, 1, 1],
      bg        => [0, 0, 0, 0.75],
      req_x     => -1,
      req_y     => 0,
      def_w     => int $::WIDTH  / 3,
      def_h     => int $::HEIGHT / 5,
      child     => (my $vbox = new CFClient::UI::VBox);

   $vbox->add ($LOGVIEW);

   $vbox->add (my $input = new CFClient::UI::Entry
      tooltip => "<b>Chat Box</b>. If you enter a text and press return/enter here, the current <i>communication command</i> "
               . "from the client setup will be prepended (e.g. <b>shout</b>, <b>chat</b>...). "
               . "If you prepend a slash (/), you will submit a command instead (similar to IRC). "
               . "A better way to submit commands (and the occasional chat command) is often the map command completer.",
      on_focus_in => sub {
         my ($input, $prev_focus) = @_;

         delete $input->{refocus_map};

         if ($prev_focus == $MAPWIDGET && $input->{auto_activated}) {
            $input->{refocus_map} = 1;
         }
         delete $input->{auto_activated};
      },
      on_activate => sub {
         my ($input, $text) = @_;
         $input->set_text ('');

         if ($text =~ /^\/(.*)/) {
            $::CONN->user_send ($1);
         } else {
            my $say_cmd = $::CFG->{say_command} || 'say';
            $::CONN->user_send ("$say_cmd $text");
         }
         if ($input->{refocus_map}) {
            delete $input->{refocus_map};
            $MAPWIDGET->focus_in
         }
      },
      on_escape => sub {
         $MAPWIDGET->focus_in
      },
   );

   $CONSOLE = {
      window => $window,
      input => $input
   };

   $window
}

sub open_quit_dialog {
   unless ($QUIT_DIALOG) {
      $QUIT_DIALOG = new CFClient::UI::FancyFrame title => "Really Quit?";

      $QUIT_DIALOG->add (my $vb = new CFClient::UI::VBox expand => 1);

      $vb->add (new CFClient::UI::Label
         text      => "You should find a savebed and apply it first!",
         max_w     => $WIDTH * 0.25,
         ellipsize => 0,
      );
      $vb->add (my $hb = new CFClient::UI::HBox expand => 1);
      $hb->add (new CFClient::UI::Button
         text => "Ok",
         expand => 1,
         on_activate => sub { $QUIT_DIALOG->hide },
      );
      $hb->add (new CFClient::UI::Button
         text => "Quit anyway",
         expand => 1,
         on_activate => sub { exit },
      );
   }

   $QUIT_DIALOG->show;
   $QUIT_DIALOG->center;
}

sub make_inventory_window {
   my $invwin = new CFClient::UI::FancyFrame
      def_w => $WIDTH  * 7/8,
      def_h => $HEIGHT * 7/8,
      title => "Inventory",
      name  => "inventory_window",
      on_visibility_change => sub {
         my ($self, $visible) = @_;
         $self->center if $visible;
      },
   ;

   $invwin->add (my $hb = new CFClient::UI::HBox homogeneous => 1);

   $hb->add (my $vb1 = new CFClient::UI::VBox);
   $vb1->add (new CFClient::UI::Label align => 0, text => "Player");
   $vb1->add ($INV = new CFClient::UI::Inventory expand => 1);

   $hb->add (my $vb2 = new CFClient::UI::VBox);

   $vb2->add (my $hb2 = new CFClient::UI::HBox);
   $hb2->add ($INVR_LBL = new CFClient::UI::Label align => 0, expand => 1, text => "Floor");
   $hb2->add (new CFClient::UI::Button
      text     => "Close",
      tooltip  => "Close the currently open container (if one is open)",
      on_activate => sub {
         $CONN->send ("apply $CONN->{open_container}")
            if $CONN->{open_container} != 0;
      },
   );

   $vb2->add ($INVR = new CFClient::UI::Inventory expand => 1);

   $invwin
}

sub make_help_window {
   my $win = new CFClient::UI::FancyFrame
      def_w => int $WIDTH  * 7/8,
      def_h => int $HEIGHT * 7/8,
      title => "Documentation";

   $win->add (my $vbox = new CFClient::UI::VBox);

   $vbox->add (my $buttons = new CFClient::UI::HBox);
   $vbox->add (my $viewer  = new CFClient::UI::TextView expand => 1, fontsize => 0.8);

   for (
      [intro        => "Introduction"],
      [manual       => "Manual"],
      [command_help => "Commands"],
      [skill_help   => "Skills"],
   ) {
      my ($pod, $label) = @$_;

      $buttons->add (new CFClient::UI::Button
         text => $label,
         on_activate => sub {
            my $parser = new Pod::POM;
            my $pom = $parser->parse_file (CFClient::find_rcfile "pod/$pod.pod");

            $viewer->clear;
            
            $viewer->add_paragraph ([1, 1, 1, 1], $_->[1], $_->[0])
               for @{ CFClient::pod_to_pango_list $pom };

            $viewer->set_offset (0);
         },
      );
   }

   $viewer->add_paragraph ([1, 1, 0, 1], "<big>Use one of the buttons above to display a document.</big>");

   $win
}

sub sdl_init {
   CFClient::SDL_Init
      and die "SDL::Init failed!\n";
}

sub video_init {
   sdl_init;

   $CFG->{sdl_mode} = 0 if $CFG->{sdl_mode} >= @SDL_MODES;

   my ($old_w, $old_h) = ($WIDTH, $HEIGHT);

   ($WIDTH, $HEIGHT) = @{ $SDL_MODES[$CFG->{sdl_mode}] };
   $FULLSCREEN = $CFG->{fullscreen};
   $FAST       = $CFG->{fast};

   CFClient::SDL_SetVideoMode $WIDTH, $HEIGHT, $FULLSCREEN
      or die "SDL_SetVideoMode failed: " . (CFClient::SDL_GetError) . "\n";

   $SDL_ACTIVE = 1;
   $LAST_REFRESH = time - 0.01;

   CFClient::OpenGL::init;

   $FONTSIZE = int $HEIGHT / 40 * $CFG->{gui_fontsize};

   $CFClient::UI::ROOT->configure (0, 0, $WIDTH, $HEIGHT);#d#

   #############################################################################

   if ($DEBUG_STATUS) {
      CFClient::UI::rescale_widgets $WIDTH / $old_w, $HEIGHT / $old_h;
   } else {
      # create the widgets

      $DEBUG_STATUS = new CFClient::UI::Label padding => 0, z => 100, req_x => -1;
      $DEBUG_STATUS->show;
      
      $STATUSBOX = new CFClient::UI::Statusbox;
      $STATUSBOX->add ("Use <b>Alt-Enter</b> to toggle fullscreen mode", pri => -100, color => [1, 1, 1, 0.8]);

      (new CFClient::UI::Frame
         bg      => [0, 0, 0, 0.4],
         req_y   => -1,
         child   => $STATUSBOX,
      )->show;

      CFClient::UI::FancyFrame->new (
         border_bg => [1, 1, 1, 192/255],
         bg        => [1, 1, 1, 0],
         child     => ($MAPMAP = new CFClient::MapWidget::MapMap
            tooltip => "<b>Map</b>. On servers that support this feature, this will display an overview of the surrounding areas.",
         ),
      )->show;

      $MAPWIDGET = new CFClient::MapWidget;
      $MAPWIDGET->connect (activate_console => sub {
         my ($mapwidget, $preset) = @_;

         if ($CONSOLE) {
            $CONSOLE->{input}->{auto_activated} = 1;
            $CONSOLE->{input}->focus_in;

            if ($preset && $CONSOLE->{input}->get_text eq '') {
               $CONSOLE->{input}->set_text ($preset);
            }
         }
      });
      $MAPWIDGET->show;
      $MAPWIDGET->focus_in;

      $LOGVIEW = new CFClient::UI::TextView
         expand     => 1,
         font       => $FONT_FIXED,
         fontsize   => $::CFG->{log_fontsize},
         can_hover  => 1,
         can_events => 1,
         tooltip    => "<b>Server Log</b>. This text viewer contains all the messages sent by the server.",
      ;

      $BUTTONBAR = new CFClient::UI::HBox;

      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Client Setup",   other => client_setup,
         tooltip => "Toggles a dialog where you can configure various aspects of the client, such as graphics mode, performance, and audio options.");
      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Server Setup",   other => server_setup,
         tooltip => "Toggles a dialog where you can configure the server to play on, your username, password and other server-related options.");
      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Message Window", other => message_window,
         tooltip => "Toggles the server message log, where the client collects <i>all</i> messages from the server.");

      make_gauge_window->show; # XXX: this has to be set before make_stats_window as make_stats_window calls update_stats_window which updated the gauges also X-D

      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Stats Window", other => make_stats_window,
         tooltip => "Toggles the statistics window, where all your Stats and Resistances are being displayed at all times.");
      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Inventory", other => make_inventory_window,
         tooltip => "Toggles the inventory window, where you can manage your loot (or treaures :).");

      $BUTTONBAR->add (new CFClient::UI::Button
         text             => "Save Config",
         tooltip          => "Saves the options chosen in the client setting, server settings and the window layout to be restored on later runs.",
         on_activate => sub {
            $::CFG->{layout} = CFClient::UI::get_layout;
            CFClient::write_cfg "$Crossfire::VARDIR/pclientrc";
            status "Configuration Saved";
         },
      );

      $BUTTONBAR->add (new CFClient::UI::Flopper text => "Help!", other => make_help_window,
         tooltip => "View Documentation");

      $BUTTONBAR->add (new CFClient::UI::Button
         text        => "Quit",
         tooltip     => "Terminates the program",
         on_activate => sub {
            if ($CONN) {
               open_quit_dialog;
            } else {
               exit;
            }
         },
      );

      $BUTTONBAR->show;

      $STATUSBOX->add ("Set video mode $WIDTH×$HEIGHT", timeout => 10, fg => [1, 1, 1, 0.5]);

      # delay till geometry is constant
      $CFClient::UI::ROOT->on_post_alloc (startup => sub {
         $BUTTONBAR->{children}[1]->emit ("activate"); # pop up server setup
         my $widget = $GAUGES->{win};
         $widget->move (0, $HEIGHT - $widget->{h});#d# to in toplevel
      });
      force_refresh ();
   }
}

sub video_shutdown {
   undef $SDL_ACTIVE;
}

my @bgmusic = qw(game1.ogg game2.ogg game3.ogg game5.ogg game6.ogg ross1.ogg ross2.ogg ross3.ogg ross4.ogg ross5.ogg); #d#
my $bgmusic;#TODO#hack#d#

sub audio_channel_finished {
   my ($channel) = @_;

   #warn "channel $channel finished\n";#d#
}

sub audio_music_finished {
   return unless $CFG->{bgm_enable};

   # TODO: hack, do play loop and mood music
   $bgmusic = new_from_file CFClient::MixMusic CFClient::find_rcfile "music/$bgmusic[0]";
   $bgmusic->play (0);

   push @bgmusic, shift @bgmusic;
}

sub audio_init {
   if ($CFG->{audio_enable}) {
      if (open my $fh, "<", CFClient::find_rcfile "sounds/config") {
         $SDL_MIXER = !CFClient::Mix_OpenAudio;

         unless ($SDL_MIXER) {
            status "Unable to open sound device: there will be no sound";
            return;
         }

         CFClient::Mix_AllocateChannels 8;
         CFClient::MixMusic::volume $CFG->{bgm_volume} * 128;

         audio_music_finished;

         while (<$fh>) {
            next if /^\s*#/;
            next if /^\s*$/;

            my ($file, $volume, $event) = split /\s+/, $_, 3;

            push @SOUNDS, "$volume,$file";

            $AUDIO_CHUNKS{"$volume,$file"} ||= do {
               my $chunk = new_from_file CFClient::MixChunk CFClient::find_rcfile "sounds/$file";
               $chunk->volume ($volume * 128 / 100);
               $chunk
            };
         }
      } else {
         status "unable to open sound config: $!";
      }
   }
}

sub audio_shutdown {
   CFClient::Mix_CloseAudio if $SDL_MIXER;
   undef $SDL_MIXER;
   @SOUNDS = ();
   %AUDIO_CHUNKS = ();
}

my %animate_object;
my $animate_timer;

my $fps = 9;

my %demo;#d#

sub force_refresh {
   $fps = $fps * 0.95 + 1 / (($NOW - $LAST_REFRESH) || 0.1) * 0.05;
   debug sprintf "%3.2f", $fps;

   $CFClient::UI::ROOT->draw;

   $WANT_REFRESH = 0;
   $CAN_REFRESH = 0;
   $LAST_REFRESH = $NOW;

0 && do {
   # some weird model-drawing code, just a joke right now
   use CFClient::OpenGL;

   $demo{t}{eye_auv}  ||= new_from_file CFClient::Texture "eye2.png" or die;
   $demo{t}{body_auv} ||= new_from_file CFClient::Texture "body_auv3.png" or die;
   $demo{r} ||= do {
      my $mod = Compress::LZF::sthaw do { local $/; open my $fh, "<:raw:perlio", "dread.lz3"; <$fh> };
      $mod->{v} = pack "f*", @{$mod->{v}};
      $_ = [scalar @$_, pack "S!*", @$_]
         for values %{$mod->{g}};
      $mod
   };

   my $r = $demo{r} or die;

   glDepthMask 1;
   glClear GL_DEPTH_BUFFER_BIT;
   glEnable GL_TEXTURE_2D;
   glEnable GL_DEPTH_TEST;
   glEnable GL_CULL_FACE;
   glShadeModel $::FAST ? GL_FLAT : GL_SMOOTH;

   glMatrixMode GL_PROJECTION;
   glLoadIdentity;
   glFrustum -1 * ($::WIDTH / $::HEIGHT), 1 * ($::WIDTH / $::HEIGHT), 1, -1, 1, 10000;
   #glOrtho 0, $::WIDTH, 0, $::HEIGHT, -10000, 10000;
   glMatrixMode GL_MODELVIEW;
   glLoadIdentity;

   glPushMatrix;
   glTranslate 0, 0, -800;
   glScale 1, -1, 1;
   glRotate $NOW * 1000 % 36000 / 5, 0, 1, 0;
   glRotate $NOW * 1000 % 36000 / 6, 1, 0, 0;
   glRotate $NOW * 1000 % 36000 / 7, 0, 0, 1;
   glScale 50, 50, 50;

   glInterleavedArrays GL_T2F_N3F_V3F, 0, $r->{v};
   while (my ($k, $v) = each %{$r->{g}}) {
      glBindTexture GL_TEXTURE_2D, ($demo{t}{$k}{name} or die);
      glDrawElements GL_TRIANGLES, $v->[0], GL_UNSIGNED_SHORT, $v->[1];
   }

   glPopMatrix;

   glShadeModel GL_FLAT;
   glDisable GL_DEPTH_TEST;
   glDisable GL_TEXTURE_2D;
   glDepthMask 0;

   $WANT_REFRESH++;
};
   
   CFClient::SDL_GL_SwapBuffers;
}

my $refresh_watcher = Event->timer (after => 0, hard => 1, interval => 1 / $MAX_FPS, cb => sub {
   $NOW = time;

   ($SDL_CB{$_->{type}} || sub { warn "unhandled event $_->{type}" })->($_)
      for CFClient::SDL_PollEvent;

   if (%animate_object) {
      $_->animate ($LAST_REFRESH - $NOW) for values %animate_object;
      $WANT_REFRESH++;
   }

   if ($WANT_REFRESH) {
      force_refresh;
   } else {
      $CAN_REFRESH = 1;
   }
});

sub animation_start {
   my ($widget) = @_;
   $animate_object{$widget} = $widget;
}

sub animation_stop {
   my ($widget) = @_;
   delete $animate_object{$widget};
}

# check once/second for faces that need to be prefetched
# this should, of course, only run on demand, but
# SDL forces worse things on us....

Event->timer (after => 1, interval => 0.25, cb => sub {
   $CONN->face_prefetch
      if $CONN;
});

%SDL_CB = (
   CFClient::SDL_QUIT => sub {
      Event::unloop -1;
   },
   CFClient::SDL_VIDEORESIZE => sub {
   },
   CFClient::SDL_VIDEOEXPOSE => sub {
      CFClient::UI::full_refresh;
   },
   CFClient::SDL_ACTIVEEVENT => sub {
#      printf "active %x %x\n", $SDL_EV->active_gain, $SDL_EV->active_state;#d#
   },
   CFClient::SDL_KEYDOWN => sub {
      if ($_[0]{mod} & CFClient::KMOD_ALT && $_[0]{sym} == 13) {
         # alt-enter
         video_shutdown;
         $CFG->{fullscreen} = !$CFG->{fullscreen};
         video_init;
      } else {
         CFClient::UI::feed_sdl_key_down_event ($_[0]);
      }
   },
   CFClient::SDL_KEYUP           => \&CFClient::UI::feed_sdl_key_up_event,
   CFClient::SDL_MOUSEMOTION     => \&CFClient::UI::feed_sdl_motion_event,
   CFClient::SDL_MOUSEBUTTONDOWN => \&CFClient::UI::feed_sdl_button_down_event,
   CFClient::SDL_MOUSEBUTTONUP   => \&CFClient::UI::feed_sdl_button_up_event,
   CFClient::SDL_USEREVENT       => sub {
      if ($_[0]{code} == 1) {
         audio_channel_finished $_[0]{data1};
      } elsif ($_[0]{code} == 0) {
         audio_music_finished;
      }
   },
);

#############################################################################

$SIG{INT} = $SIG{TERM} = sub { exit };

{
   local $SIG{__DIE__} = sub { CFClient::fatal $_[0] };

   CFClient::read_cfg "$Crossfire::VARDIR/pclientrc";
   CFClient::UI::set_layout ($::CFG->{layout});

   my %DEF_CFG = (
      sdl_mode      => 0,
      width         => 640,
      height        => 480,
      fullscreen    => 0,
      fast          => 0,
      map_scale     => 1,
      fow_enable    => 1,
      fow_intensity => 0.45,
      fow_smooth    => 0,
      gui_fontsize  => 1,
      log_fontsize  => 1,
      gauge_fontsize=> 1,
      gauge_size    => 0.35,
      stat_fontsize => 1,
      mapsize       => 100,
      host          => "crossfire.schmorp.de",
      say_command   => 'say',
      audio_enable  => 1,
      bgm_enable    => 1,
      bgm_volume    => 0.25,
      face_prefetch => 0,
      output_sync   => 1,
      output_count  => 1,
   );

   while (my ($k, $v) = each %DEF_CFG) {
      $CFG->{$k} = $v unless exists $CFG->{$k};
   }

   sdl_init;

   @SDL_MODES = reverse
                   grep $_->[0] >= 640 && $_->[1] >= 480,
                      CFClient::SDL_ListModes;

   @SDL_MODES or CFClient::fatal "Unable to find a usable video mode\n(hardware accelerated opengl fullscreen)";

   $CFG->{sdl_mode} = 0 if $CFG->{sdl_mode} > @SDL_MODES;

   {
      my @fonts = map CFClient::find_rcfile "fonts/$_", qw(
         DejaVuSans.ttf
         DejaVuSansMono.ttf
         DejaVuSans-Bold.ttf
         DejaVuSansMono-Bold.ttf
         DejaVuSans-Oblique.ttf
         DejaVuSansMono-Oblique.ttf
         DejaVuSans-BoldOblique.ttf
         DejaVuSansMono-BoldOblique.ttf
      );

      CFClient::add_font $_ for @fonts;
      
      CFClient::pango_init;

      $FONT_PROP  = new_from_file CFClient::Font $fonts[0];
      $FONT_FIXED = new_from_file CFClient::Font $fonts[1];

      $FONT_PROP->make_default;
   }

#   compare mono (ft) vs. rgba (cairo)
#   ft - 1.8s, cairo 3s, even in alpha-only mode
#   for my $rgba (0..1) {
#      my $t1 = Time::HiRes::time;
#      for (1..1000) {
#         my $layout = CFClient::Layout->new ($rgba);
#         $layout->set_text ("hallo" x 100);
#         $layout->render;
#      }
#      my $t2 = Time::HiRes::time;
#      warn $t2-$t1;
#   }

   video_init;
   audio_init;
}

Event::loop;

END { CFClient::SDL_Quit }

=head1 NAME

pclient - A Crossfire+ and Crossfire game client

=head1 SYNOPSIS

Just run it - no commandline arguments are supported.

=head1 USAGE

Pclient utilises OpenGL for all UI elements and the game. It is supposed to be used
fullscreen and interactively.

=head1 AUTHOR

Marc Lehmann <crossfire@schmorp.de>, Robin Redeker <elmex@ta-sa.org>


Revision:	1.21
Committed:	Sun May 28 01:16:04 2006 UTC (18 years ago) by root
Branch:	MAIN
Changes since 1.20:	+20 -20 lines
Log Message:	better overall layout, homogenous boxes