#!/opt/bin/perl

use strict;
use utf8;

use Glib;
use Gtk2 -init;

use SDL;
use SDL::App;
use SDL::Event;
use SDL::Surface;
use SDL::OpenGL;
use SDL::OpenGL::Constants;

use Crossfire;
use Crossfire::Client;
use Crossfire::Protocol;

use Crossfire::Client::Util;
use Crossfire::Client::Widget;

our $FACECACHE;

our $VERSION = '0.1';

our %GL_EXT;

our $CFG;
our $CONN;

our $WIDTH;
our $HEIGHT;
our $FULLSCREEN;

our $UIFONT;

our $SDL_TIMER;
our $SDL_APP;
our $SDL_EV = new SDL::Event;
our %SDL_CB;

our @GL_INIT; # hooks called on every gl init

our $ALT_ENTER_MESSAGE;

sub init_screen {
   $SDL_APP = new SDL::App
      -flags         => SDL_ANYFORMAT | SDL_HWSURFACE,
      -title         => "Crossfire+ Client",
      -width         => $WIDTH,
      -height        => $HEIGHT,
      -opengl        => 1,
      -red_size      => 8,
      -green_size    => 8,
      -blue_size     => 8,
      -double_buffer => 1,
      -fullscreen    => $FULLSCREEN,
      -resizeable    => 0;

   %GL_EXT = map +($_ => 1), split /\s+/, Crossfire::Client::gl_extensions;

   $GL_EXT{GL_ARB_texture_non_power_of_two}
      or warn "WARNING: non-power-of-two opengl extension required";

   $UIFONT = SDL::TTFOpenFont Crossfire::Client::find_rcfile "uifont.ttf", $HEIGHT / 40
      or die "TTFOpenFont: $!";

   $ALT_ENTER_MESSAGE = new Crossfire::Client::Widget::Label 0, $HEIGHT - $HEIGHT / 40, 10, $UIFONT, "Alt-Enter toggles fullscreen mode";
   $ALT_ENTER_MESSAGE->move (0, $HEIGHT - ($ALT_ENTER_MESSAGE->size_request)[1]);
   $ALT_ENTER_MESSAGE->activate;

   glClearColor 0, 0, 0, 0;

   glEnable GL_TEXTURE_2D;
   glShadeModel GL_FLAT;
   glDisable GL_DEPTH_TEST;
   glBlendFunc GL_SRC_ALPHA, GL_ONE_MINUS_SRC_ALPHA;

   glMatrixMode GL_PROJECTION;
   glLoadIdentity;
   glOrtho 0, $WIDTH, $HEIGHT, 0, -100 , 100;

   glMatrixMode GL_MODELVIEW;

   $_->() for @GL_INIT;
}

sub start_game {
   $SDL_TIMER = add Glib::Timeout 1000/100, sub {
      ($SDL_CB{$SDL_EV->type} || sub { warn "unhandled event ", $SDL_EV->type })->()
         while $SDL_EV->poll;

      1
   };

   $WIDTH      = $CFG->{width};
   $HEIGHT     = $CFG->{height};
   $FULLSCREEN = 0;

   init_screen;

   $CONN = new conn
      host => $CFG->{host},
      port => $CFG->{port},
      user => $CFG->{user},
      pass => $CFG->{password};
}

sub stop_game {
   remove Glib::Source $SDL_TIMER;

   undef $SDL_APP;
   SDL::Quit;
}


sub force_refresh {
   glViewport 0, 0, $WIDTH, $HEIGHT;
   glClear GL_COLOR_BUFFER_BIT;

   $_->draw for @Crossfire::Client::Widget::ACTIVE_WIDGETS;

   SDL::GLSwapBuffers;
}

my $refresh_handler;

sub refresh {
   $refresh_handler ||= add Glib::Idle sub {
      force_refresh;
      undef $refresh_handler;
      0
   };
}

%SDL_CB = (
   SDL_QUIT() => sub {
      main_quit Gtk2;
   },
   SDL_VIDEORESIZE() => sub {
   },
   SDL_VIDEOEXPOSE() => sub {
      refresh;
   },
   SDL_KEYDOWN() => sub {
      if ($SDL_EV->key_mod & KMOD_ALT && $SDL_EV->key_sym == SDLK_RETURN) {
         # alt-enter
         $FULLSCREEN = !$FULLSCREEN;
         init_screen;
      } else {
         Crossfire::Client::Widget::feed_sdl_key_down_event ($SDL_EV);
      }
   },
   SDL_KEYUP() => sub {
      Crossfire::Client::Widget::feed_sdl_key_up_event ($SDL_EV);
   },
   SDL_MOUSEMOTION() => sub {
      warn "sdl motion\n";#d#
   },
   SDL_MOUSEBUTTONDOWN() => sub {
      Crossfire::Client::Widget::feed_sdl_button_down_event ($SDL_EV);
   },
   SDL_MOUSEBUTTONUP() => sub {
      Crossfire::Client::Widget::feed_sdl_button_up_event ($SDL_EV);
   },
   SDL_ACTIVEEVENT() => sub {
      warn "active\n";#d#
   },
);

