#!/opt/bin/perl

use strict;
use utf8;

use Glib;
use Gtk2 -init;

use SDL;
use SDL::App;
use SDL::Event;
use SDL::Surface;
use SDL::OpenGL;
use SDL::OpenGL::Constants;

use Crossfire;
use Crossfire::Protocol;

use CFClient;
use CFClient::UI;

our $VERSION = '0.1';

my $MAX_FPS = 60;
my $TICKS_PER_FRAME = int 1000 / $MAX_FPS - 1; # min ticks per frame

our $FACECACHE;

our $CFG;
our $CONN;
our $FAST; # fast, low-quality mode

our @SDL_MODES;
our $WIDTH;
our $HEIGHT;
our $FULLSCREEN;

our $NOW;

our $MAPWIDGET;
our $FONTSIZE;

our $SDL_TIMER;
our $SDL_APP;
our $SDL_EV;
our %SDL_CB;

our $ALT_ENTER_MESSAGE;
our $STATUS_LINE;
our $DEBUG_STATUS;

my $last_refresh;
my %ANIMATE;
my $refresh_handler;

our ($tw, $te); # Test widget #d#

sub init_screen {
   $SDL_APP = new SDL::App
      -flags         => SDL_ANYFORMAT | SDL_HWSURFACE,
      -title         => "Crossfire+ Client",
      -width         => $WIDTH,
      -height        => $HEIGHT,
      -opengl        => 1,
      -red_size      => 5,
      -green_size    => 5,
      -blue_size     => 5,
      -alpha_size    => 0,
      -double_buffer => 1,
      -fullscreen    => $FULLSCREEN,
      -resizeable    => 0;

   $SDL_EV = new SDL::Event;
   $SDL_EV->set_unicode (1);

   $SDL_TIMER = add Glib::Timeout 1000 / $MAX_FPS, sub {
      ($SDL_CB{$SDL_EV->type} || sub { warn "unhandled event ", $SDL_EV->type })->()
         while $SDL_EV->poll;

      1
   };

   $last_refresh = SDL::GetTicks;

   CFClient::gl_init;

   $FONTSIZE = int $HEIGHT / 40;

   #############################################################################

   $DEBUG_STATUS = new CFClient::UI::Label padding => 0;
   $CFClient::UI::TOPLEVEL->add ($DEBUG_STATUS);
   
   $STATUS_LINE = new CFClient::UI::Label
                     padding => 0,
                     y => $HEIGHT * 49 / 50 - $FONTSIZE;
   $CFClient::UI::TOPLEVEL->add ($STATUS_LINE);

   $ALT_ENTER_MESSAGE = new CFClient::UI::Label
                           padding => 0,
                           y => $HEIGHT * 49 / 50,
                           height => $HEIGHT / 50,
                           text => "Use <b>Alt-Enter</b> to toggle fullscreen mode";
   $CFClient::UI::TOPLEVEL->add ($ALT_ENTER_MESSAGE);

   $MAPWIDGET = new CFClient::UI::MapWidget;
   $CFClient::UI::TOPLEVEL->add ($MAPWIDGET);
   $MAPWIDGET->focus_in;
}

sub destroy_screen {
   remove Glib::Source $SDL_TIMER;
   undef $SDL_APP;
   undef $SDL_EV;
   SDL::Quit;
}

