#! perl

# login handling

use Fcntl;
use Coro::AIO;

my $PLAYERDIR = sprintf "%s/%s", cf::localdir, cf::playerdir;

# paranoia function to overwrite a string-in-place
sub nuke_str {
   substr $_[0], 0, (length $_[0]), "x" x length $_[0]
}

sub query {
   my ($ns, $flags, $text) = @_;

   my $current = $Coro::current;
   $ns->query ($flags, $text, sub { $current->ready; $current = $_[0]; });
   Coro::schedule while ref $current;

   $current
}

sub can_cleanup {
   my ($playerfile, $mtime) = @_;

   my $age = time - $mtime;
   my $level = $playerfile =~ /^level (\d+)$/m ? $1 : return;

   ($level <= 3 && $age > 7 * 86400)		# 7 days for level 0..3
   || ($level <= 9 && $age > 90 * 86400)        # 3 months for level 4..9
   || ($level <= 20 && $age > 180 * 86400)      # 6 months for level 10..20
   || $age > 700 * 86400                        # 2 years for everybody else
}

sub check_playing {
   my ($ns, $user) = @_;

   return unless cf::player::find_active $user;

   $ns->send_drawinfo (
      "That player is already logged in on this server. "
    . "If you want to create a new player, choose another name. "
    . "If you are already a registered player, make sure nobody "
    . "else is using your account at this time. If you lost your conenction "
    . "then the server will likely timeout within a minute. If you still "
    . "cannot log-in after a minute, you are still logged in. Make sure "
    . "you do not have another client running. If you use windows, reboot, "
    . "this will fix anything.",
      cf::NDI_RED
   );

   1
}

sub check_clean_save {
   my ($pl) = @_;

   unless (delete $pl->{clean_save}) {
      #d#TODO
   }
}

# delete a player directory, be non-blocking AND synchronous...
# (thats hard, so we crap out and fork).
sub nuke_playerdir {
   my ($user) = @_;

   aio_stat "$PLAYERDIR/$user";
   system "cd \Q$PLAYERDIR\E "
        . "&& mv \Q$user\E ~\Q$Coro::current\E~deleting~ 2>/dev/null "
        . "&& (rm -rf ~\Q$Coro::current\E~deleting~ &)";
}

sub addme {
   my ($ns) = @_;

   $ns->destroy if $ns->pl;

   $ns->async (sub {
      my ($user, $pass);

      $ns->send_packet ("addme_success");

      for (;;) {
         $ns->send_drawinfo (
            "Please enter your username now. If you are a new user, "
          . "make one up that describes your character best. "
          . "Only letters and digits are allowed, though.",
            cf::NDI_BLUE
         );

         # read username
         while () {
            $user = query $ns, 0, "What is your name?\n:";

            if ($cf::LOGIN_LOCK{$user}) {
               $ns->send_drawinfo (
                  "That username is currently used in another login session. "
                . "Chose another, or wait till the other session has ended.",
                  cf::NDI_RED
               );
            } elsif ($user =~ /^[a-zA-Z0-9][a-zA-Z0-9\-_]{2,17}$/) {
               last;
            } else {
               $ns->send_drawinfo (
                  "Your username contains illegal characters "
                . "(only a-z, A-Z and 0-9 are allowed), "
                . "or is not between 3 and 18 characters in length.",
                  cf::NDI_RED
               );
            }
         }

         check_playing $ns, $user and next;

         $ns->send_drawinfo (
            "Welcome $user, please enter your password now. "
          . "New users should now choose a password. "
          . "Anything your client lets you enter is fine.",
            cf::NDI_BLUE
         );

         # read password
         while () {
            $pass = query $ns, cf::CS_QUERY_HIDEINPUT, "What is your password?\n:";
            last if $pass =~ /.../;
            $ns->send_drawinfo (
               "Try to use at least three characters as your password please, "
             . "that cannot be too much to ask for :)",
               cf::NDI_RED
            );
         }

         # lock this username for the remainder of this login session
         if ($cf::LOGIN_LOCK{$user}) {
            $ns->send_drawinfo (
               "That username is currently used in another login session. "
             . "Chose another, or wait till the other session has ended.",
               cf::NDI_RED
            );
            next;
         }
         local $cf::LOGIN_LOCK{$user} = 1;

         check_playing $ns, $user and next;

         # try to read the user file and check the password
         if (my $fh = aio_open cf::player::path $user, O_RDONLY, 0) {
            my $mtime = (stat $fh)[9];

            0 < aio_read $fh, 0, 16384, my $buf, 0 or next;
            $buf =~ /^password (\S+)$/m            or next;
            my $hash = $1;

            if ($hash eq crypt $pass, $hash) {
               nuke_str $pass;
               # password matches, wonderful
               my $pl = cf::player::find $user or next;
               $pl->connect ($ns);
               check_clean_save $pl;
               $pl->{clean_save} = 1;
               last;
            } elsif (can_cleanup $buf, $mtime) {
               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Player exists, but password does not match. If this is your account, "
                . "please try again. If not, you can now decide to take over this account "
                . "because it has not been in-use for some time.",
                  cf::NDI_RED
               );

               #TODO: nuke_str
               (query $ns, cf::CS_QUERY_SINGLECHAR, "Delete existing account and create a new one (Y/N)?") =~ /^[yY]/
                  or next;

               # check if the file hasn't changed
               aio_stat cf::player::path $user and next;
               $mtime == (stat _)[9] or next;

               nuke_playerdir $user;

               # fall through to creation
            } else {
               nuke_str $pass;

               Coro::Timer::sleep 1;

               $ns->send_drawinfo (
                  "Wrong username or password. Please try again "
                . "(check for Numlock and other semi-obvious error sources).",
                  cf::NDI_RED
               );
               next;
            }
         }

         # the rest of this function is character creation

         # just to make sure nothing is left over
         nuke_playerdir $user;

         my $pass2 = query $ns, cf::CS_QUERY_HIDEINPUT, "Please type your password again.";

         if ($pass2 ne $pass) {
            nuke_str $pass;
            nuke_str $pass2;
            $ns->send_drawinfo (
               "The passwords do not match, please try again.",
               cf::NDI_RED
            );
            next;
         }

         nuke_str $pass2;

         my $pl = cf::player::new $user;
         $pl->password (crypt $pass, join '', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]);
         nuke_str $pass;
         $pl->connect ($ns);

         my $ob = $pl->ob;

         while () {
            $ob->update_stats;
            $pl->save_stats;

            my $res = query $ns, cf::CS_QUERY_SINGLECHAR,
                         "[y] to roll new stats [n] to use stats\n[1-7] [1-7] to swap stats.\nRoll again (y/n/1-7)?";

            if ($res =~ /^[Nn]/) {
               last;
            } elsif ($res > 0 && $res <= 7) {
               my $swap = query $ns, cf::CS_QUERY_SINGLECHAR, "Swap stat with (will not roll new stats) [1-7]?";

               if ($swap > 0 && $swap <= 7) {
                  $ob->swap_stats ($res - 1, $swap - 1);
               }
            } else {
               $ob->roll_stats;
            }
         }

         $ob->set_animation (2);
         $ob->add_statbonus;

         $ns->send_drawinfo ($ob->msg, cf::NDI_BLUE);
         $ns->send_packet (sprintf "query %d %s", cf::CS_QUERY_SINGLECHAR,
                      "Now choose a character.\nPress any key to change outlook.\nPress `d' when you're pleased.\n");

         $ns->state (cf::ST_CHANGE_CLASS);
         delete $pl->{deny_save};#d# too early

         last;
      }
   });
}

