1 |
#! perl |
2 |
|
3 |
# implement the invite command |
4 |
|
5 |
# level 1: invite to private rooms only ~lvl 10 |
6 |
# level 2: private rooms and saving maps (guilds, some other public saving maps) |
7 |
# level 3: invite everywhere where no monsters are on the map |
8 |
# level 4: invite everywhere |
9 |
|
10 |
my $TIMEOUT = $cf::CFG{invite_timeout} || 60; |
11 |
|
12 |
# determine whether map cell is damned |
13 |
sub is_damned { |
14 |
my ($map, $x, $y) = @_; |
15 |
return grep $_->flag (cf::FLAG_DAMNED), $map->at ($x, $y); |
16 |
} |
17 |
|
18 |
# determine level available to the player |
19 |
sub player_level { |
20 |
my ($ob) = @_; |
21 |
|
22 |
return 4 |
23 |
if $ob->flag (cf::FLAG_WIZ); |
24 |
|
25 |
List::Util::max |
26 |
map $_->type == cf::FORCE && $_->slaying =~ /^Invitor Level (\d+)$/ ? $1 : 0, |
27 |
$ob->inv |
28 |
} |
29 |
|
30 |
# determine level required for the given location |
31 |
sub map_level { |
32 |
my ($map, $x, $y) = @_; |
33 |
|
34 |
for my $x (0 .. $map->width - 1) { |
35 |
for my $y (0 .. $map->height - 1) { |
36 |
return 4 |
37 |
if grep $_->flag (cf::FLAG_MONSTER), |
38 |
$map->at ($x, $y); |
39 |
} |
40 |
} |
41 |
|
42 |
if ($map->path =~ /^~/) { |
43 |
1 |
44 |
} elsif (grep $_->flag (cf::FLAG_UNIQUE) && $_->flag (cf::FLAG_IS_FLOOR), $map->at ($x, $y)) { |
45 |
2 |
46 |
} else { |
47 |
3 |
48 |
} |
49 |
} |
50 |
|
51 |
my @maplevel = ( |
52 |
"some mysterious hideout", |
53 |
"his home", |
54 |
"his guild", # wrong, this is any unique place !player-specific |
55 |
"a nice place", |
56 |
"a place with monsters", |
57 |
); |
58 |
|
59 |
my %invite; |
60 |
|
61 |
cf::register_command invite => sub { |
62 |
my ($who, $args) = @_; |
63 |
|
64 |
$who->speed_left ($who->speed_left - 0.2); |
65 |
|
66 |
my $name = $who->name; |
67 |
|
68 |
if ($args ne "" && $name ne $args) { |
69 |
my ($map, $x, $y) = ($who->map, $who->x, $who->y); |
70 |
|
71 |
my $plevel = player_level $who; |
72 |
my $mlevel = map_level $map, $x, $y; |
73 |
|
74 |
if (is_damned ($map, $x, $y)) { |
75 |
$who->message ("Your god isn't present here, you can't invite someone to unholy ground. " |
76 |
. "H<You can only use invite at places where you can use prayers.>"); |
77 |
} elsif ($plevel >= $mlevel) { |
78 |
if (my $other = cf::player::find_active $args) { |
79 |
$who->message ("inviting player '$args', to cancel, use invite with no arguments or wait $TIMEOUT seconds"); |
80 |
$other->ob->message ("$name invites you to $maplevel[$mlevel], to accept, use 'accept-invitation $name"); |
81 |
$invite{$name}{$args} = [time + $TIMEOUT, $map, $x, $y]; |
82 |
} else { |
83 |
$who->message ("cannot invite '$args': no such player"); |
84 |
} |
85 |
} elsif ($plevel) { |
86 |
$who->message ("Valriel deems you not worthy yet. Gorokh is annoyed by your sacrilege. " |
87 |
. "H<Your invite level is not high enough to invite to this place.>"); |
88 |
} else { |
89 |
$who->message ("You haven't proven your worthyness in the mountain maze. " |
90 |
. "H<To use the invite command you have to do one or more of the invite quests. The first one can be found south-east of Scorn.>"); |
91 |
} |
92 |
} else { |
93 |
$who->message ("canceling all invites"); |
94 |
delete $invite{$name}; |
95 |
} |
96 |
}; |
97 |
|
98 |
sub teleport { |
99 |
my ($pl, $map, $x, $y) = @_; |
100 |
|
101 |
my $portal = cf::object::new "exit"; |
102 |
|
103 |
$portal->slaying ($map->path); |
104 |
$portal->stats->hp ($x); |
105 |
$portal->stats->sp ($y); |
106 |
|
107 |
$portal->apply ($pl); |
108 |
|
109 |
$portal->destroy; |
110 |
} |
111 |
|
112 |
cf::register_command "accept-invitation" => sub { |
113 |
my ($who, $args) = @_; |
114 |
|
115 |
$who->speed_left ($who->speed_left - 0.2); |
116 |
|
117 |
my $name = $who->name; |
118 |
my ($map, $x, $y) = ($who->map, $who->x, $who->y); |
119 |
|
120 |
if (is_damned ($map, $x, $y)) { |
121 |
$who->message ("You can't be invited from a place where your god isn't present. " |
122 |
. "H<Go to a place where your prayers work and try again.>"); |
123 |
} elsif (!exists $invite{$args} || !exists $invite{$args}{$name}) { |
124 |
$who->message ("Sorry, $args hasn't invited you."); |
125 |
} elsif ($invite{$args}{$name}[0] < time) { |
126 |
$who->message ("Sorry, $args\'s invitation has expired. " |
127 |
. "H<Invites are only valid for $TIMEOUT seconds, ask $args to invite you again.>"); |
128 |
} else { |
129 |
my $inv = delete $invite{$args}{$name}; |
130 |
$who->message ("A godly force starts to pull you up..."); |
131 |
teleport $who, @{$inv}[1,2,3]; |
132 |
$who->message ("... and sets you down where $args invited you to."); |
133 |
} |
134 |
}; |
135 |
|