sub config_dialog {
   my $dialog = new CFClient::UI::FancyFrame x => 300, y => 100,
      child => (my $vbox = new CFClient::UI::VBox);
   $vbox->add (new CFClient::UI::Label align => 0, text => "Setup");
   $vbox->add (my $table = new CFClient::UI::Table expand => 1, col_expand => [0, 1]);

   $table->add (0, 0, new CFClient::UI::Label align => 1, text => "Video Mode");
   $table->add (1, 0, my $hbox = new CFClient::UI::HBox);

   $hbox->add (my $mode_slider = new CFClient::UI::Slider expand => 1, req_w => 100, range => [$CFG->{sdl_mode}, 0, scalar @SDL_MODES, 1]);
   $hbox->add (my $mode_label = new CFClient::UI::Label height => $FONTSIZE * 0.8);

   $mode_slider->connect (changed => sub {
      my ($self, $value) = @_;

      $CFG->{sdl_mode} = $self->{range}[0] = $value = int $value;
      $mode_label->set_text (sprintf "%dx%d", @{$SDL_MODES[$value]});
   });
   $mode_slider->emit (changed => $mode_slider->{range}[0]);
   
   $table->add (0, 1, new CFClient::UI::Label align => 1, text => "Host");
   $table->add (1, 1, my $host = new CFClient::UI::Entry text => $CFG->{host});
   
   $table->add (0, 2, new CFClient::UI::Label align => 1, text => "Port");
   $table->add (1, 2, my $port = new CFClient::UI::Entry text => $CFG->{port});

   $table->add (0, 3, new CFClient::UI::Label align => 1, text => "Username");
   $table->add (1, 3, my $user = new CFClient::UI::Entry text => $CFG->{user});

   $table->add (0, 4, new CFClient::UI::Label align => 1, text => "Password");
   $table->add (1, 4, my $pass = new CFClient::UI::Entry text => $CFG->{password}, hidden => 1);

   $table->add (0, 5, new CFClient::UI::Label align => 1, text => "Map Size");
   $table->add (1, 5, new CFClient::UI::Slider
      req_w => 100,
      range => [$CFG->{mapsize}, 10, 100 + 1, 1],
      connect_changed => sub {
         my ($self, $value) = @_;

         $CFG->{mapsize} = $self->{range}[0] = $value = int $value;
      },
   );

   $vbox->add (my $hbox = new CFClient::UI::HBox);
   $hbox->add (new CFClient::UI::Button expand => 1, align => 0, text => "Save", connect_activate => sub {
      warn "save\n";
   });
   $hbox->add (new CFClient::UI::Button expand => 1, align => 0, text => "Login", connect_activate => sub {
      warn "login\n";
   });
   $hbox->add (new CFClient::UI::Button expand => 1, align => 0, text => "Apply", connect_activate => sub {
      warn "apply\n";
   });

   $CFClient::UI::TOPLEVEL->add ($dialog);
}

sub start_game {
   $WIDTH      = $CFG->{width};
   $HEIGHT     = $CFG->{height};
   $FULLSCREEN = 0;

   init_screen;

   config_dialog;

   my $mapsize = List::Util::min 64, List::Util::max 11, int $WIDTH * $CFG->{mapsize} * 0.01 / 32;

   $CONN = new conn
      host => $CFG->{host},
      port => $CFG->{port},
      user => $CFG->{user},
      pass => $CFG->{password},
      mapw => $mapsize,
      maph => $mapsize,
   ;

   CFClient::lowdelay fileno $CONN->{fh};
}

sub stop_game {
   remove Glib::Source $refresh_handler if $refresh_handler;
   undef $refresh_handler;

   undef $CONN;
   destroy_screen;
}

sub force_refresh {
   glViewport 0, 0, $WIDTH, $HEIGHT;

   glMatrixMode GL_PROJECTION;
   glLoadIdentity;
   glOrtho 0, $WIDTH, $HEIGHT, 0, -10000 , 10000;
   glMatrixMode GL_MODELVIEW;
   glLoadIdentity;

   glClear GL_COLOR_BUFFER_BIT;

   $CFClient::UI::TOPLEVEL->draw;

   SDL::GLSwapBuffers;
}

sub debug {
   $DEBUG_STATUS->set_text ($_[0]);
   my ($w, $h) = $DEBUG_STATUS->size_request;
   $DEBUG_STATUS->size_allocate ($WIDTH - $w, 0, $w, $h);
}

my $FPS;

