package GCE::AttrEdit;

=head1 NAME

  GCE::AttrEdit - an edit wiget for attributes

=cut

use Gtk2;
use Gtk2::Gdk::Keysyms;
use Gtk2::SimpleList;

use GCE::Util;
use GCE::InventoryEditor;

use Glib::Object::Subclass Gtk2::VBox;

use Crossfire;

sub INIT_INSTANCE {
   my ($self) = @_;

   $self->pack_start (my $lbl = $self->{arch_name_lbl} = Gtk2::Label->new, 0, 1, 0);
   $self->pack_start (my $ntbook = $self->{ntbook} = Gtk2::Notebook->new, 1, 1, 0);
}

sub update_arch {
   my ($self, $arch, $key, $value) = @_;

   if ($value ne '') {

      my $al_arch = $Crossfire::ARCH{$arch->{_name}};
      if (ref $value) {
         $arch->{$key} = $value;

      } else {
         if (not defined $al_arch->{$key}) {
            if (not defined $value) {
               # try to normalize
               delete $arch->{$key};
            } else {
               # try to normalize
               $arch->{$key} = $value;
            }
         } else {
            if ($al_arch->{$key} ne $value) {
               $arch->{$key} = $value;
            } else {
               # try to normalize
               delete $arch->{$key};
            }
         }
      }

   } else {

      delete $arch->{$key};
   }

   $self->{change_cb}->($arch)
      if defined $self->{change_cb};
}

sub set_attr {
   my ($self, $key, $value) = @_;

   my $attr = $self->{arch}->{$key};

   unless (ref $attr) {

      $self->update_arch ($self->{arch}, $key, $value);
   }
}

sub set_arch {
   my ($self, $arch, $change_cb) = @_;

   $self->{change_cb} = $change_cb;

   $self->{arch} = $arch;

   my $ar = Crossfire::arch_attr $arch;

   $self->{arch_name_lbl}->set_text (
      $arch->{_name} . ($arch->{name} ? " - $arch->{name}" : "") . " ($ar->{name})"
   );

   my $al_arch = $Crossfire::ARCH{$arch->{_name}};
   $self->hide;
   $self->{ntbook}->remove ($_)
      for $self->{ntbook}->get_children;

#      warn "FO1:" . Data::Dumper::Dumper ($al_arch) . ">\n";
#      warn "FO2:" . Data::Dumper::Dumper ($ar) . ">\n";
#      warn "REAL: " . Data::Dumper::Dumper ($arch) . "\n";

   $self->{ttip} = Gtk2::Tooltips->new;

   #$self->add_section_edit_widgets ($self->{ntbook}, 'general', $arch, $ar->{attr});

   for my $sec (@{$ar->{section}}) {
      my $secname = shift @$sec;
      $self->add_section_edit_widgets ($self->{ntbook}, $secname, $arch, $sec);#$sects{$sec});
   }

   for my $key (qw/lore msg/) {
      $self->{ntbook}->append_page (my $v = Gtk2::VBox->new, $key);
         $v->pack_start (my $sw = Gtk2::ScrolledWindow->new, 1, 1, 0);
            $sw->set_policy ('automatic', 'automatic');
            $sw->add (my $tb = $self->{"${key}_txt"} = Gtk2::TextView->new);
               my $buf = $tb->get_buffer;
               $buf->set_text ($arch->{$key});
               $buf->signal_connect (changed => sub {
                  my ($buf) = @_;
                  $self->update_arch ($arch, $key,
                     $buf->get_text ($buf->get_start_iter, $buf->get_end_iter, 0)
                  );
               });
   }

   $self->{ntbook}->append_page (my $inv = GCE::InventoryEditor->new, 'inventory');
   $inv->set_arch ($arch, $change_cb);

   $self->{ttip}->enable;

   $self->show_all;
}

