#!/opt/bin/perl

use strict;
use utf8;

use Time::HiRes 'time';
use Event;

use SDL;
use SDL::App;
use SDL::Event;
use SDL::Surface;
use SDL::OpenGL;

use Crossfire;
use Crossfire::Protocol;

use CFClient;
use CFClient::UI;

our $VERSION = '0.1';

my $MAX_FPS = 60;
my $MIN_FPS =  5; # unused as of yet

our $FACECACHE;

our $LAST_REFRESH;
our $NOW;

our $CFG;
our $CONN;
our $FAST; # fast, low-quality mode, possibly useful for software-rendering

our @SDL_MODES;
our $WIDTH;
our $HEIGHT;
our $FULLSCREEN;
our $FONTSIZE;

our $MAP;
our $MAPWIDGET;

our $SDL_ACTIVE;
our $SDL_EV;
our %SDL_CB;

our $ALT_ENTER_MESSAGE;
our $STATUS_LINE;
our $DEBUG_STATUS;
our $BUTTONBAR;
our $LOGVIEW;
our $CONSOLE;

sub status {
   $STATUS_LINE->set_text ($_[0]);
   my ($w, $h) = $STATUS_LINE->size_request;
   $STATUS_LINE->size_allocate (0, $HEIGHT - $ALT_ENTER_MESSAGE->{h} - $h, $w, $h);
}

sub debug {
   $DEBUG_STATUS->set_text ($_[0]);
   my ($w, $h) = $DEBUG_STATUS->size_request;
   $DEBUG_STATUS->size_allocate ($WIDTH - $w, 0, $w, $h);
}

sub start_game {
   status "logging in...";

   my $mapsize = List::Util::min 64, List::Util::max 11, int $WIDTH * $CFG->{mapsize} * 0.01 / 32;

   $MAP = new CFClient::Map $mapsize, $mapsize;
   
   $CONN = new conn
      host => $CFG->{host},
      port => $CFG->{port},
      user => $CFG->{user},
      pass => $CFG->{password},
      mapw => $mapsize,
      maph => $mapsize,
   ;

   status "login successful";

   CFClient::lowdelay fileno $CONN->{fh};
}

sub stop_game {
   undef $CONN;
}

