1 |
#! perl # mandatory depends=irc |
2 |
|
3 |
use POSIX (); |
4 |
|
5 |
# miscellaneous commands |
6 |
|
7 |
sub rename_to($$$) { |
8 |
my ($ob, $from, $to) = @_; |
9 |
|
10 |
$to =~ /^[a-zA-Z0-9.,=#\/%$!^ ]*$/ |
11 |
or return $ob->message ("rename: name must consist only of letters, digits, spaces and a few other things."); |
12 |
|
13 |
127 >= length $to |
14 |
or return $ob->message ("rename: new name must be <= 127 characters."); |
15 |
|
16 |
my $item; |
17 |
|
18 |
if (length $from) { |
19 |
$item = $ob->find_best_object_match ($from) |
20 |
or return $ob->message ("rename: could not find a matching item to rename."); |
21 |
} else { |
22 |
$item = $ob->find_marked_object |
23 |
or return $ob->message ("rename: no from name and no marked item found to rename."); |
24 |
} |
25 |
|
26 |
$item->custom_name (length $to ? $to : undef); |
27 |
|
28 |
if (length $to) { |
29 |
$item->custom_name ($to); |
30 |
$ob->message ("Your " . $item->base_name . " will now be called $to."); |
31 |
} else { |
32 |
$item->custom_name (undef); |
33 |
$ob->message ("You stop calling your " . $item->base_name . " with weird names."); |
34 |
} |
35 |
|
36 |
$ob->esrv_update_item (cf::UPD_NAME, $item); |
37 |
|
38 |
1 |
39 |
} |
40 |
|
41 |
sub who_listing(;$$) { |
42 |
my ($privileged, $select) = @_; |
43 |
|
44 |
my ($numwiz, $numafk) = (0, 0); |
45 |
my @pl; |
46 |
|
47 |
foreach my $pl (cf::player::list) { |
48 |
my $ns = $pl->ns or next; |
49 |
my $ob = $pl->ob; |
50 |
|
51 |
next unless $ob->map |
52 |
&& ($privileged || !$pl->hidden); |
53 |
|
54 |
$numwiz++ if $ob->flag (cf::FLAG_WIZ); |
55 |
$numafk++ if $ns->afk; |
56 |
|
57 |
push @pl, $pl; |
58 |
} |
59 |
|
60 |
( |
61 |
"Total Players in The World. (" . (scalar @pl) . ") -- WIZ($numwiz) AFK($numafk) BOT(0)", |
62 |
(grep /$select/, |
63 |
map { |
64 |
my ($pl, $ob, $ns) = ($_, $_->ob, $_->ns); |
65 |
|
66 |
"* " . $ob->name . "/" . $ob->level . " " . (length $pl->own_title ? $pl->own_title : "the " . $pl->title) |
67 |
. ($pl->gender ? " [f]" : " [m]") |
68 |
. ($pl->peaceful ? " [peaceful]" : " [HOSTILE]") |
69 |
. ($ns->afk ? " [AFK]" : "") |
70 |
. ($ob->flag (cf::FLAG_WIZ) ? " [WIZ]" : "") |
71 |
. " [" . $pl->ns->version . "]" |
72 |
. " [" . ($pl->peaceful || $privileged ? $ob->map->visible_name : $ob->region->name) . "]" |
73 |
. (sprintf " [rtt %.3fs]", $pl->ns->rtt * 1e-6) |
74 |
. ($privileged ? " " . $pl->ns->host : "") |
75 |
} sort { (lc $a->ob->name) cmp (lc $b->ob->name) } @pl |
76 |
), |
77 |
eval { "* IRC: " . join ", ", ext::irc::users }, |
78 |
) |
79 |
} |
80 |
|
81 |
cf::register_command who => sub { |
82 |
my ($ob, $arg) = @_; |
83 |
|
84 |
$ob->speed_left ($ob->speed_left - 4); |
85 |
|
86 |
$ob->reply (undef, (join "\n", who_listing $ob->may ("extended_who"), $arg), cf::NDI_UNIQUE | cf::NDI_DK_ORANGE); |
87 |
|
88 |
1 |
89 |
}; |
90 |
|
91 |
cf::register_command seen => sub { |
92 |
my ($pl, $args) = @_; |
93 |
|
94 |
if (my ($login) = $args =~ /(\S+)/) { |
95 |
if ($login eq $pl->name) { |
96 |
$pl->message ("Very funny, $login. Ha. Ha.", cf::NDI_UNIQUE); |
97 |
} elsif (cf::player::find_active $login) { |
98 |
$pl->message ("$login is right here on this server!", cf::NDI_UNIQUE); |
99 |
} elsif (cf::player::exists $login |
100 |
and stat cf::player::path $login) { |
101 |
my $time = (stat _)[9]; |
102 |
|
103 |
$pl->message ("$login was last seen here " |
104 |
. (POSIX::strftime "%Y-%m-%d %H:%M:%S +0000", gmtime $time) |
105 |
. " which was " . (int +(time - $time) / 3600) . " hours ago.", cf::NDI_UNIQUE); |
106 |
} else { |
107 |
$pl->message ("No player named $login is known to me.", cf::NDI_UNIQUE); |
108 |
} |
109 |
} else { |
110 |
$pl->message ("Usage: seen <player>", cf::NDI_UNIQUE); |
111 |
} |
112 |
}; |
113 |
|
114 |
cf::register_command body => sub { |
115 |
my ($ob) = @_; |
116 |
|
117 |
# Too hard to try and make a header that lines everything up, so just |
118 |
# give a description. (comment from C++) |
119 |
my $reply = |
120 |
"The first column is the name of the body location.\n" |
121 |
. "The second column is how many of those locations your body has.\n" |
122 |
. "The third column is how many slots in that location are available.\n"; |
123 |
|
124 |
$reply .= sprintf "%-20s %3s %5s\n", "Location", "You", "Avail"; |
125 |
for (0 .. cf::NUM_BODY_LOCATIONS - 1) { |
126 |
my $msg = cf::object::slot_nonuse_name $_; |
127 |
$msg =~ s/^.*? a //; |
128 |
$reply .= sprintf "%-20s %3d %5d\n", $msg, $ob->slot_info ($_), $ob->slot_used ($_) |
129 |
if $ob->slot_info ($_) or $ob->slot_used ($_); |
130 |
} |
131 |
|
132 |
$reply .= "You are not allowed to wear armor\n" |
133 |
unless $ob->flag (cf::FLAG_USE_ARMOUR); |
134 |
$reply .= "You are not allowed to use weapons\n" |
135 |
unless $ob->flag (cf::FLAG_USE_WEAPON); |
136 |
|
137 |
$ob->reply (undef, $reply); |
138 |
|
139 |
1 |
140 |
}; |
141 |
|
142 |
cf::register_command mark => sub { |
143 |
my ($pl, $arg) = @_; |
144 |
|
145 |
if (length $arg) { |
146 |
my $ob = $pl->find_best_object_match ($arg); |
147 |
|
148 |
return $pl->reply (undef, "Could not find an object that matches $arg") |
149 |
unless $ob; |
150 |
|
151 |
$pl->contr->mark ($ob); |
152 |
$pl->reply (undef, (sprintf "Marked item %s", $ob->name, $ob->title)); |
153 |
} else { |
154 |
my $ob = $pl->find_marked_object; |
155 |
|
156 |
$pl->reply (undef, $ob |
157 |
? (sprintf "%s %s * is marked.", $ob->name, $ob->title) |
158 |
: "You have no marked object."); |
159 |
} |
160 |
|
161 |
1 |
162 |
}; |
163 |
|
164 |
for my $cmd ("run", "fire") { |
165 |
my $oncmd = "${cmd}_on"; |
166 |
cf::register_command $cmd => sub { |
167 |
my ($ob, $arg) = @_; |
168 |
|
169 |
$ob->reply (undef, "Can't $cmd into a non adjacent square.") |
170 |
if $arg < 0 or $arg >= 9; |
171 |
|
172 |
$ob->contr->$oncmd (1); |
173 |
$ob->move_player ($arg); |
174 |
|
175 |
1 |
176 |
}; |
177 |
|
178 |
cf::register_command "${cmd}_stop" => sub { |
179 |
my ($ob) = @_; |
180 |
|
181 |
$ob->contr->$oncmd (0); |
182 |
|
183 |
1 |
184 |
}; |
185 |
} |
186 |
|
187 |
cf::register_command mapinfo => sub { |
188 |
my ($ob) = @_; |
189 |
|
190 |
my $map = $ob->map |
191 |
or return; |
192 |
$ob->reply (undef, (sprintf "%s (%s) %s", $map->name, $map->path, $ob->region->longname)); |
193 |
$ob->reply (undef, (sprintf "players: %d difficulty: %d size: %d start: %dx%d timeout: %d", |
194 |
$map->players, $map->difficulty, $map->width, $map->height, $map->enter_x, $map->enter_y, $map->timeout)) |
195 |
if $ob->flag (cf::FLAG_WIZ); |
196 |
$ob->reply (undef, $map->msg); |
197 |
|
198 |
1 |
199 |
}; |
200 |
|
201 |
cf::register_command whereami => sub { |
202 |
my ($ob) = @_; |
203 |
|
204 |
my $reg = $ob->region; |
205 |
$ob->reply (undef, (sprintf "You are %s.\n%s", $reg->longname, $reg->msg)); |
206 |
|
207 |
1 |
208 |
}; |
209 |
|
210 |
sub _set_mode($$$@) { |
211 |
my ($name, $ob, $arg, $slot, @choices) = @_; |
212 |
|
213 |
my $oldmode = $ob->contr->$slot; |
214 |
|
215 |
return $ob->reply (undef, "$name is set to $choices[$oldmode]") |
216 |
unless $arg; |
217 |
|
218 |
my ($idx) = grep $choices[$_] eq $arg, 0 .. $#choices |
219 |
or return $ob->reply (undef, "$name: Unknown options '$arg', valid options are @choices"), 1; |
220 |
|
221 |
$ob->contr->$slot ($idx); |
222 |
$ob->reply (undef, "$name" . ($oldmode == $ob->contr->unapply ? "" : " now") . " set to " . $choices[$ob->contr->$slot]); |
223 |
} |
224 |
|
225 |
cf::register_command applymode => sub { |
226 |
my ($ob, $arg) = @_; |
227 |
|
228 |
_set_mode "applymode", $ob, $arg, unapply => qw(nochoice never always); |
229 |
|
230 |
1 |
231 |
}; |
232 |
|
233 |
cf::register_command petmode => sub { |
234 |
my ($ob, $arg) = @_; |
235 |
|
236 |
_set_mode "petmode", $ob, $arg, petmode => qw(normal sad defend arena); |
237 |
|
238 |
1 |
239 |
}; |
240 |
|
241 |
cf::register_command usekeys => sub { |
242 |
my ($ob, $arg) = @_; |
243 |
|
244 |
_set_mode "usekeys", $ob, $arg, usekeys => qw(inventory keyrings containers); |
245 |
|
246 |
1 |
247 |
}; |
248 |
|
249 |
cf::register_command afk => sub { |
250 |
my ($ob, $arg) = @_; |
251 |
|
252 |
$ob->contr->ns->afk ($ob->contr->ns->afk ? 0 : 1); |
253 |
$ob->reply (undef, $ob->contr->ns->afk ? "You are now AFK" : "You are no longer AFK"); |
254 |
|
255 |
1 |
256 |
}; |
257 |
|
258 |
cf::register_command sound => sub { |
259 |
my ($ob, $arg) = @_; |
260 |
|
261 |
$ob->contr->ns->sound ($ob->contr->ns->sound ? 0 : 1); |
262 |
$ob->reply (undef, $ob->contr->ns->sound ? "The sounds are enabled." : "Silence is golden..."); |
263 |
|
264 |
1 |
265 |
}; |
266 |
|
267 |
cf::register_command brace => sub { |
268 |
my ($ob, $arg) = @_; |
269 |
|
270 |
$ob->contr->braced ($ob->contr->braced ? 0 : 1); |
271 |
$ob->reply (undef, $ob->contr->braced ? "You are braced." : "Not braced."); |
272 |
|
273 |
1 |
274 |
}; |
275 |
|
276 |
cf::register_command 'output-rate' => sub { |
277 |
my ($ob, $arg) = @_; |
278 |
|
279 |
return $ob->reply (undef, sprintf "Output rate is presently %dbps.", $ob->contr->ns->max_rate / $cf::TICK) |
280 |
unless $arg > 0; |
281 |
|
282 |
# minimum is 2k/s |
283 |
$ob->contr->ns->max_rate ((List::Util::max 2048, $arg) * $cf::TICK); |
284 |
$ob->reply (undef, sprintf "Output rate now set to %dbps.", $ob->contr->ns->max_rate / $cf::TICK); |
285 |
|
286 |
1 |
287 |
}; |
288 |
|
289 |
cf::register_command 'output-count' => sub { |
290 |
my ($ob, $arg) = @_; |
291 |
|
292 |
return $ob->reply (undef, "Output count is presently " . $ob->contr->outputs_count) |
293 |
unless $arg > 0; |
294 |
|
295 |
$arg = 4 if $arg < 4; |
296 |
|
297 |
$ob->contr->outputs_count ($arg); |
298 |
$ob->reply (undef, "Output count now set to " . $ob->contr->outputs_count); |
299 |
|
300 |
1 |
301 |
}; |
302 |
|
303 |
cf::register_command 'output-sync' => sub { |
304 |
my ($ob, $arg) = @_; |
305 |
|
306 |
return $ob->reply (undef, sprintf "Output sync time is presently %.1fs", $ob->contr->outputs_sync * $cf::TICK) |
307 |
unless length $arg; |
308 |
|
309 |
$arg = 0.5 if $arg < 0.5; |
310 |
|
311 |
$ob->contr->outputs_sync ($arg / $cf::TICK); |
312 |
$ob->reply (undef, sprintf "Output sync time now set to %.1fs", $ob->contr->outputs_sync * $cf::TICK); |
313 |
|
314 |
1 |
315 |
}; |
316 |
|
317 |
# XXX: This has a bug. After one sets his wimpy level to 0 and resets it to |
318 |
# some other level (which may also be 0), this does not get echoed, |
319 |
# but it does get set. |
320 |
cf::register_command wimpy => sub { |
321 |
my ($ob, $arg) = @_; |
322 |
|
323 |
my $wimpy = $ob->run_away; |
324 |
return $ob->reply (undef, "Your current wimpy level is $wimpy.") |
325 |
if $arg eq ""; |
326 |
|
327 |
return $ob->run_away ($arg) && $ob->reply (undef, "Your new wimpy level is $arg.") |
328 |
if $arg =~ /^\d+$/ and $arg <= 100; |
329 |
|
330 |
$ob->reply (undef, "Incorrect parameters for wimpy: $arg"); |
331 |
|
332 |
1 |
333 |
}; |
334 |
|
335 |
cf::register_command peaceful => sub { |
336 |
my ($ob, $arg) = @_; |
337 |
|
338 |
$ob->reply (undef, "You cannot change your peaceful setting with this command." |
339 |
." Please speak to the priest in the temple of Gorokh" |
340 |
." if you want to become hostile or in temple of Valriel" |
341 |
." if you want to become peaceful again."); |
342 |
|
343 |
#$ob->contr->peaceful ($ob->contr->peaceful ? 0 : 1); |
344 |
#$ob->reply (undef, $ob->contr->peaceful ? "You will attack other players." : "You will not attack other players."); |
345 |
|
346 |
1 |
347 |
}; |
348 |
|
349 |
cf::register_command rename => sub { |
350 |
my ($ob, $arg) = @_; |
351 |
|
352 |
$ob->speed_left ($ob->speed_left - 0.25); |
353 |
|
354 |
if ($arg =~ /^\s* (?: <([^>]+)> \s+)? to \s+ <([^>]*)> \s*$/x) { |
355 |
# compatibility syntax |
356 |
rename_to $ob, $1, $2; |
357 |
} elsif ($arg =~ / |
358 |
^\s* |
359 |
(?: |
360 |
(?: "((?:[^"]+|\\.)*)" | (\S+) ) |
361 |
\s+)? |
362 |
to \s+ |
363 |
(?: "((?:[^"]+|\\.)*)" | (\S+) ) |
364 |
\s*$ |
365 |
/x) { |
366 |
# does not unquote $1 or $3 |
367 |
rename_to $ob, $2||$1, $4||$3; |
368 |
} else { |
369 |
$ob->reply (undef, 'Syntax error. Rename usage: rename ["oldname"] to "newname"'); |
370 |
} |
371 |
|
372 |
1 |
373 |
}; |
374 |
|
375 |
cf::register_command uptime => sub { |
376 |
my ($ob, $arg) = @_; |
377 |
|
378 |
my $startup = POSIX::strftime "%Y-%m-%d %H:%M:%S %Z", localtime $cf::UPTIME; |
379 |
my $runtime = sprintf "%.1f", (time - $cf::UPTIME) / 86400; |
380 |
$ob->reply (undef, "server started $startup, uptime ${runtime}\d"); |
381 |
|
382 |
1 |
383 |
}; |
384 |
|
385 |
my %IN_MEMORY = ( |
386 |
cf::MAP_IN_MEMORY => "I", |
387 |
cf::MAP_SWAPPED => "S", |
388 |
cf::MAP_LOADING => "L", |
389 |
); |
390 |
|
391 |
cf::register_command maps => sub { |
392 |
my ($ob, $arg) = @_; |
393 |
|
394 |
no re 'eval'; $arg = qr<$arg>; |
395 |
|
396 |
my $format = "%2s %1s %3s %5s %.60s\n"; |
397 |
|
398 |
$ob->reply (undef, (sprintf $format, "Pl", "I", "Svd", "Reset", "Name"), cf::NDI_BLACK | cf::NDI_UNIQUE); |
399 |
|
400 |
for (sort keys %cf::MAP) { |
401 |
my $map = $cf::MAP{$_} |
402 |
or next; |
403 |
|
404 |
next unless $map->path =~ $arg; |
405 |
next if $map->{deny_list}; |
406 |
|
407 |
my $svd = int $cf::RUNTIME - $map->{last_save}; |
408 |
$svd = "++" if $svd > 99; |
409 |
|
410 |
$ob->reply (undef, |
411 |
(sprintf $format, |
412 |
(scalar $map->players), |
413 |
$IN_MEMORY{$map->in_memory} || "?", |
414 |
$svd, |
415 |
(int $map->reset_at - $cf::RUNTIME), |
416 |
$map->visible_name), |
417 |
cf::NDI_BLACK | cf::NDI_UNIQUE); |
418 |
} |
419 |
|
420 |
1 |
421 |
}; |
422 |
|