cf::register_command quit => sub {
   my ($ob, $arg) = @_;

   $ob->reply (undef,
               "Quitting will delete your character PERMANENTLY: It will be gone forever and any progress will be lost. "
               . "If you are sure you want to do this, then use the quit_character command instead of quit.",
               cf::NDI_UNIQUE | cf::NDI_RED);
};

cf::register_command quit_character => sub {
   my ($ob, $arg) = @_;

   my $pl = $ob->contr;

   $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to PERMANENTLY delete your character and all associated data (y/n)?", sub {
      if ($_[0] !~ /^[yY]/) {
         $ob->reply (undef,
                     "Ok, not not quitting then.",
                     cf::NDI_UNIQUE | cf::NDI_RED);
      } else {
         $ob->reply (undef,
                     "Ok, quitting, hope to see you again.",
                     cf::NDI_UNIQUE | cf::NDI_RED);
         $pl->ns->flush;
         $pl->quit_character;
      }
   });
};

cf::object->attach (
   type     => cf::SAVEBED,
   on_apply => sub {
      my ($bed, $ob) = @_;

      return cf::override 0 unless $ob->type == cf::PLAYER;

      my $pl = $ob->contr;

      # update respawn position
      $pl->savebed ($bed->map->path, $bed->x, $bed->y);

      $pl->killer ("left");
      $ob->check_score;

      $ob->reply (undef, "In the future, you will wake up here when you die.");

      $pl->ns->query (cf::CS_QUERY_SINGLECHAR, "Do you want to continue playing (y/n)?", sub {
         if ($_[0] !~ /^[yY]/) {
            $pl->invoke (cf::EVENT_PLAYER_LOGOUT, 1);
            $pl->deactivate;
            $pl->ns->destroy;
         } else {
            cf::async { $pl->save };
         }
      });
   },
);

cf::player->attach (
   on_login  => sub {
      my ($pl) = @_;
      my $name = $pl->ob->name;

      $_->ob->message ("$name has entered the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
   },
   on_logout => sub {
      my ($pl, $cleanly) = @_;
      my $name = $pl->ob->name;

      if ($cleanly) {
         $_->ob->message ("$name left the game.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
      } else {
         $_->ob->message ("$name uncerimoniously disconnected.", cf::NDI_DK_ORANGE | cf::NDI_UNIQUE) for cf::player::list;
         delete $pl->{clean_save};
      }
   },
);

cf::client->attach (
   on_addme => \&addme,
);

#############################################################################

our $SCHEDULE_INTERVAL  =   10; # time the player scheduler sleeps between runs
our $SWAP_TIMEOUT       =   30; # time after which an unused player is evicted form memory
our $SAVE_TIMEOUT       =   20; # save players every n seconds
our $SAVE_INTERVAL      =  0.1; # save at max. one player every $SAVE_INTERVAL

our $SCHEDULER = cf::async_ext {
   while () {
      Coro::Timer::sleep $SCHEDULE_INTERVAL;

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @players = keys %cf::PLAYER;
      for (@players) {
         my $pl = $cf::PLAYER{$_}
            or next;
         $pl->valid or next;

         eval {
            if ($pl->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
               $pl->save;
               Coro::Timer::sleep $SAVE_INTERVAL;
            }
            my $ob = $pl->ob;
            Scalar::Util::weaken $pl; # 2 == from object + from perl
            Scalar::Util::weaken $ob; # 2 == one from being an object + ???
            my $a_ = $pl->refcnt;
            my $b_ = $ob->refcnt;
            my $a = $pl->refcnt_cnt;
            my $b = $ob->refcnt_cnt;
               warn "rc $a,$a_ $b,$b_\n";#d#
         };
         warn $@ if $@;
         Coro::cede;
      };
   }
};

$SCHEDULER->prio (1);