[ViewVC] Contents of: cvs/deliantra/Deliantra-Client/bin/pclient

#!/opt/bin/perl

use strict;
use utf8;

use Time::HiRes 'time';
use Event;

use SDL::Event;

use SDL::Mixer;
use SDL::Sound;
use SDL::Music;

use SDL::OpenGL;

use Crossfire;
use Crossfire::Protocol;

use Compress::LZF;

use CFClient;
use CFClient::UI;
use CFClient::MapWidget;

our $VERSION = '0.1';

my $MAX_FPS = 60;
my $MIN_FPS =  5; # unused as of yet

our $META_SERVER = "crossfire.real-time.com:13326";

our $FACEMAP;
our $TILECACHE;
our $MAPCACHE;

our $LAST_REFRESH;
our $NOW;

our $CFG;
our $CONN;
our $FAST; # fast, low-quality mode, possibly useful for software-rendering

our @SDL_MODES;
our $WIDTH;
our $HEIGHT;
our $FULLSCREEN;
our $FONTSIZE;

our $MAP;
our $MAPWIDGET;
our $BUTTONBAR;
our $LOGVIEW;
our $CONSOLE;
our $METASERVER;

our $GAUGES;

our $SDL_ACTIVE;
our $SDL_EV;
our %SDL_CB;

our $SDL_MIXER;
our @SOUNDS;       # event => file mapping
our %AUDIO_CHUNKS; # audio files

our $ALT_ENTER_MESSAGE;
our $STATUS_LINE;
our $DEBUG_STATUS;

sub status {
   $STATUS_LINE->set_text ($_[0]);
   $STATUS_LINE->move (0, $HEIGHT - $ALT_ENTER_MESSAGE->{h} - $STATUS_LINE->{h});
}

sub debug {
   $DEBUG_STATUS->set_text ($_[0]);
   $DEBUG_STATUS->move ($WIDTH - $DEBUG_STATUS->{w}, 0, $DEBUG_STATUS->{w}, $DEBUG_STATUS->{h});
}

sub start_game {
   status "logging in...";

   my $mapsize = List::Util::min 32, List::Util::max 11, int $WIDTH * $CFG->{mapsize} * 0.01 / 32;

   $MAPCACHE = CFClient::db_table "mapcache_$CFG->{host}";

   $MAP = new CFClient::Map $mapsize, $mapsize;

   my ($host, $port) = split /:/, $CFG->{host};
   
   $CONN = new conn
      host => $host,
      port => $port || 13327,
      user => $CFG->{user},
      pass => $CFG->{password},
      mapw => $mapsize,
      maph => $mapsize,
   ;

   status "login successful";

   CFClient::lowdelay fileno $CONN->{fh};
}

sub stop_game {
   undef $CONN;
}