sub refresh {
   $refresh_handler ||= add Glib::Idle sub {
      if ($SDL_APP) {
         $NOW = SDL::GetTicks;

         if ($NOW - $last_refresh < $TICKS_PER_FRAME) {
            SDL::Delay $TICKS_PER_FRAME - ($NOW - $last_refresh);
            $NOW = SDL::GetTicks;
         }
         
         my $interval = ($NOW - $last_refresh) * 0.001;
         $last_refresh = $NOW;

         if ($interval) {
            $FPS ||= 1 / $interval;
            $FPS = $FPS * 0.9 + (1 / $interval) * 0.1;
            debug sprintf "%5.02f", $FPS;
         }

         force_refresh;
         $_->animate ($interval) for grep $_, values %ANIMATE;

         if (%ANIMATE) {
            1
         } else {
            undef $refresh_handler;
            0
         }
      } else {
         undef $refresh_handler;
         0
      }
   };
}

sub animation_start {
   my ($widget) = @_;
   $ANIMATE{$widget} = $widget;
   Scalar::Util::weaken $ANIMATE{$widget};

   refresh;
}

sub animation_stop {
   my ($widget) = @_;
   delete $ANIMATE{$widget};
}

%SDL_CB = (
   SDL_QUIT() => sub {
      main_quit Gtk2;
   },
   SDL_VIDEORESIZE() => sub {
   },
   SDL_VIDEOEXPOSE() => sub {
      refresh;
   },
   SDL_KEYDOWN() => sub {
      if ($SDL_EV->key_mod & KMOD_ALT && $SDL_EV->key_sym == SDLK_RETURN) {
         # alt-enter
         $FULLSCREEN = !$FULLSCREEN;
         init_screen;
      } else {
         CFClient::UI::feed_sdl_key_down_event ($SDL_EV);
      }
   },
   SDL_KEYUP() => sub {
      CFClient::UI::feed_sdl_key_up_event ($SDL_EV);
   },
   SDL_MOUSEMOTION() => sub {
      CFClient::UI::feed_sdl_motion_event ($SDL_EV);
   },
   SDL_MOUSEBUTTONDOWN() => sub {
      CFClient::UI::feed_sdl_button_down_event ($SDL_EV);
   },
   SDL_MOUSEBUTTONUP() => sub {
      CFClient::UI::feed_sdl_button_up_event ($SDL_EV);
   },
   SDL_ACTIVEEVENT() => sub {
#      printf "active %x %x\n", $SDL_EV->active_gain, $SDL_EV->active_state;#d#
   },
);

@conn::ISA = Crossfire::Protocol::;

sub conn::map_update {
   my ($self, $dirty) = @_;

   $MAPWIDGET->update;
}

sub conn::map_scroll {
   my ($self, $dx, $dy) = @_;

#   refresh;
}

sub conn::map_clear {
   my ($self) = @_;

#   refresh;
}

