#! perl

use Coro::Debug;
use IO::Socket;

my %global; # for use by eval'ed commands

sub tcp_serve($) {
   my ($fh) = @_;

   binmode $fh, ":raw:perlio:utf8";

   my $buf;
   my ($a, $b, $c, $d, $e, $f, $g, $h, $i, $j, $k, $l, $m, $n, $o, $p, $q, $r, $s, $t, $u, $v, $w, $x, $y, $z);
   my (%l, @l); # for use by shell users

   print $fh <<EOF;
Welcome!
Remember that everything entered here will be in the main coro context within cf::!
You can freely use \$a .. \$z and \@l and \%l

Useful commands (note the '&'):

reload_pod &
reload_perl &
reload_sound &
reload_config &
reload_regions &
reload_facedata &
reload_exp_table &
reload_materials &
reload_treasures &
reload_resources &
reload_archetypes &
ext::help::reload &
ext::books::reload &
ext::map_tags::reload &
ext::map_world::reload &
ext::player_env::reload &
ext::map_scheduler::reload &
# ext::map_scheduler::loadall & # debugging only!
until (Coro::AnyEvent::readable \$fh, 1) { Coro::Debug::command "ps" } &
({mallinfo})
({objinfo})
EOF
   print $fh "\n> ";

   my $iow; $iow = AE::io $fh, 0, sub {
      if (defined (my $cmd = <$fh>)) {
         $cmd =~ s/\s+$//;

         if ($cmd =~ /^\s*exit\b/i) {
            print $fh "will not exit() server.\n";
         } elsif ($cmd =~ s/^coro\s+// or $cmd =~ /^(?:ps|bt\s)/) {
            select $fh;
            Coro::Debug::command $cmd;
            select STDOUT;
         } else {
            my $sub = sub {
               package cf;
               select $fh;

               # compile first, then execute, as Coro does not support switching in eval string
               my $cb = eval "sub { $cmd \n}";

               my $t1 = Time::HiRes::time;
               my @res = $@ ? () : eval { $cb->() };
               my $t2 = Time::HiRes::time;

               print "\n",
                     "command: '$cmd'\n",
                     "execution time: ", $t2 - $t1, "\n";
               print "evaluation error: $@\n" if $@;
               print "result:\n", cf::dumpval @res > 1 ? \@res : $res[0] if @res;
               print "\n> ";

               select STDOUT;
            };

            if ($cmd =~ s/\s*&$//) {
               cf::async {
                  $Coro::current->desc ($cmd);
                  $sub->()
               };
            } else {
               $sub->();
            }
         }

         print $fh "\n> ";
      } else {
         undef $iow;
      }
   };
}

our $LISTENER;

# now a shell listening on a tcp-port - let the firewall decide access rights
if ($cf::CFG{perl_shell}) {
   if (my $listen = new IO::Socket::INET LocalAddr => $cf::CFG{perl_shell}, Listen => 1, ReuseAddr => 1, Blocking => 0) {
      $LISTENER = AE::io $listen, 0, sub { tcp_serve $listen->accept };
   }
}