sub client_setup {
   my $dialog = new CFClient::UI::FancyFrame
      child => (my $vbox = new CFClient::UI::VBox);
   $vbox->add (new CFClient::UI::Label valign => 0, align => 0, text => "Client Setup");
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);

   $table->add (0, 0, new CFClient::UI::Label valign => 0, align => 1, text => "Video Mode");
   $table->add (1, 0, my $hbox = new CFClient::UI::HBox);

   $hbox->add (my $mode_slider = new CFClient::UI::Slider expand => 1, req_w => 100, range => [$CFG->{sdl_mode}, 0, scalar @SDL_MODES, 1]);
   $hbox->add (my $mode_label = new CFClient::UI::Label valign => 0, height => 0.8);

   $mode_slider->connect (changed => sub {
      my ($self, $value) = @_;

      $CFG->{sdl_mode} = $self->{range}[0] = $value = int $value;
      $mode_label->set_text (sprintf "%dx%d", @{$SDL_MODES[$value]});
   });
   $mode_slider->emit (changed => $mode_slider->{range}[0]);

   $table->add (0, 1, new CFClient::UI::Label valign => 0, align => 1, text => "Fullscreen");
   $table->add (1, 1, new CFClient::UI::CheckBox state => $CFG->{fullscreen}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fullscreen} = $value;
   });

   $table->add (0, 2, new CFClient::UI::Label valign => 0, align => 1, text => "Fast & Ugly");
   $table->add (1, 2, new CFClient::UI::CheckBox state => $CFG->{fast}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fast} = $value;
   });

   $table->add (0, 3, new CFClient::UI::Label valign => 0, align => 1, text => "Fog of War");
   $table->add (1, 3, new CFClient::UI::CheckBox state => $CFG->{fow_enable}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_enable} = $value;
   });

   $table->add (0, 4, new CFClient::UI::Label valign => 0, align => 1, text => "FoW Intensity");
   $table->add (1, 4, new CFClient::UI::Slider range => [$CFG->{fow_intensity}, 0, 1 + 0.001, 0.001], connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_intensity} = $value;
   });

   $table->add (0, 5, new CFClient::UI::Label valign => 0, align => 1, text => "FoW Smooth");
   $table->add (1, 5, new CFClient::UI::CheckBox state => $CFG->{fow_smooth}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{fow_smooth} = $value;
      status "Fog of War smoothing requires OpenGL 1.2 or higher" if $CFClient::GL_VERSION < 1.2;
   });

   $table->add (0, 6, new CFClient::UI::Label valign => 0, align => 1, text => "GUI Fontsize");
   $table->add (1, 6, new CFClient::UI::Slider range => [$CFG->{gui_fontsize}, 0.7, 1.7, 0.1], connect_changed => sub {
      $CFG->{gui_fontsize} = 0.1 * int $_[1] * 10;
#      $FONTSIZE = int $HEIGHT / 40 * $CFG->{gui_fontsize};
   });

   $table->add (0, 7, new CFClient::UI::Label valign => 0, align => 1, text => "Server Log Fontsize");
   $table->add (1, 7, new CFClient::UI::Slider range => [$CFG->{log_fontsize}, 0.7, 1.7, 0.1], connect_changed => sub {
      $LOGVIEW->set_fontsize ($CFG->{log_fontsize} = 0.1 * int $_[1] * 10);
   });

   $table->add (1, 8, new CFClient::UI::Button expand => 1, align => 0, text => "Apply", connect_activate => sub {
      video_shutdown ();
      video_init ();
   });

   $table->add (0, 9, new CFClient::UI::Label valign => 0, align => 1, text => "Audio Enable");
   $table->add (1, 9, new CFClient::UI::CheckBox state => $CFG->{audio_enable}, connect_changed => sub {
      $CFG->{audio_enable} = $_[1];
   });
#   $table->add (0, 9, new CFClient::UI::Label valign => 0, align => 1, text => "Effects Volume");
#   $table->add (1, 8, new CFClient::UI::Slider range => [$CFG->{effects_volume}, 0, 128, 1], connect_changed => sub {
#      $CFG->{effects_volume} = $_[1];
#   });
   $table->add (0, 10, new CFClient::UI::Label valign => 0, align => 1, text => "Background Music");
   $table->add (1, 10, my $hbox = new CFClient::UI::HBox);
   $hbox->add (new CFClient::UI::CheckBox expand => 1, state => $CFG->{bgm_enable}, connect_changed => sub {
      $CFG->{bgm_enable} = $_[1];
   });
   $hbox->add (new CFClient::UI::Slider expand => 1, range => [$CFG->{bgm_volume}, 0, 128, 1], connect_changed => sub {
      $CFG->{bgm_volume} = $_[1];
      $SDL_MIXER->music_volume ($_[1]);
   });

   $table->add (1, 11, new CFClient::UI::Button expand => 1, align => 0, text => "Apply", connect_activate => sub {
      audio_shutdown ();
      audio_init ();
   });

   $dialog
}

