1 |
#! perl # MANDATORY |
2 |
|
3 |
# login handling |
4 |
|
5 |
use Fcntl; |
6 |
use Coro::AIO; |
7 |
use List::Util qw(min max); |
8 |
|
9 |
# paranoia function to overwrite a string-in-place |
10 |
sub nuke_str { |
11 |
substr $_[0], 0, (length $_[0]), "x" x length $_[0] |
12 |
} |
13 |
|
14 |
sub query { |
15 |
my ($ns, $flags, $text) = @_; |
16 |
|
17 |
my $current = $Coro::current; |
18 |
$ns->query ($flags, $text, sub { $current->ready; $current = $_[0] }); |
19 |
Coro::schedule while ref $current; |
20 |
|
21 |
$current |
22 |
} |
23 |
|
24 |
sub can_cleanup { |
25 |
my ($pl, $mtime) = @_; |
26 |
|
27 |
my $age = time - $mtime; |
28 |
my $level = $pl->ob->level; |
29 |
|
30 |
($level <= 3 && $age > 7 * 86400) # 7 days for level 0..3 |
31 |
|| ($level <= 9 && $age > 90 * 86400) # 3 months for level 4..9 |
32 |
|| ($level <= 20 && $age > 180 * 86400) # 6 months for level 10..20 |
33 |
|| $age > 700 * 86400 # 2 years for everybody else |
34 |
} |
35 |
|
36 |
sub check_playing { |
37 |
my ($ns, $user) = @_; |
38 |
|
39 |
return unless cf::player::find_active $user; |
40 |
|
41 |
$ns->send_drawinfo ( |
42 |
"That player is already logged in on this server. " |
43 |
. "If you want to create a new player, choose another name. " |
44 |
. "If you are already a registered player, make sure nobody " |
45 |
. "else is using your account at this time. If you lost your conenction " |
46 |
. "then the server will likely timeout within a minute. If you still " |
47 |
. "cannot log-in after a minute, you are still logged in. Make sure " |
48 |
. "you do not have another client running. If you use windows, reboot, " |
49 |
. "this will fix anything.", |
50 |
cf::NDI_RED |
51 |
); |
52 |
|
53 |
1 |
54 |
} |
55 |
|
56 |
sub check_clean_save { |
57 |
my ($pl) = @_; |
58 |
|
59 |
if (my $time = delete $pl->{unclean_save}) { |
60 |
$pl->ns->send_drawinfo ( |
61 |
"You didn't use a savebed to leave this realm. This is very dangerous, " |
62 |
. "as lots of things could happen when you leave by other means, such as cave-ins, " |
63 |
. "or monsters suddenly snapping your body. Better use a savebed next time.", |
64 |
cf::NDI_RED |
65 |
); |
66 |
#d#TODO |
67 |
} |
68 |
} |
69 |
|
70 |
# delete a player directory, be non-blocking AND synchronous... |
71 |
# (thats hard, so we crap out and fork). |
72 |
sub nuke_playerdir { |
73 |
my ($user) = @_; |
74 |
|
75 |
aio_stat "$PLAYERDIR/$user"; |
76 |
system "cd \Q$PLAYERDIR\E " |
77 |
. "&& mv \Q$user\E ~\Q$Coro::current\E~deleting~ 2>/dev/null " |
78 |
. "&& (rm -rf ~\Q$Coro::current\E~deleting~ &)"; |
79 |
} |
80 |
|
81 |
sub send_capabilities { |
82 |
my ($ns) = @_; |
83 |
|
84 |
return unless $ns->extcmd; |
85 |
|
86 |
$ns->ext_event (capabilities => |
87 |
# id, name, flags (1 == 2d), edge length |
88 |
tileset => [[1, "default 64x64 faceset", 1, 64], [0, "default 32x32 faceset", 1, 32]], |
89 |
); |
90 |
} |
91 |
|
92 |
sub setup { |
93 |
my ($ns, $args) = @_; |
94 |
|
95 |
# run through the cmds of setup |
96 |
# syntax is setup <cmdname1> <parameter> <cmdname2> <parameter> ... |
97 |
# |
98 |
# we send the status of the cmd back, or a FALSE is the cmd is the server unknown |
99 |
# The client then must sort this out |
100 |
|
101 |
my %setup = split / +/, $args; |
102 |
while (my ($k, $v) = each %setup) { |
103 |
if ($k eq "sound") { |
104 |
$ns->sound ($v); |
105 |
|
106 |
} elsif ($k eq "exp64") { |
107 |
$setup{$k} = 1; |
108 |
|
109 |
} elsif ($k eq "spellmon") { |
110 |
$ns->monitor_spells ($v); |
111 |
|
112 |
} elsif ($k eq "darkness") { |
113 |
$ns->darkness ($v); |
114 |
|
115 |
} elsif ($k eq "map1cmd") { |
116 |
$ns->mapmode (cf::Map1Cmd) if $v > 0; |
117 |
|
118 |
} elsif ($k eq "map1acmd") { |
119 |
$ns->mapmode (cf::Map1aCmd) if $v > 0; |
120 |
|
121 |
} elsif ($k eq "map2cmd") { |
122 |
# gcfclient bug, map1acmd is sent too late |
123 |
$ns->mapmode (cf::Map1aCmd); |
124 |
$setup{$k} = "FALSE"; |
125 |
|
126 |
} elsif ($k eq "newmapcmd") { |
127 |
$ns->newmapcmd ($v); |
128 |
|
129 |
} elsif ($k eq "mapinfocmd") { |
130 |
$ns->mapinfocmd ($v); |
131 |
|
132 |
} elsif ($k eq "extcmd") { |
133 |
$ns->extcmd ($v > 0); |
134 |
send_capabilities $ns; |
135 |
|
136 |
} elsif ($k eq "extmap") { |
137 |
$ns->extmap ($v); |
138 |
|
139 |
} elsif ($k eq "facecache") { |
140 |
if (!$v) { |
141 |
$v = 1; |
142 |
$setup{$k} = $v; |
143 |
$ns->send_drawinfo ("(trying to forcefully enable facecaching)", cf::NDI_RED); |
144 |
} |
145 |
|
146 |
$ns->facecache ($v); |
147 |
|
148 |
} elsif ($k eq "faceset") { |
149 |
$ns->faceset (0); |
150 |
$setup{$k} = 0; |
151 |
# $ns->image2 (1) |
152 |
|
153 |
} elsif ($k eq "tileset") { |
154 |
$setup{$k} = $ns->faceset ($v & 1); |
155 |
|
156 |
} elsif ($k eq "itemcmd") { |
157 |
# Version of the item protocol command to use. Currently, |
158 |
# only supported versions are 1 and 2. Using a numeric |
159 |
# value will make it very easy to extend this in the future. |
160 |
$ns->itemcmd ($v) if $v >= 1 && $v <= 2; |
161 |
|
162 |
$setup{$k} = $ns->itemcmd; |
163 |
|
164 |
} elsif ($k eq "mapsize") { |
165 |
my ($x, $y) = split /x/, $v; |
166 |
|
167 |
$ns->mapx ($x = max 9, min cf::MAP_CLIENT_X, ($x - 1) | 1); |
168 |
$ns->mapy ($y = max 9, min cf::MAP_CLIENT_Y, ($y - 1) | 1); |
169 |
|
170 |
$setup{$k} = "${x}x${y}"; |
171 |
|
172 |
} elsif ($k eq "extendedMapInfos") { |
173 |
$ns->ext_mapinfos ($v); |
174 |
|
175 |
} elsif ($k eq "extendedTextInfos") { |
176 |
$ns->has_readable_type ($v); |
177 |
|
178 |
} elsif ($k eq "smoothing") { # cfplus-style smoothing |
179 |
$ns->smoothing ($v); |
180 |
|
181 |
} elsif ($k eq "fxix") { |
182 |
$ns->fxix ($v); |
183 |
|
184 |
} else { |
185 |
# other commands: |
186 |
# sexp: no idea, probably for oudated servers |
187 |
# tick: more stupidity, server should sned a tick per tick |
188 |
|
189 |
$setup{$k} = "FALSE"; |
190 |
} |
191 |
} |
192 |
|
193 |
$ns->send_packet (join " ", setup => %setup); |
194 |
|
195 |
cf::datalog setup => |
196 |
request => $args, |
197 |
reply => \%setup, |
198 |
client => $ns->version, |
199 |
; |
200 |
} |
201 |
|
202 |
sub addme { |
203 |
my ($ns) = @_; |
204 |
|
205 |
if (!$ns->facecache) |
206 |
{ |
207 |
$ns->send_drawinfo (<<EOF, cf::NDI_RED); |
208 |
|
209 |
|
210 |
*** |
211 |
*** WARNING: |
212 |
*** Your client does not support face/image caching, |
213 |
*** or it has been disabled. Face caching is mandatory |
214 |
*** so please enable it or use a newer client. |
215 |
*** |
216 |
*** Look at your client preferences: |
217 |
*** |
218 |
*** CFPlus: all known versions automatically enable the facecache. |
219 |
*** cfclient: use the -cache commandline option. |
220 |
*** cfclient: map will not redraw automatically (bug). |
221 |
*** gcfclient: use -cache commandline option, or enable |
222 |
*** gcfclient: Client=>Configure=>Map & Image=>Cache Images. |
223 |
*** jcrossclient: your client is broken, use CFPlus or gcfclient. |
224 |
*** |
225 |
*** |
226 |
EOF |
227 |
if ($ns->version =~ /jcrossclient/) { |
228 |
# let them, for now |
229 |
} else { |
230 |
$ns->flush; |
231 |
return $ns->destroy; |
232 |
} |
233 |
|
234 |
# $ns->facecache = true; |
235 |
} |
236 |
|
237 |
if ($ns->mapmode < cf::Map1aCmd) { |
238 |
$ns->send_drawinfo (<<EOF, cf::NDI_RED); |
239 |
|
240 |
|
241 |
*** |
242 |
*** WARNING: |
243 |
*** Your client is too old. Please upgrade to a newer version. |
244 |
EOF |
245 |
|
246 |
$ns->flush; |
247 |
return $ns->destroy; |
248 |
} |
249 |
|
250 |
$ns->pl and return $ns->destroy; |
251 |
|
252 |
$ns->async (sub { |
253 |
my ($user, $pass); |
254 |
|
255 |
$ns->send_packet ("addme_success"); |
256 |
|
257 |
for (;;) { |
258 |
$ns->send_drawinfo ( |
259 |
"Please enter your username now. If you are a new user, " |
260 |
. "make one up that describes your character best. " |
261 |
. "Only letters and digits are allowed, though.", |
262 |
cf::NDI_BLUE |
263 |
); |
264 |
|
265 |
# read username |
266 |
while () { |
267 |
$user = query $ns, 0, "What is your name?\n:"; |
268 |
|
269 |
if ($cf::LOGIN_LOCK{$user}) { |
270 |
$ns->send_drawinfo ( |
271 |
"That username is currently used in another login session. " |
272 |
. "Chose another, or wait till the other session has ended.", |
273 |
cf::NDI_RED |
274 |
); |
275 |
} elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,17}\z/) { |
276 |
last; |
277 |
} else { |
278 |
$ns->send_drawinfo ( |
279 |
"Your username contains illegal characters " |
280 |
. "(only a-z, A-Z and 0-9 are allowed), " |
281 |
. "or is not between 3 and 18 characters in length.", |
282 |
cf::NDI_RED |
283 |
); |
284 |
} |
285 |
} |
286 |
|
287 |
check_playing $ns, $user and next; |
288 |
|
289 |
$ns->send_drawinfo ( |
290 |
"Welcome $user, please enter your password now. " |
291 |
. "New users should now choose a password. " |
292 |
. "Anything your client lets you enter is fine.", |
293 |
cf::NDI_BLUE |
294 |
); |
295 |
|
296 |
# read password |
297 |
while () { |
298 |
$pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:"; |
299 |
last if $pass =~ /.../; |
300 |
$ns->send_drawinfo ( |
301 |
"Try to use at least three characters as your password please, " |
302 |
. "that cannot be too much to ask for :)", |
303 |
cf::NDI_RED |
304 |
); |
305 |
} |
306 |
|
307 |
# lock this username for the remainder of this login session |
308 |
if ($cf::LOGIN_LOCK{$user}) { |
309 |
$ns->send_drawinfo ( |
310 |
"That username is currently used in another login session. " |
311 |
. "Chose another, or wait till the other session has ended.", |
312 |
cf::NDI_RED |
313 |
); |
314 |
next; |
315 |
} |
316 |
local $cf::LOGIN_LOCK{$user} = 1; |
317 |
|
318 |
check_playing $ns, $user and next; |
319 |
|
320 |
# try to read the user file and check the password |
321 |
if (my $pl = cf::player::find $user) { |
322 |
aio_stat $pl->path and next; |
323 |
my $mtime = (stat _)[9]; |
324 |
my $hash = $pl->password; |
325 |
|
326 |
if ($cf::CFG{ext_login_nocheck} or $hash eq crypt $pass, $hash) { |
327 |
nuke_str $pass; |
328 |
# password matches, wonderful |
329 |
my $pl = cf::player::find $user or next; |
330 |
$pl->connect ($ns); |
331 |
check_clean_save $pl; |
332 |
last; |
333 |
} elsif (can_cleanup $pl, $mtime) { |
334 |
Coro::Timer::sleep 1; |
335 |
|
336 |
$ns->send_drawinfo ( |
337 |
"Player exists, but password does not match. If this is your account, " |
338 |
. "please try again. If not, you can now decide to take over this account " |
339 |
. "because it has not been in-use for some time.", |
340 |
cf::NDI_RED |
341 |
); |
342 |
|
343 |
#TODO: nuke_str |
344 |
(query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/ |
345 |
or next; |
346 |
|
347 |
# check if the file hasn't changed |
348 |
aio_stat cf::player::path $user and next; |
349 |
$mtime == (stat _)[9] or next; |
350 |
|
351 |
$pl->quit_character; |
352 |
|
353 |
# fall through to creation |
354 |
} else { |
355 |
nuke_str $pass; |
356 |
|
357 |
Coro::Timer::sleep 1; |
358 |
|
359 |
$ns->send_drawinfo ( |
360 |
"Wrong username or password. Please try again " |
361 |
. "(check for Numlock and other semi-obvious error sources).", |
362 |
cf::NDI_RED |
363 |
); |
364 |
next; |
365 |
} |
366 |
} else { |
367 |
# unable to load the playerfile: |
368 |
# check wether the player dir exists, which means the file is corrupted or |
369 |
# something very similar. |
370 |
if (!aio_stat cf::player::playerdir $user) { |
371 |
$ns->send_drawinfo ( |
372 |
"Unable to retrieve this player. It might be a locked or broken account. " |
373 |
. "If this is your account, ask a dungeon master for assistance. " |
374 |
. "Otherwise choose a different login name.", |
375 |
cf::NDI_RED |
376 |
); |
377 |
next; |
378 |
} |
379 |
} |
380 |
|
381 |
# the rest of this function is character creation |
382 |
|
383 |
# just to make sure nothing is left over |
384 |
nuke_playerdir $user; |
385 |
|
386 |
my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again."; |
387 |
|
388 |
if ($pass2 ne $pass) { |
389 |
nuke_str $pass; |
390 |
nuke_str $pass2; |
391 |
$ns->send_drawinfo ( |
392 |
"The passwords do not match, please try again.", |
393 |
cf::NDI_RED |
394 |
); |
395 |
next; |
396 |
} |
397 |
|
398 |
nuke_str $pass2; |
399 |
|
400 |
my $pl = cf::player::new $user; |
401 |
$pl->password (crypt $pass, join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]); |
402 |
nuke_str $pass; |
403 |
$pl->connect ($ns); |
404 |
|
405 |
my $ob = $pl->ob; |
406 |
|
407 |
while () { |
408 |
$ob->update_stats; |
409 |
$pl->save_stats; |
410 |
|
411 |
my $res = query $ns, cf::CS_QUERY_SINGLECHAR, |
412 |
"[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?"; |
413 |
|
414 |
if ($res =~ /^[Nn]/) { |
415 |
last; |
416 |
} elsif ($res > 0 && $res <= 7) { |
417 |
my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?"; |
418 |
|
419 |
if ($swap > 0 && $swap <= 7) { |
420 |
$ob->swap_stats ($res - 1, $swap - 1); |
421 |
} |
422 |
} else { |
423 |
$ob->roll_stats; |
424 |
} |
425 |
} |
426 |
|
427 |
$ob->set_animation (2); |
428 |
$ob->add_statbonus; |
429 |
|
430 |
$ns->send_drawinfo ($ob->msg, cf::NDI_BLUE); |
431 |
$ns->send_packet (sprintf "query %d %s", cf::CS_QUERY_SINGLECHAR, |
432 |
"Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n"); |
433 |
|
434 |
$ns->state (cf::ST_CHANGE_CLASS); |
435 |
delete $pl->{deny_save};#d# too early |
436 |
|
437 |
last; |
438 |
} |
439 |
}); |
440 |
} |
441 |
|
442 |
cf::register_command quit => sub { |
443 |
my ($ob, $arg) = @_; |
444 |
|
445 |
$ob->reply (undef, |
446 |
"Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. " |
447 |
. "If you are sure you want to do this, then use the quit_character command instead of quit.", |
448 |
cf::NDI_UNIQUE | cf::NDI_RED); |
449 |
}; |
450 |
|
451 |
cf::register_command quit_character => sub { |
452 |
my ($ob, $arg) = @_; |
453 |
|
454 |
my $pl = $ob->contr; |
455 |
|
456 |
$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub { |
457 |
if ($_[0] !~ /^[yY]/) { |
458 |
$ob->reply (undef, |
459 |
"Ok, not not quitting then.", |
460 |
cf::NDI_UNIQUE | cf::NDI_RED); |
461 |
} else { |
462 |
$ob->reply (undef, |
463 |
"Ok, quitting, hope to see you again.", |
464 |
cf::NDI_UNIQUE | cf::NDI_RED); |
465 |
$pl->ns->flush; |
466 |
cf::async { $pl->quit_character }; |
467 |
} |
468 |
}); |
469 |
}; |
470 |
|
471 |
cf::object->attach ( |
472 |
type => cf::SAVEBED, |
473 |
on_apply => sub { |
474 |
my ($bed, $ob) = @_; |
475 |
|
476 |
return cf::override 0 unless $ob->type == cf::PLAYER; |
477 |
|
478 |
my $pl = $ob->contr; |
479 |
|
480 |
# update respawn position |
481 |
$pl->savebed ($bed->map->path, $bed->x, $bed->y); |
482 |
cf::async { $pl->save }; |
483 |
|
484 |
$pl->killer ("left"); |
485 |
$ob->check_score; |
486 |
|
487 |
$ob->reply (undef, "In the future, you will wake up here when you die."); |
488 |
|
489 |
$pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub { |
490 |
if ($_[0] !~ /^[yY]/) { |
491 |
$pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1); |
492 |
$pl->deactivate; |
493 |
$pl->ns->destroy; |
494 |
} else { |
495 |
cf::async { $pl->save }; |
496 |
} |
497 |
}); |
498 |
}, |
499 |
); |
500 |
|
501 |
cf::player->attach ( |
502 |
on_login => sub { |
503 |
my ($pl) = @_; |
504 |
my $name = $pl->ob->name; |
505 |
|
506 |
$_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list; |
507 |
}, |
508 |
on_logout => sub { |
509 |
my ($pl, $cleanly) = @_; |
510 |
my $name = $pl->ob->name; |
511 |
|
512 |
if ($cleanly) { |
513 |
$_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list; |
514 |
} else { |
515 |
$_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list; |
516 |
$pl->{unclean_save} = $cf::RUNTIME; |
517 |
} |
518 |
}, |
519 |
); |
520 |
|
521 |
cf::client->attach ( |
522 |
on_addme => \&addme, |
523 |
on_setup => \&setup, |
524 |
); |
525 |
|
526 |
############################################################################# |
527 |
|
528 |
our $SCHEDULE_INTERVAL = 10; # time the player scheduler sleeps between runs |
529 |
our $SAVE_TIMEOUT = 20; # save players every n seconds |
530 |
|
531 |
our $SCHEDULER = cf::async_ext { |
532 |
my $schedule_interval = Coro::Event->timer (after => 1, interval => $SCHEDULE_INTERVAL); |
533 |
while () { |
534 |
$schedule_interval->next; |
535 |
|
536 |
# this weird form of iteration over values is used because |
537 |
# the hash changes underneath us frequently, and for |
538 |
# keeps a direct reference to the value without (in 5.8 perls) |
539 |
# keeping a reference, so this is prone to crashes or worse. |
540 |
my @players = keys %cf::PLAYER; |
541 |
for (@players) { |
542 |
my $pl = $cf::PLAYER{$_} |
543 |
or next; |
544 |
$pl->valid or next; |
545 |
|
546 |
eval { |
547 |
if ($pl->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) { |
548 |
cf::wait_for_tick_begin; |
549 |
$pl->save; |
550 |
|
551 |
unless ($pl->active) { |
552 |
# check refcounts, this is tricky and needs to be adjusted to fit server internals |
553 |
my $ob = $pl->ob; |
554 |
Scalar::Util::weaken $pl; |
555 |
Scalar::Util::weaken $ob; |
556 |
my $a_ = $pl->refcnt;#d# |
557 |
my $b_ = $ob->refcnt;#d# |
558 |
my $pl_ref = $pl->refcnt_cnt; |
559 |
my $ob_ref = $ob->refcnt_cnt; |
560 |
|
561 |
## pl_ref == one from object + one from cf::PLAYER |
562 |
## ob_ref == one from simply being an object |
563 |
if ($pl_ref == 2 && $ob_ref == 1) { |
564 |
warn "player-scheduler destroy ", $ob->name;#d# |
565 |
|
566 |
# remove from sight and get fresh "copies" |
567 |
$pl = delete $cf::PLAYER{$ob->name}; |
568 |
$ob = $pl->ob; |
569 |
|
570 |
$ob->destroy; |
571 |
$pl->destroy; |
572 |
} else { |
573 |
warn "player-scheduler refcnt ", $ob->name, " $pl_ref,$a_ $ob_ref,$b_\n";#d# |
574 |
} |
575 |
} |
576 |
} |
577 |
}; |
578 |
warn $@ if $@; |
579 |
Coro::cede; |
580 |
}; |
581 |
} |
582 |
}; |
583 |
|
584 |
$SCHEDULER->prio (1); |
585 |
|