sub add_section_edit_widgets {
   my ($self, $ntbook, $name, $arch, $section) = @_;

   $self->{ntbook}->append_page (my $sw = Gtk2::ScrolledWindow->new, $name);
      $sw->set_policy ('always', 'always');
      $sw->add_with_viewport (my $vb = Gtk2::VBox->new);
      $vb->pack_start (my $table = new Gtk2::Table (2, $cnt), 0, 1, 0);

   my $i = 0;
   for my $sec (@$section) {
      my $bwid = Gtk2::EventBox->new;
      my $al = Gtk2::Alignment->new (0.0, 0.5, 0, 1);
      my $key = $sec->[0];
      $sec = $sec->[1];
      $al->add (Gtk2::Label->new (def ($sec->{name}, $key)));
      $bwid->add ($al);
      if ($sec->{desc} !~ m/^\s*$/s) {
         $self->{ttip}->set_tip ($bwid, $sec->{desc});
      }
      $table->attach ($bwid, 0, 1, $i, $i + 1, ['shrink','fill'], 'fill', 5, 0);

      $al = Gtk2::Alignment->new (0.0, 0.5, 1, 0);
      $al->add ($self->get_edit_widget ($key, $sec, $arch, $bwid));
      $table->attach ($al, 1, 2, $i, $i + 1, ['expand', 'fill'], 'expand', 0, 0);
      $i++;
   }
}

sub label_set_color_default {
   my ($self, $lbl, $arch, $key, $val) = @_;
   my $al_arch = $Crossfire::ARCH{$arch->{_name}};

#   my $fgcolor  = $lbl->get_default_style-> Gtk2::Gdk::Color->parse ("lightblue");
#   my $fgcolor2 = Gtk2::Gdk::Color->parse ("black");#grey");

   if (   (defined $al_arch->{$key} and $al_arch->{$key} ne $val)
       or (not (defined $al_arch->{$key}) and defined $val)) 
   {
      for (qw/normal active prelight selected insensitive/) {
         $lbl->modify_bg ($_, $lbl->get_default_style->bg ('active'));
         $lbl->modify_fg ($_, $lbl->get_default_style->fg ('active'));
      }
  } else {
     for (qw/normal active prelight selected insensitive/) {
        $lbl->modify_bg ($_, $lbl->get_default_style->bg ($_));
     }
  }
}

# XXX: Warning: Ugly code ahead:
sub get_edit_widget {
   my ($self, $key, $edspec, $arch, $lbl) = @_;

   my $type = $edspec->{type};
   my $al_arch = $Crossfire::ARCH{$arch->{_name}};

   if ($type eq 'bool') {
      my $boolval = def ($edspec->{value}, [0, 1]);

      my $chk = new Gtk2::CheckButton (def ($edspec->{name}, $key));

      $self->{ttip}->set_tip ($chk, $al_arch->{$key} * 1);

      $chk->set_active (def ($arch->{$key}, $al_arch->{$key}) == $boolval->[1]);
      $self->label_set_color_default ($lbl, $arch, $key, def ($arch->{$key}, $al_arch->{$key}));
      $chk->signal_connect (clicked => sub {
         my ($chk) = @_;
         $self->label_set_color_default ($lbl, $arch, $key, $boolval->[$chk->get_active * 1]);
         $self->update_arch ($arch, $key, $boolval->[$chk->get_active * 1]);
      });
      return $chk

   } elsif (grep { $type eq $_ } qw/string int treasurelist float/) {
      my $entry = new Gtk2::Entry;
      $self->{ttip}->set_tip ($entry, $al_arch->{$key});
      $entry->set_text (def ($arch->{$key}, $al_arch->{$key}));
      $self->label_set_color_default ($lbl, $arch, $key, def ($arch->{$key}, $al_arch->{$key}));
      $entry->signal_connect (changed => sub {
         my ($entry) = @_;
         $self->label_set_color_default ($lbl, $arch, $key, $entry->get_text);
         $self->update_arch ($arch, $key, $entry->get_text);
      });
      return $entry

   } elsif ($type eq 'spell' or $type eq 'nz_spell') { # XXX: nz_spell bug in datafiles?
      my $comb = Gtk2::ComboBox->new_text;
      my $spells_idx = {};
      my $spells_cmb_idx = {};
      my $sp = \%Crossfire::Data::SPELL;

      $comb->append_text ("<none>");

      my $idx = 1; # XXX: replace this idx with a more save/correct method?
      for (sort { $sp->{$a} cmp $sp->{$b} } keys %$sp) {
         $spells_cmd_idx{$idx} = $_;
         $spells_idx{$_} = $idx++;

         $comb->append_text ($sp->{$_});
      }
      #XXX: FIXME: $self->{ttip}->set_tip ($comb, $sp->{$al_arch->{$key}});
      $comb->set_active ($spells_idx{def ($arch->{$key}, $al_arch->{$key})});
      $self->label_set_color_default ($lbl, $arch, $key, def ($arch->{$key}, $al_arch->{$key}));

      $comb->signal_connect (changed => sub {
         my ($comb) = @_;
         $self->label_set_color_default ($lbl, $arch, $key, $spells_cmd_idx{$comb->get_active});
         $self->update_arch ($arch, $key, $spells_cmd_idx{$comb->get_active});
      });
      return $comb

   } elsif ($type eq 'bitmask') {
      my $lblb = Gtk2::Label->new ("bitmask: " . (def ($arch->{$key}, $al_arch->{$key})) * 1);
      my $btn = Gtk2::Button->new;
      $self->{ttip}->set_tip ($btn, $al_arch->{$key});
      $btn->add ($lblb);
      my $chval = def ($arch->{$key}, $al_arch->{$key});
      my $menu = $self->create_bitmask_menu ($edspec->{value}, $lbl, $lblb, $arch, $key, \$chval);

      $self->label_set_color_default ($lbl, $arch, $key, def ($arch->{$key}, $al_arch->{$key}));

      $btn->signal_connect (button_press_event => sub {
         my ($btn, $ev) = @_;
         $menu->popup (undef, undef, undef, undef, $ev->button, 0);
      });
      return $btn;

   } elsif ($type eq 'list') {
      my $lblb = Gtk2::Label->new ($edspec->{value}->{def($arch->{$key}, $al_arch->{$key}) * 1});
      my $btn = Gtk2::Button->new;
      $self->{ttip}->set_tip ($btn, $edspec->{value}->{$al_arch->{$key}});
      $btn->add ($lblb);
      my $menu = $self->create_list_menu ($edspec->{value}, $lbl, $lblb, $arch, $key);

      $self->label_set_color_default ($lbl, $arch, $key, def ($arch->{$key}, $al_arch->{$key}));

      $btn->signal_connect (button_press_event => sub {
         my ($btn, $ev) = @_;
         $menu->popup (undef, undef, undef, undef, $ev->button, 0);
      });
      return $btn;

   } elsif ($type eq 'fixed') {
      return Gtk2::Label->new ("$edspec->{name} = $edspec->{value}");

   } elsif ($type eq 'text') {
      return Gtk2::Label->new ("<see $key tab>");

   } else {
      return Gtk2::Label->new ("$key => $edspec->{name} ($type)");

   }
}