sub metaserver_dialog {
   my $dialog = new CFClient::UI::FancyFrame
      child => (my $vbox = new CFClient::UI::VBox);

   $vbox->add ($dialog->{table} = new CFClient::UI::Table);

   $dialog
}

sub update_metaserver {
   my ($HOST) = @_;

   status "fetching metaserver list...";

   my $buf;

   my $fh = new IO::Socket::INET PeerHost => $META_SERVER, Blocking => 0;

   Event->io (fd => $fh, poll => 'r', cb => sub {
      my $res = sysread $fh, $buf, 8192, length $buf;

      if (!defined $res) {
         $_[0]->w->cancel;
         status "metaserver: $!";
      } elsif ($res == 0) {
         $_[0]->w->cancel;
         status "server list retrieved";

         my $table = $METASERVER->{table};

         $table->clear;

         my @col = qw(Use #Users Host Uptime Version Description);
         $table->add ($_, 0, new CFClient::UI::Label align => 0, fg => [1, 1, 0], text => $col[$_])
            for 0 .. $#col;

         my @align = qw(1 0 1 1 -1);

         my $y = 0;
         for my $m (sort { $b->[3] <=> $a->[3] } map [split /\|/], split /\015?\012/, $buf) {
            my ($ip, $last, $host, $users, $version, $desc, $ibytes, $obytes, $uptime) = @$m;

            for ($desc) {
               s/<br>/\n/gi;
               s/<li>/\n· /gi;
               s/<.*?>//sgi;
               s/&/&amp;/g;
               s/</&lt;/g;
               s/>/&gt;/g;
            }

            $uptime = sprintf "%dd %02d:%02d:%02d",
               (int $m->[8] / 86400),
               (int $m->[8] / 3600) % 24,
               (int $m->[8] / 60) % 60,
               $m->[8] % 60;

            $m = [$users, $host, $uptime, $version, $desc];

            $y++;

            $table->add (0, $y, new CFClient::UI::VBox children => [
               (new CFClient::UI::Button text => " ", connect_activate => sub {
                  $HOST->set_text ($CFG->{host} = $host);
               }),
               (new CFClient::UI::Empty expand => 1),
            ]);
            
            $table->add ($_ + 1, $y, new CFClient::UI::Label align => $align[$_], text => $m->[$_], fontsize => 0.8)
               for 0 .. $#$m;
         }
      }
   });
}

sub server_setup {
   my $dialog = new CFClient::UI::FancyFrame
      child => (my $vbox = new CFClient::UI::VBox);
   
   $vbox->add (new CFClient::UI::Label valign => 0, align => 0, text => "Server Setup");
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);
   $table->add (0, 2, new CFClient::UI::Label valign => 0, align => 1, text => "Host:Port");

   {
      $table->add (1, 2, my $vbox = new CFClient::UI::VBox);

      $vbox->add (my $HOST = new CFClient::UI::Entry expand => 1, text => $CFG->{host}, connect_changed => sub {
         my ($self, $value) = @_;
         $CFG->{host} = $value;
      });

      $METASERVER = metaserver_dialog;

      $vbox->add (new CFClient::UI::Flopper expand => 1, text => "Metaserver", other => $METASERVER, connect_open => sub {
         update_metaserver $HOST;
      });
   }

   $table->add (0, 4, new CFClient::UI::Label valign => 0, align => 1, text => "Username");
   $table->add (1, 4, new CFClient::UI::Entry text => $CFG->{user}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{user} = $value;
   });

   $table->add (0, 5, new CFClient::UI::Label valign => 0, align => 1, text => "Password");
   $table->add (1, 5, new CFClient::UI::Entry text => $CFG->{password}, hidden => 1, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{password} = $value;
   });

   $table->add (0, 6, new CFClient::UI::Label valign => 0, align => 1, text => "Def. say cmd");
   $table->add (1, 6, my $saycmd = new CFClient::UI::Entry text => $CFG->{say_command}, connect_changed => sub {
      my ($self, $value) = @_;
      $CFG->{say_command} = $value;
   });

   $table->add (0, 7, new CFClient::UI::Label valign => 0, align => 1, text => "Map Size");
   $table->add (1, 7, new CFClient::UI::Slider
      req_w => 100,
      range => [$CFG->{mapsize}, 10, 100 + 1, 1],
      connect_changed => sub {
         my ($self, $value) = @_;

         $CFG->{mapsize} = $self->{range}[0] = $value = int $value;
      },
   );

   $table->add (1, 8, new CFClient::UI::Button expand => 1, align => 0, text => "Login", connect_activate => sub {
      start_game;
   });

   $dialog
}

