dnl Process this file with autoconf to produce a configure script.

AC_INIT([crossfire], [2.0+], [crossfire@schmorp.de])
AC_CONFIG_AUX_DIR(utils)
AC_CONFIG_SRCDIR([server/main.C])
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(include/autoconf.h)

AM_MAINTAINER_MODE

AC_PREFIX_DEFAULT(/usr/games/crossfire)

dnl Checks for programs.
AC_LANG(C++)
AC_PROG_CXX
AC_PROG_LIBTOOL

case "$target" in
  alpha-dec-osf*)
    # If we are not using gcc, we want the ansi version of cc.
    if test -z "$GCC"; then
#      CFLAGS="$CFLAGS -std1 -warnprotos" # Not yet ready for warnprotos...
      CFLAGS="$CFLAGS -std1"
    fi
    ;;
  *)
    ;;
esac

AC_PROG_CPP

AC_PATH_PROG(PERL, perl5.8)
AC_PATH_PROG(PERL, perl5)
AC_PATH_PROG(PERL, perl)

for module_vers in "Coro 3.5" "Coro::Event 2.1" "Event 1.08" \
                   "IO::AIO 2.32" "BDB 0.1" "Storable 2.0" "Time::HiRes 1.0" "YAML::Syck 0.71" \
                   "Digest::MD5 2.0" "Compress::LZF 1.7" "Safe::Hole 0.10" "Pod::POM 0.17"; do
   set -- $module_vers
   module=$1
   minvers=$2
   AC_MSG_CHECKING(for $module perl module version $minvers or higher)
   if $PERL -M$module -e0 >/dev/null 2>&1; then
      version=`$PERL -M$module -e "print \\$$module::VERSION"`
      if $PERL -M$module=$minvers -e0 >/dev/null 2>&1; then
         AC_MSG_RESULT([ok, version $version])
      else
         AC_MSG_ERROR([no, installed version is $version])
      fi
   else
      AC_MSG_ERROR([no, cannot load module $module])
   fi
done

AC_MSG_CHECKING(for $PERL suitability)
if $PERL -MExtUtils::Embed -e "use v5.8" >/dev/null 2>&1; then
  save_CXXFLAGS="$CXXFLAGS"
  save_LIBS="$LIBS"
  xPERLFLAGS="`$PERL -MExtUtils::Embed -e ccopts`"
  xPERLFLAGS="$xPERLFLAGS `$PERL -MEvent::MakeMaker -e 'print +{&Event::MakeMaker::event_args}->{INC}'`"
  xPERLFLAGS="$xPERLFLAGS `$PERL -MCoro::MakeMaker -e 'print +{&Coro::MakeMaker::coro_args}->{INC}'`"
  CXXFLAGS="$CXXFLAGS $xPERLFLAGS"
  LIBS="$LIBS `$PERL -MExtUtils::Embed -e ldopts`"
  AC_TRY_LINK([
#include <EXTERN.h>
#include <perl.h>
#include <XSUB.h>
#include "EventAPI.h"
],[
  PerlInterpreter *perl = perl_alloc ();
],[perl_link=yes],[perl_link=no])
  CXXFLAGS="$save_CXXFLAGS"
  LIBS="$save_LIBS"

  if test x$perl_link = xyes; then
     AC_MSG_RESULT(ok)
     AC_DEFINE(ENABLE_PERL, 1, Define if you can embed a perl interpreter)
     PERLFLAGS="$xPERLFLAGS"
     PERLLIB="`$PERL -MExtUtils::Embed -e ldopts`"
     PERLPRIVLIBEXP="`$PERL -MConfig -e 'print $Config{privlibexp}'`"
     CPPFLAGS="$CPPFLAGS $PERLFLAGS"
  else
     AC_MSG_ERROR([no, unable to link])
  fi
else
  AC_MSG_ERROR([no working perl found, or perl not version >= 5.8])
fi
AC_SUBST(PERLLIB)
AC_SUBST(PERLFLAGS)
AC_SUBST(PERLPRIVLIBEXP)
AC_SUBST(PERL)

dnl check for some other programs
AC_PATH_PROG(TAR, tar)
AC_PATH_PROG(BASENAME, basename)

AC_PATH_PROG(GPERF, gperf)
if test -z "$GPERF"; then
   AC_MSG_ERROR([we need gperf, the GNU perfect hash generator])
fi

AC_CHECK_LIB(nsl, main)
AC_CHECK_LIB(socket, main)

dnl Checks for libraries.
AC_CHECK_LIB(m, main)

AC_CHECK_HEADER(tr1/unordered_map,[],[AC_MSG_ERROR([Your compiler must support the Library Technical Report 1 extensions.])])

AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(long long)

AC_PATH_PROG(PKG_CONFIG, pkg-config, no)

AC_MSG_CHECKING(glib >= 2.10)
if $PKG_CONFIG glib-2.0 --atleast-version 2.10; then
   CXXFLAGS="$CXXFLAGS `$PKG_CONFIG glib-2.0 --cflags`"
   LIBS="$LIBS `$PKG_CONFIG glib-2.0 --libs`"
   AC_MSG_RESULT(ok)
else
   AC_MSG_ERROR(no)
fi

AC_MSG_CHECKING(libpng)
if $PKG_CONFIG libpng --exists; then
   CXXFLAGS="$CXXFLAGS `$PKG_CONFIG libpng --cflags`"
   LIBS="$LIBS `$PKG_CONFIG libpng --libs`"
   AC_MSG_RESULT(ok)
else
   AC_MSG_ERROR(no)
fi

AC_SUBST(x_includes)
AC_SUBST(x_libraries)
AC_SUBST(no_x)
AM_CONDITIONAL(HAVE_X,test "x$no_x" = "x")
AC_SUBST(X11LIBS)

AC_SUBST(pkgstatedir,$localstatedir/$PACKAGE)
AC_SUBST(pkgconfdir,$sysconfdir/$PACKAGE)

AC_OUTPUT([Makefile
	include/Makefile lib/Makefile pod/Makefile random_maps/Makefile socket/Makefile
	server/Makefile src/Makefile utils/Makefile ext/Makefile
	lib/checkarch.pl lib/collect.pl utils/add_throw.perl
	utils/crossloop.tmpl utils/crossloop.pl.tmpl utils/metaserver.pl
	utils/crossloop.web utils/scores.pl utils/player_dl.pl common/Makefile
])