| 1 |
=head1 NAME |
| 2 |
|
| 3 |
Deliantra - Deliantra suppport module to read/write archetypes, maps etc. |
| 4 |
|
| 5 |
=over 4 |
| 6 |
|
| 7 |
=cut |
| 8 |
|
| 9 |
package Deliantra; |
| 10 |
|
| 11 |
our $VERSION = '2.01'; |
| 12 |
|
| 13 |
use common::sense; |
| 14 |
|
| 15 |
use base 'Exporter'; |
| 16 |
|
| 17 |
use Carp (); |
| 18 |
use File::Spec; |
| 19 |
use List::Util qw(min max); |
| 20 |
use Storable qw(freeze thaw); |
| 21 |
|
| 22 |
our @EXPORT = qw( |
| 23 |
read_pak read_arch |
| 24 |
*ARCH $TILE *FACE *FACEDATA |
| 25 |
TILESIZE CACHESTRIDE |
| 26 |
editor_archs arch_extents |
| 27 |
); |
| 28 |
|
| 29 |
use JSON::XS qw(decode_json encode_json); |
| 30 |
|
| 31 |
our $LIB = $ENV{DELIANTRA_LIBDIR}; |
| 32 |
|
| 33 |
our $VARDIR = $ENV{HOME} ? "$ENV{HOME}/.deliantra" |
| 34 |
: $ENV{AppData} ? "$ENV{APPDATA}/deliantra" |
| 35 |
: File::Spec->tmpdir . "/deliantra"; |
| 36 |
|
| 37 |
mkdir $VARDIR, 0777; |
| 38 |
|
| 39 |
sub TILESIZE (){ 32 } |
| 40 |
sub CACHESTRIDE (){ 64 } |
| 41 |
|
| 42 |
our %ARCH; |
| 43 |
our %FACE; # face32 |
| 44 |
our %FACEDATA; |
| 45 |
our $TILE; |
| 46 |
|
| 47 |
our %FIELD_MULTILINE = ( |
| 48 |
msg => "endmsg", |
| 49 |
lore => "endlore", |
| 50 |
maplore => "endmaplore", |
| 51 |
); |
| 52 |
|
| 53 |
# movement bit type, PITA |
| 54 |
our %FIELD_MOVEMENT = map +($_ => undef), |
| 55 |
qw(move_type move_block move_allow move_on move_off move_slow); |
| 56 |
|
| 57 |
# same as in server save routine, to (hopefully) be compatible |
| 58 |
# to the other editors. |
| 59 |
our @FIELD_ORDER_MAP = (qw( |
| 60 |
file_format_version |
| 61 |
name attach swap_time reset_timeout fixed_resettime difficulty |
| 62 |
region music |
| 63 |
shopitems shopgreed shopmin shopmax shoprace |
| 64 |
darkness width height enter_x enter_y msg maplore |
| 65 |
unique template |
| 66 |
outdoor temp pressure humid windspeed winddir sky nosmooth |
| 67 |
tile_path_1 tile_path_2 tile_path_3 tile_path_4 |
| 68 |
)); |
| 69 |
|
| 70 |
our @FIELD_ORDER = (qw( |
| 71 |
inherit |
| 72 |
|
| 73 |
elevation |
| 74 |
|
| 75 |
name name_pl custom_name attach title race |
| 76 |
slaying skill msg lore other_arch |
| 77 |
sound sound_destroy face animation is_animated |
| 78 |
magicmap glyph smoothlevel smoothface |
| 79 |
str dex con wis pow cha int |
| 80 |
hp maxhp sp maxsp grace maxgrace |
| 81 |
exp perm_exp expmul |
| 82 |
food dam luck wc ac x y speed speed_left move_state attack_movement |
| 83 |
nrof level direction type subtype attacktype |
| 84 |
|
| 85 |
resist_physical resist_magic resist_fire resist_electricity |
| 86 |
resist_cold resist_confusion resist_acid resist_drain |
| 87 |
resist_weaponmagic resist_ghosthit resist_poison resist_slow |
| 88 |
resist_paralyze resist_turn_undead resist_fear resist_cancellation |
| 89 |
resist_deplete resist_death resist_chaos resist_counterspell |
| 90 |
resist_godpower resist_holyword resist_blind resist_internal |
| 91 |
resist_life_stealing resist_disease |
| 92 |
|
| 93 |
path_attuned path_repelled path_denied material materialname |
| 94 |
value carrying weight invisible state magic |
| 95 |
last_heal last_sp last_grace last_eat |
| 96 |
connected glow_radius randomitems tresure_env npx_status npc_program |
| 97 |
run_away pick_up container will_apply smoothlevel |
| 98 |
current_weapon_script weapontype tooltype elevation client_type |
| 99 |
item_power duration range |
| 100 |
range_modifier duration_modifier dam_modifier gen_sp_armour |
| 101 |
move_type move_block move_allow move_on move_off move_on move_slow move_slow_penalty |
| 102 |
|
| 103 |
alive wiz was_wiz applied unpaid can_use_shield no_pick is_animated monster |
| 104 |
friendly generator is_thrown auto_apply treasure player sold see_invisible |
| 105 |
can_roll overlay_floor is_turnable is_used_up identified reflecting changing |
| 106 |
splitting hitback startequip blocksview undead scared unaggressive |
| 107 |
reflect_missile reflect_spell no_magic no_fix_player is_lightable tear_down |
| 108 |
run_away pick_up unique no_drop can_cast_spell can_use_scroll can_use_range |
| 109 |
can_use_bow can_use_armour can_use_weapon can_use_ring has_ready_range |
| 110 |
has_ready_bow xrays is_floor lifesave no_strength sleep stand_still |
| 111 |
random_move only_attack confused stealth cursed damned see_anywhere |
| 112 |
known_magical known_cursed can_use_skill been_applied has_ready_scroll |
| 113 |
can_use_rod can_use_horn make_invisible inv_locked is_wooded is_hilly |
| 114 |
has_ready_skill has_ready_weapon no_skill_ident is_blind can_see_in_dark |
| 115 |
is_cauldron is_dust no_steal one_hit berserk neutral no_attack no_damage |
| 116 |
activate_on_push activate_on_release is_water use_content_on_gen is_buildable |
| 117 |
precious |
| 118 |
|
| 119 |
body_range body_arm body_torso body_head body_neck body_skill |
| 120 |
body_finger body_shoulder body_foot body_hand body_wrist body_waist |
| 121 |
)); |
| 122 |
|
| 123 |
our %EVENT_TYPE = ( |
| 124 |
apply => 1, |
| 125 |
attack => 2, |
| 126 |
death => 3, |
| 127 |
drop => 4, |
| 128 |
pickup => 5, |
| 129 |
say => 6, |
| 130 |
stop => 7, |
| 131 |
time => 8, |
| 132 |
throw => 9, |
| 133 |
trigger => 10, |
| 134 |
close => 11, |
| 135 |
timer => 12, |
| 136 |
); |
| 137 |
|
| 138 |
# 1 up 2 right 4 down 8 left |
| 139 |
our %WALLDIR = ( |
| 140 |
0 => 0, |
| 141 |
1_2 => 1, |
| 142 |
1_4 => 2, |
| 143 |
2_2_1 => 3, |
| 144 |
1_1 => 4, |
| 145 |
2_1_1 => 5, |
| 146 |
2_2_2 => 6, |
| 147 |
3_2 => 7, |
| 148 |
1_3 => 8, |
| 149 |
2_2_4 => 9, |
| 150 |
2_1_2 => 10, |
| 151 |
3_1 => 11, |
| 152 |
2_2_3 => 12, |
| 153 |
3_4 => 13, |
| 154 |
3_3 => 14, |
| 155 |
4 => 15, |
| 156 |
); |
| 157 |
|
| 158 |
sub MOVE_WALK (){ 0x01 } |
| 159 |
sub MOVE_FLY_LOW (){ 0x02 } |
| 160 |
sub MOVE_FLY_HIGH (){ 0x04 } |
| 161 |
sub MOVE_FLYING (){ 0x06 } |
| 162 |
sub MOVE_SWIM (){ 0x08 } |
| 163 |
sub MOVE_BOAT (){ 0x10 } |
| 164 |
sub MOVE_SHIP (){ 0x20 } |
| 165 |
sub MOVE_KNOWN (){ 0x3f } # all of above |
| 166 |
sub MOVE_ALL (){ 0x10000 } # very special value |
| 167 |
|
| 168 |
our %MOVE_TYPE = ( |
| 169 |
walk => MOVE_WALK, |
| 170 |
fly_low => MOVE_FLY_LOW, |
| 171 |
fly_high => MOVE_FLY_HIGH, |
| 172 |
flying => MOVE_FLYING, |
| 173 |
swim => MOVE_SWIM, |
| 174 |
boat => MOVE_BOAT, |
| 175 |
ship => MOVE_SHIP, |
| 176 |
all => MOVE_ALL, |
| 177 |
); |
| 178 |
|
| 179 |
our @MOVE_TYPE = qw(all walk flying fly_low fly_high swim boat ship); |
| 180 |
|
| 181 |
{ |
| 182 |
package Deliantra::MoveType; |
| 183 |
|
| 184 |
use overload |
| 185 |
'=' => sub { bless [@{$_[0]}], ref $_[0] }, |
| 186 |
'""' => \&as_string, |
| 187 |
'>=' => sub { $_[0][0] & $MOVE_TYPE{$_[1]} ? $_[0][1] & $MOVE_TYPE{$_[1]} : undef }, |
| 188 |
'<=' => sub { |
| 189 |
($_[0][0] & $MOVE_TYPE{$_[1]}) == $MOVE_TYPE{$_[1]} |
| 190 |
? $_[0][1] & $MOVE_TYPE{$_[1]} |
| 191 |
: undef |
| 192 |
}, |
| 193 |
'+=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] |= $MOVE_TYPE{$_[1]}; &normalise }, |
| 194 |
'-=' => sub { $_[0][0] |= $MOVE_TYPE{$_[1]}; $_[0][1] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 195 |
'/=' => sub { $_[0][0] &= ~$MOVE_TYPE{$_[1]}; &normalise }, |
| 196 |
'x=' => sub { # toggle between off, + and - |
| 197 |
my $cur = $_[0] >= $_[1]; |
| 198 |
if (!defined $cur) { |
| 199 |
if ($_[0] >= "all") { |
| 200 |
$_[0] -= $_[1]; |
| 201 |
} else { |
| 202 |
$_[0] += $_[1]; |
| 203 |
} |
| 204 |
} elsif ($cur) { |
| 205 |
$_[0] -= $_[1]; |
| 206 |
} else { |
| 207 |
$_[0] /= $_[1]; |
| 208 |
} |
| 209 |
|
| 210 |
$_[0] |
| 211 |
}, |
| 212 |
'eq' => sub { "$_[0]" eq "$_[1]" }, |
| 213 |
'ne' => sub { "$_[0]" ne "$_[1]" }, |
| 214 |
; |
| 215 |
|
| 216 |
sub TO_JSON { |
| 217 |
$_[0][0] |
| 218 |
} |
| 219 |
} |
| 220 |
|
| 221 |
sub Deliantra::MoveType::new { |
| 222 |
my ($class, $string) = @_; |
| 223 |
|
| 224 |
my $mask; |
| 225 |
my $value; |
| 226 |
|
| 227 |
if ($string =~ /^\s*\d+\s*$/) { |
| 228 |
$mask = MOVE_ALL; |
| 229 |
$value = $string+0; |
| 230 |
} else { |
| 231 |
for (split /\s+/, lc $string) { |
| 232 |
if (s/^-//) { |
| 233 |
$mask |= $MOVE_TYPE{$_}; |
| 234 |
$value &= ~$MOVE_TYPE{$_}; |
| 235 |
} else { |
| 236 |
$mask |= $MOVE_TYPE{$_}; |
| 237 |
$value |= $MOVE_TYPE{$_}; |
| 238 |
} |
| 239 |
} |
| 240 |
} |
| 241 |
|
| 242 |
(bless [$mask, $value], $class)->normalise |
| 243 |
} |
| 244 |
|
| 245 |
sub Deliantra::MoveType::normalise { |
| 246 |
my ($self) = @_; |
| 247 |
|
| 248 |
if ($self->[0] & MOVE_ALL) { |
| 249 |
my $mask = ~(($self->[1] & MOVE_ALL ? $self->[1] : ~$self->[1]) & $self->[0] & ~MOVE_ALL); |
| 250 |
$self->[0] &= $mask; |
| 251 |
$self->[1] &= $mask; |
| 252 |
} |
| 253 |
|
| 254 |
$self->[1] &= $self->[0]; |
| 255 |
|
| 256 |
$self |
| 257 |
} |
| 258 |
|
| 259 |
sub Deliantra::MoveType::as_string { |
| 260 |
my ($self) = @_; |
| 261 |
|
| 262 |
my @res; |
| 263 |
|
| 264 |
my ($mask, $value) = @$self; |
| 265 |
|
| 266 |
for (@Deliantra::MOVE_TYPE) { |
| 267 |
my $bit = $Deliantra::MOVE_TYPE{$_}; |
| 268 |
if (($mask & $bit) == $bit && (($value & $bit) == $bit || ($value & $bit) == 0)) { |
| 269 |
$mask &= ~$bit; |
| 270 |
push @res, $value & $bit ? $_ : "-$_"; |
| 271 |
} |
| 272 |
} |
| 273 |
|
| 274 |
join " ", @res |
| 275 |
} |
| 276 |
|
| 277 |
sub load_ref($) { |
| 278 |
my ($path) = @_; |
| 279 |
|
| 280 |
open my $fh, "<:raw:perlio", $path |
| 281 |
or die "$path: $!"; |
| 282 |
local $/; |
| 283 |
|
| 284 |
thaw <$fh> |
| 285 |
} |
| 286 |
|
| 287 |
sub save_ref($$) { |
| 288 |
my ($ref, $path) = @_; |
| 289 |
|
| 290 |
open my $fh, ">:raw:perlio", "$path~" |
| 291 |
or die "$path~: $!"; |
| 292 |
print $fh freeze $ref; |
| 293 |
close $fh; |
| 294 |
rename "$path~", $path |
| 295 |
or die "$path: $!"; |
| 296 |
} |
| 297 |
|
| 298 |
my %attack_mask = ( |
| 299 |
physical => 0x00000001, |
| 300 |
magic => 0x00000002, |
| 301 |
fire => 0x00000004, |
| 302 |
electricity => 0x00000008, |
| 303 |
cold => 0x00000010, |
| 304 |
confusion => 0x00000020, |
| 305 |
acid => 0x00000040, |
| 306 |
drain => 0x00000080, |
| 307 |
weaponmagic => 0x00000100, |
| 308 |
ghosthit => 0x00000200, |
| 309 |
poison => 0x00000400, |
| 310 |
slow => 0x00000800, |
| 311 |
paralyze => 0x00001000, |
| 312 |
turn_undead => 0x00002000, |
| 313 |
fear => 0x00004000, |
| 314 |
cancellation => 0x00008000, |
| 315 |
deplete => 0x00010000, |
| 316 |
death => 0x00020000, |
| 317 |
chaos => 0x00040000, |
| 318 |
counterspell => 0x00080000, |
| 319 |
godpower => 0x00100000, |
| 320 |
holyword => 0x00200000, |
| 321 |
blind => 0x00400000, |
| 322 |
internal => 0x00800000, |
| 323 |
life_stealing => 0x01000000, |
| 324 |
disease => 0x02000000, |
| 325 |
); |
| 326 |
|
| 327 |
sub _add_resist($$$) { |
| 328 |
my ($ob, $mask, $value) = @_; |
| 329 |
|
| 330 |
while (my ($k, $v) = each %attack_mask) { |
| 331 |
$ob->{"resist_$k"} = min 100, max -100, $ob->{"resist_$k"} + $value if $mask & $v; |
| 332 |
} |
| 333 |
} |
| 334 |
|
| 335 |
my %MATERIAL = reverse |
| 336 |
paper => 1, |
| 337 |
iron => 2, |
| 338 |
glass => 4, |
| 339 |
leather => 8, |
| 340 |
wood => 16, |
| 341 |
organic => 32, |
| 342 |
stone => 64, |
| 343 |
cloth => 128, |
| 344 |
adamant => 256, |
| 345 |
liquid => 512, |
| 346 |
tin => 1024, |
| 347 |
bone => 2048, |
| 348 |
ice => 4096, |
| 349 |
|
| 350 |
# guesses |
| 351 |
runestone => 12, |
| 352 |
bronze => 18, |
| 353 |
"ancient wood" => 20, |
| 354 |
glass => 36, |
| 355 |
marble => 66, |
| 356 |
ice => 68, |
| 357 |
stone => 70, |
| 358 |
stone => 80, |
| 359 |
cloth => 136, |
| 360 |
ironwood => 144, |
| 361 |
adamantium => 258, |
| 362 |
glacium => 260, |
| 363 |
blood => 544, |
| 364 |
; |
| 365 |
|
| 366 |
# object as in "Object xxx", i.e. archetypes |
| 367 |
sub normalize_object($) { |
| 368 |
my ($ob) = @_; |
| 369 |
|
| 370 |
delete $ob->{editable}; # deprecated |
| 371 |
|
| 372 |
# convert material bitset to materialname, if possible |
| 373 |
if (exists $ob->{material}) { |
| 374 |
if (!$ob->{material}) { |
| 375 |
delete $ob->{material}; |
| 376 |
} elsif (exists $ob->{materialname}) { |
| 377 |
if ($MATERIAL{$ob->{material}} eq $ob->{materialname}) { |
| 378 |
delete $ob->{material}; |
| 379 |
} else { |
| 380 |
warn "object $ob->{_name} has both materialname ($ob->{materialname}) and material ($ob->{material}) set.\n"; |
| 381 |
delete $ob->{material}; # assume materilname is more specific and nuke material |
| 382 |
} |
| 383 |
} elsif (my $name = $MATERIAL{$ob->{material}}) { |
| 384 |
delete $ob->{material}; |
| 385 |
$ob->{materialname} = $name; |
| 386 |
} else { |
| 387 |
warn "object $ob->{_name} has unknown material ($ob->{material}) set.\n"; |
| 388 |
} |
| 389 |
} |
| 390 |
|
| 391 |
# check whether attachment is the same as in the archetype |
| 392 |
if (exists $ob->{attach}) { |
| 393 |
my $arch = $ARCH{$ob->{_name}}; |
| 394 |
my $js = JSON::XS->new->utf8->canonical (1); |
| 395 |
|
| 396 |
if (defined $arch->{attach} |
| 397 |
&& $js->encode ($js->decode ($ob->{attach})) eq $js->encode ($arch->{attach})) { |
| 398 |
delete $ob->{attach} |
| 399 |
} |
| 400 |
} |
| 401 |
|
| 402 |
# color_fg is used as default for magicmap if magicmap does not exist |
| 403 |
$ob->{magicmap} ||= delete $ob->{color_fg} if exists $ob->{color_fg}; |
| 404 |
|
| 405 |
# nuke outdated or never supported fields |
| 406 |
delete @$ob{qw( |
| 407 |
can_knockback can_parry can_impale can_cut can_dam_armour |
| 408 |
can_apply pass_thru can_pass_thru color_bg color_fg |
| 409 |
)}; |
| 410 |
|
| 411 |
if (my $mask = delete $ob->{immune} ) { _add_resist $ob, $mask, 100; } |
| 412 |
if (my $mask = delete $ob->{protected} ) { _add_resist $ob, $mask, 30; } |
| 413 |
if (my $mask = delete $ob->{vulnerable}) { _add_resist $ob, $mask, -100; } |
| 414 |
|
| 415 |
# convert movement strings to bitsets |
| 416 |
for my $attr (keys %FIELD_MOVEMENT) { |
| 417 |
next unless exists $ob->{$attr}; |
| 418 |
|
| 419 |
$ob->{$attr} = new Deliantra::MoveType $ob->{$attr}; |
| 420 |
} |
| 421 |
|
| 422 |
# convert outdated movement flags to new movement sets |
| 423 |
if (defined (my $v = delete $ob->{no_pass})) { |
| 424 |
$ob->{move_block} = new Deliantra::MoveType $v ? "all" : "0"; |
| 425 |
} |
| 426 |
if (defined (my $v = delete $ob->{slow_move})) { |
| 427 |
$ob->{move_slow} += "walk"; |
| 428 |
$ob->{move_slow_penalty} = $v; |
| 429 |
} |
| 430 |
if (defined (my $v = delete $ob->{walk_on})) { |
| 431 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "walk" } else { $ob->{move_on} -= "walk" } |
| 432 |
} |
| 433 |
if (defined (my $v = delete $ob->{walk_off})) { |
| 434 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "walk" } else { $ob->{move_off} -= "walk" } |
| 435 |
} |
| 436 |
if (defined (my $v = delete $ob->{fly_on})) { |
| 437 |
$ob->{move_on} ||= new Deliantra::MoveType; if ($v) { $ob->{move_on} += "fly_low" } else { $ob->{move_on} -= "fly_low" } |
| 438 |
} |
| 439 |
if (defined (my $v = delete $ob->{fly_off})) { |
| 440 |
$ob->{move_off} ||= new Deliantra::MoveType; if ($v) { $ob->{move_off} += "fly_low" } else { $ob->{move_off} -= "fly_low" } |
| 441 |
} |
| 442 |
if (defined (my $v = delete $ob->{flying})) { |
| 443 |
$ob->{move_type} ||= new Deliantra::MoveType; if ($v) { $ob->{move_type} += "fly_low" } else { $ob->{move_type} -= "fly_low" } |
| 444 |
} |
| 445 |
|
| 446 |
# convert idiotic event_xxx things into objects |
| 447 |
while (my ($event, $subtype) = each %EVENT_TYPE) { |
| 448 |
if (exists $ob->{"event_${event}_plugin"}) { |
| 449 |
push @{$ob->{inventory}}, { |
| 450 |
_name => "event_$event", |
| 451 |
title => delete $ob->{"event_${event}_plugin"}, |
| 452 |
slaying => delete $ob->{"event_${event}"}, |
| 453 |
name => delete $ob->{"event_${event}_options"}, |
| 454 |
}; |
| 455 |
} |
| 456 |
} |
| 457 |
|
| 458 |
# some archetypes had "+3" instead of the canonical "3", so fix |
| 459 |
$ob->{dam} *= 1 if exists $ob->{dam}; |
| 460 |
|
| 461 |
$ob |
| 462 |
} |
| 463 |
|
| 464 |
# arch as in "arch xxx", ie.. objects |
| 465 |
sub normalize_arch($) { |
| 466 |
my ($ob) = @_; |
| 467 |
|
| 468 |
normalize_object $ob; |
| 469 |
|
| 470 |
return if $ob->{_atype} eq "object"; |
| 471 |
|
| 472 |
my $arch = $ARCH{$ob->{_name}} |
| 473 |
or (warn "$ob->{_name}: no such archetype", return $ob); |
| 474 |
|
| 475 |
if ($arch->{type} == 22) { # map |
| 476 |
my %normalize = ( |
| 477 |
"enter_x" => "hp", |
| 478 |
"enter_y" => "sp", |
| 479 |
"width" => "x", |
| 480 |
"height" => "y", |
| 481 |
"reset_timeout" => "weight", |
| 482 |
"swap_time" => "value", |
| 483 |
"difficulty" => "level", |
| 484 |
"darkness" => "invisible", |
| 485 |
"fixed_resettime" => "stand_still", |
| 486 |
); |
| 487 |
|
| 488 |
while (my ($k2, $k1) = each %normalize) { |
| 489 |
if (defined (my $v = delete $ob->{$k1})) { |
| 490 |
$ob->{$k2} = $v; |
| 491 |
} |
| 492 |
} |
| 493 |
} else { |
| 494 |
# if value matches archetype default, delete |
| 495 |
while (my ($k, $v) = each %$ob) { |
| 496 |
if (exists $arch->{$k} and $arch->{$k} eq $v) { |
| 497 |
next if $k eq "_name"; |
| 498 |
delete $ob->{$k}; |
| 499 |
} |
| 500 |
} |
| 501 |
} |
| 502 |
|
| 503 |
# a speciality for the editor |
| 504 |
if (exists $ob->{attack_movement}) { |
| 505 |
my $am = delete $ob->{attack_movement}; |
| 506 |
$ob->{attack_movement_bits_0_3} = $am & 15; |
| 507 |
$ob->{attack_movement_bits_4_7} = $am & 240; |
| 508 |
} |
| 509 |
|
| 510 |
$ob |
| 511 |
} |
| 512 |
|
| 513 |
sub attr_thaw($) { |
| 514 |
my ($ob) = @_; |
| 515 |
|
| 516 |
$ob->{attach} = decode_json $ob->{attach} |
| 517 |
if exists $ob->{attach}; |
| 518 |
|
| 519 |
$ob |
| 520 |
} |
| 521 |
|
| 522 |
sub attr_freeze($) { |
| 523 |
my ($ob) = @_; |
| 524 |
|
| 525 |
$ob->{attach} = JSON::XS->new->utf8->canonical->encode ($ob->{attach}) |
| 526 |
if exists $ob->{attach}; |
| 527 |
|
| 528 |
$ob |
| 529 |
} |
| 530 |
|
| 531 |
sub read_pak($) { |
| 532 |
my ($path) = @_; |
| 533 |
|
| 534 |
my %pak; |
| 535 |
|
| 536 |
open my $fh, "<:raw:perlio", $path |
| 537 |
or Carp::croak "$_[0]: $!"; |
| 538 |
binmode $fh; |
| 539 |
while (<$fh>) { |
| 540 |
my ($type, $id, $len, $path) = split; |
| 541 |
$path =~ s/.*\///; |
| 542 |
read $fh, $pak{$path}, $len; |
| 543 |
} |
| 544 |
|
| 545 |
\%pak |
| 546 |
} |
| 547 |
|
| 548 |
sub read_arch($;$) { |
| 549 |
my ($path, $toplevel) = @_; |
| 550 |
|
| 551 |
my %arc; |
| 552 |
my ($more, $prev); |
| 553 |
my $comment; |
| 554 |
|
| 555 |
open my $fh, "<:utf8", $path |
| 556 |
or Carp::croak "$path: $!"; |
| 557 |
|
| 558 |
# binmode $fh; |
| 559 |
|
| 560 |
my $parse_block; $parse_block = sub { |
| 561 |
my %arc = @_; |
| 562 |
|
| 563 |
while (<$fh>) { |
| 564 |
s/\s+$//; |
| 565 |
if (/^end$/i) { |
| 566 |
last; |
| 567 |
|
| 568 |
} elsif (/^arch (\S+)$/i) { |
| 569 |
push @{ $arc{inventory} }, attr_thaw normalize_arch $parse_block->(_name => $1); |
| 570 |
|
| 571 |
} elsif (/^lore$/i) { |
| 572 |
while (<$fh>) { |
| 573 |
last if /^endlore\s*$/i; |
| 574 |
$arc{lore} .= $_; |
| 575 |
} |
| 576 |
} elsif (/^msg$/i) { |
| 577 |
while (<$fh>) { |
| 578 |
last if /^endmsg\s*$/i; |
| 579 |
$arc{msg} .= $_; |
| 580 |
} |
| 581 |
} elsif (/^anim$/i) { |
| 582 |
while (<$fh>) { |
| 583 |
last if /^mina\s*$/i; |
| 584 |
chomp; |
| 585 |
push @{ $arc{anim} }, $_; |
| 586 |
} |
| 587 |
} elsif (/^(\S+)\s*(.*)$/) { |
| 588 |
$arc{lc $1} = $2; |
| 589 |
} elsif (/^\s*#/) { |
| 590 |
$arc{_comment} .= "$_\n"; |
| 591 |
|
| 592 |
} elsif (/^\s*$/) { |
| 593 |
# |
| 594 |
} else { |
| 595 |
warn "$path: unparsable line '$_' in arch $arc{_name}"; |
| 596 |
} |
| 597 |
} |
| 598 |
|
| 599 |
\%arc |
| 600 |
}; |
| 601 |
|
| 602 |
while (<$fh>) { |
| 603 |
s/\s+$//; |
| 604 |
if (/^more$/i) { |
| 605 |
$more = $prev; |
| 606 |
} elsif (/^object (\S+)$/i) { |
| 607 |
my $name = $1; |
| 608 |
my $arc = attr_thaw normalize_object $parse_block->(_name => $name, _comment => $comment); |
| 609 |
undef $comment; |
| 610 |
delete $arc{_comment} unless length $arc{_comment}; |
| 611 |
$arc->{_atype} = 'object'; |
| 612 |
|
| 613 |
if ($more) { |
| 614 |
$more->{more} = $arc; |
| 615 |
} else { |
| 616 |
$arc{$name} = $arc; |
| 617 |
} |
| 618 |
$prev = $arc; |
| 619 |
$more = undef; |
| 620 |
} elsif (/^arch (\S+)$/i) { |
| 621 |
my $name = $1; |
| 622 |
my $arc = attr_thaw normalize_arch $parse_block->(_name => $name, _comment => $comment); |
| 623 |
undef $comment; |
| 624 |
delete $arc{_comment} unless length $arc{_comment}; |
| 625 |
$arc->{_atype} = 'arch'; |
| 626 |
|
| 627 |
if ($more) { |
| 628 |
$more->{more} = $arc; |
| 629 |
} else { |
| 630 |
push @{ $arc{arch} }, $arc; |
| 631 |
} |
| 632 |
$prev = $arc; |
| 633 |
$more = undef; |
| 634 |
} elsif ($toplevel && /^(\S+)\s+(.*)$/) { |
| 635 |
if ($1 eq "lev_array") { |
| 636 |
while (<$fh>) { |
| 637 |
last if /^endplst\s*$/; |
| 638 |
push @{$toplevel->{lev_array}}, $_+0; |
| 639 |
} |
| 640 |
} else { |
| 641 |
$toplevel->{$1} = $2; |
| 642 |
} |
| 643 |
} elsif (/^\s*#/) { |
| 644 |
$comment .= "$_\n"; |
| 645 |
} elsif (/^\s*($|#)/) { |
| 646 |
# |
| 647 |
} else { |
| 648 |
die "$path: unparseable top-level line '$_'"; |
| 649 |
} |
| 650 |
} |
| 651 |
|
| 652 |
undef $parse_block; # work around bug in perl not freeing $fh etc. |
| 653 |
|
| 654 |
\%arc |
| 655 |
} |
| 656 |
|
| 657 |
sub archlist_to_string { |
| 658 |
my ($arch) = @_; |
| 659 |
|
| 660 |
my $str; |
| 661 |
|
| 662 |
my $append; $append = sub { |
| 663 |
my %a = %{$_[0]}; |
| 664 |
|
| 665 |
Deliantra::attr_freeze \%a; |
| 666 |
Deliantra::normalize_arch \%a; |
| 667 |
|
| 668 |
# undo the bit-split we did before |
| 669 |
if (exists $a{attack_movement_bits_0_3} or exists $a{attack_movement_bits_4_7}) { |
| 670 |
$a{attack_movement} = (delete $a{attack_movement_bits_0_3}) |
| 671 |
| (delete $a{attack_movement_bits_4_7}); |
| 672 |
} |
| 673 |
|
| 674 |
if (my $comment = delete $a{_comment}) { |
| 675 |
if ($comment =~ /[^\n\s#]/) { |
| 676 |
$str .= $comment; |
| 677 |
} |
| 678 |
} |
| 679 |
|
| 680 |
$str .= ((exists $a{_atype}) ? $a{_atype} : 'arch'). " $a{_name}\n"; |
| 681 |
|
| 682 |
my $inv = delete $a{inventory}; |
| 683 |
my $more = delete $a{more}; # arches do not support 'more', but old maps can contain some |
| 684 |
my $anim = delete $a{anim}; |
| 685 |
|
| 686 |
if ($a{_atype} eq 'object') { |
| 687 |
$str .= join "\n", "anim", @$anim, "mina\n" |
| 688 |
if $anim; |
| 689 |
} |
| 690 |
|
| 691 |
my @kv; |
| 692 |
|
| 693 |
for ($a{_name} eq "map" |
| 694 |
? @Deliantra::FIELD_ORDER_MAP |
| 695 |
: @Deliantra::FIELD_ORDER) { |
| 696 |
push @kv, [$_, delete $a{$_}] |
| 697 |
if exists $a{$_}; |
| 698 |
} |
| 699 |
|
| 700 |
for (sort keys %a) { |
| 701 |
next if /^_/; # ignore our _-keys |
| 702 |
push @kv, [$_, delete $a{$_}]; |
| 703 |
} |
| 704 |
|
| 705 |
for (@kv) { |
| 706 |
my ($k, $v) = @$_; |
| 707 |
|
| 708 |
if (my $end = $Deliantra::FIELD_MULTILINE{$k}) { |
| 709 |
$v =~ s/\n$//; |
| 710 |
$str .= "$k\n$v\n$end\n"; |
| 711 |
} else { |
| 712 |
$str .= "$k $v\n"; |
| 713 |
} |
| 714 |
} |
| 715 |
|
| 716 |
if ($inv) { |
| 717 |
$append->($_) for @$inv; |
| 718 |
} |
| 719 |
|
| 720 |
$str .= "end\n"; |
| 721 |
|
| 722 |
if ($a{_atype} eq 'object') { |
| 723 |
if ($more) { |
| 724 |
$str .= "more\n"; |
| 725 |
$append->($more) if $more; |
| 726 |
} else { |
| 727 |
$str .= "\n"; |
| 728 |
} |
| 729 |
} |
| 730 |
}; |
| 731 |
|
| 732 |
for (@$arch) { |
| 733 |
$append->($_); |
| 734 |
} |
| 735 |
|
| 736 |
$str |
| 737 |
} |
| 738 |
|
| 739 |
# put all archs into a hash with editor_face as it's key |
| 740 |
# NOTE: the arrays in the hash values are references to |
| 741 |
# the archs from $ARCH |
| 742 |
sub editor_archs { |
| 743 |
my %paths; |
| 744 |
|
| 745 |
for (keys %ARCH) { |
| 746 |
my $arch = $ARCH{$_}; |
| 747 |
push @{$paths{$arch->{editor_folder}}}, $arch; |
| 748 |
} |
| 749 |
|
| 750 |
\%paths |
| 751 |
} |
| 752 |
|
| 753 |
=item ($minx, $miny, $maxx, $maxy) = arch_extents $arch |
| 754 |
|
| 755 |
arch_extents determines the extents of the given arch's face(s), linked |
| 756 |
faces and single faces are handled here it returns (minx, miny, maxx, |
| 757 |
maxy) |
| 758 |
|
| 759 |
=cut |
| 760 |
|
| 761 |
sub arch_extents { |
| 762 |
my ($a) = @_; |
| 763 |
|
| 764 |
my $o = $ARCH{$a->{_name}} |
| 765 |
or return; |
| 766 |
|
| 767 |
my $face = $FACE{$a->{face} || $o->{face} || "blank.111"}; |
| 768 |
unless ($face) { |
| 769 |
$face = $FACE{"blank.x11"} |
| 770 |
or (warn "no face data found for arch '$a->{_name}'"), return; |
| 771 |
} |
| 772 |
|
| 773 |
if ($face->{w} > 1 || $face->{h} > 1) { |
| 774 |
# bigface |
| 775 |
return (0, 0, $face->{w} - 1, $face->{h} - 1); |
| 776 |
|
| 777 |
} elsif ($o->{more}) { |
| 778 |
# linked face |
| 779 |
my ($minx, $miny, $maxx, $maxy) = ($o->{x}, $o->{y}) x 2; |
| 780 |
|
| 781 |
for (; $o; $o = $o->{more}) { |
| 782 |
$minx = min $minx, $o->{x}; |
| 783 |
$miny = min $miny, $o->{y}; |
| 784 |
$maxx = max $maxx, $o->{x}; |
| 785 |
$maxy = max $maxy, $o->{y}; |
| 786 |
} |
| 787 |
|
| 788 |
return ($minx, $miny, $maxx, $maxy); |
| 789 |
|
| 790 |
} else { |
| 791 |
# single face |
| 792 |
return (0, 0, 0, 0); |
| 793 |
} |
| 794 |
} |
| 795 |
|
| 796 |
=item $type = arch_attr $arch |
| 797 |
|
| 798 |
Returns a hashref describing the object and its attributes. It can contain |
| 799 |
the following keys: |
| 800 |
|
| 801 |
name the name, suitable for display purposes |
| 802 |
ignore |
| 803 |
attr |
| 804 |
desc |
| 805 |
use |
| 806 |
section => [name => \%attr, name => \%attr] |
| 807 |
import |
| 808 |
|
| 809 |
=cut |
| 810 |
|
| 811 |
sub arch_attr($) { |
| 812 |
my ($obj) = @_; |
| 813 |
|
| 814 |
require Deliantra::Data; |
| 815 |
|
| 816 |
my $root; |
| 817 |
my $attr = { }; |
| 818 |
|
| 819 |
my $arch = $ARCH{ $obj->{_name} }; |
| 820 |
my $type = $obj->{type} || $arch->{type}; |
| 821 |
|
| 822 |
if ($type > 0) { |
| 823 |
$root = $Deliantra::Data::ATTR{$type}; |
| 824 |
} else { |
| 825 |
my %a = (%$arch, %$obj); |
| 826 |
|
| 827 |
if ($a{is_floor} && !$a{alive}) { |
| 828 |
$root = $Deliantra::Data::TYPE{Floor}; |
| 829 |
} elsif (!$a{is_floor} && $a{alive} && !$a{tear_down}) { |
| 830 |
$root = $Deliantra::Data::TYPE{"Monster & NPC"}; |
| 831 |
} elsif (!$a{is_floor} && !$a{alive} && $a{move_block}) { |
| 832 |
$root = $Deliantra::Data::TYPE{Wall}; |
| 833 |
} elsif (!$a{is_floor} && $a{alive} && $a{tear_down}) { |
| 834 |
$root = $Deliantra::Data::TYPE{"Weak Wall"}; |
| 835 |
} else { |
| 836 |
$root = $Deliantra::Data::TYPE{Misc}; |
| 837 |
} |
| 838 |
} |
| 839 |
|
| 840 |
my (%ignore); |
| 841 |
my @import = ($root); |
| 842 |
|
| 843 |
my @new_import; |
| 844 |
while (my $type = shift @import) { |
| 845 |
# first import everything we will need: |
| 846 |
push @import, |
| 847 |
grep $_, |
| 848 |
map $Deliantra::Data::TYPE{$_}, |
| 849 |
@{$type->{import} || []}; |
| 850 |
|
| 851 |
# and compute the ignored attributes |
| 852 |
for (@{$type->{ignore} || []}) { |
| 853 |
$ignore{$_}++ for ref $_ ? @$_ : $_; |
| 854 |
} |
| 855 |
|
| 856 |
push @new_import, $type; |
| 857 |
} |
| 858 |
(@import) = @new_import; |
| 859 |
|
| 860 |
# then add defaults to the back of the list, so they are added |
| 861 |
# as last resort. |
| 862 |
push @import, \%Deliantra::Data::DEFAULT_ATTR |
| 863 |
unless $type == 116; |
| 864 |
|
| 865 |
my (@section_order, %section, @attr_order); |
| 866 |
|
| 867 |
# @import = root, imported, default |
| 868 |
while (my $type = pop @import) { |
| 869 |
$attr->{$_} ||= $type->{$_} |
| 870 |
for qw(name desc use); |
| 871 |
|
| 872 |
for ([general => ($type->{attr} || [])], @{$type->{section} || []}) { |
| 873 |
my ($name, $attr) = @$_; |
| 874 |
push @section_order, $name; |
| 875 |
for (@$attr) { |
| 876 |
my ($k, $v) = @$_; |
| 877 |
push @attr_order, $k; |
| 878 |
$section{$name}{$k} = $v; # overwrite, so that the root decides |
| 879 |
} |
| 880 |
} |
| 881 |
} |
| 882 |
|
| 883 |
# remove ignores for "root" type |
| 884 |
for ( |
| 885 |
map @{$_->[1]}, # section attributes |
| 886 |
[general => ($root->{attr} || [])], |
| 887 |
@{$root->{section} || []} |
| 888 |
) { |
| 889 |
my ($k, $v) = @$_; |
| 890 |
# skip fixed attributes, if they are ignored thats fine |
| 891 |
next if $v->{type} eq 'fixed'; |
| 892 |
|
| 893 |
delete $ignore{$k}; # if the attributes are defined explicitly they |
| 894 |
# should NOT be ignored. ignore should mainly |
| 895 |
# hit imported/inherited attributes. |
| 896 |
} |
| 897 |
|
| 898 |
$attr->{section} = [ |
| 899 |
map !exists $section{$_} ? () : do { |
| 900 |
my $attr = delete $section{$_}; |
| 901 |
|
| 902 |
[ |
| 903 |
$_, |
| 904 |
map exists $attr->{$_} && !$ignore{$_} |
| 905 |
? [$_ => delete $attr->{$_}] : (), |
| 906 |
@attr_order |
| 907 |
] |
| 908 |
}, |
| 909 |
exists $section{$_} ? [$_ => delete $section{$_}] : (), |
| 910 |
@section_order |
| 911 |
]; |
| 912 |
|
| 913 |
$attr |
| 914 |
} |
| 915 |
|
| 916 |
sub cache_file($$&&) { |
| 917 |
my ($src, $cache, $load, $create) = @_; |
| 918 |
|
| 919 |
my ($size, $mtime) = (stat $src)[7,9] |
| 920 |
or Carp::croak "$src: $!"; |
| 921 |
|
| 922 |
if (-e $cache) { |
| 923 |
my $ref = eval { load_ref $cache }; |
| 924 |
|
| 925 |
if ($ref->{version} == 1 |
| 926 |
&& $ref->{size} == $size |
| 927 |
&& $ref->{mtime} == $mtime |
| 928 |
&& eval { $load->($ref->{data}); 1 }) { |
| 929 |
return; |
| 930 |
} |
| 931 |
} |
| 932 |
|
| 933 |
my $ref = { |
| 934 |
version => 1, |
| 935 |
size => $size, |
| 936 |
mtime => $mtime, |
| 937 |
data => $create->(), |
| 938 |
}; |
| 939 |
|
| 940 |
$load->($ref->{data}); |
| 941 |
|
| 942 |
save_ref $ref, $cache; |
| 943 |
} |
| 944 |
|
| 945 |
=item set_libdir $path |
| 946 |
|
| 947 |
Sets the library directory to the given path |
| 948 |
(default: $ENV{CROSSFIRE_LIBDIR}). |
| 949 |
|
| 950 |
You have to (re-)load the archetypes and tilecache manually after steting |
| 951 |
the library path. |
| 952 |
|
| 953 |
=cut |
| 954 |
|
| 955 |
sub set_libdir($) { |
| 956 |
$LIB = $_[0]; |
| 957 |
} |
| 958 |
|
| 959 |
=item load_archetypes |
| 960 |
|
| 961 |
(Re-)Load archetypes into %ARCH. |
| 962 |
|
| 963 |
=cut |
| 964 |
|
| 965 |
sub load_archetypes() { |
| 966 |
cache_file "$LIB/archetypes", "$VARDIR/archetypes.pst", sub { |
| 967 |
*ARCH = $_[0]; |
| 968 |
}, sub { |
| 969 |
read_arch "$LIB/archetypes" |
| 970 |
}; |
| 971 |
} |
| 972 |
|
| 973 |
sub construct_tilecache_pb { |
| 974 |
my ($idx, $cache) = @_; |
| 975 |
|
| 976 |
my $pb = new Gtk2::Gdk::Pixbuf "rgb", 1, 8, CACHESTRIDE * TILESIZE, TILESIZE * int +($idx + CACHESTRIDE - 1) / CACHESTRIDE; |
| 977 |
|
| 978 |
while (my ($name, $tile) = each %$cache) { |
| 979 |
my $tpb = delete $tile->{pb}; |
| 980 |
my $ofs = $tile->{idx}; |
| 981 |
|
| 982 |
for my $x (0 .. $tile->{w} - 1) { |
| 983 |
for my $y (0 .. $tile->{h} - 1) { |
| 984 |
my $idx = $ofs + $x + $y * $tile->{w}; |
| 985 |
$tpb->copy_area ($x * TILESIZE, $y * TILESIZE, TILESIZE, TILESIZE, |
| 986 |
$pb, ($idx % CACHESTRIDE) * TILESIZE, TILESIZE * int $idx / CACHESTRIDE); |
| 987 |
} |
| 988 |
} |
| 989 |
} |
| 990 |
|
| 991 |
$pb->save ("$VARDIR/tilecache.png", "png", compression => 1); |
| 992 |
|
| 993 |
$cache |
| 994 |
} |
| 995 |
|
| 996 |
sub use_tilecache { |
| 997 |
my ($face) = @_; |
| 998 |
$TILE = new_from_file Gtk2::Gdk::Pixbuf "$VARDIR/tilecache.png" |
| 999 |
or die "$VARDIR/tilecache.png: $!"; |
| 1000 |
*FACE = $_[0]; |
| 1001 |
} |
| 1002 |
|
| 1003 |
=item load_tilecache |
| 1004 |
|
| 1005 |
(Re-)Load %TILE and %FACE. |
| 1006 |
|
| 1007 |
=cut |
| 1008 |
|
| 1009 |
sub load_tilecache() { |
| 1010 |
require Gtk2; |
| 1011 |
|
| 1012 |
cache_file "$LIB/facedata", "$VARDIR/tilecache.pst", \&use_tilecache, |
| 1013 |
sub { |
| 1014 |
my %cache; |
| 1015 |
my $facedata = Storable::retrieve "$LIB/faceinfo"; |
| 1016 |
|
| 1017 |
open my $fh, "<", "$LIB/facedata" |
| 1018 |
or die "$LIB/facedata: $!"; |
| 1019 |
|
| 1020 |
$facedata->{version} == 2 |
| 1021 |
or die "$LIB/facedata: version mismatch, cannot proceed."; |
| 1022 |
|
| 1023 |
my $faces = $facedata->{faceinfo}; |
| 1024 |
my $idx = 0; |
| 1025 |
|
| 1026 |
for (sort keys %$faces) { |
| 1027 |
my ($face, $info) = ($_, $faces->{$_}); |
| 1028 |
|
| 1029 |
my $pb = new Gtk2::Gdk::PixbufLoader; |
| 1030 |
|
| 1031 |
if (exists $info->{data32}) { |
| 1032 |
$pb->write ($info->{data32}); |
| 1033 |
} else { |
| 1034 |
sysseek $fh, $info->{fofs32}, 0; |
| 1035 |
sysread $fh, my $buf, $info->{size32}; |
| 1036 |
$pb->write ($buf); |
| 1037 |
} |
| 1038 |
$pb->close; |
| 1039 |
my $pb = $pb->get_pixbuf; |
| 1040 |
|
| 1041 |
my $tile = $cache{$face} = { |
| 1042 |
pb => $pb, |
| 1043 |
idx => $idx, |
| 1044 |
w => int $pb->get_width / TILESIZE, |
| 1045 |
h => int $pb->get_height / TILESIZE, |
| 1046 |
}; |
| 1047 |
|
| 1048 |
$idx += $tile->{w} * $tile->{h}; |
| 1049 |
} |
| 1050 |
|
| 1051 |
construct_tilecache_pb $idx, \%cache; |
| 1052 |
|
| 1053 |
\%cache |
| 1054 |
}; |
| 1055 |
} |
| 1056 |
|
| 1057 |
=back |
| 1058 |
|
| 1059 |
=head1 AUTHOR |
| 1060 |
|
| 1061 |
Marc Lehmann <schmorp@schmorp.de> |
| 1062 |
http://home.schmorp.de/ |
| 1063 |
|
| 1064 |
Robin Redeker <elmex@ta-sa.org> |
| 1065 |
http://www.ta-sa.org/ |
| 1066 |
|
| 1067 |
=cut |
| 1068 |
|
| 1069 |
1 |
| 1070 |
|