sub config_dialog {
   my $dialog = new CFClient::UI::FancyFrame
      child => (my $vbox = new CFClient::UI::VBox);
   $vbox->add (new CFClient::UI::Label align => 0, text => "Client Setup");
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);

   $table->add (0, 0, new CFClient::UI::Label align => 1, text => "Video Mode");
   $table->add (1, 0, my $hbox = new CFClient::UI::HBox);

   $hbox->add (my $mode_slider = new CFClient::UI::Slider expand => 1, req_w => 100, range => [$CFG->{sdl_mode}, 0, scalar @SDL_MODES, 1]);
   $hbox->add (my $mode_label = new CFClient::UI::Label height => $FONTSIZE * 0.8);

   $mode_slider->connect (changed => sub {
      my ($self, $value) = @_;

      $CFG->{sdl_mode} = $self->{range}[0] = $value = int $value;
      $mode_label->set_text (sprintf "%dx%d", @{$SDL_MODES[$value]});
   });
   $mode_slider->emit (changed => $mode_slider->{range}[0]);

   $table->add (0, 1, new CFClient::UI::Label align => 1, text => "Fullscreen");
   $table->add (1, 1, new CFClient::UI::CheckBox state => $CFG->{fullscreen}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fullscreen} = $value;
   });

   $table->add (0, 2, new CFClient::UI::Label align => 1, text => "Fast & Ugly");
   $table->add (1, 2, new CFClient::UI::CheckBox state => $CFG->{fast}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fast} = $value;
   });

   $table->add (0, 3, new CFClient::UI::Label align => 1, text => "Fog of War");
   $table->add (1, 3, new CFClient::UI::CheckBox state => $CFG->{fow_enable}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_enable} = $value;
   });

   $table->add (0, 4, new CFClient::UI::Label align => 1, text => "FoW Intensity");
   $table->add (1, 4, new CFClient::UI::Slider range => [$CFG->{fow_intensity}, 0, 1 + 0.001, 0.001], connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_intensity} = $value;
   });

   $table->add (0, 5, new CFClient::UI::Label align => 1, text => "FoW Smooth");
   $table->add (1, 5, new CFClient::UI::CheckBox state => $CFG->{fow_smooth}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_smooth} = $value;
   });

   $table->add (0, 5, new CFClient::UI::Label align => 1, text => "Log Fontsize");
   $table->add (1, 5, new CFClient::UI::Slider range => [$CFG->{log_fontsize}, 8, 30, 1], connect_changed => sub {
      my ($self, $value) = @_;
      $LOGVIEW->set_fontsize ($CFG->{log_fontsize} = int $value);
   });

   $table->add (1, 6, new CFClient::UI::Button expand => 1, align => 0, text => "Apply", connect_activate => sub {
      destroy_screen ();
      init_screen ();
   });
   
   $vbox->add (new CFClient::UI::Label align => 0, text => "Server Setup");
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);
   $table->add (0, 2, new CFClient::UI::Label align => 1, text => "Host");
   $table->add (1, 2, my $host = new CFClient::UI::Entry text => $CFG->{host}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{host} = $value;
   });

   $table->add (0, 3, new CFClient::UI::Label align => 1, text => "Port");
   $table->add (1, 3, my $port = new CFClient::UI::Entry text => $CFG->{port}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{port} = $value;
   });

   $table->add (0, 4, new CFClient::UI::Label align => 1, text => "Username");
   $table->add (1, 4, my $user = new CFClient::UI::Entry text => $CFG->{user}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{user} = $value;
   });

   $table->add (0, 5, new CFClient::UI::Label align => 1, text => "Password");
   $table->add (1, 5, my $pass = new CFClient::UI::Entry text => $CFG->{password}, hidden => 1, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{password} = $value;
   });

   $table->add (0, 6, new CFClient::UI::Label align => 1, text => "Def. say cmd");
   $table->add (1, 6, my $saycmd = new CFClient::UI::Entry text => $CFG->{say_command}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{say_command} = $value;
   });

   $table->add (0, 7, new CFClient::UI::Label align => 1, text => "Map Size");
   $table->add (1, 7, new CFClient::UI::Slider
      req_w => 100,
      range => [$CFG->{mapsize}, 10, 100 + 1, 1],
      connect_changed => sub {
         my ($self, $value) = @_;

         $CFG->{mapsize} = $self->{range}[0] = $value = int $value;
      },
   );

   $table->add (1, 8, new CFClient::UI::Button expand => 1, align => 0, text => "Login", connect_activate => sub {
      start_game;
   });

   $vbox->add (my $hbox = new CFClient::UI::HBox);

   $hbox->add (new CFClient::UI::Button expand => 1, align => 0, text => "Save", connect_activate => sub {
      CFClient::write_cfg "$Crossfire::VARDIR/pclientrc";
      status "Configuration Saved";
   });

   $dialog
}

sub console_window {
   my $window = new CFClient::UI::FancyFrame
      border_bg => [1, 1, 1, 0.5],
      bg        => [0.3, 0.3, 0.3, 0.8],
      user_w    => $::WIDTH/4,
      user_h    => $::HEIGHT,
      child     => (my $vbox = new CFClient::UI::VBox);

   $vbox->add ($LOGVIEW = new CFClient::UI::TextView
      expand   => 1,
      fontsize => $::CFG->{log_fontsize},
   );

   $vbox->add (my $input = new CFClient::UI::LineEntry);
      $input->connect (activate => sub {
         my ($input, $text) = @_;
         $input->set_text ('');

         if ($text =~ /^\/(.*)/) {
            $::CONN->user_send ("command $1");
         } else {
            my $say_cmd = $::CFG->{say_command} || 'say';
            $::CONN->user_send ("command $say_cmd $text");
         }
         1
      });
      $input->connect (escape => sub {
         $MAPWIDGET->focus_in
      });
      $input->focus_in;

   $CONSOLE = {
      window => $window,
      input => $input
   };

   $window
}

sub sdl_init {
   SDL::Init SDL_INIT_AUDIO | SDL_INIT_VIDEO
      and die "SDL::Init failed!\n";
}