sub conn::face_find {
   my ($self, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"}
}

sub conn::face_update {
   my ($self, $face) = @_;

   $FACECACHE->{"$face->{chksum},$face->{name}"} = $face->{image};

   $face->{texture} = new_from_image CFClient::Texture delete $face->{image};
}

sub conn::query {
   my ($self, $flags, $prompt) = @_;

   warn "<<<<QUERY:$flags:$prompt>>>\n";#d#
}

sub gtk_add_cfg_field {
   my ($tbl, $cfg, $klbl, $key, $value) = @_;
   my $i = $cfg->{_i}++;
   $tbl->attach_defaults (my $lbl = Gtk2::Label->new ($klbl), 0, 1, $i, $i + 1);
   $tbl->attach_defaults (my $ent = Gtk2::Entry->new,         1, 2, $i, $i + 1);
      if ($key eq 'password') {
         $ent->set_invisible_char ("*");
         $ent->set (visibility => 0)
      }
      $ent->set_text ($value);
      $ent->signal_connect (changed => sub {
         my ($ent) = @_;
         $cfg->{$key} = $ent->get_text;
         # TODO: Mapsize should be a slider in the game gui
         if ($key eq 'mapsize' and $cfg->{$key} > 100) {
            $cfg->{$key} = 100;
         } elsif ($key eq 'mapsize' and $cfg->{$key} < 50) {
            $cfg->{$key} = 50;
         }
      });
}

sub run_config_dialog {
   my (%events) = @_;

   my $w = Gtk2::Window->new;

   my @cfg = (
      [qw/Host     host/],
      [qw/Port     port/],
      [qw/Mapsize% mapsize/],
      [qw/Username user/],
      [qw/Password password/],
   );

   my $cfg = {};

   $w->add (my $vb = Gtk2::VBox->new);
      $vb->pack_start (my $t = Gtk2::Table->new (2, scalar @cfg), 0, 0, 0);
         my $selmode = $::CFG->{width} . 'x' . $::CFG->{height};
         $t->attach_defaults (Gtk2::Label->new ("Modes"), 0, 1, 0, 1);
         $t->attach_defaults (my $cb = Gtk2::ComboBox->new_text, 1, 2, 0, 1);
            my $i = 0;
            my $act = 0;
            for (map { "$_->[0]x$_->[1]" } @SDL_MODES) {
               if ($_ eq $selmode) { $act = $i }
               $cb->append_text ($_);
               $i++;
            }
            $cb->set_active ($act);
            $cb->signal_connect (changed => sub {
               my ($cb) = @_;
               my $txt = $cb->get_active_text;
               if ($txt =~ m/(\d+)x(\d+)/) {
                  $::CFG->{width} = $1;
                  $::CFG->{height} = $2;
               }
            });

         $cfg->{_i} = 1;
         for (@cfg) {
            gtk_add_cfg_field ($t, $cfg, $_->[0], $_->[1], $::CFG->{$_->[1]});
         }

      $vb->pack_start (my $hb = Gtk2::HBox->new, 0, 0, 0);
         $hb->pack_start (my $cb = Gtk2::Button->new ("save"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               for (keys %$cfg) {
                  $::CFG->{$_} = $cfg->{$_}
                     if $_ ne '_i';
               }
               CFClient::write_cfg "$CFrossfire::VARDIR/pclientrc";
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("login"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               for (keys %$cfg) {
                  $::CFG->{$_} = $cfg->{$_}
                     if $_ ne '_i';
               }
               my $cb = $events{login} || sub {};
               $cb->($::CFG->{user}, $::CFG->{password});
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("logout"), 1, 1, 5);
            $cb->signal_connect (clicked => sub {
               my $cb = $events{logout} || sub {};
               $cb->();
            });
         $hb->pack_start (my $cb = Gtk2::Button->new ("quit"), 1, 1, 5);
            $cb->signal_connect (clicked => sub { $w->destroy });

   $w->show_all;

   $w->signal_connect (destroy => sub { Gtk2->main_quit });
}


#############################################################################

SDL::Init SDL_INIT_EVERYTHING;

@SDL_MODES = reverse map [SDL::RectW ($_), SDL::RectH ($_)],
                @{ SDL::ListModes 0, SDL_FULLSCREEN|SDL_HWSURFACE };

CFClient::read_cfg "$Crossfire::VARDIR/pclientrc";

$CFG ||= {
   width      => 640,
   height     => 480,
   mapsize    => 100,
   fullscreen => 0,
   host       => "crossfire.schmorp.de",
   port       => 13327,
};

{
   my @fonts = map CFClient::find_rcfile $_, qw(uifont.ttf uifontb.ttf uifonti.ttf uifontbi.ttf);

   CFClient::add_font $_ for @fonts;
   CFClient::set_font $fonts[0];
}

$FACECACHE = eval { Crossfire::load_ref "$Crossfire::VARDIR/pclient.faces" } || {};

run_config_dialog
   login  => sub { start_game  },
   logout => sub { stop_game };

main Gtk2;

Crossfire::save_ref $FACECACHE, "$Crossfire::VARDIR/pclient.faces";