#! perl

# this extension swaps out maps and resets them, in essence managing
# the reset/swap policy of the server.

our $DEACTIVATE_TIMEOUT =   20; # number of seconds after which maps get deactivated to save cpu
our $SWAP_TIMEOUT       =   35; # number of seconds after which maps inactive get swapped out
our $SCHEDULE_INTERVAL  =    2; # time the map scheduler sleeps between runs
our $SAVE_TIMEOUT       =   20; # save maps every n seconds
our $SAVE_INTERVAL      =  0.1; # save at max. one map every $SAVE_INTERVAL

cf::coro {
   $Coro::current->prio (Coro::PRIO_MIN);
   # load the header of swapped-out maps.
   # this is not a correctness issue, it simply saves diskspace
   # because old files will get cleaned up on reset time
   Coro::Timer::sleep 1;

   my $files = Coro::AIO::aio_readdir cf::localdir . "/" . cf::tmpdir;

   for my $map (@$files) {
      utf8::decode $map;
      next if $map =~ /\.(?:pst|meta)$/;
      $map =~ s/∕/\//g;
      cf::map::find $map;
      Coro::Timer::sleep 0.05;
   }

   #TODO: should also preload random maps...
};

our $SCHEDULER = cf::coro {
   while () {
      Coro::Timer::sleep $SCHEDULE_INTERVAL;

      # this weird form of iteration over values is used because
      # the hash changes underneath us frequently, and for
      # keeps a direct reference to the value without (in 5.8 perls)
      # keeping a reference, so this is prone to crashes or worse.
      my @maps = keys %cf::MAP;
      for (@maps) {
         my $map = $cf::MAP{$_}
            or next;
         $map->valid or next;

         eval {
            # not yet, because maps might become visible to players nearby
            # we need to remove the map from %cf::MAP and all tiled map links
#         if ($last_access + $DEACTIVATE_TIMEOUT <= $cf::RUNTIME) {
#            $map->deactivate;
#            delete $map->{active};
#         }
            if ($map->should_reset) {
               $map->reset;
            } elsif ($map->in_memory == cf::MAP_IN_MEMORY) {
               if ($map->last_access + $SWAP_TIMEOUT <= $cf::RUNTIME && !$map->players) {
                  $map->swap_out;
                  Coro::Timer::sleep $SAVE_INTERVAL;
               } elsif ($map->{last_save} + $SAVE_TIMEOUT <= $cf::RUNTIME) {
                  $map->save;
                  Coro::Timer::sleep $SAVE_INTERVAL;
               }
            }
         };
         warn $@ if $@;
         Coro::cede;
      };
   }
};

$SCHEDULER->prio (-2);

# map load prefetch for tiled maps, possibly exits, too
cf::map->attach (
   on_enter => sub {
      my ($map, $pl) = @_;

      (Coro::async_pool {
         my @diag; # diagonal neighbours

         for (0 .. 3) {
            my $neigh = $map->tile_path ($_)
               or next;
            $neigh = cf::map::find $neigh, $map
               or next;
            $neigh->load;

            push @diag, [$neigh->tile_path (($_ + 3) % 4), $neigh],
                        [$neigh->tile_path (($_ + 1) % 4), $neigh];
         }

         for (@diag) {
            my $neigh = cf::map::find @$_
               or next;
            $neigh->load;
         }
      })->prio (2);
      # higher prio because prefetching is very important
      # as it prefetches maps that can make the server block
   },
);