sub init_screen {
   sdl_init;

   ($WIDTH, $HEIGHT) = @{ $SDL_MODES[$CFG->{sdl_mode}] };
   $FULLSCREEN = $CFG->{fullscreen};
   $FAST       = $CFG->{fast};

   SDL::GLSetAttribute SDL_GL_RED_SIZE, 5;
   SDL::GLSetAttribute SDL_GL_GREEN_SIZE, 5;
   SDL::GLSetAttribute SDL_GL_BLUE_SIZE, 5;
   SDL::GLSetAttribute SDL_GL_ALPHA_SIZE, 0;

   SDL::GLSetAttribute SDL_GL_ACCUM_RED_SIZE, 0;
   SDL::GLSetAttribute SDL_GL_ACCUM_GREEN_SIZE, 0;
   SDL::GLSetAttribute SDL_GL_ACCUM_BLUE_SIZE, 0;
   SDL::GLSetAttribute SDL_GL_ACCUM_ALPHA_SIZE, 0;

   SDL::GLSetAttribute SDL_GL_DOUBLEBUFFER, 1;
   SDL::GLSetAttribute SDL_GL_BUFFER_SIZE, 15;
   SDL::GLSetAttribute SDL_GL_DEPTH_SIZE, 0;

   SDL::SetVideoMode $WIDTH, $HEIGHT, 0,
      SDL_HWSURFACE | SDL_ANYFORMAT | SDL_OPENGL | SDL_DOUBLEBUF
      | ($FULLSCREEN ? SDL_FULLSCREEN : 0)
      or die "SDL::SetVideoMode failed!\n";

   SDL::WMSetCaption "Crossfire+ Client", "Crossfire+";

   $SDL_EV = new SDL::Event;
   $SDL_EV->set_unicode (1);

   $SDL_ACTIVE = 1;

   $LAST_REFRESH = time - 0.01;

   CFClient::gl_init;

   $FONTSIZE = int $HEIGHT / 40;

   #############################################################################

   $DEBUG_STATUS = new CFClient::UI::Label padding => 0, z => 100;
   $CFClient::UI::TOPLEVEL->add ($DEBUG_STATUS);
   
   $STATUS_LINE = new CFClient::UI::Label
                     padding => 0,
                     y => $HEIGHT * 44 / 45 - $FONTSIZE;
   $CFClient::UI::TOPLEVEL->add ($STATUS_LINE);

   $ALT_ENTER_MESSAGE = new CFClient::UI::Label
                           padding => 0,
                           y => $HEIGHT * 44 / 45,
                           height => $HEIGHT / 45,
                           text => "Use <b>Alt-Enter</b> to toggle fullscreen mode";
   $CFClient::UI::TOPLEVEL->add ($ALT_ENTER_MESSAGE);

   $CFClient::UI::TOPLEVEL->add ($MAPWIDGET = new CFClient::UI::MapWidget);
   $MAPWIDGET->focus_in;
   $MAPWIDGET->connect (activate_console => sub {
      my ($mapwidget, $preset) = @_;

      if ($CONSOLE) {
         $CONSOLE->{input}->focus_in;

         if ($preset && $CONSOLE->{input}->get_text eq '') {
            $CONSOLE->{input}->set_text ($preset);
         }
      }
   });

   $CFClient::UI::TOPLEVEL->add ($BUTTONBAR = new CFClient::UI::HBox);

   $BUTTONBAR->add (my $setup = new CFClient::UI::Flopper x => 0, y => 0, text => "Setup",   other => config_dialog, state => 1);
   $BUTTONBAR->add (my $setup = new CFClient::UI::Flopper x => 0, y => 0, text => "Console", other => console_window);
}

sub destroy_screen {
   $CFClient::UI::TOPLEVEL->{children} = [];
   undef $SDL_ACTIVE;
   undef $SDL_EV;
   SDL::Quit;
}

my %animate_object;
my $animate_timer;

my $want_refresh;
my $can_refresh;

my $fps = 9;

sub force_refresh {
   $fps = $fps * 0.95 + 1 / ($NOW - $LAST_REFRESH) * 0.05;
   debug sprintf "%3.2f", $fps;

   $want_refresh = 0;
   $can_refresh = 0;

   $CFClient::UI::TOPLEVEL->draw;

   SDL::GLSwapBuffers;

   $LAST_REFRESH = $NOW;
}

my $refresh_watcher = Event->timer (after => 0, hard => 1, interval => 1 / $MAX_FPS, cb => sub {
   $NOW = time;

   ($SDL_CB{$SDL_EV->type} || sub { warn "unhandled event ", $SDL_EV->type })->()
      while $SDL_EV->poll;

   if (%animate_object) {
      $_->animate ($LAST_REFRESH - $NOW) for values %animate_object;
      $want_refresh++;
   }

   if ($want_refresh) {
      force_refresh;
   } else {
      $can_refresh = 1;
   }
});

sub refresh {
   $want_refresh++;
}

sub animation_start {
   my ($widget) = @_;
   $animate_object{$widget} = $widget;
}

sub animation_stop {
   my ($widget) = @_;
   delete $animate_object{$widget};
}

@conn::ISA = Crossfire::Protocol::;

sub conn::user_send {
   my ($self, $command) = @_;

   $self->send ($command);
   status $command;
}

sub conn::feed_map1a {
   my ($self, $data) = @_;

#   $self->Crossfire::Protocol::feed_map1a ($data);

   $MAP->scroll (delete $self->{delayed_scroll_x}, delete $self->{delayed_scroll_y});
   $MAP->map1a_update ($data);
   $MAPWIDGET->update;
}