sub message_window {
   my $window = new CFClient::UI::FancyFrame
      border_bg => [1, 1, 1, 0.5],
      bg        => [0.3, 0.3, 0.3, 0.8],
      user_w    => int $::WIDTH  / 3,
      user_h    => int $::HEIGHT / 5,
      child     => (my $vbox = new CFClient::UI::VBox);

   $vbox->add ($LOGVIEW = new CFClient::UI::TextView
      expand   => 1,
      fontsize => $::CFG->{log_fontsize},
   );

   $vbox->add (my $input = new CFClient::UI::Entry
      connect_focus_in => sub {
         my ($input, $prev_focus) = @_;

         delete $input->{refocus_map};

         if ($prev_focus == $MAPWIDGET && $input->{auto_activated}) {
            $input->{refocus_map} = 1;
         }
         delete $input->{auto_activated};
      },
      connect_activate => sub {
         my ($input, $text) = @_;
         $input->set_text ('');

         if ($text =~ /^\/(.*)/) {
            $::CONN->user_send ($1);
         } else {
            my $say_cmd = $::CFG->{say_command} || 'say';
            $::CONN->user_send ("$say_cmd $text");
         }
         if ($input->{refocus_map}) {
            delete $input->{refocus_map};
            $MAPWIDGET->focus_in
         }
      },
      connect_escape => sub {
         $MAPWIDGET->focus_in
      },
   );

   $CONSOLE = {
      window => $window,
      input => $input
   };

   $window
}

sub sdl_init {
   CFClient::SDL_Init
      and die "SDL::Init failed!\n";
}

sub video_init {
   sdl_init;

   ($WIDTH, $HEIGHT) = @{ $SDL_MODES[$CFG->{sdl_mode}] };
   $FULLSCREEN = $CFG->{fullscreen};
   $FAST       = $CFG->{fast};

   CFClient::SDL_SetVideoMode $WIDTH, $HEIGHT, $FULLSCREEN
      or die "SDL_SetVideoMode failed!\n";

   $SDL_EV = new SDL::Event;
   $SDL_EV->set_unicode (1);

   $SDL_ACTIVE = 1;

   $LAST_REFRESH = time - 0.01;

   CFClient::gl_init;

   $FONTSIZE = int $HEIGHT / 40 * $CFG->{gui_fontsize};

   #############################################################################

   $DEBUG_STATUS = new CFClient::UI::Label padding => 0, z => 100;
   $DEBUG_STATUS->show;
   
   $STATUS_LINE = new CFClient::UI::Label
                     padding => 0,
                     y => $HEIGHT - $FONTSIZE * 1.8;
   $STATUS_LINE->show;

   $ALT_ENTER_MESSAGE = new CFClient::UI::Label
                           padding  => 0,
                           fontsize => 0.8,
                           markup   => "Use <b>Alt-Enter</b> to toggle fullscreen mode";
   $ALT_ENTER_MESSAGE->show;
   $ALT_ENTER_MESSAGE->move (0, $HEIGHT - $ALT_ENTER_MESSAGE->{h});

   $CFClient::UI::ROOT->add ($MAPWIDGET = new CFClient::MapWidget);
   $MAPWIDGET->focus_in;
   $MAPWIDGET->connect (activate_console => sub {
      my ($mapwidget, $preset) = @_;

      if ($CONSOLE) {
         $CONSOLE->{input}->{auto_activated} = 1;
         $CONSOLE->{input}->focus_in;

         if ($preset && $CONSOLE->{input}->get_text eq '') {
            $CONSOLE->{input}->set_text ($preset);
         }
      }
   });

   $CFClient::UI::ROOT->add ($BUTTONBAR = new CFClient::UI::HBox);

   $BUTTONBAR->add (new CFClient::UI::Flopper text => "Client Setup",   other => client_setup);
   $BUTTONBAR->add (new CFClient::UI::Flopper text => "Server Setup",   other => server_setup);
   $BUTTONBAR->add (new CFClient::UI::Flopper text => "Message Window", other => message_window);

   $BUTTONBAR->add (new CFClient::UI::Button text => "Save Config", connect_activate => sub {
      CFClient::write_cfg "$Crossfire::VARDIR/pclientrc";
      status "Configuration Saved";
   });

   $BUTTONBAR->{children}[1]->emit ("activate"); # pop up server setup

   my $tgw = new CFClient::UI::FancyFrame (x => $WIDTH - 300, y => 0);
   $tgw->add (my $hbox = new CFClient::UI::HBox ());

   $hbox->add (my $hg = new CFClient::UI::VGauge (gauge => 'hp'));
   $hbox->add (my $mg = new CFClient::UI::VGauge (gauge => 'mana'));
   $hbox->add (my $gg = new CFClient::UI::VGauge (gauge => 'grace'));
   $hbox->add (my $fg = new CFClient::UI::VGauge (gauge => 'food'));

   $GAUGES = { food => $fg, mana => $mg, hp => $hg, grace => $gg };
   $CFClient::UI::ROOT->add ($tgw);
}