sub bitmask_to_list {
   my ($self, $bitlist, $bits) = @_;

   my @l;
   for (%$bitlist) {
      if ($bits & (1 << $_)) {
         push @l, $bitlist->{$_};
      }
   }
   return @l;
}

sub create_list_menu {
   my ($self, $list, $clbl, $lbl, $arch, $key) = @_;

   my $menu = Gtk2::Menu->new;

   for my $item (sort keys %$list) {
      my $lbltxt = $list->{$item};
      my $menuitem = Gtk2::MenuItem->new_with_label ($lbltxt);
      $menuitem->signal_connect (activate => sub {
         my ($menuitem) = @_;
         $lbl->set_text ($list->{$item});
         $self->label_set_color_default ($clbl, $arch, $key, $item);
         $self->update_arch ($arch, $key, $item);
      });
      $menu->append ($menuitem);
      $menuitem->show;
   }

   return $menu;
}

sub create_bitmask_menu {
   my ($self, $bits, $clbl, $lbl, $arch, $key, $rval) = @_;

   my $menu = Gtk2::Menu->new;

   for my $bit (keys %$bits) {
      my $lbltxt = $bits->{$bit};
      my $menuitem = Gtk2::CheckMenuItem->new_with_label ($lbltxt);
      if ($$rval & (1 << $bit)) {
         $menuitem->set_active (1);#$arch->{$key} & (1 << $bit));
      }
      $menuitem->signal_connect (toggled => sub {
         my ($menuitem) = @_;
         my $newval = $arch->{$key};
         $$rval &= ~(1 << $bit);
         $$rval |= (1 << $bit) if $menuitem->get_active;
         $lbl->set_text ("bitmask: " . ($$rval * 1));
         $self->label_set_color_default ($clbl, $arch, $key, $$rval);
         $self->update_arch ($arch, $key, $$rval);
      });
      $menu->append ($menuitem);
      $menuitem->show;
   }

   return $menu;
}


=head1 AUTHOR

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

 Robin Redeker <elmex@ta-sa.org>
 http://www.ta-sa.org/

=cut
1;