#sub conn::map_update {
#   my ($self, $dirty) = @_;
#
#   $MAPWIDGET->update;
#}

sub conn::map_clear {
   my ($self) = @_;

   $MAP->clear;

#   refresh;
}

sub conn::face_find {
   my ($self, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"}
}

sub conn::face_update {
   my ($self, $facenum, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"} = $face->{image};

   my $tex = $face->{texture} = new_from_image CFClient::Texture delete $face->{image};

   $MAP->set_texture ($facenum, @$tex{qw(name w h s t)});
   $MAPWIDGET->update;
}

sub conn::query {
   my ($self, $flags, $prompt) = @_;

   #TODO
   warn "<<<<QUERY:$flags:$prompt>>>\n";#d#
}

sub conn::drawinfo {
   my ($self, $color, $text) = @_;

   my @color = (
      [1.00, 1.00, 1.00], #[0.00, 0.00, 0.00],
      [1.00, 1.00, 1.00],
      [0.00, 0.00, 0.55],
      [1.00, 0.00, 0.00],
      [1.00, 0.54, 0.00],
      [0.11, 0.56, 1.00],
      [0.93, 0.46, 0.00],
      [0.18, 0.54, 0.34],
      [0.56, 0.73, 0.56],
      [0.80, 0.80, 0.80],
      [0.55, 0.41, 0.13],
      [0.99, 0.77, 0.26],
      [0.74, 0.65, 0.41],
   );

   $LOGVIEW->add_paragraph ($color[$color], $text);
}

%SDL_CB = (
   SDL_QUIT() => sub {
      Event::unloop -1;
   },
   SDL_VIDEORESIZE() => sub {
   },
   SDL_VIDEOEXPOSE() => sub {
      refresh;
   },
   SDL_KEYDOWN() => sub {
      if ($SDL_EV->key_mod & KMOD_ALT && $SDL_EV->key_sym == SDLK_RETURN) {
         # alt-enter
         destroy_screen;
         $CFG->{fullscreen} = !$CFG->{fullscreen};
         init_screen;
      } else {
         CFClient::UI::feed_sdl_key_down_event ($SDL_EV);
      }
   },
   SDL_KEYUP() => sub {
      CFClient::UI::feed_sdl_key_up_event ($SDL_EV);
   },
   SDL_MOUSEMOTION() => sub {
      CFClient::UI::feed_sdl_motion_event ($SDL_EV);
   },
   SDL_MOUSEBUTTONDOWN() => sub {
      CFClient::UI::feed_sdl_button_down_event ($SDL_EV);
   },
   SDL_MOUSEBUTTONUP() => sub {
      CFClient::UI::feed_sdl_button_up_event ($SDL_EV);
   },
   SDL_ACTIVEEVENT() => sub {
#      printf "active %x %x\n", $SDL_EV->active_gain, $SDL_EV->active_state;#d#
   },
);

#############################################################################

CFClient::read_cfg "$Crossfire::VARDIR/pclientrc";

my %DEF_CFG = (
   sdl_mode      => 0,
   width         => 640,
   height        => 480,
   fullscreen    => 0,
   fast          => 0,
   fow_enable    => 1,
   fow_intensity => 0.45,
   fow_smooth    => 0,
   log_fontsize  => 14,
   mapsize       => 100,
   host          => "crossfire.schmorp.de",
   port          => 13327,
   say_command   => 'say',
);

while (my ($k, $v) = each %DEF_CFG) {
   $CFG->{$k} = $v unless exists $CFG->{$k};
}

sdl_init;

@SDL_MODES = reverse
                grep $_->[0] >= 640 && $_->[1] >= 480,
                   map [SDL::RectW ($_), SDL::RectH ($_)],
                      @{ SDL::ListModes 0, SDL_FULLSCREEN | SDL_HWSURFACE | SDL_OPENGL };

@SDL_MODES or CFClient::fatal "Unable to find a usable video mode\n(hardware accelerated opengl fullscreen)";

$CFG->{sdl_mode} = 0 if $CFG->{sdl_mode} > @SDL_MODES;

init_screen;

{
   my @fonts = map CFClient::find_rcfile $_, qw(uifont.ttf uifontb.ttf uifonti.ttf uifontbi.ttf);

   CFClient::add_font $_ for @fonts;
   CFClient::set_font $fonts[0];
}

$FACECACHE = eval { Crossfire::load_ref "$Crossfire::VARDIR/pclient.faces" } || {};

Event::loop;

Crossfire::save_ref $FACECACHE, "$Crossfire::VARDIR/pclient.faces";