sub video_shutdown {
   $CFClient::UI::ROOT->{children} = [];
   undef $SDL_ACTIVE;
   undef $SDL_EV;
}

my $bgmusic;#TODO#hack#d#

sub audio_init {
   if ($CFG->{audio_enable}) {
      if (open my $fh, "<:utf8", CFClient::find_rcfile "sounds/config") {
         
         $SDL_MIXER = new SDL::Mixer
            -rate     => 22050,
            -channels => 1, # mono
            -size     => 512;

         $SDL_MIXER->allocate_channels (8);

         # TODO: hack, do play loop and mood music
         if ($CFG->{bgm_enable}) {
            $bgmusic = new SDL::Music CFClient::find_rcfile "music/game3.ogg";
            $SDL_MIXER->play_music ($bgmusic, -1);
            $SDL_MIXER->music_volume ($CFG->{bgm_volume});
         }

         while (<$fh>) {
            next if /^\s*#/;
            next if /^\s*$/;

            my ($file, $volume, $event) = split /\s+/, $_, 3;

            push @SOUNDS, "$volume,$file";

            $AUDIO_CHUNKS{"$volume,$file"} ||= do {
               my $chunk = new SDL::Sound CFClient::find_rcfile "sounds/$file";
               $chunk->volume ($volume * 128 / 100);
               $chunk
            };
         }
      } else {
         status "unable to open sound config: $!";
      }
   }
}

sub audio_shutdown {
   undef $SDL_MIXER;
   @SOUNDS = ();
   %AUDIO_CHUNKS = ();
}

my %animate_object;
my $animate_timer;

my $want_refresh;
my $can_refresh;

my $fps = 9;

sub force_refresh {
   $fps = $fps * 0.95 + 1 / ($NOW - $LAST_REFRESH) * 0.05;
   debug sprintf "%3.2f", $fps;

   $want_refresh = 0;
   $can_refresh = 0;

   $CFClient::UI::ROOT->draw;

   SDL::GLSwapBuffers;

   $LAST_REFRESH = $NOW;
}

