#! perl

# implement a replacement for the built-in chat/shout/tell/reply commands
# adds ignore/unignore functionality

sub clean_timeouts {
   my ($player) = @_;
   my $NOW = time;

   for my $hash (@$player{qw(ext_ignore_shout ext_ignore_tell)}) {
      delete $hash->{$_} for grep $hash->{$_} < $NOW, keys %$hash;
   }
}

sub on_logout {
   my ($pl, $host) = @_;

   clean_timeouts $pl->ob;
}

cf::register_command chat => 0, sub {
   my ($who, $msg) = @_;

   if ($msg) {
      my $name = $who->name;
      my $NOW = time;

      $_->ob->message ("$name chats: $msg", cf::NDI_BLUE)
         for grep $_->ob->{ext_ignore_shout}{$name} < $NOW, cf::player::list;

   } else {
      $who->message ("Chat what?", cf::NDI_UNIQUE);
   }
};

cf::register_command shout => 0, sub {
   my ($who, $msg) = @_;

   if ($msg) {
      my $NOW = time;
      my $name = $who->name;

      $_->ob->message ("$name shouts: $msg", cf::NDI_RED)
         for grep $_->ob->{ext_ignore_shout}{$name} < $NOW, cf::player::list;

   } else {
      $who->message ("Shout what?", cf::NDI_UNIQUE);
   }

};

cf::register_command tell => 0, sub {
   my ($who, $args) = @_;
   my ($target, $msg) = split /\s+/, $args, 2;

   my $name = $who->name;

   if ($msg) {
      if (my $other = cf::player::find $target) {

         if ($target ne $name and $other->ob->{ext_ignore_tell}{$name} < time) {
            $who->message ("You tell $target: $msg");
            $other->ob->message ("$name tells you: $msg");
            $other->ob->{ext_last_tell} = $name;
         } elsif ($target eq $name) {
            $who->message ("You are talking to yourself, you freak!", cf::NDI_UNIQUE);
         } else {
            $who->message ($other->ob->name . " ignores what you say. Give up on it.", cf::NDI_UNIQUE);
         }

      } else {
         $who->message ("No such player or ambiguous name. Your message: $msg", cf::NDI_UNIQUE);
      }
   } else {
      $who->message ("What do you want to tell $target?", cf::NDI_UNIQUE);
   }
};

cf::register_command reply => 0, sub {
   my ($who, $args) = @_;
   my $name = $who->name;

   if ($args) {
      if (my $other = cf::player::find $who->{ext_last_tell}) {

         $other->ob->{ext_ignore_tell}{$name} >= time
            or delete $other->ob->{ext_ignore_tell}{$name};

         if ($other->ob->{ext_ignore_tell}{$name} < time) {
            $who->message ("You tell " . $other->ob->name . ": $args");
            $other->ob->message ("$name tells you: $args");
            $who->{ext_last_tell} = $other->ob->name;
         } else {
            $who->message ($other->ob->name . " ignores what you say. Give up on it.", cf::NDI_UNIQUE);
         }

      } else {
         $who->message ("Can't reply, player left. Your message: $args", cf::NDI_UNIQUE);
      }
   } else {
      $who->message ("What do you want to tell ".$other->ob->name."?", cf::NDI_UNIQUE);
   }
};

cf::register_command ignore => 0, sub {
   my ($who, $args) = @_;
   my ($target, $type, $timeout) = split /\s+/, $args;

   if ($args eq "list") {
      clean_timeouts $who;

      if ((my @ignored_tell = sort keys %{$who->{ext_ignore_tell}})
          + (my @ignored_shout = sort keys %{$who->{ext_ignore_shout}})) {
         $who->message ("Currently ignoring private messages from: ", cf::NDI_UNIQUE);
         $who->message ((join ", ", @ignored_tell), cf::NDI_UNIQUE);
         $who->message ("Currently ignoring shouts from: ", cf::NDI_UNIQUE);
         $who->message ((join ", ", @ignored_shout), cf::NDI_UNIQUE);
         $who->message ("To stop ignoring one, use unignore.", cf::NDI_UNIQUE);
      } else {
         $who->message ("Not ignoring anyone", cf::NDI_UNIQUE);
      }

   } elsif ($target && $type) {

      $timeout ne "" or $timeout = 24;

      my $absolute_timeout = time + $timeout * 3600;

      if (my $other = cf::player::find $target) {
         if ($type eq "tell") {
            $who->message ("Now ignoring private messages from " . $other->ob->name . " for $timeout hours.", cf::NDI_UNIQUE);
            $who->{ext_ignore_tell}{$other->ob->name}  = $absolute_timeout;
         } elsif ($type eq "shout") {
            $who->message ("Now ignoring shouts from " . $other->ob->name . " for $timeout hours.", cf::NDI_UNIQUE);
            $who->{ext_ignore_shout}{$other->ob->name} = $absolute_timeout;
         } elsif ($type eq "all") {
            $who->message ("Now ignoring everything from " . $other->ob->name . " for $timeout hours.", cf::NDI_UNIQUE);
            $who->{ext_ignore_tell}{$other->ob->name}  = $absolute_timeout;
            $who->{ext_ignore_shout}{$other->ob->name} = $absolute_timeout;
         } else {
            $who->message ("You need to specify tell, shout or all.", cf::NDI_UNIQUE);
         }
      } else {
         $who->message ("No such player or ambiguous name: $target", cf::NDI_UNIQUE);
      }

   } else {
      $who->message ("Usage:", cf::NDI_UNIQUE);
      $who->message ("ignore <player> <tell | shout | all> <timeout>", cf::NDI_UNIQUE);
      $who->message ("will ignore a player for <timeout> hours.", cf::NDI_UNIQUE);
      $who->message ("ignore list", cf::NDI_UNIQUE);
      $who->message ("will show you a list of players currently ignored.", cf::NDI_UNIQUE);
   }
};

cf::register_command unignore => 0, sub {
   my ($who, $args) = @_;
   my ($target, $type) = split /\s+/, $args;

   if ($args eq "") {
      if ($who->{ ext_ignore_tell }) {
         $who->message ("Currently ignoring private messages from: ", cf::NDI_UNIQUE);
         $who->message ((join ", ", sort keys %{ $who->{ext_ignore_tell} }), cf::NDI_UNIQUE);
         $who->message ("Currently ignoring shouts from: ", cf::NDI_UNIQUE);
         $who->message ((join ", ", sort keys %{ $who->{ext_ignore_shout} }), cf::NDI_UNIQUE);
      } else {
         $who->message ("Not ignoring anyone", cf::NDI_UNIQUE);
      }
   } else {

      if (my $other = cf::player::find $target) {
         if ($type eq "tell") {
            $who->message ("Not ignoring private messages from " . $other->ob->name . " anymore.", cf::NDI_UNIQUE);
            delete $who->{ext_ignore_tell}{$other->ob->name};
         } elsif ($type eq "shout") {
            $who->message ("Not ignoring shouts from " . $other->ob->name." anymore . ", cf::NDI_UNIQUE);
            delete $who->{ext_ignore_shout}{$other->ob->name};
         } elsif ($type eq "all") {
            $who->message ("Not ignoring anything from " . $other->ob->name." anymore . ", cf::NDI_UNIQUE);
            delete $who->{ext_ignore_tell} {$other->ob->name};
            delete $who->{ext_ignore_shout}{$other->ob->name};
         } else {
            $who->message ("You need to specify tell, shout or all.", cf::NDI_UNIQUE);
         }
      } else {
         $who->message ("No such player or ambiguous name: $target", cf::NDI_UNIQUE);
      }

   }
};