@conn::ISA = Crossfire::Protocol::;

sub conn::map_update {
   my ($self, $dirty) = @_;

   refresh;
}

sub conn::map_scroll {
   my ($self, $dx, $dy) = @_;

   refresh;
}

sub conn::map_clear {
   my ($self) = @_;

   refresh;
}

sub conn::face_find {
   my ($self, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"}
}

sub conn::face_update {
   my ($self, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"} = $face->{image};

   $face->{texture} = new_from_image Crossfire::Client::Texture delete $face->{image};
}

sub gtk_add_cfg_field {
   my ($tbl, $cfg, $klbl, $key, $value) = @_;
   my $i = $cfg->{_i}++;
   $tbl->attach_defaults (my $lbl = Gtk2::Label->new ($klbl), 0, 1, $i, $i + 1);
   $tbl->attach_defaults (my $ent = Gtk2::Entry->new,         1, 2, $i, $i + 1);
      if ($key eq 'password') {
         $ent->set_invisible_char ("*");
         $ent->set (visibility => 0)
      }
      $ent->set_text ($value);
      $ent->signal_connect (changed => sub {
         my ($ent) = @_;
         $cfg->{$key} = $ent->get_text;
      });
}

sub run_config_dialog {
   my (%events) = @_;

   my $w = Gtk2::Window->new;

   my @cfg = (
      [qw/Host     host/],
      [qw/Port     port/],
      [qw/Username user/],
      [qw/Password password/],
   );

   my $cfg = {};

   my $a = SDL::ListModes (0, SDL_FULLSCREEN|SDL_HWSURFACE);
   my @modes = map { [SDL::RectW ($_), SDL::RectH ($_)] } @$a;

   $w->add (my $vb = Gtk2::VBox->new);
      $vb->pack_start (my $t = Gtk2::Table->new (2, scalar @cfg), 0, 0, 0);
         my $selmode = $::CFG->{width} . 'x' . $::CFG->{height};
         $t->attach_defaults (Gtk2::Label->new ("Modes"), 0, 1, 0, 1);
         $t->attach_defaults (my $cb = Gtk2::ComboBox->new_text, 1, 2, 0, 1);
            my $i = 0;
            my $act = 0;
            for (map { "$_->[0]x$_->[1]" } reverse @modes) {
               if ($_ eq $selmode) { $act = $i }
               $cb->append_text ($_);
               $i++;
            }
            $cb->set_active ($act);
            $cb->signal_connect (changed => sub {
               my ($cb) = @_;
               my $txt = $cb->get_active_text;
               if ($txt =~ m/(\d+)x(\d+)/) {
                  $::CFG->{width} = $1;
                  $::CFG->{height} = $2;
               }
            });

         $cfg->{_i} = 1;
         for (@cfg) {
            gtk_add_cfg_field ($t, $cfg, $_->[0], $_->[1], $::CFG->{$_->[1]});
         }

      $vb->pack_start (my $hb = Gtk2::HBox->new, 0, 0, 0);
         $hb->pack_start (my $cb = Gtk2::Button->new ("save"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               for (keys %$cfg) {
                  $::CFG->{$_} = $cfg->{$_}
                     if $_ ne '_i';
               }
               Crossfire::Client::write_cfg "$Crossfire::VARDIR/pclientrc";
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("login"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               for (keys %$cfg) {
                  $::CFG->{$_} = $cfg->{$_}
                     if $_ ne '_i';
               }
               my $cb = $events{login} || sub {};
               $cb->($::CFG->{user}, $::CFG->{password});
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("logout"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               my $cb = $events{login} || sub {};
               $cb->();
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("quit"), 1, 1, 5);
            $cb->signal_connect (clicked => sub { $w->destroy });

   $w->show_all;

   $w->signal_connect (destroy => sub { Gtk2->main_quit });
}


#############################################################################

SDL::Init SDL_INIT_EVERYTHING;
SDL::TTFInit;

my $mapwidget = Crossfire::Client::Widget::MapWidget->new;

$mapwidget->activate;
$mapwidget->focus_in;

Crossfire::Client::read_cfg "$Crossfire::VARDIR/pclientrc";

$CFG ||= {
   width      => 640,
   height     => 480,
   fullscreen => 0,
   host       => "crossfire.schmorp.de",
   port       => 13327,
};

$FACECACHE = eval { Crossfire::load_ref "$Crossfire::VARDIR/pclient.faces" } || {};

run_config_dialog
   login  => sub { start_game  },
   logout => sub { stop_game };

main Gtk2;

Crossfire::save_ref $FACECACHE, "$Crossfire::VARDIR/pclient.faces";