my $refresh_watcher = Event->timer (after => 0, hard => 1, interval => 1 / $MAX_FPS, cb => sub {
   $NOW = time;

   ($SDL_CB{$SDL_EV->type} || sub { warn "unhandled event ", $SDL_EV->type })->()
      while $SDL_EV->poll;

   if (%animate_object) {
      $_->animate ($LAST_REFRESH - $NOW) for values %animate_object;
      $want_refresh++;
   }

   if ($want_refresh) {
      force_refresh;
   } else {
      $can_refresh = 1;
   }
});

sub refresh {
   $want_refresh++;
}

sub animation_start {
   my ($widget) = @_;
   $animate_object{$widget} = $widget;
}

sub animation_stop {
   my ($widget) = @_;
   delete $animate_object{$widget};
}

@conn::ISA = Crossfire::Protocol::;

sub conn::stats_update {
   my ($self, $stats) = @_;

   # i love text protocols!!!
   # FIXME: the stats are somehow weird
   my $hp   = $stats->{1};
   my $hp_m = $stats->{2};
   my $sp   = $stats->{3};
   my $sp_m = $stats->{4};
   my $fo   = $stats->{18};
   my $fo_m = 1000;
   my $gr   = $stats->{23};
   my $gr_m = $stats->{24};

   #d# warn "DATA $hp $hp_m $sp $sp_m $fo $fo_m $gr $gr_m\n";
   $GAUGES->{hp}->set_value ($hp, $hp_m);
   $GAUGES->{mana}->set_value ($sp, $sp_m);
   $GAUGES->{food}->set_value ($fo, $fo_m);
   $GAUGES->{grace}->set_value ($gr, $gr_m);
}

sub conn::user_send {
   my ($self, $command) = @_;

   $self->send_command ($command);
   status $command;
}

sub conn::map_scroll {
   my ($self, $dx, $dy) = @_;

   $MAP->scroll ($dx, $dy);
}

sub conn::feed_map1a {
   my ($self, $data) = @_;

#   $self->Crossfire::Protocol::feed_map1a ($data);

   $MAP->map1a_update ($data);
   $MAPWIDGET->update;
}

sub conn::flush_map {
   my ($self) = @_;

   my $map_info = delete $self->{map_info}
      or return;

   my ($hash, $x, $y, $w, $h) = @$map_info;

   my $data = $MAP->get_rect ($x, $y, $w, $h);
   $MAPCACHE->put ($hash => Compress::LZF::compress $data);

   warn sprintf "SAVEmap[%s] length %d\n", $hash, length $data;#d#
   
}

sub conn::map_clear {
   my ($self) = @_;

   $self->flush_map;
   delete $self->{neigh};

   $MAP->clear;
}


sub conn::load_map($$$) {
   my ($self, $hash, $x, $y) = @_;

   if (defined (my $data = $MAPCACHE->get ($hash))) {
      $data = Compress::LZF::decompress $data;
      warn sprintf "LOADmap[%s,%d,%d] length %d\n", $hash, $x, $y, length $data;#d#
      for my $id ($MAP->set_rect ($x, $y, $data)) {
         my $data = $TILECACHE->get ($id)
            or next;

         $self->set_texture ($id => $data);
      }
   }
}

sub conn::flood_fill {
   my ($self, $path, $hash, $flags, $x0, $y0, $x1, $y1) = @_;

   # the server does not allow map paths > 6
   return if 6 <= length $path;

   for my $tile (1..4) {
      next if $self->{neigh}{$hash}[$tile];
      next unless $flags & (1 << ($tile - 1));

      my $neigh = $self->{neigh}{$hash} ||= [];

      $self->send_mapinfo ("spatial $path$tile", sub {
         my ($mode, $flags, $x, $y, $w, $h, $hash) = @_;

         #warn "map<$path>_$tile=<$mode,$x,$y,$w,$h,$hash>\n";#d#
         return if $mode ne "spatial";

         $x += $MAP->ox;
         $y += $MAP->oy;
         
         $self->load_map ($hash, $x, $y)
            unless $self->{neigh}{$hash}[5]++;#d#

         $neigh->[$tile] = [$x, $y, $w, $h];

         $self->flood_fill ("$path$tile", $hash, $flags, $x0, $y0, $x1, $y1)
            if $x >= $x0 && $x + $w < $x1 && $y >= $y0  && $y + $h < $y1;
      });
   }
}

sub conn::map_change {
   my ($self, $mode, $flags, $x, $y, $w, $h, $hash) = @_;

   $self->flush_map;

   my ($ox, $oy) = ($::MAP->ox, $::MAP->oy);

   my $mapmapw = 250;
   my $mapmaph = 250;
   
   $self->flood_fill ("", $hash, $flags,
                      $ox - $mapmapw * 0.5, $oy - $mapmapw * 0.5,
                      $ox + $mapmapw * 0.5, $oy + $mapmapw * 0.5);

   $x += $ox;
   $y += $oy;

   $self->{map_info} = [$hash, $x, $y, $w, $h];

   $self->load_map ($hash, $x, $y);
}

sub conn::face_find {
   my ($self, $facenum, $face) = @_;

   my $hash = "$face->{chksum},$face->{name}";

   my $id = $FACEMAP->get ($hash);

   unless ($id) {
      # create new id for face
      # i love transactions
      for (1..100) {
         my $txn = $CFClient::DB_ENV->txn_begin;
         my $status = $FACEMAP->db_get (id => $id, BerkeleyDB::DB_RMW);
         if ($status == 0 || $status == BerkeleyDB::DB_NOTFOUND) {
            $id++;
            if ($FACEMAP->put (id => $id) == 0
                && $FACEMAP->put ($hash => $id) == 0) {
               $txn->txn_commit;

               goto gotid;
            }
         }
         $txn->abort;
      }

      CFClient::fatal "maximum number of transaction retries reached - database problems?";
   }

gotid:
   $face->{id} = $id;
   $MAP->set_face ($facenum => $id);
   $TILECACHE->get ($id)
}

sub conn::face_update {
   my ($self, $facenum, $face) = @_;

   $TILECACHE->put ($face->{id} => $face->{image}); #TODO: try to avoid duplicate writes

   $self->set_texture ($face->{id} => delete $face->{image});
}

sub conn::set_texture {
   my ($self, $id, $data) = @_;

   $self->{texture}[$id] ||= do {
      my $tex =
         new_from_image CFClient::Texture
            $data, minify => 1;

      $MAP->set_texture ($id, @$tex{qw(name w h s t)}, @{$tex->{minified}});
      $MAPWIDGET->update;

      $tex
   };
}

sub conn::sound_play {
   my ($self, $x, $y, $soundnum, $type) = @_;

   $SDL_MIXER
      or return;

   my $chunk = $AUDIO_CHUNKS{$SOUNDS[$soundnum]}
      or return;

   $SDL_MIXER->play_channel (-1, $chunk);
#   warn "sound $x,$y,$soundnum,$type\n";#d#
}

sub conn::query {
   my ($self, $flags, $prompt) = @_;

   #TODO, display dialog with relevant information
   warn "<<<<QUERY:$flags:$prompt>>>\n";#d#
}

sub conn::drawinfo {
   my ($self, $color, $text) = @_;

   my @color = (
      [1.00, 1.00, 1.00], #[0.00, 0.00, 0.00],
      [1.00, 1.00, 1.00],
      [0.50, 0.50, 1.00], #[0.00, 0.00, 0.55]
      [1.00, 0.00, 0.00],
      [1.00, 0.54, 0.00],
      [0.11, 0.56, 1.00],
      [0.93, 0.46, 0.00],
      [0.18, 0.54, 0.34],
      [0.56, 0.73, 0.56],
      [0.80, 0.80, 0.80],
      [0.55, 0.41, 0.13],
      [0.99, 0.77, 0.26],
      [0.74, 0.65, 0.41],
   );

   $LOGVIEW->add_paragraph ($color[$color], $text);
}

sub conn::spell_add {
   my ($self, $spell) = @_;

   $MAPWIDGET->add_command ("invoke $spell->{name}", $spell->{message}, sub {
   });
   $MAPWIDGET->add_command ("cast $spell->{name}", $spell->{message}, sub {
   });
}

sub conn::spell_delete {
   my ($self, $spell) = @_;
}

sub conn::addme_success {
   my ($self) = @_;

   for my $skill (values %{$self->{skill_info}}) {
      $MAPWIDGET->add_command ("ready_skill $skill", "", sub {
      });
      $MAPWIDGET->add_command ("use_skill $skill", "", sub {
      });
   }
}

%SDL_CB = (
   CFClient::SDL_QUIT => sub {
      Event::unloop -1;
   },
   CFClient::SDL_VIDEORESIZE => sub {
   },
   CFClient::SDL_VIDEOEXPOSE => sub {
      refresh;
   },
   CFClient::SDL_KEYDOWN => sub {
      if ($SDL_EV->key_mod & CFClient::KMOD_ALT && $SDL_EV->key_sym == 13) {
         # alt-enter
         video_shutdown;
         $CFG->{fullscreen} = !$CFG->{fullscreen};
         video_init;
      } else {
         CFClient::UI::feed_sdl_key_down_event ($SDL_EV);
      }
   },
   CFClient::SDL_KEYUP => sub {
      CFClient::UI::feed_sdl_key_up_event ($SDL_EV);
   },
   CFClient::SDL_MOUSEMOTION => sub {
      CFClient::UI::feed_sdl_motion_event ($SDL_EV);
   },
   CFClient::SDL_MOUSEBUTTONDOWN => sub {
      CFClient::UI::feed_sdl_button_down_event ($SDL_EV);
   },
   CFClient::SDL_MOUSEBUTTONUP => sub {
      CFClient::UI::feed_sdl_button_up_event ($SDL_EV);
   },
   CFClient::SDL_ACTIVEEVENT => sub {
#      printf "active %x %x\n", $SDL_EV->active_gain, $SDL_EV->active_state;#d#
   },
);

#############################################################################

$SIG{INT} = $SIG{TERM} = sub { exit };

$TILECACHE = CFClient::db_table "tilecache";
$FACEMAP   = CFClient::db_table "facemap";

CFClient::read_cfg "$Crossfire::VARDIR/pclientrc";

my %DEF_CFG = (
   sdl_mode      => 0,
   width         => 640,
   height        => 480,
   fullscreen    => 0,
   fast          => 0,
   fow_enable    => 1,
   fow_intensity => 0.45,
   fow_smooth    => 0,
   gui_fontsize  => 1,
   log_fontsize  => 14,
   mapsize       => 100,
   host          => "crossfire.schmorp.de",
   say_command   => 'say',
   audio_enable  => 1,
   bgm_enable    => 1,
   bgm_volume    => 64,
);

while (my ($k, $v) = each %DEF_CFG) {
   $CFG->{$k} = $v unless exists $CFG->{$k};
}

sdl_init;

@SDL_MODES = reverse
                grep $_->[0] >= 640 && $_->[1] >= 480,
                   CFClient::SDL_ListModes;

@SDL_MODES or CFClient::fatal "Unable to find a usable video mode\n(hardware accelerated opengl fullscreen)";

$CFG->{sdl_mode} = 0 if $CFG->{sdl_mode} > @SDL_MODES;

{
   my @fonts = map CFClient::find_rcfile $_, qw(uifont.ttf uifontb.ttf uifonti.ttf uifontbi.ttf);

   CFClient::add_font $_ for @fonts;
   CFClient::set_font $fonts[0];
}

video_init;
audio_init;

Event::loop;

END { SDL::Quit }


Revision:	1.145
Committed:	Wed Apr 19 20:46:45 2006 UTC (18 years, 1 month ago) by root
Branch:	MAIN
Changes since 1.144:	+14 -37 lines
Log Message:	got rid of base SDL perl module